New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 32

Last change on this file since 32 was 32, checked in by opalod, 20 years ago

CT : UPDATE001 : First major NEMO update
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 12.2 KB
Line 
1MODULE traldf_iso
2   !!==============================================================================
3   !!                    ***  MODULE  traldf_iso  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if defined key_ldfslp   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'                  rotation of the lateral mixing tensor
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_iso : update the tracer trend with the horizontal component
11   !!                 of iso neutral laplacian operator or horizontal
12   !!                 laplacian operator in s-coordinate
13   !!----------------------------------------------------------------------
14   !! * Modules used
15   USE oce             ! ocean dynamics and tracers variables
16   USE dom_oce         ! ocean space and time domain variables
17   USE ldftra_oce     ! ocean active tracers: lateral physics
18   USE trdtra_oce     ! ocean active tracers: trend variables
19   USE in_out_manager  ! I/O manager
20   USE ldfslp          ! iso-neutral slopes
21   USE lbclnk
22
23   IMPLICIT NONE
24   PRIVATE
25
26   !! * Routine accessibility
27   PUBLIC tra_ldf_iso  ! routine called by step.F90
28
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31#  include "ldftra_substitute.h90"
32#  include "ldfeiv_substitute.h90"
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35
36CONTAINS
37
38   SUBROUTINE tra_ldf_iso( kt )
39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE tra_ldf_iso  ***
41      !!
42      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
43      !!      trend and add it to the general trend of tracer equation.
44      !!
45      !! ** Method  :   The horizontal component of the lateral diffusive trends
46      !!      is provided by a 2nd order operator rotated along neural or geopo-
47      !!      tential surfaces to which an eddy induced advection can be added
48      !!      It is computed using before fields (forward in time) and isopyc-
49      !!      nal or geopotential slopes computed in routine ldfslp.
50      !!
51      !!      horizontal fluxes associated with the rotated lateral mixing:
52      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
53      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
54      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
55      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
56      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
57      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
58      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
59      !!      take the horizontal divergence of the fluxes:
60      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
61      !!      Add this trend to the general trend (ta,sa):
62      !!         ta = ta + difft
63      !!
64      !! ** Action  : - Update (ta,sa) arrays with the before isopycnal or
65      !!                geopotential s-coord harmonic mixing trend.
66      !!              - Save the trends in (ttrd,strd) ('key_diatrends')
67      !!
68      !! History :
69      !!        !  94-08  (G. Madec, M. Imbard)
70      !!        !  97-05  (G. Madec)  split into traldf and trazdf
71      !!   8.5  !  02-08  (G. Madec)  Free form, F90
72      !!----------------------------------------------------------------------
73      !! * Modules used
74      USE oce           , zftu => ua,  &  ! use ua as workspace
75         &                zfsu => va      ! use va as workspace
76
77      !! * Arguments
78      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
79
80      !! * Local declarations
81      INTEGER ::   ji, jj, jk             ! dummy loop indices
82      REAL(wp) ::   &
83         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
84         zmsku, zmskv, zbtr, zta, zsa, &
85         zcg1, zcg2, zuwk, zvwk,       &
86         zuwk1, zvwk1,                 &
87         ztagu, ztagv, zsagu, zsagv
88      REAL(wp), DIMENSION(jpi,jpj) ::   &
89         zdkt, zdk1t,      &  ! workspace
90         zdks, zdk1s,      &
91         zftug, zftvg,                 &
92         zfsug, zfsvg
93      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
94         zftv, zfsv                       ! workspace
95      !!----------------------------------------------------------------------
96
97      IF( kt == nit000 ) THEN
98         IF(lwp) WRITE(numout,*)
99         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : iso neutral lateral diffusion or'
100         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   horizontal laplacian diffusion in s-coordinate'
101#if defined key_diaeiv
102         u_eiv(:,:,:) = 0.e0
103         v_eiv(:,:,:) = 0.e0
104#endif
105      ENDIF
106
107      ztagu = 0.e0
108      ztagv = 0.e0
109      zsagu = 0.e0
110      zsagv = 0.e0
111
112      !                                                ! ===============
113      DO jk = 1, jpkm1                                 ! Horizontal slab
114         !                                             ! ===============
115         ! 1. Vertical tracer gradient at level jk and jk+1
116         ! ------------------------------------------------
117         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
118
119         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
120         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
121
122         IF( jk == 1 ) THEN
123            zdkt(:,:) = zdk1t(:,:)
124            zdks(:,:) = zdk1s(:,:)
125         ELSE
126            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
127            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
128         ENDIF
129
130
131         ! 2. Horizontal fluxes
132         ! --------------------
133
134         DO jj = 1 , jpjm1
135            DO ji = 1, fs_jpim1   ! vector opt.
136               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
137               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
138
139               zmsku = 1. / MAX(   tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
140                                 + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
141
142               zmskv = 1. / MAX(   tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
143                                 + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
144
145               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
146               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
147
148               zftu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   tb(ji+1,jj,jk) - tb(ji,jj,jk)  )   &
149                  &                              + zcof1 * (   zdkt (ji+1,jj) + zdk1t(ji,jj)      &
150                  &                                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
151
152               zftv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   tb(ji,jj+1,jk) - tb(ji,jj,jk)  )   &
153                  &                              + zcof2 * (   zdkt (ji,jj+1) + zdk1t(ji,jj)      &
154                  &                                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
155
156               zfsu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   sb(ji+1,jj,jk) - sb(ji,jj,jk)  )   &
157                  &                              + zcof1 * (   zdks (ji+1,jj) + zdk1s(ji,jj)      &
158                  &                              + zdk1s(ji+1,jj) + zdks (ji,jj)  )  )
159
160               zfsv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   sb(ji,jj+1,jk) - sb(ji,jj,jk)  )   &
161                  &                              + zcof2 * (   zdks (ji,jj+1) + zdk1s(ji,jj)      &
162                  &                              + zdk1s(ji,jj+1) + zdks (ji,jj)  )  )
163            END DO
164         END DO
165
166         !                              ! ---------------------------------------!
167         IF( lk_traldf_eiv ) THEN       ! Eddy induced vertical advective fluxes !
168            !                           ! ---------------------------------------!
169            DO jj = 1, jpjm1
170               DO ji = 1, fs_jpim1   ! vector opt.
171                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
172                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
173                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
174                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
175   
176                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
177                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
178   
179                  zftug(ji,jj) = zcg1 * ( tb(ji+1,jj,jk) + tb(ji,jj,jk) )
180                  zftvg(ji,jj) = zcg2 * ( tb(ji,jj+1,jk) + tb(ji,jj,jk) )
181                  zfsug(ji,jj) = zcg1 * ( sb(ji+1,jj,jk) + sb(ji,jj,jk) )
182                  zfsvg(ji,jj) = zcg2 * ( sb(ji,jj+1,jk) + sb(ji,jj,jk) )
183   
184                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
185                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
186                  zfsu(ji,jj,jk) = zfsu(ji,jj,jk) + zfsug(ji,jj)
187                  zfsv(ji,jj,jk) = zfsv(ji,jj,jk) + zfsvg(ji,jj)
188#   if defined key_diaeiv
189                  u_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
190                  v_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
191#   endif
192               END DO
193            END DO
194         ENDIF
195
196         ! II.4 Second derivative (divergence) and add to the general trend
197         ! ----------------------------------------------------------------
198
199         DO jj = 2 , jpjm1
200            DO ji = fs_2, fs_jpim1   ! vector opt.
201               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
202               zta = zbtr * (  zftu(ji,jj,jk) - zftu(ji-1,jj  ,jk)   &
203                  &          + zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk)  )
204               zsa = zbtr * (  zfsu(ji,jj,jk) - zfsu(ji-1,jj  ,jk)   &
205                  &          + zfsv(ji,jj,jk) - zfsv(ji  ,jj-1,jk)  )
206               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
207               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
208#if defined key_trdtra || defined key_trdmld
209#   if defined key_traldf_eiv
210               ztagu = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
211               ztagv = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
212               zsagu = ( zfsug(ji,jj) - zfsug(ji-1,jj  ) ) * zbtr
213               zsagv = ( zfsvg(ji,jj) - zfsvg(ji  ,jj-1) ) * zbtr
214               ttrdh(ji,jj,jk,3) = ztagu
215               ttrdh(ji,jj,jk,4) = ztagv
216               strdh(ji,jj,jk,3) = zsagu
217               strdh(ji,jj,jk,4) = zsagv
218#   endif
219               ttrd (ji,jj,jk,3) = zta - ztagu - ztagv
220               strd (ji,jj,jk,3) = zsa - zsagu - zsagv
221#endif
222            END DO
223         END DO
224         !                                          ! ===============
225      END DO                                        !   End of slab 
226      !                                             ! ===============
227
228      IF( l_ctl .AND. lwp ) THEN         ! print mean trends (used for debugging)
229         zta = SUM( ta(2:jpim1,2:jpjm1,1:jpkm1) * tmask(2:jpim1,2:jpjm1,1:jpkm1) )
230         zsa = SUM( sa(2:jpim1,2:jpjm1,1:jpkm1) * tmask(2:jpim1,2:jpjm1,1:jpkm1) )
231         WRITE(numout,*) ' ldf  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl
232         t_ctl = zta   ;   s_ctl = zsa
233      ENDIF
234
235#if defined key_diaptr
236      !!bug  no separation of diff iso and eiv
237      IF( MOD( kt, nf_ptr ) == 0 ) THEN
238      ! "zonal" mean lateral diffusive heat and salt transports
239         pht_ldf(:,:) = prt_vj( zftv(:,:,:) )
240         pst_ldf(:,:) = prt_vj( zfsv(:,:,:) )
241         ! "zonal" mean lateral eddy induced velocity heat and salt transports
242         pht_eiv(:,:) = prt_vj( zftv(:,:,:) )
243         pst_eiv(:,:) = prt_vj( zfsv(:,:,:) )
244      ENDIF
245#endif
246
247   END SUBROUTINE tra_ldf_iso
248
249#else
250   !!----------------------------------------------------------------------
251   !!   Dummy module :             No rotation of the lateral mixing tensor
252   !!----------------------------------------------------------------------
253CONTAINS
254   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
255      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
256   END SUBROUTINE tra_ldf_iso
257#endif
258
259   !!==============================================================================
260END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.