| 1 | MODULE sbcssr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcssr *** |
|---|
| 4 | !! Surface module : heat and fresh water fluxes a restoring term toward observed SST/SSS |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-06 (G. Madec) Original code |
|---|
| 7 | !! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! sbc_ssr : add to sbc a restoring term toward SST/SSS climatology |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | USE sbc_oce ! surface boundary condition |
|---|
| 16 | USE phycst ! physical constants |
|---|
| 17 | USE daymod ! calendar |
|---|
| 18 | USE sbcrnf ! surface boundary condition : runoffs |
|---|
| 19 | USE fldread ! read input fields |
|---|
| 20 | USE iom ! I/O manager |
|---|
| 21 | USE in_out_manager ! I/O manager |
|---|
| 22 | USE lib_mpp ! distribued memory computing library |
|---|
| 23 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC sbc_ssr ! routine called in sbcmod |
|---|
| 29 | |
|---|
| 30 | |
|---|
| 31 | REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: erp !: evaporation damping [kg/m2/s] |
|---|
| 32 | REAL(wp), PUBLIC, DIMENSION(jpi,jpj) :: qrp !: heat flux damping [w/m2] |
|---|
| 33 | |
|---|
| 34 | ! !!* Namelist namsbc_ssr * |
|---|
| 35 | INTEGER, PUBLIC :: nn_sstr = 0 ! SST/SSS restoring indicator |
|---|
| 36 | INTEGER, PUBLIC :: nn_sssr = 0 ! SST/SSS restoring indicator |
|---|
| 37 | REAL(wp) :: rn_dqdt = -40.e0 ! restoring factor on SST and SSS |
|---|
| 38 | REAL(wp) :: rn_deds = -27.70 ! restoring factor on SST and SSS |
|---|
| 39 | LOGICAL :: ln_sssr_bnd = .false. ! flag to bound erp term |
|---|
| 40 | REAL(wp) :: rn_sssr_bnd = 0.e0 ! ABS(Max./Min.) value of erp term [mm/day] |
|---|
| 41 | |
|---|
| 42 | REAL(wp) , ALLOCATABLE, DIMENSION(:) :: buffer ! Temporary buffer for exchange |
|---|
| 43 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_sst ! structure of input SST (file informations, fields read) |
|---|
| 44 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_sss ! structure of input SSS (file informations, fields read) |
|---|
| 45 | |
|---|
| 46 | !! * Substitutions |
|---|
| 47 | # include "domzgr_substitute.h90" |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009) |
|---|
| 50 | !! $Id$ |
|---|
| 51 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 52 | !!---------------------------------------------------------------------- |
|---|
| 53 | |
|---|
| 54 | CONTAINS |
|---|
| 55 | |
|---|
| 56 | SUBROUTINE sbc_ssr( kt ) |
|---|
| 57 | !!--------------------------------------------------------------------- |
|---|
| 58 | !! *** ROUTINE sbc_ssr *** |
|---|
| 59 | !! |
|---|
| 60 | !! ** Purpose : Add to heat and/or freshwater fluxes a damping term |
|---|
| 61 | !! toward observed SST and/or SSS. |
|---|
| 62 | !! |
|---|
| 63 | !! ** Method : - Read namelist namsbc_ssr |
|---|
| 64 | !! - Read observed SST and/or SSS |
|---|
| 65 | !! - at each nscb time step |
|---|
| 66 | !! add a retroaction term on qns (nn_sstr = 1) |
|---|
| 67 | !! add a damping term on emps (nn_sssr = 1) |
|---|
| 68 | !! add a damping term on emp & emps (nn_sssr = 2) |
|---|
| 69 | !!--------------------------------------------------------------------- |
|---|
| 70 | INTEGER, INTENT(in ) :: kt ! ocean time step |
|---|
| 71 | !! |
|---|
| 72 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 73 | REAL(wp) :: zerp ! local scalar for evaporation damping |
|---|
| 74 | REAL(wp) :: zqrp ! local scalar for heat flux damping |
|---|
| 75 | REAL(wp) :: zsrp ! local scalar for unit conversion of rn_deds factor |
|---|
| 76 | REAL(wp) :: zerp_bnd ! local scalar for unit conversion of rn_epr_max factor |
|---|
| 77 | INTEGER :: ierror ! return error code |
|---|
| 78 | !! |
|---|
| 79 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 80 | TYPE(FLD_N) :: sn_sst, sn_sss ! informations about the fields to be read |
|---|
| 81 | NAMELIST/namsbc_ssr/ cn_dir, nn_sstr, nn_sssr, rn_dqdt, rn_deds, sn_sst, sn_sss, ln_sssr_bnd, rn_sssr_bnd |
|---|
| 82 | !!---------------------------------------------------------------------- |
|---|
| 83 | ! |
|---|
| 84 | ! ! -------------------- ! |
|---|
| 85 | IF( kt == nit000 ) THEN ! First call kt=nit000 ! |
|---|
| 86 | ! ! -------------------- ! |
|---|
| 87 | ! !* set file information |
|---|
| 88 | cn_dir = './' ! directory in which the model is executed |
|---|
| 89 | ! ... default values (NB: frequency positive => hours, negative => months) |
|---|
| 90 | ! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 91 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 92 | sn_sst = FLD_N( 'sst' , 24. , 'sst' , .false. , .false. , 'yearly' , '' , '' ) |
|---|
| 93 | sn_sss = FLD_N( 'sss' , -1. , 'sss' , .true. , .false. , 'yearly' , '' , '' ) |
|---|
| 94 | |
|---|
| 95 | REWIND ( numnam ) !* read in namlist namflx |
|---|
| 96 | READ( numnam, namsbc_ssr ) |
|---|
| 97 | |
|---|
| 98 | IF(lwp) THEN !* control print |
|---|
| 99 | WRITE(numout,*) |
|---|
| 100 | WRITE(numout,*) 'sbc_ssr : SST and/or SSS damping term ' |
|---|
| 101 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 102 | WRITE(numout,*) ' Namelist namsbc_ssr :' |
|---|
| 103 | WRITE(numout,*) ' SST restoring term (Yes=1) nn_sstr = ', nn_sstr |
|---|
| 104 | WRITE(numout,*) ' SSS damping term (Yes=1, salt flux) nn_sssr = ', nn_sssr |
|---|
| 105 | WRITE(numout,*) ' (Yes=2, volume flux) ' |
|---|
| 106 | WRITE(numout,*) ' dQ/dT (restoring magnitude on SST) rn_dqdt = ', rn_dqdt, ' W/m2/K' |
|---|
| 107 | WRITE(numout,*) ' dE/dS (restoring magnitude on SST) rn_deds = ', rn_deds, ' mm/day' |
|---|
| 108 | WRITE(numout,*) ' flag to bound erp term ln_sssr_bnd = ', ln_sssr_bnd |
|---|
| 109 | WRITE(numout,*) ' ABS(Max./Min.) erp threshold rn_sssr_bnd = ', rn_sssr_bnd, ' mm/day' |
|---|
| 110 | ENDIF |
|---|
| 111 | |
|---|
| 112 | IF( nn_sstr == 1 ) THEN !* set sf_sst structure |
|---|
| 113 | ! |
|---|
| 114 | ALLOCATE( sf_sst(1), STAT=ierror ) |
|---|
| 115 | IF( ierror > 0 ) THEN |
|---|
| 116 | CALL ctl_stop( 'sbc_ssr: unable to allocate sf_sst structure' ) ; RETURN |
|---|
| 117 | ENDIF |
|---|
| 118 | ALLOCATE( sf_sst(1)%fnow(jpi,jpj) ) |
|---|
| 119 | ALLOCATE( sf_sst(1)%fdta(jpi,jpj,2) ) |
|---|
| 120 | ! |
|---|
| 121 | ! fill sf_sst with sn_sst and control print |
|---|
| 122 | CALL fld_fill( sf_sst, (/ sn_sst /), cn_dir, 'sbc_ssr', 'SST restoring term toward SST data', 'namsbc_ssr' ) |
|---|
| 123 | ENDIF |
|---|
| 124 | ! |
|---|
| 125 | IF( nn_sssr >= 1 ) THEN ! set sf_sss structure |
|---|
| 126 | ! |
|---|
| 127 | ALLOCATE( sf_sss(1), STAT=ierror ) |
|---|
| 128 | IF( ierror > 0 ) THEN |
|---|
| 129 | CALL ctl_stop( 'sbc_ssr: unable to allocate sf_sss structure' ) ; RETURN |
|---|
| 130 | ENDIF |
|---|
| 131 | ALLOCATE( sf_sss(1)%fnow(jpi,jpj) ) |
|---|
| 132 | ALLOCATE( sf_sss(1)%fdta(jpi,jpj,2) ) |
|---|
| 133 | ! |
|---|
| 134 | ! fill sf_sss with sn_sss and control print |
|---|
| 135 | CALL fld_fill( sf_sss, (/ sn_sss /), cn_dir, 'sbc_ssr', 'SSS restoring term toward SSS data', 'namsbc_ssr' ) |
|---|
| 136 | ENDIF |
|---|
| 137 | ! |
|---|
| 138 | ! Initialize qrp and erp if no restoring |
|---|
| 139 | IF( nn_sstr /= 1 ) qrp(:,:) = 0.e0 |
|---|
| 140 | IF( nn_sssr /= 1 .OR. nn_sssr /= 2 ) erp(:,:) = 0.e0 |
|---|
| 141 | ENDIF |
|---|
| 142 | |
|---|
| 143 | IF( nn_sstr + nn_sssr /= 0 ) THEN |
|---|
| 144 | ! |
|---|
| 145 | IF( nn_sstr == 1) CALL fld_read( kt, nn_fsbc, sf_sst ) ! Read SST data and provides it at kt |
|---|
| 146 | IF( nn_sssr >= 1) CALL fld_read( kt, nn_fsbc, sf_sss ) ! Read SSS data and provides it at kt |
|---|
| 147 | ! |
|---|
| 148 | ! ! ========================= ! |
|---|
| 149 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN ! Add restoring term ! |
|---|
| 150 | ! ! ========================= ! |
|---|
| 151 | ! |
|---|
| 152 | IF( nn_sstr == 1 ) THEN !* Temperature restoring term |
|---|
| 153 | !CDIR COLLAPSE |
|---|
| 154 | DO jj = 1, jpj |
|---|
| 155 | DO ji = 1, jpi |
|---|
| 156 | zqrp = rn_dqdt * ( sst_m(ji,jj) - sf_sst(1)%fnow(ji,jj) ) |
|---|
| 157 | qns(ji,jj) = qns(ji,jj) + zqrp |
|---|
| 158 | qrp(ji,jj) = zqrp |
|---|
| 159 | END DO |
|---|
| 160 | END DO |
|---|
| 161 | CALL iom_put( "qrp", qrp ) ! heat flux damping |
|---|
| 162 | ENDIF |
|---|
| 163 | ! |
|---|
| 164 | IF( nn_sssr == 1 ) THEN !* Salinity damping term (salt flux, emps only) |
|---|
| 165 | zsrp = rn_deds / rday ! from [mm/day] to [kg/m2/s] |
|---|
| 166 | !CDIR COLLAPSE |
|---|
| 167 | DO jj = 1, jpj |
|---|
| 168 | DO ji = 1, jpi |
|---|
| 169 | zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) ) & ! No damping in vicinity of river mouths |
|---|
| 170 | & * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj) ) & |
|---|
| 171 | & / ( sss_m(ji,jj) + 1.e-20 ) |
|---|
| 172 | emps(ji,jj) = emps(ji,jj) + zerp |
|---|
| 173 | erp( ji,jj) = zerp |
|---|
| 174 | END DO |
|---|
| 175 | END DO |
|---|
| 176 | CALL iom_put( "erp", erp ) ! freshwater flux damping |
|---|
| 177 | ! |
|---|
| 178 | ELSEIF( nn_sssr == 2 ) THEN !* Salinity damping term (volume flux, emp and emps) |
|---|
| 179 | zsrp = rn_deds / rday ! from [mm/day] to [kg/m2/s] |
|---|
| 180 | zerp_bnd = rn_sssr_bnd / rday ! - - |
|---|
| 181 | !CDIR COLLAPSE |
|---|
| 182 | DO jj = 1, jpj |
|---|
| 183 | DO ji = 1, jpi |
|---|
| 184 | zerp = zsrp * ( 1. - 2.*rnfmsk(ji,jj) ) & ! No damping in vicinity of river mouths |
|---|
| 185 | & * ( sss_m(ji,jj) - sf_sss(1)%fnow(ji,jj) ) & |
|---|
| 186 | & / ( sss_m(ji,jj) + 1.e-20 ) |
|---|
| 187 | IF( ln_sssr_bnd ) zerp = SIGN( 1., zerp ) * MIN( zerp_bnd, ABS(zerp) ) |
|---|
| 188 | emp (ji,jj) = emp (ji,jj) + zerp |
|---|
| 189 | emps(ji,jj) = emps(ji,jj) + zerp |
|---|
| 190 | erp (ji,jj) = zerp |
|---|
| 191 | END DO |
|---|
| 192 | END DO |
|---|
| 193 | CALL iom_put( "erp", erp ) ! freshwater flux damping |
|---|
| 194 | ENDIF |
|---|
| 195 | ! |
|---|
| 196 | ENDIF |
|---|
| 197 | ! |
|---|
| 198 | ENDIF |
|---|
| 199 | ! |
|---|
| 200 | END SUBROUTINE sbc_ssr |
|---|
| 201 | |
|---|
| 202 | !!====================================================================== |
|---|
| 203 | END MODULE sbcssr |
|---|
