New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_zps.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_iso_zps.F90 @ 216

Last change on this file since 216 was 216, checked in by opalod, 19 years ago

CT : UPDATE151 : New trends organization
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 14.4 KB
Line 
1MODULE traldf_iso_zps
2   !!==============================================================================
3   !!                   ***  MODULE  traldf_iso_zps  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if ( defined key_ldfslp   &&   defined key_partial_steps )   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'               slope of the lateral diffusive direction
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_iso_zps : update the tracer trend with the horizontal
11   !!                     component of a iso-neutral laplacian operator
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE ldftra_oce      ! ocean active tracers: lateral physics
17   USE trdmod          ! ocean active tracers trends
18   USE trdmod_oce      ! ocean variables trends
19   USE zdf_oce         ! ocean vertical physics
20   USE in_out_manager  ! I/O manager
21   USE ldfslp          ! iso-neutral slopes
22   USE diaptr          ! poleward transport diagnostics
23
24
25   IMPLICIT NONE
26   PRIVATE
27
28   !! * Accessibility
29   PUBLIC tra_ldf_iso_zps  ! routine called by step.F90
30
31   !! * Substitutions
32#  include "domzgr_substitute.h90"
33#  include "ldftra_substitute.h90"
34#  include "ldfeiv_substitute.h90"
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !!   OPA 9.0 , LODYC-IPSL (2003)
38   !!----------------------------------------------------------------------
39
40CONTAINS
41
42   SUBROUTINE tra_ldf_iso_zps( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE tra_ldf_iso_zps  ***
45      !!
46      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
47      !!      trend and add it to the general trend of tracer equation.
48      !!
49      !! ** Method  :   The horizontal component of the lateral diffusive trends
50      !!      is provided by a 2nd order operator rotated along neural or geopo-
51      !!      tential surfaces to which an eddy induced advection can be added
52      !!      It is computed using before fields (forward in time) and isopyc-
53      !!      nal or geopotential slopes computed in routine ldfslp.
54      !!
55      !!      horizontal fluxes associated with the rotated lateral mixing:
56      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
57      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
58      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
59      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
60      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
61      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
62      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
63      !!      take the horizontal divergence of the fluxes:
64      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
65      !!      Add this trend to the general trend (ta,sa):
66      !!         ta = ta + difft
67      !!
68      !!      'key_trdtra' defined: the trend is saved for diagnostics.
69      !!
70      !!      macro-tasked on horizontal slab (jk-loop).
71      !!
72      !! ** Action :
73      !!         Update (ta,sa) arrays with the before along level biharmonic
74      !!      mixing trend.
75      !!         Save in (ztdta,ztdsa) arrays the trends if 'key_trdtra' defined
76      !!
77      !! History :
78      !!        !  94-08  (G. Madec, M. Imbard)
79      !!        !  97-05  (G. Madec)  split into traldf and trazdf
80      !!   8.5  !  02-08  (G. Madec)  Free form, F90
81      !!   9.0  !  04-08  (C. Talandier) New trends organization
82      !!----------------------------------------------------------------------
83      !! * Modules used
84      USE oce           , zftu => ua,  &  ! use ua as workspace
85         &                zfsu => va      ! use va as workspace
86
87      !! * Arguments
88      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
89
90      !! * Local declarations
91      INTEGER ::   ji, jj, jk             ! dummy loop indices
92      INTEGER ::   iku, ikv               ! temporary integer
93      REAL(wp) ::   &
94         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
95         zmsku, zmskv, zbtr, zta, zsa     !    "           "
96      REAL(wp), DIMENSION(jpi,jpj) ::   & ! temporary workspace
97         zdkt , zdk1t, zdks , zdk1s       !    "           "
98      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
99         zftv, zgtbu, zgtbv,                &  ! temporary workspace
100         zfsv, zgsbu, zgsbv,                &  !    "           "
101         ztdta, ztdsa
102         
103#if defined key_traldf_eiv 
104      REAL(wp) ::   &
105         zcg1, zcg2, zuwk, zvwk,            &  ! temporary scalars
106         zuwk1, zvwk1                          !    "           "
107      REAL(wp), DIMENSION(jpi,jpj) ::       &  ! temporary workspace
108         zftug, zftvg, zfsug, zfsvg            !     "        "     
109#endif
110      !!----------------------------------------------------------------------
111
112      IF( kt == nit000 ) THEN
113         IF(lwp) WRITE(numout,*)
114         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_zps : iso neutral laplacian diffusion in '
115         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~   z-coordinates with partial steps'
116#if defined key_diaeiv
117         u_eiv(:,:,:) = 0.e0
118         v_eiv(:,:,:) = 0.e0
119#endif
120      ENDIF
121
122      ! Save ta and sa trends
123      IF( l_trdtra )   THEN
124         ztdta(:,:,:) = ta(:,:,:) 
125         ztdsa(:,:,:) = sa(:,:,:) 
126      ENDIF
127
128      ! Horizontal temperature and salinity gradient
129      DO jk = 1, jpk
130         DO jj = 1, jpj-1
131            DO ji = 1, fs_jpim1   ! vector opt.
132               zgtbu(ji,jj,jk) = tmask(ji,jj,jk) * ( tb(ji+1,jj  ,jk) - tb(ji,jj,jk) )
133               zgsbu(ji,jj,jk) = tmask(ji,jj,jk) * ( sb(ji+1,jj  ,jk) - sb(ji,jj,jk) )
134               zgtbv(ji,jj,jk) = tmask(ji,jj,jk) * ( tb(ji  ,jj+1,jk) - tb(ji,jj,jk) )
135               zgsbv(ji,jj,jk) = tmask(ji,jj,jk) * ( sb(ji  ,jj+1,jk) - sb(ji,jj,jk) )
136            END DO
137         END DO
138      END DO
139      ! partial steps correction at the last level
140      DO jj = 1, jpj-1
141         DO ji = 1, jpi-1
142            ! last level
143            iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
144            ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
145            zgtbu(ji,jj,iku) = gtu(ji,jj) 
146            zgsbu(ji,jj,iku) = gsu(ji,jj)               
147            zgtbv(ji,jj,ikv) = gtv(ji,jj) 
148            zgsbv(ji,jj,ikv) = gsv(ji,jj)               
149         END DO
150      END DO
151     
152      !                                                ! ===============
153      DO jk = 1, jpkm1                                 ! Horizontal slab
154         !                                             ! ===============
155         ! 1. Vertical tracer gradient at level jk and jk+1
156         ! ------------------------------------------------
157         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
158
159         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
160         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
161
162         IF( jk == 1 ) THEN
163            zdkt(:,:) = zdk1t(:,:)
164            zdks(:,:) = zdk1s(:,:)
165         ELSE
166            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
167            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
168         ENDIF
169
170
171         ! 2. Horizontal fluxes
172         ! --------------------
173
174         DO jj = 1 , jpjm1
175            DO ji = 1, fs_jpim1   ! vector opt.
176               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
177               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
178
179               zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
180                                + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
181
182               zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
183                                + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
184
185               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
186               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
187
188               zftu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgtbu(ji,jj,jk)   &
189                  &                                + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
190                  &                                           + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
191               zftv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgtbv(ji,jj,jk)   &
192                  &                                + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
193                  &                                           + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
194               zfsu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgsbu(ji,jj,jk)   &
195                  &                                + zcof1 * (  zdks (ji+1,jj) + zdk1s(ji,jj)      &
196                  &                                           + zdk1s(ji+1,jj) + zdks (ji,jj)  )  )
197               zfsv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgsbv(ji,jj,jk)   &
198                  &                                + zcof2 * (  zdks (ji,jj+1) + zdk1s(ji,jj)      &
199                  &                                           + zdk1s(ji,jj+1) + zdks (ji,jj)  )  )
200            END DO
201         END DO
202
203#if defined key_traldf_eiv
204                                        ! ---------------------------------------!
205                                        ! Eddy induced vertical advective fluxes !
206                                        ! ---------------------------------------!
207            DO jj = 1, jpjm1
208               DO ji = 1, fs_jpim1   ! vector opt.
209                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
210                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
211                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
212                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
213
214                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
215                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
216
217                  zftug(ji,jj) = zcg1 * ( tb(ji+1,jj,jk) + tb(ji,jj,jk) )
218                  zftvg(ji,jj) = zcg2 * ( tb(ji,jj+1,jk) + tb(ji,jj,jk) )
219                  zfsug(ji,jj) = zcg1 * ( sb(ji+1,jj,jk) + sb(ji,jj,jk) )
220                  zfsvg(ji,jj) = zcg2 * ( sb(ji,jj+1,jk) + sb(ji,jj,jk) )
221
222                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
223                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
224                  zfsu(ji,jj,jk) = zfsu(ji,jj,jk) + zfsug(ji,jj)
225                  zfsv(ji,jj,jk) = zfsv(ji,jj,jk) + zfsvg(ji,jj)
226#   if defined key_diaeiv
227                  u_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
228                  v_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
229#   endif
230               END DO
231            END DO
232#endif
233
234         ! II.4 Second derivative (divergence) and add to the general trend
235         ! ----------------------------------------------------------------
236
237         DO jj = 2 , jpjm1
238            DO ji = fs_2, fs_jpim1   ! vector opt.
239               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
240               zta = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
241               zsa = zbtr * ( zfsu(ji,jj,jk) - zfsu(ji-1,jj,jk) + zfsv(ji,jj,jk) - zfsv(ji,jj-1,jk)  )
242               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
243               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
244            END DO
245         END DO
246         !                                          ! ===============
247      END DO                                        !   End of slab 
248      !                                             ! ===============
249
250      ! save the trends for diagnostic
251      ! save the horizontal diffusive trends
252      IF( l_trdtra )   THEN
253#   if defined key_traldf_eiv
254         DO jk = 1 , jpkm1
255            DO jj = 2 , jpjm1
256               DO ji = fs_2, fs_jpim1   ! vector opt.
257                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
258                  tladi(ji,jj,jk) = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
259                  tladj(ji,jj,jk) = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
260                  sladi(ji,jj,jk) = ( zfsug(ji,jj) - zfsug(ji-1,jj  ) ) * zbtr
261                  sladj(ji,jj,jk) = ( zfsvg(ji,jj) - zfsvg(ji  ,jj-1) ) * zbtr
262               END DO
263            END DO
264         END DO
265#   else
266         tladi(:,:,:) = 0.e0
267         tladj(:,:,:) = 0.e0
268         sladi(:,:,:) = 0.e0
269         sladj(:,:,:) = 0.e0
270#   endif
271
272         ! Substract the eddy induced velocity for T/S
273         ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:) - tladi(:,:,:) - tladj(:,:,:) 
274         ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:) - sladi(:,:,:) - sladj(:,:,:) 
275
276         CALL trd_mod(ztdta, ztdsa, jpttdldf, 'TRA', kt)
277      ENDIF
278
279      IF(l_ctl) THEN         ! print mean trends (used for debugging)
280         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
281         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
282         WRITE(numout,*) ' ldf  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl
283         t_ctl = zta   ;   s_ctl = zsa
284      ENDIF
285
286
287      !!bug  no separation of diff iso and eiv
288      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
289         ! "zonal" mean lateral diffusive heat and salt transports
290         pht_ldf(:) = ptr_vj( zftv(:,:,:) )
291         pst_ldf(:) = ptr_vj( zfsv(:,:,:) )
292         ! "zonal" mean lateral eddy induced velocity heat and salt transports
293         pht_eiv(:) = ptr_vj( zftv(:,:,:) )
294         pst_eiv(:) = ptr_vj( zfsv(:,:,:) )
295      ENDIF
296
297   END SUBROUTINE tra_ldf_iso_zps
298
299#else
300   !!----------------------------------------------------------------------
301   !!   default option :   Dummy code   NO rotation of the diffusive tensor
302   !!----------------------------------------------------------------------
303CONTAINS
304   SUBROUTINE tra_ldf_iso_zps( kt )               ! Empty routine
305      WRITE(*,*) 'tra_ldf_iso_zps: You should not have seen this print! error?', kt
306   END SUBROUTINE tra_ldf_iso_zps
307#endif
308
309   !!==============================================================================
310END MODULE traldf_iso_zps
Note: See TracBrowser for help on using the repository browser.