New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in trunk/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMO/OPA_SRC/TRA/traqsr.F90 @ 1656

Last change on this file since 1656 was 1601, checked in by ctlod, 15 years ago

Doctor naming of OPA namelist variables , see ticket: #526
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 21.6 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_qsr      : trend due to the solar radiation penetration
16   !!   tra_qsr_init : solar radiation penetration initialization
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and active tracers
19   USE dom_oce         ! ocean space and time domain
20   USE sbc_oce         ! surface boundary condition: ocean
21   USE trc_oce         ! share SMS/Ocean variables
22   USE trdmod_oce      ! ocean variables trends
23   USE trdmod          ! ocean active tracers trends
24   USE in_out_manager  ! I/O manager
25   USE phycst          ! physical constants
26   USE prtctl          ! Print control
27   USE iom             ! I/O manager
28   USE fldread         ! read input fields
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_qsr        ! routine called by step.F90 (ln_traqsr=T)
34
35   !                                           !!* Namelist namtra_qsr: penetrative solar radiation
36   LOGICAL , PUBLIC ::   ln_traqsr  = .TRUE.    !: light absorption (qsr) flag
37   LOGICAL , PUBLIC ::   ln_qsr_rgb = .FALSE.   !: Red-Green-Blue light absorption flag 
38   LOGICAL , PUBLIC ::   ln_qsr_2bd = .TRUE.    !: 2 band         light absorption flag
39   LOGICAL , PUBLIC ::   ln_qsr_bio = .FALSE.   !: bio-model      light absorption flag
40   INTEGER , PUBLIC ::   nn_chldta  = 0         !: use Chlorophyll data (=1) or not (=0)
41   REAL(wp), PUBLIC ::   rn_abs     = 0.58_wp   !: fraction absorbed in the very near surface (RGB & 2 bands)
42   REAL(wp), PUBLIC ::   rn_si0     = 0.35_wp   !: very near surface depth of extinction      (RGB & 2 bands)
43   REAL(wp), PUBLIC ::   rn_si1     = 23.0_wp   !: deepest depth of extinction (water type I)       (2 bands)
44   REAL(wp), PUBLIC ::   rn_si2     = 61.8_wp   !: deepest depth of extinction (blue & 0.01 mg.m-3)     (RGB)
45   
46   ! Module variables
47   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
48   INTEGER ::   nksr   ! levels below which the light cannot penetrate ( depth larger than 391 m)
49   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
50
51   !! * Substitutions
52#  include "domzgr_substitute.h90"
53#  include "vectopt_loop_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
56   !! $Id$
57   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE tra_qsr( kt )
63      !!----------------------------------------------------------------------
64      !!                  ***  ROUTINE tra_qsr  ***
65      !!
66      !! ** Purpose :   Compute the temperature trend due to the solar radiation
67      !!      penetration and add it to the general temperature trend.
68      !!
69      !! ** Method  : The profile of the solar radiation within the ocean is defined
70      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
71      !!      Considering the 2 wavebands case:
72      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
73      !!         The temperature trend associated with the solar radiation penetration
74      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
75      !!         At the bottom, boudary condition for the radiation is no flux :
76      !!      all heat which has not been absorbed in the above levels is put
77      !!      in the last ocean level.
78      !!         In z-coordinate case, the computation is only done down to the
79      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
80      !!      used for the computation are calculated one for once as they
81      !!      depends on k only.
82      !!
83      !! ** Action  : - update ta with the penetrative solar radiation trend
84      !!              - save the trend in ttrd ('key_trdtra')
85      !!
86      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
87      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
88      !!----------------------------------------------------------------------
89      USE oce, ONLY :   ztrdt => ua   ! use ua as 3D workspace   
90      USE oce, ONLY :   ztrds => va   ! use va as 3D workspace   
91      !!
92      INTEGER, INTENT(in) ::   kt     ! ocean time-step
93      !!
94      INTEGER  ::   ji, jj, jk           ! dummy loop indices
95      INTEGER  ::   irgb                 ! temporary integers
96      REAL(wp) ::   zchl, zcoef, zsi0r   ! temporary scalars
97      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
98      REAL(wp), DIMENSION(jpi,jpj)     ::   zekb, zekg, zekr            ! 2D workspace
99      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze0, ze1 , ze2, ze3, zea    ! 3D workspace
100      !!----------------------------------------------------------------------
101
102      IF( kt == nit000 ) THEN
103         IF(lwp) WRITE(numout,*)
104         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
105         IF(lwp) WRITE(numout,*) '~~~~~~~'
106         CALL tra_qsr_init
107         IF( .NOT.ln_traqsr )   RETURN
108      ENDIF
109
110      IF( l_trdtra ) THEN      ! Save ta and sa trends
111         ztrdt(:,:,:) = ta(:,:,:) 
112         ztrds(:,:,:) = 0.e0
113      ENDIF
114
115     
116      !                                           ! ============================================== !
117      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
118         !                                        ! ============================================== !
119         DO jk = 1, jpkm1
120            DO jj = 2, jpjm1
121               DO ji = fs_2, fs_jpim1   ! vector opt.
122                  ta(ji,jj,jk) = ta(ji,jj,jk) + ro0cpr * ( etot3(ji,jj,jk) - etot3(ji,jj,jk+1) ) / fse3t(ji,jj,jk) 
123               END DO
124            END DO
125         END DO
126         !                                        ! ============================================== !
127      ELSE                                        !  Ocean alone :
128         !                                        ! ============================================== !
129         !
130         !                                                ! ------------------------- !
131         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
132            !                                             ! ------------------------- !
133            ! Set chlorophyl concentration
134            IF( nn_chldta ==1 ) THEN                             !*  Variable Chlorophyll
135               !
136               CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
137               !         
138!CDIR COLLAPSE
139!CDIR NOVERRCHK
140               DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
141!CDIR NOVERRCHK
142                  DO ji = 1, jpi
143                     zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj) ) )
144                     irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
145                     zekb(ji,jj) = rkrgb(1,irgb)
146                     zekg(ji,jj) = rkrgb(2,irgb)
147                     zekr(ji,jj) = rkrgb(3,irgb)
148                  END DO
149               END DO
150               !
151               zsi0r = 1.e0 / rn_si0
152               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
153               ze0(:,:,1) = rn_abs  * qsr(:,:)
154               ze1(:,:,1) = zcoef * qsr(:,:)
155               ze2(:,:,1) = zcoef * qsr(:,:)
156               ze3(:,:,1) = zcoef * qsr(:,:)
157               zea(:,:,1) =         qsr(:,:)
158               !
159               DO jk = 2, nksr+1
160!CDIR NOVERRCHK
161                  DO jj = 1, jpj
162!CDIR NOVERRCHK   
163                     DO ji = 1, jpi
164                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r     )
165                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
166                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
167                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
168                        ze0(ji,jj,jk) = zc0
169                        ze1(ji,jj,jk) = zc1
170                        ze2(ji,jj,jk) = zc2
171                        ze3(ji,jj,jk) = zc3
172                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
173                     END DO
174                  END DO
175               END DO
176               !
177               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
178                  ta(:,:,jk) = ta(:,:,jk) + ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) / fse3t(:,:,jk)
179               END DO
180               !
181            ELSE                                                 !*  Constant Chlorophyll
182               DO jk = 1, nksr
183                  ta(:,:,jk) = ta(:,:,jk) + etot3(:,:,jk) * qsr(:,:)
184               END DO
185            ENDIF
186
187         ENDIF
188         !                                                ! ------------------------- !
189         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
190            !                                             ! ------------------------- !
191            !
192            DO jk = 1, nksr
193               DO jj = 2, jpjm1
194                  DO ji = fs_2, fs_jpim1   ! vector opt.
195                     ta(ji,jj,jk) = ta(ji,jj,jk) + etot3(ji,jj,jk) * qsr(ji,jj)
196                  END DO
197               END DO
198            END DO
199            !
200         ENDIF
201         !
202      ENDIF
203
204      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
205         ztrdt(:,:,:) = ta(:,:,:) - ztrdt(:,:,:)
206         CALL trd_mod( ztrdt, ztrds, jptra_trd_qsr, 'TRA', kt )
207      ENDIF
208      !                       ! print mean trends (used for debugging)
209      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ta, clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
210      !
211   END SUBROUTINE tra_qsr
212
213
214   SUBROUTINE tra_qsr_init
215      !!----------------------------------------------------------------------
216      !!                  ***  ROUTINE tra_qsr_init  ***
217      !!
218      !! ** Purpose :   Initialization for the penetrative solar radiation
219      !!
220      !! ** Method  :   The profile of solar radiation within the ocean is set
221      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
222      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
223      !!      default values correspond to clear water (type I in Jerlov'
224      !!      (1968) classification.
225      !!         called by tra_qsr at the first timestep (nit000)
226      !!
227      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
228      !!
229      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
230      !!----------------------------------------------------------------------
231      INTEGER  ::   ji, jj, jk            ! dummy loop indices
232      INTEGER  ::   irgb, ierror          ! temporary integer
233      INTEGER  ::   ioptio, nqsr          ! temporary integer
234      REAL(wp) ::   zc0  , zc1            ! temporary scalars
235      REAL(wp) ::   zc2  , zc3  , zchl    !    -         -
236      REAL(wp) ::   zsi0r, zsi1r, zcoef   !    -         -
237      REAL(wp), DIMENSION(jpi,jpj)     ::   zekb, zekg, zekr              ! 2D workspace
238      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ze0 , ze1 , ze2 , ze3 , zea   ! 3D workspace
239      !!
240      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
241      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
242      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio,   &
243         &                  nn_chldta, rn_abs, rn_si0, rn_si1, rn_si2
244      !!----------------------------------------------------------------------
245
246      cn_dir = './'       ! directory in which the model is executed
247      ! ... default values (NB: frequency positive => hours, negative => months)
248      !            !     file       ! frequency !  variable  ! time interp !  clim   ! 'yearly' or ! weights  ! rotation   !
249      !            !     name       !  (hours)  !    name    !    (T/F)    !  (T/F)  ! 'monthly'   ! filename ! pairs      !
250      sn_chl = FLD_N( 'chlorophyll' ,    -1     ,  'CHLA'    ,  .true.     , .true.  ,   'yearly'  , ''       , ''         )
251      !
252      REWIND( numnam )            ! Read Namelist namtra_qsr : ratio and length of penetration
253      READ  ( numnam, namtra_qsr )
254      !
255      IF(lwp) THEN                ! control print
256         WRITE(numout,*)
257         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
258         WRITE(numout,*) '~~~~~~~~~~~~'
259         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
260         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
261         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
262         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
263         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
264         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
265         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
266         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
267         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
268         WRITE(numout,*) '      3 bands: longest depth of extinction         rn_si2 = ', rn_si2
269      ENDIF
270
271      IF( ln_traqsr ) THEN     ! control consistency
272         !                     
273         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
274            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
275            ln_qsr_bio = .FALSE.
276         ENDIF
277         !
278         ioptio = 0                      ! Parameter control
279         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
280         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
281         IF( ln_qsr_bio  )   ioptio = ioptio + 1
282         !
283         IF( ioptio /= 1 ) THEN
284            ln_qsr_rgb = .TRUE.
285            nn_chldta  = 0
286            ln_qsr_2bd = .FALSE.
287            ln_qsr_bio = .FALSE.
288            CALL ctl_warn( '          Choose ONE type of light penetration in namelist namtra_qsr',   &
289           &               ' otherwise, we force the model to run with RGB light penetration' )
290         ENDIF
291         !
292         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
293         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
294         IF( ln_qsr_2bd                      )   nqsr =  3
295         IF( ln_qsr_bio                      )   nqsr =  4
296         !
297         IF(lwp) THEN                   ! Print the choice
298            WRITE(numout,*)
299            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B  light penetration - Constant Chlorophyll'
300            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B  light penetration - Chl data '
301            IF( nqsr ==  3 )   WRITE(numout,*) '         2 band light penetration'
302            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
303         ENDIF
304         !
305      ENDIF
306      !                          ! ===================================== !
307      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
308         !                       ! ===================================== !
309         !
310         zsi0r = 1.e0 / rn_si0
311         zsi1r = 1.e0 / rn_si1
312         !                                ! ---------------------------------- !
313         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
314            !                             ! ---------------------------------- !
315            !
316            !                                ! level of light extinction
317            nksr = trc_oce_ext_lev( rn_si2, 0.33e2 )
318            IF(lwp) THEN
319               WRITE(numout,*)
320               WRITE(numout,*) '        level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
321            ENDIF
322            !
323            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
324!!gm            CALL trc_oce_rgb_read( rkrgb )           !* tabulated attenuation coef.
325            !
326            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
327               IF(lwp) WRITE(numout,*)
328               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
329               ALLOCATE( sf_chl(1), STAT=ierror )
330               IF( ierror > 0 ) THEN
331                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
332               ENDIF
333               ALLOCATE( sf_chl(1)%fnow(jpi,jpj)   )
334               ALLOCATE( sf_chl(1)%fdta(jpi,jpj,2) )
335               !                                        ! fill sf_chl with sn_chl and control print
336               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
337                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
338               !
339            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
340               IF(lwp) WRITE(numout,*)
341               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
342               IF(lwp) WRITE(numout,*) '        light distribution computed once for all'
343               !
344               zchl = 0.05                                 ! constant chlorophyll
345               irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
346               zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyl concentration
347               zekg(:,:) = rkrgb(2,irgb)
348               zekr(:,:) = rkrgb(3,irgb)
349               !
350               zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
351               ze0(:,:,1) = rn_abs
352               ze1(:,:,1) = zcoef
353               ze2(:,:,1) = zcoef 
354               ze3(:,:,1) = zcoef
355               zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
356               
357               DO jk = 2, nksr+1
358!CDIR NOVERRCHK
359                  DO jj = 1, jpj
360!CDIR NOVERRCHK   
361                     DO ji = 1, jpi
362                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zsi0r     )
363                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
364                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
365                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
366                        ze0(ji,jj,jk) = zc0                 
367                        ze1(ji,jj,jk) = zc1
368                        ze2(ji,jj,jk) = zc2     
369                        ze3(ji,jj,jk) = zc3
370                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
371                     END DO
372                  END DO
373               END DO 
374               !
375               DO jk = 1, nksr
376                  etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) / fse3t(:,:,jk)
377               END DO
378               etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
379            ENDIF
380            !
381         ENDIF
382            !                             ! ---------------------------------- !
383         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
384            !                             ! ---------------------------------- !
385            !
386            !                                ! level of light extinction
387            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
388            IF(lwp) THEN
389               WRITE(numout,*)
390               WRITE(numout,*) '        level max of computation of qsr = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m'
391            ENDIF
392            !
393            DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
394               DO jj = 1, jpj                              ! top 400 meters
395                  DO ji = 1, jpi
396                     zc0 = rn_abs * EXP( -fsdepw(ji,jj,jk  )*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk  )*zsi1r )
397                     zc1 = rn_abs * EXP( -fsdepw(ji,jj,jk+1)*zsi0r ) + (1.-rn_abs) * EXP( -fsdepw(ji,jj,jk+1)*zsi1r )
398                     etot3(ji,jj,jk) = ro0cpr * (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) / fse3t(ji,jj,jk)
399                  END DO
400               END DO
401            END DO
402            etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
403            !
404         ENDIF
405         !                       ! ===================================== !
406      ELSE                       !        No light penetration           !                   
407         !                       ! ===================================== !
408         IF(lwp) THEN
409            WRITE(numout,*)
410            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
411            WRITE(numout,*) '~~~~~~~~~~~~'
412         ENDIF
413      ENDIF
414      !
415   END SUBROUTINE tra_qsr_init
416
417   !!======================================================================
418END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.