New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 193

Last change on this file since 193 was 132, checked in by opalod, 20 years ago

CT : UPDATE082 : Finalization of the poleward transport diagnostics
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 7.6 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6
7   !!----------------------------------------------------------------------
8   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
9   !!                 using a iso-level harmonic (laplacien) operator.
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE oce             ! ocean dynamics and active tracers
13   USE dom_oce         ! ocean space and time domain
14   USE ldftra_oce      ! ocean active tracers: lateral physics
15   USE trdtra_oce      ! ocean active tracer trends
16   USE in_out_manager  ! I/O manager
17   USE diaptr          ! poleward transport diagnostics
18
19
20   IMPLICIT NONE
21   PRIVATE
22
23   !! * Routine accessibility
24   PUBLIC tra_ldf_lap  ! routine called by step.F90
25
26   !! * Substitutions
27#  include "domzgr_substitute.h90"
28#  include "ldftra_substitute.h90"
29#  include "vectopt_loop_substitute.h90"
30   !!----------------------------------------------------------------------
31   !!   OPA 9.0 , LODYC-IPSL (2003)
32   !!----------------------------------------------------------------------
33   
34CONTAINS
35
36   SUBROUTINE tra_ldf_lap( kt )
37      !!----------------------------------------------------------------------
38      !!                  ***  ROUTINE tra_ldf_lap  ***
39      !!                   
40      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
41      !!      trend and add it to the general trend of tracer equation.
42      !!
43      !! ** Method  :   Second order diffusive operator evaluated using before
44      !!      fields (forward time scheme). The horizontal diffusive trends of
45      !!      temperature (idem for salinity) is given by:
46      !!       * s-coordinate ('key_s_coord' defined), the vertical scale
47      !!      factors e3. are inside the derivatives:
48      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
49      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
50      !!       * z-coordinate (default key), e3t=e3u=e3v, the trend becomes:
51      !!          difft = 1/(e1t*e2t) {  di-1[ aht e2u/e1u di(tb) ]
52      !!                               + dj-1[ aht e1v/e2v dj(tb) ] }
53      !!      Add this trend to the general tracer trend (ta,sa):
54      !!          (ta,sa) = (ta,sa) + ( difft , diffs )
55      !!
56      !! ** Action  : - Update (ta,sa) arrays with the before iso-level
57      !!                harmonic mixing trend.
58      !!              - Save the trends in (ttrd,strd) ('key_diatrends')
59      !!
60      !! History :
61      !!   1.0  !  87-06  (P. Andrich, D. L Hostis)  Original code
62      !!        !  91-11  (G. Madec)
63      !!        !  95-11  (G. Madec)  suppress volumetric scale factors
64      !!        !  96-01  (G. Madec)  statement function for e3
65      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
66      !!----------------------------------------------------------------------
67      USE oce              , ztu => ua,  &  ! use ua as workspace
68         &                   zsu => va      ! use va as workspace
69
70      !! * Arguments
71      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
72     
73      !! * Local save
74      REAL(wp), DIMENSION(jpi,jpj), SAVE ::   &
75         ze1ur, ze2vr, zbtr2              ! scale factor coefficients
76     
77      !! * Local declarations
78      INTEGER ::   ji, jj, jk             ! dummy loop indices
79      REAL(wp) ::   &
80         zabe1, zabe2, zbtr, zta, zsa     ! temporary scalars
81      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
82         ztv, zsv               ! workspace
83      !!----------------------------------------------------------------------
84     
85      IF( kt == nit000 ) THEN
86         IF(lwp) WRITE(numout,*)
87         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion'
88         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
89         ze1ur(:,:) = e2u(:,:) / e1u(:,:)
90         ze2vr(:,:) = e1v(:,:) / e2v(:,:)
91         zbtr2(:,:) = 1. / ( e1t(:,:) * e2t(:,:) )
92      ENDIF
93     
94      !                                                  ! =============
95      DO jk = 1, jpkm1                                   ! Vertical slab
96         !                                               ! =============
97         ! 1. First derivative (gradient)
98         ! -------------------
99         DO jj = 1, jpjm1
100            DO ji = 1, fs_jpim1   ! vector opt.
101#if defined key_s_coord
102               zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * ze1ur(ji,jj) * fse3u(ji,jj,jk)
103               zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * ze2vr(ji,jj) * fse3v(ji,jj,jk)
104#else
105               zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * ze1ur(ji,jj)
106               zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * ze2vr(ji,jj)
107#endif
108               ztu(ji,jj,jk) = zabe1 * ( tb(ji+1,jj  ,jk) - tb(ji,jj,jk) )
109               zsu(ji,jj,jk) = zabe1 * ( sb(ji+1,jj  ,jk) - sb(ji,jj,jk) )
110               ztv(ji,jj,jk) = zabe2 * ( tb(ji  ,jj+1,jk) - tb(ji,jj,jk) )
111               zsv(ji,jj,jk) = zabe2 * ( sb(ji  ,jj+1,jk) - sb(ji,jj,jk) )
112            END DO 
113         END DO 
114         
115         
116         ! 2. Second derivative (divergence)
117         ! --------------------
118         DO jj = 2, jpjm1
119            DO ji = fs_2, fs_jpim1   ! vector opt.
120#if defined key_s_coord
121               zbtr = zbtr2(ji,jj) / fse3t(ji,jj,jk)
122#else
123               zbtr = zbtr2(ji,jj)
124#endif
125               ! horizontal diffusive trends
126               zta = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
127                  &          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
128               zsa = zbtr * (  zsu(ji,jj,jk) - zsu(ji-1,jj,jk)   &
129                  &          + zsv(ji,jj,jk) - zsv(ji,jj-1,jk)  )
130               ! add it to the general tracer trends
131               ta(ji,jj,jk) = ta(ji,jj,jk) + zta
132               sa(ji,jj,jk) = sa(ji,jj,jk) + zsa
133#if defined key_trdtra || defined key_trdmld
134               ! save the horizontal diffusive trends
135               ttrd(ji,jj,jk,3) = zta
136               strd(ji,jj,jk,3) = zsa
137#endif
138            END DO 
139         END DO 
140         !                                               ! =============
141      END DO                                             !  End of slab 
142      !                                                  ! =============
143
144      IF(l_ctl) THEN         ! print mean trends (used for debugging)
145         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
146         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
147         WRITE(numout,*) ' ldf  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl
148         t_ctl = zta   ;   s_ctl = zsa
149      ENDIF
150
151      ! "zonal" mean lateral diffusive heat and salt transport
152      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
153# if defined key_s_coord || defined key_partial_steps
154         pht_ldf(:) = ptr_vj( ztv(:,:,:) )
155         pst_ldf(:) = ptr_vj( zsv(:,:,:) )
156# else
157         DO jk = 1, jpkm1
158            DO jj = 2, jpjm1
159               DO ji = fs_2, fs_jpim1   ! vector opt.
160                 ztv(ji,jj,jk) = ztv(ji,jj,jk) * fse3v(ji,jj,jk)
161                 zsv(ji,jj,jk) = zsv(ji,jj,jk) * fse3v(ji,jj,jk)
162               END DO
163            END DO
164         END DO
165         pht_ldf(:) = ptr_vj( ztv(:,:,:) )
166         pst_ldf(:) = ptr_vj( zsv(:,:,:) )
167# endif
168      ENDIF
169
170   END SUBROUTINE tra_ldf_lap
171
172   !!==============================================================================
173END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.