New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in trunk/NEMO/OPA_SRC – NEMO

source: trunk/NEMO/OPA_SRC/daymod.F90 @ 1213

Last change on this file since 1213 was 1213, checked in by smasson, 16 years ago

correct description of variable sec1jan000
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 16.6 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :        !  94-09  (M. Pontaud M. Imbard)  Original code
7   !!                  !  97-03  (O. Marti)
8   !!                  !  97-05  (G. Madec)
9   !!                  !  97-08  (M. Imbard)
10   !!             9.0  !  03-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                  !  04-01  (A.M. Treguier) new calculation based on adatrj
12   !!                  !  06-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------     
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !! 
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !! 
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE prtctl          ! Print control
33   USE restart         !
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC day        ! called by step.F90
39   PUBLIC day_init   ! called by istate.F90
40
41   INTEGER , PUBLIC ::   nyear       !: current year
42   INTEGER , PUBLIC ::   nmonth      !: current month
43   INTEGER , PUBLIC ::   nday        !: current day of the month
44   INTEGER , PUBLIC ::   ndastp      !: time step date in yyyymmdd format
45   INTEGER , PUBLIC ::   nday_year   !: current day counted from jan 1st of the current year
46   REAL(wp), PUBLIC ::   rsec_year   !: current time step counted in second since 00h jan 1st of the current year
47   REAL(wp), PUBLIC ::   rsec_month  !: current time step counted in second since 00h 1st day of the current month
48   REAL(wp), PUBLIC ::   rsec_day    !: current time step counted in second since 00h of the current day
49
50   REAL(wp), PUBLIC ::   adatrj      !: number of elapsed days since the begining of the run
51   !                                 !: it is the accumulated duration of previous runs
52   !                                 !: that may have been run with different time steps.
53   INTEGER , PUBLIC, DIMENSION(0:1)  ::   nyear_len    !: length in days of the previous/current year
54   INTEGER , PUBLIC, DIMENSION(0:13) ::   nmonth_len   !: length in days of the months of the current year
55   REAL(wp), PUBLIC, DIMENSION(0:13) ::   rmonth_half  !: second since the beginning of the year and the halft of the months
56   REAL(wp), PUBLIC, DIMENSION(0:13) ::   rmonth_end   !: second since the beginning of the year and the end of the months
57   REAL(wp), PUBLIC                  ::   sec1jan000   !: second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
58
59   ! this two variables are wrong DO NOT USE THEM !!!
60   INTEGER, PUBLIC, DIMENSION(12) ::   nbiss = (/ 31, 29, 31, 30, 31, 30,    &  !: number of days per month
61      &                                           31, 31, 30, 31, 30, 31 /)     !: (leap-year)
62   INTEGER, PUBLIC, DIMENSION(12) ::   nobis = (/ 31, 28, 31, 30, 31, 30,    &  !: number of days per month
63      &                                           31, 31, 30, 31, 30, 31 /)     !: (365 days a year)
64
65
66   !!----------------------------------------------------------------------
67   !!  OPA 9.0 , LOCEAN-IPSL (2006)
68   !! $Id$
69   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71
72CONTAINS
73
74   SUBROUTINE day_init
75      !!----------------------------------------------------------------------
76      !!                   ***  ROUTINE day_init  ***
77      !!
78      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
79      !!                because day will be called at the beginning of step
80      !!
81      !! ** Action  : - nyear        : current year
82      !!              - nmonth       : current month of the year nyear
83      !!              - nday         : current day of the month nmonth
84      !!              - nday_year    : current day of the year nyear
85      !!              - rsec_year    : current time step counted in second since 00h jan 1st of the current year
86      !!              - rsec_month   : current time step counted in second since 00h 1st day of the current month
87      !!              - rsec_day     : current time step counted in second since 00h of the current day
88      !!              - sec1jan000   : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
89      !!              - nmonth_len, nyear_len, rmonth_half, rmonth_end through day_mth
90      !!----------------------------------------------------------------------
91
92      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
93      IF( MOD( rday, rdttra(1) ) /= 0 )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
94
95      CALL day_rst( nit000, 'READ' ) 
96
97      ! set the calandar from ndastp (read in restart file and namelist)
98
99      nyear   =   ndastp / 10000
100      nmonth  = ( ndastp - (nyear * 10000) ) / 100
101      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 ) 
102
103      sec1jan000 = 0.e0
104      CALL day_mth
105     
106      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
107         nmonth = nmonth - 1 
108         nday = nmonth_len(nmonth)
109      ENDIF
110      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
111         nmonth = 12
112         nyear = nyear - 1
113         sec1jan000 = sec1jan000 - rday * REAL( nyear_len(0), wp )
114         IF( nleapy == 1 )   CALL day_mth
115      ENDIF
116     
117      ! day since january 1st
118      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
119     
120      ! number of seconds since the beginning of current year/month at the middle of the time-step
121      rsec_year  = REAL( nday_year, wp ) * rday - 0.5 * rdttra(1)   ! 1 time step before the middle of the first time step
122      rsec_month = REAL( nday     , wp ) * rday - 0.5 * rdttra(1)   ! because day will be called at the beginning of step
123      rsec_day   =                         rday - 0.5 * rdttra(1)
124
125      ! control print
126      IF(lwp) WRITE(numout,*)' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
127           &                   nyear, '/', nmonth, '/', nday, '  rsec_day:', rsec_day
128     
129   END SUBROUTINE day_init
130
131
132   SUBROUTINE day_mth
133      !!----------------------------------------------------------------------
134      !!                   ***  ROUTINE day_init  ***
135      !!
136      !! ** Purpose :   calendar values related to the months
137      !!
138      !! ** Action  : - nmonth_len    : length in days of the months of the current year
139      !!              - nyear_len     : length in days of the previous/current year
140      !!              - rmonth_half   : second since the beginning of the year and the halft of the months
141      !!              - rmonth_end    : second since the beginning of the year and the end of the months
142      !!----------------------------------------------------------------------
143      INTEGER  ::   jm               ! dummy loop indice
144      !!----------------------------------------------------------------------
145
146      ! length of the month of the current year (from nleapy, read in namelist)
147      IF ( nleapy < 2 ) THEN
148         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
149         nyear_len(:) = 365
150         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
151            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
152               nyear_len(0) = 366
153            ENDIF
154            IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN
155               nmonth_len(2) = 29
156               nyear_len(1) = 366
157            ENDIF
158         ENDIF
159      ELSE
160         nmonth_len(:) = nleapy   ! all months with nleapy days per year
161         nyear_len(:) = 12 * nleapy
162      ENDIF
163
164      ! half month in second since the begining of the year:
165      ! time since Jan 1st   0     1     2    ...    11    12    13
166      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
167      !                 <---> <---> <--->  ...  <---> <---> <--->       
168      ! month number      0     1     2    ...    11    12    13
169      !
170      ! rmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
171      rmonth_half(0) = - 0.5 * rday * REAL( nmonth_len(0), wp )
172      DO jm = 1, 13
173         rmonth_half(jm) = rmonth_half(jm-1) + 0.5 * rday * REAL( nmonth_len(jm-1) + nmonth_len(jm), wp )
174      END DO
175
176      rmonth_end(0) = 0.
177      DO jm = 1, 13
178         rmonth_end(jm) = rmonth_end(jm-1) + rday * REAL( nmonth_len(jm), wp )
179      END DO
180                 
181   END SUBROUTINE
182
183
184   SUBROUTINE day( kt )
185      !!----------------------------------------------------------------------
186      !!                      ***  ROUTINE day  ***
187      !!
188      !! ** Purpose :   Compute the date with a day iteration IF necessary.
189      !!
190      !! ** Method  : - ???
191      !!
192      !! ** Action  : - nyear     : current year
193      !!              - nmonth    : current month of the year nyear
194      !!              - nday      : current day of the month nmonth
195      !!              - nday_year : current day of the year nyear
196      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
197      !!              - adatrj    : date in days since the beginning of the run
198      !!              - rsec_year : current time of the year (in second since 00h, jan 1st)
199      !!----------------------------------------------------------------------     
200      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
201      !
202      CHARACTER (len=25) ::   charout
203      !!----------------------------------------------------------------------
204
205      !                                                 ! New time-step
206      rsec_year  = rsec_year  + rdttra(1) 
207      rsec_month = rsec_month + rdttra(1)                 
208      rsec_day   = rsec_day   + rdttra(1)                 
209      adatrj = adatrj + rdttra(1) / rday
210     
211      IF( rsec_day > rday ) THEN                        ! NEW day
212         !
213         nday      = nday + 1
214         nday_year = nday_year + 1
215         rsec_day  = 0.5 * rdttra(1)                 
216         !
217         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! NEW month
218            nday   = 1
219            nmonth = nmonth + 1
220            rsec_month = 0.5 * rdttra(1)
221            IF( nmonth == 13 ) THEN                     ! NEW year
222               nyear     = nyear + 1
223               nmonth    = 1
224               nday_year = 1
225               rsec_year = 0.5 * rdttra(1)
226               sec1jan000 = sec1jan000 + rday * REAL( nyear_len(1), wp )
227               IF( nleapy == 1 )   CALL day_mth
228            ENDIF
229         ENDIF
230         !
231         ndastp = nyear * 10000 + nmonth * 100 + nday   ! NEW date
232         !
233         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
234              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
235         IF(lwp) WRITE(numout,'(a,F9.0,a,F9.0,a,F9.0)') '         rsec_year = ', rsec_year,   &
236              &   '   rsec_month = ', rsec_month, '   rsec_day = ', rsec_day
237      ENDIF
238     
239      IF(ln_ctl) THEN
240         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
241         CALL prt_ctl_info(charout)
242      ENDIF
243
244      IF( lrst_oce )   CALL day_rst( kt, 'WRITE' )
245      !
246   END SUBROUTINE day
247
248
249   SUBROUTINE day_rst( kt, cdrw )
250      !!---------------------------------------------------------------------
251      !!                   ***  ROUTINE ts_rst  ***
252      !!
253      !!  ** Purpose : Read or write calendar in restart file:
254      !!
255      !!  WRITE(READ) mode:
256      !!       kt        : number of time step since the begining of the experiment at the
257      !!                   end of the current(previous) run
258      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
259      !!                   end of the current(previous) run (REAL -> keep fractions of day)
260      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
261      !!
262      !!   According to namelist parameter nrstdt,
263      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
264      !!       nrstdt = 1  we verify that nit000 is equal to the last
265      !!                   time step of previous run + 1.
266      !!       In both those options, the  exact duration of the experiment
267      !!       since the beginning (cumulated duration of all previous restart runs)
268      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
269      !!       This is valid is the time step has remained constant.
270      !!
271      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
272      !!                    has been stored in the restart file.
273      !!----------------------------------------------------------------------
274      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
275      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
276      !
277      REAL(wp) ::   zkt, zndastp
278      !!----------------------------------------------------------------------
279     
280      IF( TRIM(cdrw) == 'READ' ) THEN
281
282         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
283            ! Get Calendar informations
284            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
285            IF(lwp) THEN
286               WRITE(numout,*) ' *** Info read in restart : '
287               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
288               WRITE(numout,*) ' *** restart option'
289               SELECT CASE ( nrstdt )
290               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
291               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
292               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
293               END SELECT
294               WRITE(numout,*)
295            ENDIF
296            ! Control of date
297            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         & 
298                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 & 
299                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
300            ! define ndastp and adatrj
301            IF ( nrstdt == 2 ) THEN
302               CALL iom_get( numror, 'ndastp', zndastp )
303               ndastp = NINT( zndastp )
304               CALL iom_get( numror, 'adatrj', adatrj  )
305            ELSE
306               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam
307               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
308               ! note this is wrong if time step has changed during run
309            ENDIF
310         ELSE
311            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam
312            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
313         ENDIF
314         !
315         IF(lwp) THEN
316            WRITE(numout,*) ' *** Info used values : '
317            WRITE(numout,*) '   date ndastp                                      : ', ndastp
318            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
319            WRITE(numout,*)
320         ENDIF
321         !
322      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
323         !
324         IF( kt == nitrst ) THEN
325            IF(lwp) WRITE(numout,*)
326            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
327            IF(lwp) WRITE(numout,*) '~~~~~~~'         
328         ENDIF
329         ! calendar control
330         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
331         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
332         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
333         !                                                                     ! the begining of the run [s]
334      ENDIF
335      !
336   END SUBROUTINE day_rst
337
338   !!======================================================================
339END MODULE daymod
Note: See TracBrowser for help on using the repository browser.