New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in trunk/NEMO/OPA_SRC – NEMO

source: trunk/NEMO/OPA_SRC/daymod.F90 @ 1713

Last change on this file since 1713 was 1713, checked in by smasson, 15 years ago

suppress nbiss and nobis, see ticket:589
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 16.8 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------     
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !! 
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !! 
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE restart         !
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   day        ! called by step.F90
40   PUBLIC   day_init   ! called by istate.F90
41
42   INTEGER , PUBLIC ::   nyear       !: current year
43   INTEGER , PUBLIC ::   nmonth      !: current month
44   INTEGER , PUBLIC ::   nday        !: current day of the month
45   INTEGER , PUBLIC ::   ndastp      !: time step date in yyyymmdd format
46   INTEGER , PUBLIC ::   nday_year   !: current day counted from jan 1st of the current year
47   REAL(wp), PUBLIC ::   rsec_year   !: current time step counted in second since 00h jan 1st of the current year
48   REAL(wp), PUBLIC ::   rsec_month  !: current time step counted in second since 00h 1st day of the current month
49   REAL(wp), PUBLIC ::   rsec_day    !: current time step counted in second since 00h of the current day
50
51   REAL(wp), PUBLIC ::   fjulday     !: julian day
52   REAL(wp), PUBLIC ::   adatrj      !: number of elapsed days since the begining of the whole simulation
53   !                                 !: (cumulative duration of previous runs that may have used different time-step size)
54   INTEGER , PUBLIC, DIMENSION(0: 1) ::   nyear_len    !: length in days of the previous/current year
55   INTEGER , PUBLIC, DIMENSION(0:13) ::   nmonth_len   !: length in days of the months of the current year
56   REAL(wp), PUBLIC, DIMENSION(0:13) ::   rmonth_half  !: second since Jan 1st 0h of the current year and the half of the months
57   REAL(wp), PUBLIC, DIMENSION(0:13) ::   rmonth_end   !: second since Jan 1st 0h of the current year and the end of the months
58   REAL(wp), PUBLIC                  ::   sec1jan000   !: second since Jan 1st 0h of nit000 year and Jan 1st 0h the current year
59
60   !!----------------------------------------------------------------------
61   !! NEMO/OPA 3.2 , LOCEAN-IPSL (2009)
62   !! $Id$
63   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
64   !!----------------------------------------------------------------------
65
66CONTAINS
67
68   SUBROUTINE day_init
69      !!----------------------------------------------------------------------
70      !!                   ***  ROUTINE day_init  ***
71      !!
72      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
73      !!                because day will be called at the beginning of step
74      !!
75      !! ** Action  : - nyear        : current year
76      !!              - nmonth       : current month of the year nyear
77      !!              - nday         : current day of the month nmonth
78      !!              - nday_year    : current day of the year nyear
79      !!              - rsec_year    : current time step counted in second since 00h jan 1st of the current year
80      !!              - rsec_month   : current time step counted in second since 00h 1st day of the current month
81      !!              - rsec_day     : current time step counted in second since 00h of the current day
82      !!              - sec1jan000   : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
83      !!              - nmonth_len, nyear_len, rmonth_half, rmonth_end through day_mth
84      !!----------------------------------------------------------------------
85
86      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
87      IF( MOD( rday, rdttra(1) ) /= 0 )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
88
89      CALL day_rst( nit000, 'READ' ) 
90
91      ! set the calandar from ndastp (read in restart file and namelist)
92
93      nyear   =   ndastp / 10000
94      nmonth  = ( ndastp - (nyear * 10000) ) / 100
95      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 ) 
96
97      CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday )  ! we assume that we start run at 00:00
98      fjulday = fjulday + 1.                             ! move back to the day at nit000 (and not at nit000 - 1)
99
100      sec1jan000 = 0.e0
101      CALL day_mth
102     
103      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
104         nmonth = nmonth - 1 
105         nday = nmonth_len(nmonth)
106      ENDIF
107      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
108         nmonth = 12
109         nyear = nyear - 1
110         sec1jan000 = sec1jan000 - rday * REAL( nyear_len(0), wp )
111         IF( nleapy == 1 )   CALL day_mth
112      ENDIF
113     
114      ! day since january 1st
115      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
116     
117      ! number of seconds since the beginning of current year/month at the middle of the time-step
118      rsec_year  = REAL( nday_year, wp ) * rday - 0.5 * rdttra(1)   ! 1 time step before the middle of the first time step
119      rsec_month = REAL( nday     , wp ) * rday - 0.5 * rdttra(1)   ! because day will be called at the beginning of step
120      rsec_day   =                         rday - 0.5 * rdttra(1)
121
122      ! control print
123      IF(lwp) WRITE(numout,*)' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
124           &                   nyear, '/', nmonth, '/', nday, '  rsec_day:', rsec_day
125     
126   END SUBROUTINE day_init
127
128
129   SUBROUTINE day_mth
130      !!----------------------------------------------------------------------
131      !!                   ***  ROUTINE day_init  ***
132      !!
133      !! ** Purpose :   calendar values related to the months
134      !!
135      !! ** Action  : - nmonth_len    : length in days of the months of the current year
136      !!              - nyear_len     : length in days of the previous/current year
137      !!              - rmonth_half   : second since the beginning of the year and the halft of the months
138      !!              - rmonth_end    : second since the beginning of the year and the end of the months
139      !!----------------------------------------------------------------------
140      INTEGER  ::   jm               ! dummy loop indice
141      !!----------------------------------------------------------------------
142
143      ! length of the month of the current year (from nleapy, read in namelist)
144      IF ( nleapy < 2 ) THEN
145         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
146         nyear_len(:) = 365
147         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
148            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
149               nyear_len(0) = 366
150            ENDIF
151            IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN
152               nmonth_len(2) = 29
153               nyear_len(1) = 366
154            ENDIF
155         ENDIF
156      ELSE
157         nmonth_len(:) = nleapy   ! all months with nleapy days per year
158         nyear_len(:) = 12 * nleapy
159      ENDIF
160
161      ! half month in second since the begining of the year:
162      ! time since Jan 1st   0     1     2    ...    11    12    13
163      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
164      !                 <---> <---> <--->  ...  <---> <---> <--->       
165      ! month number      0     1     2    ...    11    12    13
166      !
167      ! rmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
168      rmonth_half(0) = - 0.5 * rday * REAL( nmonth_len(0), wp )
169      DO jm = 1, 13
170         rmonth_half(jm) = rmonth_half(jm-1) + 0.5 * rday * REAL( nmonth_len(jm-1) + nmonth_len(jm), wp )
171      END DO
172
173      rmonth_end(0) = 0.
174      DO jm = 1, 13
175         rmonth_end(jm) = rmonth_end(jm-1) + rday * REAL( nmonth_len(jm), wp )
176      END DO
177      !           
178   END SUBROUTINE
179
180
181   SUBROUTINE day( kt )
182      !!----------------------------------------------------------------------
183      !!                      ***  ROUTINE day  ***
184      !!
185      !! ** Purpose :   Compute the date with a day iteration IF necessary.
186      !!
187      !! ** Method  : - ???
188      !!
189      !! ** Action  : - nyear     : current year
190      !!              - nmonth    : current month of the year nyear
191      !!              - nday      : current day of the month nmonth
192      !!              - nday_year : current day of the year nyear
193      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
194      !!              - adatrj    : date in days since the beginning of the run
195      !!              - rsec_year : current time of the year (in second since 00h, jan 1st)
196      !!----------------------------------------------------------------------     
197      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
198      !
199      CHARACTER (len=25) ::   charout
200      !!----------------------------------------------------------------------
201
202      !                                                 ! New time-step
203      rsec_year  = rsec_year  + rdttra(1) 
204      rsec_month = rsec_month + rdttra(1)                 
205      rsec_day   = rsec_day   + rdttra(1)                 
206      adatrj  = adatrj  + rdttra(1) / rday
207      fjulday = fjulday + rdttra(1) / rday
208     
209      IF( rsec_day > rday ) THEN                        ! NEW day
210         !
211         nday      = nday + 1
212         nday_year = nday_year + 1
213         rsec_day  = 0.5 * rdttra(1)                 
214         !
215         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! NEW month
216            nday   = 1
217            nmonth = nmonth + 1
218            rsec_month = 0.5 * rdttra(1)
219            IF( nmonth == 13 ) THEN                     ! NEW year
220               nyear     = nyear + 1
221               nmonth    = 1
222               nday_year = 1
223               rsec_year = 0.5 * rdttra(1)
224               sec1jan000 = sec1jan000 + rday * REAL( nyear_len(1), wp )
225               IF( nleapy == 1 )   CALL day_mth
226            ENDIF
227         ENDIF
228         !
229         ndastp = nyear * 10000 + nmonth * 100 + nday   ! NEW date
230         !
231         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
232              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
233         IF(lwp) WRITE(numout,'(a,F9.0,a,F9.0,a,F9.0)') '         rsec_year = ', rsec_year,   &
234              &   '   rsec_month = ', rsec_month, '   rsec_day = ', rsec_day
235      ENDIF
236     
237      IF(ln_ctl) THEN
238         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
239         CALL prt_ctl_info(charout)
240      ENDIF
241
242      IF( lrst_oce )   CALL day_rst( kt, 'WRITE' )
243      !
244   END SUBROUTINE day
245
246
247   SUBROUTINE day_rst( kt, cdrw )
248      !!---------------------------------------------------------------------
249      !!                   ***  ROUTINE ts_rst  ***
250      !!
251      !!  ** Purpose : Read or write calendar in restart file:
252      !!
253      !!  WRITE(READ) mode:
254      !!       kt        : number of time step since the begining of the experiment at the
255      !!                   end of the current(previous) run
256      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
257      !!                   end of the current(previous) run (REAL -> keep fractions of day)
258      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
259      !!
260      !!   According to namelist parameter nrstdt,
261      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
262      !!       nrstdt = 1  we verify that nit000 is equal to the last
263      !!                   time step of previous run + 1.
264      !!       In both those options, the  exact duration of the experiment
265      !!       since the beginning (cumulated duration of all previous restart runs)
266      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
267      !!       This is valid is the time step has remained constant.
268      !!
269      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
270      !!                    has been stored in the restart file.
271      !!----------------------------------------------------------------------
272      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
273      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
274      !
275      REAL(wp) ::   zkt, zndastp
276      !!----------------------------------------------------------------------
277     
278      IF( TRIM(cdrw) == 'READ' ) THEN
279
280         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
281            ! Get Calendar informations
282            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
283            IF(lwp) THEN
284               WRITE(numout,*) ' *** Info read in restart : '
285               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
286               WRITE(numout,*) ' *** restart option'
287               SELECT CASE ( nrstdt )
288               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
289               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
290               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
291               END SELECT
292               WRITE(numout,*)
293            ENDIF
294            ! Control of date
295            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         & 
296                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 & 
297                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
298            ! define ndastp and adatrj
299            IF ( nrstdt == 2 ) THEN 
300               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
301               CALL iom_get( numror, 'ndastp', zndastp )
302               ndastp = NINT( zndastp )
303               CALL iom_get( numror, 'adatrj', adatrj  )
304            ELSE 
305               ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
306               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
307               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
308               ! note this is wrong if time step has changed during run
309            ENDIF
310         ELSE
311            ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
312            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
313            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday 
314         ENDIF
315         !
316         IF(lwp) THEN
317            WRITE(numout,*) ' *** Info used values : '
318            WRITE(numout,*) '   date ndastp                                      : ', ndastp
319            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
320            WRITE(numout,*)
321         ENDIF
322         !
323      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
324         !
325         IF( kt == nitrst ) THEN
326            IF(lwp) WRITE(numout,*)
327            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
328            IF(lwp) WRITE(numout,*) '~~~~~~~'         
329         ENDIF
330         ! calendar control
331         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
332         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
333         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
334         !                                                                     ! the begining of the run [s]
335      ENDIF
336      !
337   END SUBROUTINE day_rst
338
339   !!======================================================================
340END MODULE daymod
Note: See TracBrowser for help on using the repository browser.