New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 467

Last change on this file since 467 was 457, checked in by opalod, 18 years ago

nemo_v1_update_049:RB: reorganization of tracers part, remove traadv_cen2_atsk.h90 traldf_iso_zps.F90 trazdf_iso.F90 trazdf_iso_vopt.F90, change atsk routines to jki
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 14.5 KB
Line 
1MODULE traldf_iso
2   !!==============================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if   defined key_ldfslp   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'               slope of the lateral diffusive direction
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_iso  : update the tracer trend with the horizontal
11   !!                  component of a iso-neutral laplacian operator
12   !!                  and with the vertical part of
13   !!                  the isopycnal or geopotential s-coord. operator
14   !!                  vector optimization, use k-j-i loops.
15   !!----------------------------------------------------------------------
16   !! * Modules used
17   USE oce             ! ocean dynamics and active tracers
18   USE dom_oce         ! ocean space and time domain
19   USE ldftra_oce      ! ocean active tracers: lateral physics
20   USE trdmod          ! ocean active tracers trends
21   USE trdmod_oce      ! ocean variables trends
22   USE zdf_oce         ! ocean vertical physics
23   USE in_out_manager  ! I/O manager
24   USE ldfslp          ! iso-neutral slopes
25   USE diaptr          ! poleward transport diagnostics
26   USE prtctl          ! Print control
27
28
29   IMPLICIT NONE
30   PRIVATE
31
32   !! * Accessibility
33   PUBLIC tra_ldf_iso   ! routine called by step.F90
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "ldftra_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !!   OPA 9.0 , LOCEAN-IPSL (2005)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE tra_ldf_iso( kt )
46      !!----------------------------------------------------------------------
47      !!                  ***  ROUTINE tra_ldf_iso  ***
48      !!
49      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
50      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
51      !!      add it to the general trend of tracer equation.
52      !!
53      !! ** Method  :   The horizontal component of the lateral diffusive trends
54      !!      is provided by a 2nd order operator rotated along neural or geopo-
55      !!      tential surfaces to which an eddy induced advection can be added
56      !!      It is computed using before fields (forward in time) and isopyc-
57      !!      nal or geopotential slopes computed in routine ldfslp.
58      !!
59      !!      1st part :  masked horizontal derivative of T & S ( di[ t ] )
60      !!      ========    with partial cell update if ln_zps=T.
61      !!
62      !!      2nd part :  horizontal fluxes of the lateral mixing operator
63      !!      ========   
64      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
65      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
66      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
67      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
68      !!      take the horizontal divergence of the fluxes:
69      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
70      !!      Add this trend to the general trend (ta,sa):
71      !!         ta = ta + difft
72      !!
73      !!      3rd part: vertical trends of the lateral mixing operator
74      !!      ========  (excluding the vertical flux proportional to dk[t] )
75      !!      vertical fluxes associated with the rotated lateral mixing:
76      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
77      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
78      !!      take the horizontal divergence of the fluxes:
79      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
80      !!      Add this trend to the general trend (ta,sa):
81      !!         ta = ta + difft
82      !!
83      !! ** Action :
84      !!         Update (ta,sa) arrays with the before rotated diffusion trend
85      !!            (except the dk[ dk[.] ] term)
86      !!
87      !! History :
88      !!        !  94-08  (G. Madec, M. Imbard)
89      !!        !  97-05  (G. Madec)  split into traldf and trazdf
90      !!   8.5  !  02-08  (G. Madec)  Free form, F90
91      !!   9.0  !  04-08  (C. Talandier) New trends organization
92      !!        !  05-11  (G. Madec)  merge traldf and trazdf :-)
93      !!----------------------------------------------------------------------
94      !! * Modules used
95      USE oce           , zftv => ua,   &  ! use ua as workspace
96         &                zfsv => va       ! use va as workspace
97
98      !! * Arguments
99      INTEGER, INTENT( in ) ::   kt        ! ocean time-step index
100
101      !! * Local declarations
102      INTEGER ::   ji, jj, jk              ! dummy loop indices
103      INTEGER ::   iku, ikv                ! temporary integer
104      REAL(wp) ::   &
105         zabe1, zabe2, zcof1, zcof2,    &  ! temporary scalars
106         zmsku, zta,                    &  !    "           "
107         zmskv, zsa, zbtr,              &  !    "           "
108         zcoef0, zcoef3, zcoef4            !    "         "
109      REAL(wp), DIMENSION(jpi,jpj) ::   &  ! temporary workspace
110         zdkt , zdk1t, zftu,            &  !    "           "
111         zdks , zdk1s, zfsu                !    "           "
112      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
113         zdit, zdjt, ztfw,              &  ! temporary workspace
114         zdis, zdjs, zsfw                  !    "           "
115      !!----------------------------------------------------------------------
116
117      IF( kt == nit000 ) THEN
118         IF(lwp) WRITE(numout,*)
119         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator'
120         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
121      ENDIF
122
123      !!----------------------------------------------------------------------
124      !!   I - masked horizontal derivative of T & S
125      !!----------------------------------------------------------------------
126!!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
127      zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
128      zdis (1,:,:) = 0.e0     ;     zdis (jpi,:,:) = 0.e0
129      zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
130      zdjs (1,:,:) = 0.e0     ;     zdjs (jpi,:,:) = 0.e0
131!!end
132
133
134      ! Horizontal temperature and salinity gradient
135      DO jk = 1, jpkm1
136         DO jj = 1, jpjm1
137            DO ji = 1, fs_jpim1   ! vector opt.
138               zdit(ji,jj,jk) = ( tb(ji+1,jj  ,jk) - tb(ji,jj,jk) ) * umask(ji,jj,jk)
139               zdis(ji,jj,jk) = ( sb(ji+1,jj  ,jk) - sb(ji,jj,jk) ) * umask(ji,jj,jk)
140               zdjt(ji,jj,jk) = ( tb(ji  ,jj+1,jk) - tb(ji,jj,jk) ) * vmask(ji,jj,jk)
141               zdjs(ji,jj,jk) = ( sb(ji  ,jj+1,jk) - sb(ji,jj,jk) ) * vmask(ji,jj,jk)
142            END DO
143         END DO
144      END DO
145      IF( ln_zps ) THEN      ! partial steps correction at the last level
146         DO jj = 1, jpjm1
147            DO ji = 1, fs_jpim1   ! vector opt.
148               ! last level
149               iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
150               ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
151               zdit(ji,jj,iku) = gtu(ji,jj) 
152               zdis(ji,jj,iku) = gsu(ji,jj)               
153               zdjt(ji,jj,ikv) = gtv(ji,jj) 
154               zdjs(ji,jj,ikv) = gsv(ji,jj)               
155            END DO
156         END DO
157      ENDIF
158
159      !!----------------------------------------------------------------------
160      !!   II - horizontal trend of T & S (full)
161      !!----------------------------------------------------------------------
162     
163!CDIR PARALLEL DO PRIVATE( zdk1t, zdk1s, zftu, zfsu )
164!$OMP PARALLEL DO PRIVATE( zdk1t, zdk1s, zftu, zfsu )
165      !                                                ! ===============
166      DO jk = 1, jpkm1                                 ! Horizontal slab
167         !                                             ! ===============
168         ! 1. Vertical tracer gradient at level jk and jk+1
169         ! ------------------------------------------------
170         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
171
172         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
173         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
174
175         IF( jk == 1 ) THEN
176            zdkt(:,:) = zdk1t(:,:)
177            zdks(:,:) = zdk1s(:,:)
178         ELSE
179            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
180            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
181         ENDIF
182
183
184         ! 2. Horizontal fluxes
185         ! --------------------
186
187         DO jj = 1 , jpjm1
188            DO ji = 1, fs_jpim1   ! vector opt.
189               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
190               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
191
192               zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
193                  &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
194
195               zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
196                  &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
197
198               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
199               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
200
201               zftu(ji,jj   ) = (  zabe1 * zdit(ji,jj,jk)   &
202                  &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
203                  &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
204               zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
205                  &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
206                  &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)
207               zfsu(ji,jj   ) = (  zabe1 * zdis(ji,jj,jk)   &
208                  &              + zcof1 * (  zdks (ji+1,jj) + zdk1s(ji,jj)      &
209                  &                         + zdk1s(ji+1,jj) + zdks (ji,jj)  )  ) * umask(ji,jj,jk)
210               zfsv(ji,jj,jk) = (  zabe2 * zdjs(ji,jj,jk)   &
211                  &              + zcof2 * (  zdks (ji,jj+1) + zdk1s(ji,jj)      &
212                  &                         + zdk1s(ji,jj+1) + zdks (ji,jj)  )  ) * vmask(ji,jj,jk)
213            END DO
214         END DO
215
216
217         ! II.4 Second derivative (divergence) and add to the general trend
218         ! ----------------------------------------------------------------
219
220         DO jj = 2 , jpjm1
221            DO ji = fs_2, fs_jpim1   ! vector opt.
222               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
223               zta = zbtr * ( zftu(ji,jj   ) - zftu(ji-1,jj   ) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
224               zsa = zbtr * ( zfsu(ji,jj   ) - zfsu(ji-1,jj   ) + zfsv(ji,jj,jk) - zfsv(ji,jj-1,jk)  )
225               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
226               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
227            END DO
228         END DO
229         !                                          ! ===============
230      END DO                                        !   End of slab 
231      !                                             ! ===============
232
233      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
234         ! "zonal" mean lateral diffusive heat and salt transports
235         pht_ldf(:) = ptr_vj( zftv(:,:,:) )
236         pst_ldf(:) = ptr_vj( zfsv(:,:,:) )
237      ENDIF
238
239      !!----------------------------------------------------------------------
240      !!   III - vertical trend of T & S (extra diagonal terms only)
241      !!----------------------------------------------------------------------
242
243      ! Local constant initialization
244      ! -----------------------------
245      ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
246      zsfw(1,:,:) = 0.e0     ;     zsfw(jpi,:,:) = 0.e0
247
248
249      ! Vertical fluxes
250      ! ---------------
251
252      ! Surface and bottom vertical fluxes set to zero
253      ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
254      zsfw(:,:, 1 ) = 0.e0      ;      zsfw(:,:,jpk) = 0.e0
255
256      ! interior (2=<jk=<jpk-1)
257      DO jk = 2, jpkm1
258         DO jj = 2, jpjm1
259            DO ji = fs_2, fs_jpim1   ! vector opt.
260               zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
261
262               zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
263                  &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
264
265               zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
266                  &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
267
268               zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
269               zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
270
271               ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
272                  &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
273                  &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
274                  &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
275
276               zsfw(ji,jj,jk) = zcoef3 * (   zdis(ji  ,jj  ,jk-1) + zdis(ji-1,jj  ,jk)      &
277                  &                        + zdis(ji-1,jj  ,jk-1) + zdis(ji  ,jj  ,jk)  )   &
278                  &           + zcoef4 * (   zdjs(ji  ,jj  ,jk-1) + zdjs(ji  ,jj-1,jk)      &
279                  &                        + zdjs(ji  ,jj-1,jk-1) + zdjs(ji  ,jj  ,jk)  )
280            END DO
281         END DO
282      END DO
283
284
285      ! I.5 Divergence of vertical fluxes added to the general tracer trend
286      ! -------------------------------------------------------------------
287
288      DO jk = 1, jpkm1
289         DO jj = 2, jpjm1
290            DO ji = fs_2, fs_jpim1   ! vector opt.
291               zbtr =  1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
292               zta  = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
293               zsa  = (  zsfw(ji,jj,jk) - zsfw(ji,jj,jk+1)  ) * zbtr
294               ta(ji,jj,jk) = ta(ji,jj,jk) + zta
295               sa(ji,jj,jk) = sa(ji,jj,jk) + zsa
296            END DO
297         END DO
298      END DO
299
300   END SUBROUTINE tra_ldf_iso
301
302#else
303   !!----------------------------------------------------------------------
304   !!   default option :   Dummy code   NO rotation of the diffusive tensor
305   !!----------------------------------------------------------------------
306CONTAINS
307   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
308      INTEGER :: kt
309      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
310   END SUBROUTINE tra_ldf_iso
311#endif
312
313   !!==============================================================================
314END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.