New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
tau_forced_monthly.h90 in trunk/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMO/OPA_SRC/SBC/tau_forced_monthly.h90 @ 359

Last change on this file since 359 was 319, checked in by opalod, 19 years ago

nemo_v1_bugfix_012:RB: initialize itime before calling flinopen
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 8.9 KB
Line 
1   !!----------------------------------------------------------------------
2   !!                ***  tau_forced_monthly.h90  ***
3   !!----------------------------------------------------------------------
4
5   !!----------------------------------------------------------------------
6   !!   tau     : update the surface wind stress - monthly fields in NetCDF
7   !!             file.
8   !!----------------------------------------------------------------------
9   !! * local modules variables
10   INTEGER ::   &
11      numtau,   &  ! logical unit for the i-component of the wind data
12      numtav,   &  ! logical unit for the j-component of the wind data
13      ntau1, ntau2  ! index of the first and second record used
14
15   CHARACTER (len=34) ::   &      !!! * monthly climatology/interanual fields
16      cl_taux = 'taux_1m.nc',  & ! generic name of the i-component monthly NetCDF file
17      cl_tauy = 'tauy_1m.nc'     ! generic name of the j-component monthly NetCDF file
18
19   REAL(wp), DIMENSION(jpi,jpj,2) ::   &
20      taux_dta,    &  ! i- and j-components of the surface stress (Pascal)
21      tauy_dta        ! at 2 consecutive months in the (i,j) referential
22   !!----------------------------------------------------------------------
23   !!   OPA 9.0 , LOCEAN-IPSL (2005)
24   !! $Header$
25   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
26   !!----------------------------------------------------------------------
27
28CONTAINS
29
30   SUBROUTINE tau( kt )
31      !!---------------------------------------------------------------------
32      !!                  ***  ROUTINE tau  ***
33      !!             
34      !! ** Purpose :   provide to the ocean the stress at each time step
35      !!
36      !! ** Method  : - Read the 2 monthly surface stress components in NetCDF
37      !!      file at 2 consecutive time-steps
38      !!        They are given in the (i,j) referential
39      !!        The i-component is given at U-point (INTERP package)
40      !!        The j-component is given at V-point (INTERP package)
41      !!              - a linear time-interpolation is performed to provide the
42      !!      stress at the kt time-step.
43      !!
44      !!    CAUTION: never mask the surface stress field !
45      !!
46      !! ** Action :
47      !!        update at each time-step the two components of the surface
48      !!      stress in both (i,j) and geographical referencial
49      !!
50      !! History :
51      !!   4.0  !  91-03  (G. Madec)  Original code
52      !!   6.0  !  92-07  (M. Imbard)
53      !!   8.1  !  00-08  (D. Ludicone) adapted to ERS-NCEP
54      !!   8.5  !  02-11  (G. Madec)  F90: Free form and module
55      !!        !                     daily/monthly, forced/coupled form
56      !!----------------------------------------------------------------------
57      !! * Modules used
58      USE ioipsl       ! NetCDF library
59      !! * Arguments
60      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
61
62      !! * Local declarations
63      INTEGER, PARAMETER ::   jpmonth = 12
64      INTEGER ::   &
65         imois, iman, itime,   &
66         i15,   &
67         ipi, ipj, ipk
68      INTEGER, DIMENSION(jpmonth) ::   istep
69      REAL(wp) , DIMENSION(jpi,jpj)::  &
70         zlon  , &
71         zlat
72      REAL(wp) , DIMENSION(jpk)::  &
73         zlev
74      REAL(wp) ::   &
75         zsecond,   & ! ???
76         zdate0,    & ! ???
77         zxy          ! coefficient of the linear time interpolation
78      !!---------------------------------------------------------------------
79
80      ! -------------- !
81      ! Initialization !
82      ! -------------- !
83     
84      ! iman=number of dates in data file (12 for a year of monthly values)
85      iman  = INT( raamo )
86      itime = jpmonth
87      ipi   = jpiglo
88      ipj   = jpjglo
89      ipk   = jpk
90
91      i15 = INT( 2*FLOAT( nday ) / ( FLOAT( nobis(nmonth) ) + 0.5 ) )
92
93      imois = nmonth + i15 - 1
94      IF( imois == 0 ) imois = iman
95
96
97      ! -------------------- !
98      ! First call kt=nit000 !
99      ! -------------------- !
100
101      IF( kt == nit000 ) THEN
102         ntau1 = 0
103         IF(lwp) WRITE(numout,*)
104         IF(lwp) WRITE(numout,*) ' tau    : MONTHLY climatological wind stress (NetCDF files)'
105         IF(lwp) WRITE(numout,*) ' ~~~    '
106         
107         ! title, dimensions and tests
108         
109         CALL flinopen( cl_taux, mig(1), nlci, mjg(1), nlcj,   &   ! taux on U-grid
110                        .FALSE., ipi   , ipj, ipk   ,        &
111                        zlon , zlat  , zlev   , itime,       &
112                        istep, zdate0, zsecond, numtau )
113         
114         IF( itime /= jpmonth ) THEN
115            IF(lwp) WRITE(numout,cform_err)
116            IF(lwp) WRITE(numout,*) '   problem with time coordinates in file ', cl_taux
117            IF(lwp) WRITE(numout,*) '   itime = ', itime,' jpmonth = ',jpmonth
118            nstop = nstop + 1
119         ENDIF
120         IF( ipi /= jpidta .AND. ipj /= jpjdta .AND. ipk /= 1 ) THEN
121            IF(lwp) WRITE(numout,cform_err)
122            IF(lwp) WRITE(numout,*) '   problem with size read in file ', cl_taux
123            IF(lwp) WRITE(numout,*) '   ipi = ',ipi,' jpidta = ',jpidta
124            IF(lwp) WRITE(numout,*) '   ipj = ',ipj,' jpjdta = ',jpjdta
125            IF(lwp) WRITE(numout,*) '   ipk = ',ipk,' must be 1'
126            nstop = nstop + 1
127         ENDIF
128
129         CALL flinopen( cl_tauy, mig(1), nlci, mjg(1), nlcj,   &   ! tauy on V-grid
130                        .FALSE., ipi   , ipj, ipk   ,        &
131                        zlon , zlat  , zlev   , itime,       &
132                        istep, zdate0, zsecond, numtav )
133
134         IF( itime /= jpmonth ) THEN         
135            IF(lwp) WRITE(numout,cform_err)
136            IF(lwp) WRITE(numout,*) '   problem with time coordinates in file ', cl_tauy
137            IF(lwp) WRITE(numout,*) '   itime = ', itime,' jpmonth = ',jpmonth
138            nstop = nstop + 1
139         ENDIF
140         IF( ipi /= jpidta .AND. ipj /= jpjdta .AND. ipk /= 1) THEN
141            IF(lwp) WRITE(numout,cform_err)
142            IF(lwp) WRITE(numout,*) '   problem with size read in file ', cl_tauy
143            IF(lwp) WRITE(numout,*) '   ipi = ',ipi,' jpidta = ',jpidta
144            IF(lwp) WRITE(numout,*) '   ipj = ',ipj,' jpjdta = ',jpjdta
145            IF(lwp) WRITE(numout,*) '   ipk = ',ipk,' must be 1'
146            nstop = nstop + 1
147         ENDIF
148      ENDIF
149     
150      ! ----------------- !
151      ! Read monthly file !
152      ! ----------------- !
153
154      IF( kt == nit000 .OR. imois /= ntau1 ) THEN
155
156         ! Calendar computation
157         ntau1 = imois          ! index of the first record
158         ntau2 = ntau1 + 1      ! index of the last  record
159         ntau1 = MOD( ntau1, iman )
160         IF( ntau1 == 0 ) ntau1 = iman
161         ntau2 = MOD( ntau2, iman )
162         IF( ntau2 == 0 ) ntau2 = iman
163         IF(lwp) WRITE(numout,*) 'first month used ntau1 = ', ntau1
164         IF(lwp) WRITE(numout,*) 'last  month used ntau2 = ', ntau2
165
166         ! Read the corresponding 2 monthly stress data
167         ! ntau1
168         CALL flinget( numtau,'sozotaux',    &               ! i-component at U-pt
169            jpidta,jpjdta,1,jpmonth,ntau1,   &
170            ntau1,mig(1),nlci,mjg(1),nlcj,taux_dta(1:nlci,1:nlcj,1) )
171         CALL flinget( numtav,'sometauy',    &               ! j-component at V-pt
172            jpidta,jpjdta,1,jpmonth,ntau1,   &
173            ntau1,mig(1),nlci,mjg(1),nlcj,tauy_dta(1:nlci,1:nlcj,1) )
174         ! ntau2
175         CALL flinget( numtau,'sozotaux',    &               ! i-component at U-pt
176            jpidta,jpjdta,1,jpmonth,ntau2,   &
177            ntau2,mig(1),nlci,mjg(1),nlcj,taux_dta(1:nlci,1:nlcj,2) )
178         CALL flinget( numtav,'sometauy',    &               ! j-component at V-pt
179            jpidta,jpjdta,1,jpmonth,ntau2,   &
180            ntau2,mig(1),nlci,mjg(1),nlcj,tauy_dta(1:nlci,1:nlcj,2) )
181         
182         IF(lwp .AND. nitend-nit000 <= 100 ) THEN
183            WRITE(numout,*)
184            WRITE(numout,*) ' monthly stress read'
185            WRITE(numout,*)
186            WRITE(numout,*) ' month: ', ntau1, '  taux: 1 multiply by ', 1.
187            CALL prihre( taux_dta(1,1,1), jpi, jpj, 1, jpi, 20, 1, jpj, 10, 1., numout )
188            WRITE(numout,*)
189            WRITE(numout,*) ' month: ', ntau2, '  tauy: 2 multiply by ', 1.
190            CALL prihre( tauy_dta(1,1,2), jpi, jpj, 1, jpi, 20, 1, jpj, 10, 1., numout )
191         ENDIF
192
193         CALL FLUSH(numout)
194      ENDIF
195
196      ! ------------------------------- !
197      ! linear time interpolation at kt !
198      ! ------------------------------- !
199
200      ! zxy : coefficient for linear interpolation in time
201
202      zxy = FLOAT( nday ) / FLOAT( nobis(ntau1) ) + 0.5 - i15
203
204      taux(:,:) = (1.-zxy) * taux_dta(:,:,1) + zxy * taux_dta(:,:,2)
205      tauy(:,:) = (1.-zxy) * tauy_dta(:,:,1) + zxy * tauy_dta(:,:,2)
206
207      ! Save components
208
209      tauxg(:,:) = taux(:,:)
210      tauyg(:,:) = tauy(:,:)
211
212      CALL FLUSH(numout)
213
214      ! ------------------- !
215      ! Last call kt=nitend !
216      ! ------------------- !
217
218      ! Closing of the 2 files (required in mpp)
219      IF( kt == nitend ) THEN
220          CALL flinclo(numtau)
221          CALL flinclo(numtav)
222      ENDIF
223
224   END SUBROUTINE tau
Note: See TracBrowser for help on using the repository browser.