New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_zps.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_iso_zps.F90 @ 3

Last change on this file since 3 was 3, checked in by opalod, 20 years ago

Initial revision
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 13.7 KB
Line 
1MODULE traldf_iso_zps
2   !!==============================================================================
3   !!                   ***  MODULE  traldf_iso_zps  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if defined key_ldfslp   ||   defined key_esopa
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'               slope of the lateral diffusive direction
9   !!----------------------------------------------------------------------
10   !!   tra_ldf_iso_zps : update the tracer trend with the horizontal
11   !!                     component of a iso-neutral laplacian operator
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE ldftra_oce     ! ocean active tracers: lateral physics
17   USE trdtra_oce     ! ocean active tracers: trend
18   USE zdf_oce         ! ocean vertical physics
19   USE in_out_manager  ! I/O manager
20   USE ldfslp          ! iso-neutral slopes
21   USE lbclnk
22
23   IMPLICIT NONE
24   PRIVATE
25
26   !! * Accessibility
27   PUBLIC tra_ldf_iso_zps  ! routine called by step.F90
28
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31#  include "ldftra_substitute.h90"
32#  include "ldfeiv_substitute.h90"
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35   !!   OPA 9.0 , LODYC-IPSL (2003)
36   !!----------------------------------------------------------------------
37
38CONTAINS
39
40   SUBROUTINE tra_ldf_iso_zps( kt )
41      !!----------------------------------------------------------------------
42      !!                  ***  ROUTINE tra_ldf_iso_zps  ***
43      !!
44      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
45      !!      trend and add it to the general trend of tracer equation.
46      !!
47      !! ** Method  :   The horizontal component of the lateral diffusive trends
48      !!      is provided by a 2nd order operator rotated along neural or geopo-
49      !!      tential surfaces to which an eddy induced advection can be added
50      !!      It is computed using before fields (forward in time) and isopyc-
51      !!      nal or geopotential slopes computed in routine ldfslp.
52      !!
53      !!      horizontal fluxes associated with the rotated lateral mixing:
54      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
55      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
56      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
57      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
58      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
59      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
60      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
61      !!      take the horizontal divergence of the fluxes:
62      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
63      !!      Add this trend to the general trend (ta,sa):
64      !!         ta = ta + difft
65      !!
66      !!      'key_trdtra' defined: the trend is saved for diagnostics.
67      !!
68      !!      macro-tasked on horizontal slab (jk-loop).
69      !!
70      !! ** Action :
71      !!         Update (ta,sa) arrays with the before along level biharmonic
72      !!      mixing trend.
73      !!         Save in (ttrd,strd) arrays the trends if 'key_diatrends' defined
74      !!
75      !! History :
76      !!        !  94-08  (G. Madec, M. Imbard)
77      !!        !  97-05  (G. Madec)  split into traldf and trazdf
78      !!   8.5  !  02-08  (G. Madec)  Free form, F90
79      !!----------------------------------------------------------------------
80      !! * Modules used
81      USE oce           , zftu => ua,  &  ! use ua as workspace
82         &                zfsu => va      ! use va as workspace
83
84      !! * Arguments
85      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
86
87      !! * Local declarations
88      INTEGER ::   ji, jj, jk             ! dummy loop indices
89      INTEGER ::   iku, ikv               ! temporary integer
90      REAL(wp) ::   &
91         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
92         zmsku, zmskv, zbtr, zta, zsa, &
93         zcg1, zcg2, zuwk, zvwk,       &
94         zuwk1, zvwk1,                 &
95         ztagu, ztagv, zsagu, zsagv
96      REAL(wp), DIMENSION(jpi,jpj) ::   &
97         zdkt , zdk1t, zftug, zftvg,   &  ! temporary workspace
98         zdks , zdk1s, zfsug, zfsvg       !    "           "
99      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
100         zftv, zgtbu, zgtbv,           &  ! temporary workspace
101         zfsv, zgsbu, zgsbv               !    "           "
102      !!----------------------------------------------------------------------
103
104      IF( kt == nit000 ) THEN
105         IF(lwp) WRITE(numout,*)
106         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_zps : iso neutral laplacian diffusion in '
107         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~   z-coordinates with partial steps'
108#if defined key_diaeiv
109         u_eiv(:,:,:) = 0.e0
110         v_eiv(:,:,:) = 0.e0
111#endif
112      ENDIF
113
114      ztagu = 0.e0
115      ztagv = 0.e0
116      zsagu = 0.e0
117      zsagv = 0.e0
118
119      ! Horizontal temperature and salinity gradient
120      DO jk = 1, jpk
121         DO jj = 1, jpj-1
122            DO ji = 1, fs_jpim1   ! vector opt.
123               zgtbu(ji,jj,jk) = tmask(ji,jj,jk) * ( tb(ji+1,jj  ,jk) - tb(ji,jj,jk) )
124               zgsbu(ji,jj,jk) = tmask(ji,jj,jk) * ( sb(ji+1,jj  ,jk) - sb(ji,jj,jk) )
125               zgtbv(ji,jj,jk) = tmask(ji,jj,jk) * ( tb(ji  ,jj+1,jk) - tb(ji,jj,jk) )
126               zgsbv(ji,jj,jk) = tmask(ji,jj,jk) * ( sb(ji  ,jj+1,jk) - sb(ji,jj,jk) )
127            END DO
128         END DO
129      END DO
130      ! partial steps correction at the last level
131      DO jj = 1, jpj-1
132         DO ji = 1, jpi-1
133            ! last level
134       iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
135       ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
136            zgtbu(ji,jj,iku) = gtu(ji,jj) 
137            zgsbu(ji,jj,iku) = gsu(ji,jj)               
138            zgtbv(ji,jj,ikv) = gtv(ji,jj) 
139            zgsbv(ji,jj,ikv) = gsv(ji,jj)               
140         END DO
141      END DO
142     
143      !                                                ! ===============
144      DO jk = 1, jpkm1                                 ! Horizontal slab
145         !                                             ! ===============
146         ! 1. Vertical tracer gradient at level jk and jk+1
147         ! ------------------------------------------------
148         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
149
150         zdk1t(:,:) = ( tb(:,:,jk) - tb(:,:,jk+1) ) * tmask(:,:,jk+1)
151         zdk1s(:,:) = ( sb(:,:,jk) - sb(:,:,jk+1) ) * tmask(:,:,jk+1)
152
153         IF( jk == 1 ) THEN
154            zdkt(:,:) = zdk1t(:,:)
155            zdks(:,:) = zdk1s(:,:)
156         ELSE
157            zdkt(:,:) = ( tb(:,:,jk-1) - tb(:,:,jk) ) * tmask(:,:,jk)
158            zdks(:,:) = ( sb(:,:,jk-1) - sb(:,:,jk) ) * tmask(:,:,jk)
159         ENDIF
160
161
162         ! 2. Horizontal fluxes
163         ! --------------------
164
165         DO jj = 1 , jpjm1
166            DO ji = 1, fs_jpim1   ! vector opt.
167               zabe1 = ( fsahtu(ji,jj,jk) + ahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
168               zabe2 = ( fsahtv(ji,jj,jk) + ahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
169
170               zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
171                                + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
172
173               zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
174                                + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
175
176               zcof1 = -fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
177               zcof2 = -fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
178
179               zftu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgtbu(ji,jj,jk)   &
180                  &                                + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
181                  &                                           + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
182               zftv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgtbv(ji,jj,jk)   &
183                  &                                + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
184                  &                                           + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
185               zfsu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgsbu(ji,jj,jk)   &
186                  &                                + zcof1 * (  zdks (ji+1,jj) + zdk1s(ji,jj)      &
187                  &                                           + zdk1s(ji+1,jj) + zdks (ji,jj)  )  )
188               zfsv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgsbv(ji,jj,jk)   &
189                  &                                + zcof2 * (  zdks (ji,jj+1) + zdk1s(ji,jj)      &
190                  &                                           + zdk1s(ji,jj+1) + zdks (ji,jj)  )  )
191            END DO
192         END DO
193
194         !                              ! ---------------------------------------!
195         IF( lk_traldf_eiv ) THEN       ! Eddy induced vertical advective fluxes !
196            !                           ! ---------------------------------------!
197            DO jj = 1, jpjm1
198               DO ji = 1, fs_jpim1   ! vector opt.
199                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeiu(ji,jj,jk  ) * umask(ji,jj,jk  )
200                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeiu(ji,jj,jk+1) * umask(ji,jj,jk+1)
201                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeiv(ji,jj,jk  ) * vmask(ji,jj,jk  )
202                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeiv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
203
204                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
205                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
206
207                  zftug(ji,jj) = zcg1 * ( tb(ji+1,jj,jk) + tb(ji,jj,jk) )
208                  zftvg(ji,jj) = zcg2 * ( tb(ji,jj+1,jk) + tb(ji,jj,jk) )
209                  zfsug(ji,jj) = zcg1 * ( sb(ji+1,jj,jk) + sb(ji,jj,jk) )
210                  zfsvg(ji,jj) = zcg2 * ( sb(ji,jj+1,jk) + sb(ji,jj,jk) )
211
212                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
213                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
214                  zfsu(ji,jj,jk) = zfsu(ji,jj,jk) + zfsug(ji,jj)
215                  zfsv(ji,jj,jk) = zfsv(ji,jj,jk) + zfsvg(ji,jj)
216#   if defined key_diaeiv
217                  u_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
218                  v_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
219#   endif
220               END DO
221            END DO
222         ENDIF
223
224         ! II.4 Second derivative (divergence) and add to the general trend
225         ! ----------------------------------------------------------------
226
227         DO jj = 2 , jpjm1
228            DO ji = fs_2, fs_jpim1   ! vector opt.
229               zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
230               zta = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
231               zsa = zbtr * ( zfsu(ji,jj,jk) - zfsu(ji-1,jj,jk) + zfsv(ji,jj,jk) - zfsv(ji,jj-1,jk)  )
232               ta (ji,jj,jk) = ta (ji,jj,jk) + zta
233               sa (ji,jj,jk) = sa (ji,jj,jk) + zsa
234#if defined key_trdtra || defined key_trdmld
235               ttrd (ji,jj,jk,3) = zta
236               strd (ji,jj,jk,3) = zsa
237#endif
238            END DO
239         END DO
240#if defined key_trdtra || defined key_trdmld
241         IF( lk_traldf_eiv ) THEN
242         DO jj = 2 , jpjm1
243            DO ji = fs_2, fs_jpim1   ! vector opt.
244               zbtr= 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
245               ztagu = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
246               ztagv = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
247               zsagu = ( zfsug(ji,jj) - zfsug(ji-1,jj  ) ) * zbtr
248               zsagv = ( zfsvg(ji,jj) - zfsvg(ji  ,jj-1) ) * zbtr
249               ttrdh(ji,jj,jk,3) = ztagu
250               ttrdh(ji,jj,jk,4) = ztagv
251               strdh(ji,jj,jk,3) = zsagu
252               strdh(ji,jj,jk,4) = zsagv
253               ttrd (ji,jj,jk,3) = ttrd(ji,jj,jk,3) - ztagu - ztagv
254               strd (ji,jj,jk,3) = ttrd(ji,jj,jk,3) - zsagu - zsagv
255            END DO
256         END DO
257         ENDIF
258#endif
259         !                                          ! ===============
260      END DO                                        !   End of slab 
261      !                                             ! ===============
262
263      IF( l_ctl .AND. lwp ) THEN         ! print mean trends (used for debugging)
264         zta = SUM( ta(2:jpim1,2:jpjm1,1:jpkm1) * tmask(2:jpim1,2:jpjm1,1:jpkm1) )
265         zsa = SUM( sa(2:jpim1,2:jpjm1,1:jpkm1) * tmask(2:jpim1,2:jpjm1,1:jpkm1) )
266         WRITE(numout,*) ' ldf  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl
267         t_ctl = zta   ;   s_ctl = zsa
268      ENDIF
269
270
271#if defined key_diaptr
272      !!bug  no separation of diff iso and eiv
273      IF( MOD( kt, nf_ptr ) == 0 ) THEN
274         ! "zonal" mean lateral diffusive heat and salt transports
275         pht_ldf(:,:) = prt_vj( zftv(:,:,:) )
276         pst_ldf(:,:) = prt_vj( zfsv(:,:,:) )
277         ! "zonal" mean lateral eddy induced velocity heat and salt transports
278         pht_eiv(:,:) = prt_vj( zftv(:,:,:) )
279         pst_eiv(:,:) = prt_vj( zfsv(:,:,:) )
280      ENDIF
281#endif
282
283   END SUBROUTINE tra_ldf_iso_zps
284
285#else
286   !!----------------------------------------------------------------------
287   !!   default option :   Dummy code   NO rotation of the diffusive tensor
288   !!----------------------------------------------------------------------
289CONTAINS
290   SUBROUTINE tra_ldf_iso_zps( kt )               ! Empty routine
291      WRITE(*,*) kt
292   END SUBROUTINE tra_ldf_iso_zps
293#endif
294
295   !!==============================================================================
296END MODULE traldf_iso_zps
Note: See TracBrowser for help on using the repository browser.