New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 313

Last change on this file since 313 was 282, checked in by opalod, 19 years ago

nemo_v1_compil_002 : CT : move the zwn(:,:,:) array declaration which depends on the cpp key key_trabbl_adv
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 22.0 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean active tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6
7   !!----------------------------------------------------------------------
8   !!   tra_adv_tvd  : update the tracer trend with the horizontal
9   !!                  and vertical advection trends using a TVD scheme
10   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
11   !!                  algorithm
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE trdmod          ! ocean active tracers trends
17   USE trdmod_oce      ! ocean variables trends
18   USE in_out_manager  ! I/O manager
19   USE dynspg_fsc      ! surface pressure gradient
20   USE dynspg_fsc_atsk ! autotasked surface pressure gradient
21   USE trabbl          ! Advective term of BBL
22   USE lib_mpp
23   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
24   USE diaptr          ! poleward transport diagnostics
25   USE prtctl          ! Print control
26
27
28   IMPLICIT NONE
29   PRIVATE
30
31   !! * Accessibility
32   PUBLIC tra_adv_tvd    ! routine called by step.F90
33
34   !! * Substitutions
35#  include "domzgr_substitute.h90"
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !!   OPA 9.0 , LOCEAN-IPSL (2005)
39   !! $Header$
40   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE tra_adv_tvd( kt )
46      !!----------------------------------------------------------------------
47      !!                  ***  ROUTINE tra_adv_tvd  ***
48      !!
49      !! **  Purpose :   Compute the now trend due to total advection of
50      !!       tracers and add it to the general trend of tracer equations
51      !!
52      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
53      !!       corrected flux (monotonic correction)
54      !!       note: - this advection scheme needs a leap-frog time scheme
55      !!
56      !! ** Action : - update (ta,sa) with the now advective tracer trends
57      !!             - save the trends in (ttrdh,strdh) ('key_trdtra')
58      !!
59      !! History :
60      !!        !  95-12  (L. Mortier)  Original code
61      !!        !  00-01  (H. Loukos)  adapted to ORCA
62      !!        !  00-10  (MA Foujols E.Kestenare)  include file not routine
63      !!        !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
64      !!        !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
65      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
66      !!   9.0  !  04-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
67      !!   9.0  !  08-04  (S. Cravatte) add the i-, j- & k- trends computation
68      !!----------------------------------------------------------------------
69      !! * Modules used
70      USE trdmod_oce         , ztay => tladj,  &  ! use tladj latter
71         &                     zsay => sladj,  &  ! use sladj latter
72         &                     ztaz => tladi,  &  ! use ua as workspace
73         &                     zsaz => sladi      ! use ua as workspace
74#if defined key_trabbl_adv
75      USE oce                , zun => ua,  &  ! use ua as workspace
76         &                     zvn => va      ! use va as workspace
77
78      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
79#else
80      USE oce                , zun => un,  &  ! When no bbl, zun == un
81                               zvn => vn,  &  !             zvn == vn
82                               zwn => wn      !             zwn == wn
83#endif
84
85      !! * Arguments
86      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
87
88      !! * Local declarations
89      INTEGER  ::   ji, jj, jk              ! dummy loop indices
90      REAL(wp) ::                        &  ! temporary scalar
91         ztai, ztaj, ztak,               &  !    "         "   
92         zsai, zsaj, zsak                   !    "         "   
93      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   &
94         zti, ztu, ztv, ztw,             &  ! temporary workspace
95         zsi, zsu, zsv, zsw,             &  !    "           "
96         ztdta, ztdsa                       !    "           "
97      REAL(wp) ::   &
98         z2dtt, zbtr, zeu, zev, zew, z2, &  ! temporary scalar
99         zfp_ui, zfp_vj, zfp_wk,         &  !    "         "
100         zfm_ui, zfm_vj, zfm_wk             !    "         "
101      !!----------------------------------------------------------------------
102
103      IF( kt == nit000 .AND. lwp ) THEN
104         WRITE(numout,*)
105         WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme'
106         WRITE(numout,*) '~~~~~~~~~~~'
107      ENDIF
108
109      IF( neuler == 0 .AND. kt == nit000 ) THEN
110         z2=1.
111      ELSE
112         z2=2.
113      ENDIF
114
115      ! Save ta and sa trends
116      IF( l_trdtra )   THEN
117         ztdta(:,:,:) = ta(:,:,:) 
118         ztdsa(:,:,:) = sa(:,:,:) 
119         l_adv = 'tvd'
120      ENDIF
121
122#if defined key_trabbl_adv
123      ! Advective Bottom boundary layer: add the velocity
124      ! -------------------------------------------------
125      zun(:,:,:) = un (:,:,:) - u_bbl(:,:,:)
126      zvn(:,:,:) = vn (:,:,:) - v_bbl(:,:,:)
127      zwn(:,:,:) = wn (:,:,:) + w_bbl(:,:,:)
128#endif
129
130      ! 1. Bottom value : flux set to zero
131      ! ---------------
132      ztu(:,:,jpk) = 0.e0   ;   zsu(:,:,jpk) = 0.e0
133      ztv(:,:,jpk) = 0.e0   ;   zsv(:,:,jpk) = 0.e0
134      ztw(:,:,jpk) = 0.e0   ;   zsw(:,:,jpk) = 0.e0
135      zti(:,:,jpk) = 0.e0   ;   zsi(:,:,jpk) = 0.e0
136
137
138      ! 2. upstream advection with initial mass fluxes & intermediate update
139      ! --------------------------------------------------------------------
140      ! upstream tracer flux in the i and j direction
141      DO jk = 1, jpkm1
142         DO jj = 1, jpjm1
143            DO ji = 1, fs_jpim1   ! vector opt.
144               zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
145               zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
146               ! upstream scheme
147               zfp_ui = zeu + ABS( zeu )
148               zfm_ui = zeu - ABS( zeu )
149               zfp_vj = zev + ABS( zev )
150               zfm_vj = zev - ABS( zev )
151               ztu(ji,jj,jk) = zfp_ui * tb(ji,jj,jk) + zfm_ui * tb(ji+1,jj  ,jk)
152               ztv(ji,jj,jk) = zfp_vj * tb(ji,jj,jk) + zfm_vj * tb(ji  ,jj+1,jk)
153               zsu(ji,jj,jk) = zfp_ui * sb(ji,jj,jk) + zfm_ui * sb(ji+1,jj  ,jk)
154               zsv(ji,jj,jk) = zfp_vj * sb(ji,jj,jk) + zfm_vj * sb(ji  ,jj+1,jk)
155            END DO
156         END DO
157      END DO
158
159      ! upstream tracer flux in the k direction
160      ! Surface value
161      IF( lk_dynspg_fsc .OR. lk_dynspg_fsc_tsk ) THEN   ! free surface-constant volume
162         DO jj = 1, jpj
163            DO ji = 1, jpi
164               zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1)
165               ztw(ji,jj,1) = zew * tb(ji,jj,1)
166               zsw(ji,jj,1) = zew * sb(ji,jj,1)
167            END DO
168         END DO
169      ELSE                                              ! rigid lid : flux set to zero
170         ztw(:,:,1) = 0.e0
171         zsw(:,:,1) = 0.e0
172      ENDIF
173
174      ! Interior value
175      DO jk = 2, jpkm1
176         DO jj = 1, jpj
177            DO ji = 1, jpi
178               zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
179               zfp_wk = zew + ABS( zew )
180               zfm_wk = zew - ABS( zew )
181               ztw(ji,jj,jk) = zfp_wk * tb(ji,jj,jk) + zfm_wk * tb(ji,jj,jk-1)
182               zsw(ji,jj,jk) = zfp_wk * sb(ji,jj,jk) + zfm_wk * sb(ji,jj,jk-1)
183            END DO
184         END DO
185      END DO
186
187      ! total advective trend
188      DO jk = 1, jpkm1
189         DO jj = 2, jpjm1
190            DO ji = fs_2, fs_jpim1   ! vector opt.
191               zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
192
193               ! i- j- horizontal & k- vertical advective trends
194               ztai = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  ) ) * zbtr
195               ztaj = - ( ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  ) ) * zbtr
196               ztak = - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
197               zsai = - ( zsu(ji,jj,jk) - zsu(ji-1,jj  ,jk  ) ) * zbtr
198               zsaj = - ( zsv(ji,jj,jk) - zsv(ji  ,jj-1,jk  ) ) * zbtr
199               zsak = - ( zsw(ji,jj,jk) - zsw(ji  ,jj  ,jk+1) ) * zbtr
200
201               ! total intermediate advective trends
202               zti(ji,jj,jk) = ztai + ztaj + ztak
203               zsi(ji,jj,jk) = zsai + zsaj + zsak
204            END DO
205         END DO
206      END DO
207
208     ! Save the intermediate vertical & j- horizontal advection trends
209     IF( l_trdtra )   THEN
210         DO jk = 1, jpkm1
211            DO jj = 2, jpjm1
212               DO ji = fs_2, fs_jpim1   ! vector opt.
213                  zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
214                  ztay(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  ) ) * zbtr
215                  zsay(ji,jj,jk) = - ( zsv(ji,jj,jk) - zsv(ji  ,jj-1,jk  ) ) * zbtr
216                  ztaz(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
217                  zsaz(ji,jj,jk) = - ( zsw(ji,jj,jk) - zsw(ji  ,jj  ,jk+1) ) * zbtr
218               END DO
219            END DO
220         END DO
221      ENDIF
222
223      ! update and guess with monotonic sheme
224      DO jk = 1, jpkm1
225         z2dtt = z2 * rdttra(jk)
226         DO jj = 2, jpjm1
227            DO ji = fs_2, fs_jpim1   ! vector opt.
228               ta(ji,jj,jk) =  ta(ji,jj,jk) + zti(ji,jj,jk)
229               sa(ji,jj,jk) =  sa(ji,jj,jk) + zsi(ji,jj,jk)
230               zti (ji,jj,jk) = ( tb(ji,jj,jk) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk)
231               zsi (ji,jj,jk) = ( sb(ji,jj,jk) + z2dtt * zsi(ji,jj,jk) ) * tmask(ji,jj,jk)
232            END DO
233         END DO
234      END DO
235
236      ! Lateral boundary conditions on zti, zsi   (unchanged sign)
237      CALL lbc_lnk( zti, 'T', 1. )
238      CALL lbc_lnk( zsi, 'T', 1. )
239
240
241      ! 3. antidiffusive flux : high order minus low order
242      ! --------------------------------------------------
243      ! antidiffusive flux on i and j
244      DO jk = 1, jpkm1
245         DO jj = 1, jpjm1
246            DO ji = 1, fs_jpim1   ! vector opt.
247               zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
248               zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
249               ztu(ji,jj,jk) = zeu * ( tn(ji,jj,jk) + tn(ji+1,jj,jk) ) - ztu(ji,jj,jk)
250               zsu(ji,jj,jk) = zeu * ( sn(ji,jj,jk) + sn(ji+1,jj,jk) ) - zsu(ji,jj,jk)
251               ztv(ji,jj,jk) = zev * ( tn(ji,jj,jk) + tn(ji,jj+1,jk) ) - ztv(ji,jj,jk)
252               zsv(ji,jj,jk) = zev * ( sn(ji,jj,jk) + sn(ji,jj+1,jk) ) - zsv(ji,jj,jk)
253            END DO
254         END DO
255      END DO
256     
257      ! antidiffusive flux on k
258      ! Surface value
259      ztw(:,:,1) = 0.
260      zsw(:,:,1) = 0.
261
262      ! Interior value
263      DO jk = 2, jpkm1
264         DO jj = 1, jpj
265            DO ji = 1, jpi
266               zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
267               ztw(ji,jj,jk) = zew * ( tn(ji,jj,jk) + tn(ji,jj,jk-1) ) - ztw(ji,jj,jk)
268               zsw(ji,jj,jk) = zew * ( sn(ji,jj,jk) + sn(ji,jj,jk-1) ) - zsw(ji,jj,jk)
269            END DO
270         END DO
271      END DO
272
273      ! Lateral bondary conditions
274      CALL lbc_lnk( ztu, 'U', -1. )   ;   CALL lbc_lnk( zsu, 'U', -1. )
275      CALL lbc_lnk( ztv, 'V', -1. )   ;   CALL lbc_lnk( zsv, 'V', -1. )
276      CALL lbc_lnk( ztw, 'W',  1. )   ;   CALL lbc_lnk( zsw, 'W',  1. )
277
278      ! 4. monotonicity algorithm
279      ! -------------------------
280      CALL nonosc( tb, ztu, ztv, ztw, zti, z2 )
281      CALL nonosc( sb, zsu, zsv, zsw, zsi, z2 )
282
283
284      ! 5. final trend with corrected fluxes
285      ! ------------------------------------
286      DO jk = 1, jpkm1
287         DO jj = 2, jpjm1
288            DO ji = fs_2, fs_jpim1   ! vector opt. 
289               zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
290               ! i- j- horizontal & k- vertical advective trends
291               ztai = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )) * zbtr
292               ztaj = - ( ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )) * zbtr
293               ztak = - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1)) * zbtr
294               zsai = - ( zsu(ji,jj,jk) - zsu(ji-1,jj  ,jk  )) * zbtr
295               zsaj = - ( zsv(ji,jj,jk) - zsv(ji  ,jj-1,jk  )) * zbtr
296               zsak = - ( zsw(ji,jj,jk) - zsw(ji  ,jj  ,jk+1)) * zbtr
297
298               ! add them to the general tracer trends
299               ta(ji,jj,jk) = ta(ji,jj,jk) + ztai + ztaj + ztak
300               sa(ji,jj,jk) = sa(ji,jj,jk) + zsai + zsaj + zsak
301            END DO
302         END DO
303      END DO
304
305      ! save the advective trends for diagnostic
306      ! tracers trends
307      IF( l_trdtra )   THEN
308         ! Compute the final vertical & j- horizontal advection trends
309         DO jk = 1, jpkm1
310            DO jj = 2, jpjm1
311               DO ji = fs_2, fs_jpim1   ! vector opt.
312                  zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
313                  ztay(ji,jj,jk) = - ( ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  ) ) * zbtr   &
314                     &             + ztay(ji,jj,jk) 
315                  zsay(ji,jj,jk) = - ( zsv(ji,jj,jk) - zsv(ji  ,jj-1,jk  ) ) * zbtr   &
316                     &             + zsay(ji,jj,jk) 
317                  ztaz(ji,jj,jk) = - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr   &
318                     &             + ztaz(ji,jj,jk) 
319                  zsaz(ji,jj,jk) = - ( zsw(ji,jj,jk) - zsw(ji  ,jj  ,jk+1) ) * zbtr   &
320                     &             + zsaz(ji,jj,jk) 
321               END DO
322            END DO
323         END DO
324
325         ! horizontal advection:
326         ! make the difference between the new trends ta()/sa() and the
327         ! previous one ztdta()/ztdsa() to have the total advection trends
328         ! to which we substract the vertical trends ztaz()/zsaz()
329         ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:) - ztaz(:,:,:)
330         ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:) - zsaz(:,:,:)
331
332         ! Add the term tn()/sn()*hdivn() to recover the Uh gradh(T/S) trends
333         ztdta(:,:,:) = ztdta(:,:,:) + tn(:,:,:) * hdivn(:,:,:)
334         ztdsa(:,:,:) = ztdsa(:,:,:) + sn(:,:,:) * hdivn(:,:,:)
335
336         CALL trd_mod(ztdta, ztdsa, jpttdlad, 'TRA', kt)
337
338         ! vertical advection:
339         ! Substract the term tn()/sn()*hdivn() to recover the W gradz(T/S) trends
340         ztaz(:,:,:) = ztaz(:,:,:) - tn(:,:,:) * hdivn(:,:,:)
341         zsaz(:,:,:) = zsaz(:,:,:) - sn(:,:,:) * hdivn(:,:,:)
342
343         CALL trd_mod(ztaz, zsaz, jpttdzad, 'TRA', kt)
344
345      ENDIF
346
347      IF(ln_ctl) THEN
348         CALL prt_ctl(tab3d_1=ta, clinfo1=' tvd adv  - Ta: ', mask1=tmask, &
349            &         tab3d_2=sa, clinfo2=' Sa: ', mask2=tmask, clinfo3='tra')
350      ENDIF
351
352      ! "zonal" mean advective heat and salt transport
353      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
354         pht_adv(:) = ptr_vj( ztv(:,:,:) )
355         pst_adv(:) = ptr_vj( zsv(:,:,:) )
356      ENDIF
357
358   END SUBROUTINE tra_adv_tvd
359
360
361   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
362      !!---------------------------------------------------------------------
363      !!                    ***  ROUTINE nonosc  ***
364      !!     
365      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
366      !!       scheme and the before field by a nonoscillatory algorithm
367      !!
368      !! **  Method  :   ... ???
369      !!       warning : pbef and paft must be masked, but the boundaries
370      !!       conditions on the fluxes are not necessary zalezak (1979)
371      !!       drange (1995) multi-dimensional forward-in-time and upstream-
372      !!       in-space based differencing for fluid
373      !!
374      !! History :
375      !!        !  97-04  (L. Mortier) Original code
376      !!        !  00-02  (H. Loukos)  rewritting for opa8
377      !!        !  00-10  (M.A Foujols, E. Kestenare)  lateral b.c.
378      !!        !  01-03  (E. Kestenare)  add key_passivetrc
379      !!        !  01-07  (E. Durand G. Madec)  adapted for T & S
380      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
381      !!----------------------------------------------------------------------
382      !! * Arguments
383      REAL(wp), INTENT( in ) ::   &
384         prdt                               ! ???
385      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
386         pbef,                            & ! before field
387         paft,                            & ! after field
388         paa,                             & ! monotonic flux in the i direction
389         pbb,                             & ! monotonic flux in the j direction
390         pcc                                ! monotonic flux in the k direction
391
392      !! * Local declarations
393      INTEGER ::   ji, jj, jk               ! dummy loop indices
394      INTEGER ::   ikm1
395      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
396      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
397      !!----------------------------------------------------------------------
398
399      zbig = 1.e+40
400      zrtrn = 1.e-15
401
402      ! Search local extrema
403      ! --------------------
404      ! large negative value (-zbig) inside land
405      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
406      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
407      ! search maximum in neighbourhood
408      DO jk = 1, jpkm1
409         ikm1 = MAX(jk-1,1)
410         DO jj = 2, jpjm1
411            DO ji = fs_2, fs_jpim1   ! vector opt.
412               zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
413                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
414                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
415                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
416                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
417                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
418                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
419            END DO
420         END DO
421      END DO
422      ! large positive value (+zbig) inside land
423      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
424      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
425      ! search minimum in neighbourhood
426      DO jk = 1, jpkm1
427         ikm1 = MAX(jk-1,1)
428         DO jj = 2, jpjm1
429            DO ji = fs_2, fs_jpim1   ! vector opt.
430               zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
431                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
432                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
433                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
434                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
435                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
436                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
437            END DO
438         END DO
439      END DO
440
441      ! restore masked values to zero
442      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
443      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
444 
445
446      ! 2. Positive and negative part of fluxes and beta terms
447      ! ------------------------------------------------------
448
449      DO jk = 1, jpkm1
450         z2dtt = prdt * rdttra(jk)
451         DO jj = 2, jpjm1
452            DO ji = fs_2, fs_jpim1   ! vector opt.
453               ! positive & negative part of the flux
454               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
455                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
456                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
457               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
458                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
459                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
460               ! up & down beta terms
461               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
462               zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
463               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
464            END DO
465         END DO
466      END DO
467
468      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
469      CALL lbc_lnk( zbetup, 'T', 1. )
470      CALL lbc_lnk( zbetdo, 'T', 1. )
471
472
473      ! 3. monotonic flux in the i & j direction (paa & pbb)
474      ! ----------------------------------------
475      DO jk = 1, jpkm1
476         DO jj = 2, jpjm1
477            DO ji = fs_2, fs_jpim1   ! vector opt.
478               za = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
479               zb = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
480               zc = 0.5 * ( 1.e0 + SIGN( 1.e0, paa(ji,jj,jk) ) )
481               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zc * za + ( 1.e0 - zc) * zb )
482
483               za = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
484               zb = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
485               zc = 0.5 * ( 1.e0 + SIGN( 1.e0, pbb(ji,jj,jk) ) )
486               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zc * za + ( 1.e0 - zc) * zb )
487            END DO
488         END DO
489      END DO
490
491
492      ! monotonic flux in the k direction, i.e. pcc
493      ! -------------------------------------------
494      DO jk = 2, jpkm1
495         DO jj = 2, jpjm1
496            DO ji = fs_2, fs_jpim1   ! vector opt.
497
498               za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
499               zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
500               zc = 0.5 * ( 1.e0 + SIGN( 1.e0, pcc(ji,jj,jk) ) )
501               pcc(ji,jj,jk) = pcc(ji,jj,jk) * ( zc * za + ( 1.e0 - zc) * zb )
502            END DO
503         END DO
504      END DO
505
506      ! lateral boundary condition on paa, pbb, pcc
507      CALL lbc_lnk( paa, 'U', -1. )      ! changed sign
508      CALL lbc_lnk( pbb, 'V', -1. )      ! changed sign
509      CALL lbc_lnk( pcc, 'W',  1. )      ! NO changed sign
510
511   END SUBROUTINE nonosc
512
513   !!======================================================================
514END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.