New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 136

Last change on this file since 136 was 132, checked in by opalod, 20 years ago

CT : UPDATE082 : Finalization of the poleward transport diagnostics
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 18.7 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean active tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6
7   !!----------------------------------------------------------------------
8   !!   tra_adv_tvd  : update the tracer trend with the horizontal
9   !!                  and vertical advection trends using a TVD scheme
10   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
11   !!                  algorithm
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE trdtra_oce     ! ocean active tracer trends
17   USE in_out_manager  ! I/O manager
18   USE dynspg_fsc      ! surface pressure gradient
19   USE dynspg_fsc_atsk ! autotasked surface pressure gradient
20   USE trabbl          ! Advective term of BBL
21   USE lib_mpp
22   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
23   USE diaptr          ! poleward transport diagnostics
24
25
26   IMPLICIT NONE
27   PRIVATE
28
29   !! * Accessibility
30   PUBLIC tra_adv_tvd    ! routine called by step.F90
31
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !!   OPA 9.0 , LODYC-IPSL (2003)
37   !!----------------------------------------------------------------------
38
39CONTAINS
40
41   SUBROUTINE tra_adv_tvd( kt )
42      !!----------------------------------------------------------------------
43      !!                  ***  ROUTINE tra_adv_tvd  ***
44      !!
45      !! **  Purpose :   Compute the now trend due to total advection of
46      !!       tracers and add it to the general trend of tracer equations
47      !!
48      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
49      !!       corrected flux (monotonic correction)
50      !!       note: - this advection scheme needs a leap-frog time scheme
51      !!
52      !! ** Action : - update (ta,sa) with the now advective tracer trends
53      !!             - save the trends in (ttrdh,strdh) ('key_trdtra')
54      !!
55      !! History :
56      !!        !  95-12  (L. Mortier)  Original code
57      !!        !  00-01  (H. Loukos)  adapted to ORCA
58      !!        !  00-10  (MA Foujols E.Kestenare)  include file not routine
59      !!        !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
60      !!        !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
61      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
62      !!   9.0  !  04-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
63      !!----------------------------------------------------------------------
64      !! * Modules used
65#if defined key_trabbl_adv
66      USE oce                , zun => ua,  &  ! use ua as workspace
67         &                     zvn => va      ! use va as workspace
68      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
69#else
70      USE oce                , zun => un,  &  ! When no bbl, zun == un
71                               zvn => vn,  &  !             zvn == vn
72                               zwn => wn      !             zwn == wn
73#endif
74      !! * Arguments
75      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
76
77      !! * Local declarations
78      INTEGER  ::   ji, jj, jk              ! dummy loop indices
79      REAL(wp) ::   zta, zsa                ! temporary scalar
80      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   &
81         zti, ztu, ztv, ztw,             &  ! temporary workspace
82         zsi, zsu, zsv, zsw                 !    "           "
83      REAL(wp) ::   &
84         z2dtt, zbtr, zeu, zev, zew, z2, &  ! temporary scalar
85         zfp_ui, zfp_vj, zfp_wk,         &  !    "         "
86         zfm_ui, zfm_vj, zfm_wk             !    "         "
87      !!----------------------------------------------------------------------
88
89      IF( kt == nit000 .AND. lwp ) THEN
90         WRITE(numout,*)
91         WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme'
92         WRITE(numout,*) '~~~~~~~~~~~'
93      ENDIF
94
95      IF( neuler == 0 .AND. kt == nit000 ) THEN
96         z2=1.
97      ELSE
98         z2=2.
99      ENDIF
100
101#if defined key_trabbl_adv
102
103      ! Advective Bottom boundary layer: add the velocity
104      ! -------------------------------------------------
105      zun(:,:,:) = un (:,:,:) - u_bbl(:,:,:)
106      zvn(:,:,:) = vn (:,:,:) - v_bbl(:,:,:)
107      zwn(:,:,:) = wn (:,:,:) + w_bbl(:,:,:)
108#endif
109
110      ! 1. Bottom value : flux set to zero
111      ! ---------------
112      ztu(:,:,jpk) = 0.e0   ;   zsu(:,:,jpk) = 0.e0
113      ztv(:,:,jpk) = 0.e0   ;   zsv(:,:,jpk) = 0.e0
114      ztw(:,:,jpk) = 0.e0   ;   zsw(:,:,jpk) = 0.e0
115      zti(:,:,jpk) = 0.e0   ;   zsi(:,:,jpk) = 0.e0
116
117
118      ! 2. upstream advection with initial mass fluxes & intermediate update
119      ! --------------------------------------------------------------------
120      ! upstream tracer flux in the i and j direction
121      DO jk = 1, jpkm1
122         DO jj = 1, jpjm1
123            DO ji = 1, fs_jpim1   ! vector opt.
124               zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
125               zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
126               ! upstream scheme
127               zfp_ui = zeu + ABS( zeu )
128               zfm_ui = zeu - ABS( zeu )
129               zfp_vj = zev + ABS( zev )
130               zfm_vj = zev - ABS( zev )
131               ztu(ji,jj,jk) = zfp_ui * tb(ji,jj,jk) + zfm_ui * tb(ji+1,jj  ,jk)
132               ztv(ji,jj,jk) = zfp_vj * tb(ji,jj,jk) + zfm_vj * tb(ji  ,jj+1,jk)
133               zsu(ji,jj,jk) = zfp_ui * sb(ji,jj,jk) + zfm_ui * sb(ji+1,jj  ,jk)
134               zsv(ji,jj,jk) = zfp_vj * sb(ji,jj,jk) + zfm_vj * sb(ji  ,jj+1,jk)
135            END DO
136         END DO
137      END DO
138
139      ! upstream tracer flux in the k direction
140      ! Surface value
141      IF( lk_dynspg_fsc .OR. lk_dynspg_fsc_tsk ) THEN   ! free surface-constant volume
142         DO jj = 1, jpj
143            DO ji = 1, jpi
144               zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1)
145               ztw(ji,jj,1) = zew * tb(ji,jj,1)
146               zsw(ji,jj,1) = zew * sb(ji,jj,1)
147            END DO
148         END DO
149      ELSE                                      ! rigid lid : flux set to zero
150         ztw(:,:,1) = 0.e0
151         zsw(:,:,1) = 0.e0
152      ENDIF
153
154      ! Interior value
155      DO jk = 2, jpkm1
156         DO jj = 1, jpj
157            DO ji = 1, jpi
158               zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
159               zfp_wk = zew + ABS( zew )
160               zfm_wk = zew - ABS( zew )
161               ztw(ji,jj,jk) = zfp_wk * tb(ji,jj,jk) + zfm_wk * tb(ji,jj,jk-1)
162               zsw(ji,jj,jk) = zfp_wk * sb(ji,jj,jk) + zfm_wk * sb(ji,jj,jk-1)
163            END DO
164         END DO
165      END DO
166
167      ! total advective trend
168      DO jk = 1, jpkm1
169         DO jj = 2, jpjm1
170            DO ji = fs_2, fs_jpim1   ! vector opt.
171               zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
172               zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
173                  &              + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
174                  &              + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
175               zsi(ji,jj,jk) = - ( zsu(ji,jj,jk) - zsu(ji-1,jj  ,jk  )   &
176                  &              + zsv(ji,jj,jk) - zsv(ji  ,jj-1,jk  )   &
177                  &              + zsw(ji,jj,jk) - zsw(ji  ,jj  ,jk+1) ) * zbtr
178            END DO
179         END DO
180      END DO
181     
182
183      ! update and guess with monotonic sheme
184      DO jk = 1, jpkm1
185         z2dtt = z2 * rdttra(jk)
186         DO jj = 2, jpjm1
187            DO ji = fs_2, fs_jpim1   ! vector opt.
188               ta(ji,jj,jk) =  ta(ji,jj,jk) + zti(ji,jj,jk)
189               sa(ji,jj,jk) =  sa(ji,jj,jk) + zsi(ji,jj,jk)
190               zti (ji,jj,jk) = ( tb(ji,jj,jk) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk)
191               zsi (ji,jj,jk) = ( sb(ji,jj,jk) + z2dtt * zsi(ji,jj,jk) ) * tmask(ji,jj,jk)
192            END DO
193         END DO
194      END DO
195
196      ! Lateral boundary conditions on zti, zsi   (unchanged sign)
197      CALL lbc_lnk( zti, 'T', 1. )
198      CALL lbc_lnk( zsi, 'T', 1. )
199
200
201      ! 3. antidiffusive flux : high order minus low order
202      ! --------------------------------------------------
203      ! antidiffusive flux on i and j
204      DO jk = 1, jpkm1
205         DO jj = 1, jpjm1
206            DO ji = 1, fs_jpim1   ! vector opt.
207               zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
208               zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
209               ztu(ji,jj,jk) = zeu * ( tn(ji,jj,jk) + tn(ji+1,jj,jk) ) - ztu(ji,jj,jk)
210               zsu(ji,jj,jk) = zeu * ( sn(ji,jj,jk) + sn(ji+1,jj,jk) ) - zsu(ji,jj,jk)
211               ztv(ji,jj,jk) = zev * ( tn(ji,jj,jk) + tn(ji,jj+1,jk) ) - ztv(ji,jj,jk)
212               zsv(ji,jj,jk) = zev * ( sn(ji,jj,jk) + sn(ji,jj+1,jk) ) - zsv(ji,jj,jk)
213            END DO
214         END DO
215      END DO
216     
217      ! antidiffusive flux on k
218      ! Surface value
219      ztw(:,:,1) = 0.
220      zsw(:,:,1) = 0.
221
222      ! Interior value
223      DO jk = 2, jpkm1
224         DO jj = 1, jpj
225            DO ji = 1, jpi
226               zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
227               ztw(ji,jj,jk) = zew * ( tn(ji,jj,jk) + tn(ji,jj,jk-1) ) - ztw(ji,jj,jk)
228               zsw(ji,jj,jk) = zew * ( sn(ji,jj,jk) + sn(ji,jj,jk-1) ) - zsw(ji,jj,jk)
229            END DO
230         END DO
231      END DO
232
233      ! Lateral bondary conditions
234      CALL lbc_lnk( ztu, 'U', -1. )   ;   CALL lbc_lnk( zsu, 'U', -1. )
235      CALL lbc_lnk( ztv, 'V', -1. )   ;   CALL lbc_lnk( zsv, 'V', -1. )
236      CALL lbc_lnk( ztw, 'W',  1. )   ;   CALL lbc_lnk( zsw, 'W',  1. )
237
238      ! 4. monotonicity algorithm
239      ! -------------------------
240      CALL nonosc( tb, ztu, ztv, ztw, zti, z2 )
241      CALL nonosc( sb, zsu, zsv, zsw, zsi, z2 )
242
243
244      ! 5. final trend with corrected fluxes
245      ! ------------------------------------
246      DO jk = 1, jpkm1
247         DO jj = 2, jpjm1
248            DO ji = fs_2, fs_jpim1   ! vector opt.
249               zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
250               ta(ji,jj,jk) = ta(ji,jj,jk)   &
251                  &         - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
252                  &           + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
253                  &           + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
254               sa(ji,jj,jk) = sa(ji,jj,jk)   &
255                  &         - ( zsu(ji,jj,jk) - zsu(ji-1,jj  ,jk  )   &
256                  &           + zsv(ji,jj,jk) - zsv(ji  ,jj-1,jk  )   &
257                  &           + zsw(ji,jj,jk) - zsw(ji  ,jj  ,jk+1) ) * zbtr
258            END DO
259         END DO
260      END DO
261
262      IF(l_ctl) THEN
263         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
264         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
265         WRITE(numout,*) ' zad  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl, ' tvd'
266         t_ctl = zta   ;   s_ctl = zsa
267      ENDIF
268
269      ! "zonal" mean advective heat and salt transport
270      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
271         pht_adv(:) = ptr_vj( ztv(:,:,:) )
272         pst_adv(:) = ptr_vj( zsv(:,:,:) )
273      ENDIF
274
275   END SUBROUTINE tra_adv_tvd
276
277
278   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
279      !!---------------------------------------------------------------------
280      !!                    ***  ROUTINE nonosc  ***
281      !!     
282      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
283      !!       scheme and the before field by a nonoscillatory algorithm
284      !!
285      !! **  Method  :   ... ???
286      !!       warning : pbef and paft must be masked, but the boundaries
287      !!       conditions on the fluxes are not necessary zalezak (1979)
288      !!       drange (1995) multi-dimensional forward-in-time and upstream-
289      !!       in-space based differencing for fluid
290      !!
291      !! History :
292      !!        !  97-04  (L. Mortier) Original code
293      !!        !  00-02  (H. Loukos)  rewritting for opa8
294      !!        !  00-10  (M.A Foujols, E. Kestenare)  lateral b.c.
295      !!        !  01-03  (E. Kestenare)  add key_passivetrc
296      !!        !  01-07  (E. Durand G. Madec)  adapted for T & S
297      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
298      !!----------------------------------------------------------------------
299      !! * Arguments
300      REAL(wp), INTENT( in ) ::   &
301         prdt                               ! ???
302      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
303         pbef,                            & ! before field
304         paft,                            & ! after field
305         paa,                             & ! monotonic flux in the i direction
306         pbb,                             & ! monotonic flux in the j direction
307         pcc                                ! monotonic flux in the k direction
308
309      !! * Local declarations
310      INTEGER ::   ji, jj, jk               ! dummy loop indices
311      INTEGER ::   ikm1
312      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
313      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
314      !!----------------------------------------------------------------------
315
316      zbig = 1.e+40
317      zrtrn = 1.e-15
318
319      ! Search local extrema
320      ! --------------------
321      ! large negative value (-zbig) inside land
322      WHERE( tmask(:,:,:) == 0. )
323         pbef(:,:,:) = -zbig
324         paft(:,:,:) = -zbig
325      ENDWHERE 
326      ! search maximum in neighbourhood
327      DO jk = 1, jpkm1
328         ikm1 = MAX(jk-1,1)
329         DO jj = 2, jpjm1
330            DO ji = fs_2, fs_jpim1   ! vector opt.
331               zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
332                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
333                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
334                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
335                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
336                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
337                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
338            END DO
339         END DO
340      END DO
341      ! large positive value (+zbig) inside land
342      WHERE( tmask(:,:,:) == 0. )
343         pbef(:,:,:) = +zbig
344         paft(:,:,:) = +zbig
345      ENDWHERE
346      ! search minimum in neighbourhood
347      DO jk = 1, jpkm1
348         ikm1 = MAX(jk-1,1)
349         DO jj = 2, jpjm1
350            DO ji = fs_2, fs_jpim1   ! vector opt.
351               zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
352                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
353                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
354                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
355                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
356                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
357                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
358            END DO
359         END DO
360      END DO
361
362      ! restore masked values to zero
363      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
364      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
365 
366
367      ! 2. Positive and negative part of fluxes and beta terms
368      ! ------------------------------------------------------
369
370      DO jk = 1, jpkm1
371         z2dtt = prdt * rdttra(jk)
372         DO jj = 2, jpjm1
373            DO ji = fs_2, fs_jpim1   ! vector opt.
374               ! positive & negative part of the flux
375               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
376                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
377                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
378               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
379                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
380                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
381               ! up & down beta terms
382               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
383               zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
384               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
385            END DO
386         END DO
387      END DO
388
389      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
390      CALL lbc_lnk( zbetup, 'T', 1. )
391      CALL lbc_lnk( zbetdo, 'T', 1. )
392
393
394      ! 3. monotonic flux in the i direction, i.e. paa
395      ! ----------------------------------------------
396      DO jk = 1, jpkm1
397         DO jj = 2, jpjm1
398            DO ji = fs_2, fs_jpim1   ! vector opt.
399               zc = paa(ji,jj,jk)
400               IF( zc >= 0. ) THEN
401                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
402                  paa(ji,jj,jk) = za * zc
403               ELSE
404                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
405                  paa(ji,jj,jk) = zb * zc
406               ENDIF
407            END DO
408         END DO
409      END DO
410
411      ! lateral boundary condition on paa   (changed sign)
412      CALL lbc_lnk( paa, 'U', -1. )
413
414
415      ! 4. monotonic flux in the j direction, i.e. pbb
416      ! ----------------------------------------------
417      DO jk = 1, jpkm1
418         DO jj = 2, jpjm1
419            DO ji = fs_2, fs_jpim1   ! vector opt.
420               zc = pbb(ji,jj,jk)
421               IF( zc >= 0. ) THEN
422                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
423                  pbb(ji,jj,jk) = za * zc
424               ELSE
425                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
426                  pbb(ji,jj,jk) = zb * zc
427               ENDIF
428            END DO
429         END DO
430      END DO
431
432      ! lateral boundary condition on pbb   (changed sign)
433      CALL lbc_lnk( pbb, 'V', -1. )
434
435
436      ! monotonic flux in the k direction, i.e. pcc
437      ! -------------------------------------------
438      DO jk = 2, jpkm1
439         DO jj = 2, jpjm1
440            DO ji = fs_2, fs_jpim1   ! vector opt.
441               zc = pcc(ji,jj,jk)
442               IF( zc >= 0. ) THEN
443                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
444                  pcc(ji,jj,jk) = za * zc
445               ELSE
446                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
447                  pcc(ji,jj,jk) = zb * zc
448               ENDIF
449            END DO
450         END DO
451      END DO
452
453      ! lateral boundary condition on pcc   (unchanged sign)
454      CALL lbc_lnk( pcc, 'W', 1. )
455
456   END SUBROUTINE nonosc
457
458   !!======================================================================
459END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.