New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_lap.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traldf_lap.F90 @ 247

Last change on this file since 247 was 247, checked in by opalod, 19 years ago

CL : Add CVS Header and CeCILL licence information
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 8.1 KB
Line 
1MODULE traldf_lap
2   !!==============================================================================
3   !!                       ***  MODULE  traldf_lap  ***
4   !! Ocean active tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6
7   !!----------------------------------------------------------------------
8   !!   tra_ldf_lap  : update the tracer trend with the horizontal diffusion
9   !!                 using a iso-level harmonic (laplacien) operator.
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE oce             ! ocean dynamics and active tracers
13   USE dom_oce         ! ocean space and time domain
14   USE ldftra_oce      ! ocean active tracers: lateral physics
15   USE trdmod          ! ocean active tracers trends
16   USE trdmod_oce      ! ocean variables trends
17   USE in_out_manager  ! I/O manager
18   USE diaptr          ! poleward transport diagnostics
19
20
21   IMPLICIT NONE
22   PRIVATE
23
24   !! * Routine accessibility
25   PUBLIC tra_ldf_lap  ! routine called by step.F90
26
27   !! * Substitutions
28#  include "domzgr_substitute.h90"
29#  include "ldftra_substitute.h90"
30#  include "vectopt_loop_substitute.h90"
31   !!----------------------------------------------------------------------
32   !!   OPA 9.0 , LOCEAN-IPSL (2005)
33   !! $Header$
34   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
35   !!----------------------------------------------------------------------
36   
37CONTAINS
38
39   SUBROUTINE tra_ldf_lap( kt )
40      !!----------------------------------------------------------------------
41      !!                  ***  ROUTINE tra_ldf_lap  ***
42      !!                   
43      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
44      !!      trend and add it to the general trend of tracer equation.
45      !!
46      !! ** Method  :   Second order diffusive operator evaluated using before
47      !!      fields (forward time scheme). The horizontal diffusive trends of
48      !!      temperature (idem for salinity) is given by:
49      !!       * s-coordinate ('key_s_coord' defined), the vertical scale
50      !!      factors e3. are inside the derivatives:
51      !!          difft = 1/(e1t*e2t*e3t) {  di-1[ aht e2u*e3u/e1u di(tb) ]
52      !!                                   + dj-1[ aht e1v*e3v/e2v dj(tb) ] }
53      !!       * z-coordinate (default key), e3t=e3u=e3v, the trend becomes:
54      !!          difft = 1/(e1t*e2t) {  di-1[ aht e2u/e1u di(tb) ]
55      !!                               + dj-1[ aht e1v/e2v dj(tb) ] }
56      !!      Add this trend to the general tracer trend (ta,sa):
57      !!          (ta,sa) = (ta,sa) + ( difft , diffs )
58      !!
59      !! ** Action  : - Update (ta,sa) arrays with the before iso-level
60      !!                harmonic mixing trend.
61      !!              - Save the trends in (ztdta,ztdsa) ('key_trdtra')
62      !!
63      !! History :
64      !!   1.0  !  87-06  (P. Andrich, D. L Hostis)  Original code
65      !!        !  91-11  (G. Madec)
66      !!        !  95-11  (G. Madec)  suppress volumetric scale factors
67      !!        !  96-01  (G. Madec)  statement function for e3
68      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
69      !!   9.0  !  04-08  (C. Talandier) New trends organization
70      !!----------------------------------------------------------------------
71      USE oce              , ztu => ua,  &  ! use ua as workspace
72         &                   zsu => va      ! use va as workspace
73
74      !! * Arguments
75      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
76     
77      !! * Local save
78      REAL(wp), DIMENSION(jpi,jpj), SAVE ::   &
79         ze1ur, ze2vr, zbtr2              ! scale factor coefficients
80     
81      !! * Local declarations
82      INTEGER ::   ji, jj, jk             ! dummy loop indices
83      REAL(wp) ::   &
84         zabe1, zabe2, zbtr, zta, zsa     ! temporary scalars
85      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
86         ztv, zsv,                      &  ! temporary workspace arrays
87         ztdta, ztdsa                      !    "         "
88      !!----------------------------------------------------------------------
89     
90      IF( kt == nit000 ) THEN
91         IF(lwp) WRITE(numout,*)
92         IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion'
93         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
94         ze1ur(:,:) = e2u(:,:) / e1u(:,:)
95         ze2vr(:,:) = e1v(:,:) / e2v(:,:)
96         zbtr2(:,:) = 1. / ( e1t(:,:) * e2t(:,:) )
97      ENDIF
98     
99      ! Save ta and sa trends
100      IF( l_trdtra )   THEN
101         ztdta(:,:,:) = ta(:,:,:) 
102         ztdsa(:,:,:) = sa(:,:,:) 
103      ENDIF
104
105      !                                                  ! =============
106      DO jk = 1, jpkm1                                   ! Vertical slab
107         !                                               ! =============
108         ! 1. First derivative (gradient)
109         ! -------------------
110         DO jj = 1, jpjm1
111            DO ji = 1, fs_jpim1   ! vector opt.
112#if defined key_s_coord
113               zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * ze1ur(ji,jj) * fse3u(ji,jj,jk)
114               zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * ze2vr(ji,jj) * fse3v(ji,jj,jk)
115#else
116               zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * ze1ur(ji,jj)
117               zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * ze2vr(ji,jj)
118#endif
119               ztu(ji,jj,jk) = zabe1 * ( tb(ji+1,jj  ,jk) - tb(ji,jj,jk) )
120               zsu(ji,jj,jk) = zabe1 * ( sb(ji+1,jj  ,jk) - sb(ji,jj,jk) )
121               ztv(ji,jj,jk) = zabe2 * ( tb(ji  ,jj+1,jk) - tb(ji,jj,jk) )
122               zsv(ji,jj,jk) = zabe2 * ( sb(ji  ,jj+1,jk) - sb(ji,jj,jk) )
123            END DO 
124         END DO 
125         
126         
127         ! 2. Second derivative (divergence)
128         ! --------------------
129         DO jj = 2, jpjm1
130            DO ji = fs_2, fs_jpim1   ! vector opt.
131#if defined key_s_coord
132               zbtr = zbtr2(ji,jj) / fse3t(ji,jj,jk)
133#else
134               zbtr = zbtr2(ji,jj)
135#endif
136               ! horizontal diffusive trends
137               zta = zbtr * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk)   &
138                  &          + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
139               zsa = zbtr * (  zsu(ji,jj,jk) - zsu(ji-1,jj,jk)   &
140                  &          + zsv(ji,jj,jk) - zsv(ji,jj-1,jk)  )
141               ! add it to the general tracer trends
142               ta(ji,jj,jk) = ta(ji,jj,jk) + zta
143               sa(ji,jj,jk) = sa(ji,jj,jk) + zsa
144            END DO 
145         END DO 
146         !                                               ! =============
147      END DO                                             !  End of slab 
148      !                                                  ! =============
149
150      ! save the trends for diagnostic
151      ! save the horizontal diffusive trends
152      IF( l_trdtra )   THEN
153         ztdta(:,:,:) = ta(:,:,:) - ztdta(:,:,:)
154         ztdsa(:,:,:) = sa(:,:,:) - ztdsa(:,:,:)
155
156         CALL trd_mod(ztdta, ztdsa, jpttdldf, 'TRA', kt)
157      ENDIF
158
159      IF(l_ctl) THEN         ! print mean trends (used for debugging)
160         zta = SUM( ta(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
161         zsa = SUM( sa(2:nictl,2:njctl,1:jpkm1) * tmask(2:nictl,2:njctl,1:jpkm1) )
162         WRITE(numout,*) ' ldf  - Ta: ', zta-t_ctl, ' Sa: ', zsa-s_ctl
163         t_ctl = zta   ;   s_ctl = zsa
164      ENDIF
165
166      ! "zonal" mean lateral diffusive heat and salt transport
167      IF( ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
168# if defined key_s_coord || defined key_partial_steps
169         pht_ldf(:) = ptr_vj( ztv(:,:,:) )
170         pst_ldf(:) = ptr_vj( zsv(:,:,:) )
171# else
172         DO jk = 1, jpkm1
173            DO jj = 2, jpjm1
174               DO ji = fs_2, fs_jpim1   ! vector opt.
175                 ztv(ji,jj,jk) = ztv(ji,jj,jk) * fse3v(ji,jj,jk)
176                 zsv(ji,jj,jk) = zsv(ji,jj,jk) * fse3v(ji,jj,jk)
177               END DO
178            END DO
179         END DO
180         pht_ldf(:) = ptr_vj( ztv(:,:,:) )
181         pst_ldf(:) = ptr_vj( zsv(:,:,:) )
182# endif
183      ENDIF
184
185   END SUBROUTINE tra_ldf_lap
186
187   !!==============================================================================
188END MODULE traldf_lap
Note: See TracBrowser for help on using the repository browser.