New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
mppini.F90 in trunk/NEMO/OPA_SRC – NEMO

source: trunk/NEMO/OPA_SRC/mppini.F90 @ 555

Last change on this file since 555 was 516, checked in by opalod, 18 years ago

nemo_v1_update_072 : CT : - lights modifications to ensure good control prints for the restartability & reproductibility tests

  • build all ocean.output_XXXX files only if logical namelist ln_ctl is TRUE, in all case keep the initial ocean.output file (require a new namelist namctl)
  • conditionning some prints using nprint parameter
  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 18.9 KB
Line 
1MODULE mppini
2   !!==============================================================================
3   !!                       ***  MODULE mppini   ***
4   !! Ocean initialization : distributed memory computing initialization
5   !!==============================================================================
6
7   !!----------------------------------------------------------------------
8   !!   mpp_init       : Lay out the global domain over processors
9   !!   mpp_init2      : Lay out the global domain over processors
10   !!                    with land processor elimination
11   !!   mpp_init_ioispl: IOIPSL initialization in mpp
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE dom_oce         ! ocean space and time domain
15   USE in_out_manager  ! I/O Manager
16   USE sol_oce         ! ocean elliptic solver
17   USE lib_mpp         ! distribued memory computing library
18   USE ioipsl
19
20   IMPLICIT NONE
21   PRIVATE
22
23   !! * Routine accessibility
24   PUBLIC mpp_init       ! called by opa.F90
25   PUBLIC mpp_init2      ! called by opa.F90
26
27   !! * Substitutions
28#  include "domzgr_substitute.h90"
29   !!----------------------------------------------------------------------
30   !!   OPA 9.0 , LOCEAN-IPSL (2005)
31   !! $Header$
32   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
33   !!----------------------------------------------------------------------
34
35CONTAINS
36
37#if ! defined key_mpp_mpi   &&   ! defined key_mpp_shmem
38   !!----------------------------------------------------------------------
39   !!   Default option :                            shared memory computing
40   !!----------------------------------------------------------------------
41
42   SUBROUTINE mpp_init
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE mpp_init  ***
45      !!
46      !! ** Purpose :   Lay out the global domain over processors.
47      !!
48      !! ** Method  :   Shared memory computing, set the local processor
49      !!      variables to the value of the global domain
50      !!
51      !! History :
52      !!   9.0  !  04-01  (G. Madec, J.M. Molines)  F90 : free form, north fold jpni >1
53      !!----------------------------------------------------------------------
54
55      ! No mpp computation
56      nimpp  = 1
57      njmpp  = 1
58      nlci   = jpi
59      nlcj   = jpj
60      nldi   = 1
61      nldj   = 1
62      nlei   = jpi
63      nlej   = jpj
64      nperio = jperio
65      nbondi = 2
66      nbondj = 2
67      nidom  = FLIO_DOM_NONE
68
69      IF(lwp) THEN
70         WRITE(numout,*)
71         WRITE(numout,*) 'mpp_init(2) : NO massively parallel processing'
72         WRITE(numout,*) '~~~~~~~~~~~: '
73         WRITE(numout,*) '         nperio = ', nperio
74         WRITE(numout,*) '         npolj  = ', npolj
75         WRITE(numout,*) '         nimpp  = ', nimpp
76         WRITE(numout,*) '         njmpp  = ', njmpp
77      ENDIF
78
79      IF(  jpni /= 1 .OR. jpnj /= 1 .OR. jpnij /= 1 ) &
80          CALL ctl_stop( 'equality  jpni = jpnj = jpnij = 1 is not satisfied',   &
81          &              'the domain is lay out for distributed memory computing! ' )
82
83   END SUBROUTINE mpp_init
84
85
86   SUBROUTINE mpp_init2 
87      CALL mpp_init                             ! same routine as mpp_init
88   END SUBROUTINE mpp_init2
89
90#else
91   !!----------------------------------------------------------------------
92   !!   'key_mpp_mpi'          OR         MPI massively parallel processing
93   !!   'key_mpp_shmem'                 SHMEM massively parallel processing
94   !!----------------------------------------------------------------------
95
96   SUBROUTINE mpp_init
97      !!----------------------------------------------------------------------
98      !!                  ***  ROUTINE mpp_init  ***
99      !!                   
100      !! ** Purpose :   Lay out the global domain over processors.
101      !!
102      !! ** Method  :   Global domain is distributed in smaller local domains.
103      !!      Periodic condition is a function of the local domain position
104      !!      (global boundary or neighbouring domain) and of the global
105      !!      periodic
106      !!      Type :         jperio global periodic condition
107      !!                     nperio local  periodic condition
108      !!
109      !! ** Action  : - set domain parameters
110      !!                    nimpp     : longitudinal index
111      !!                    njmpp     : latitudinal  index
112      !!                    nperio    : lateral condition type
113      !!                    narea     : number for local area
114      !!                    nlci      : first dimension
115      !!                    nlcj      : second dimension
116      !!                    nbondi    : mark for "east-west local boundary"
117      !!                    nbondj    : mark for "north-south local boundary"
118      !!                    nproc     : number for local processor
119      !!                    noea      : number for local neighboring processor
120      !!                    nowe      : number for local neighboring processor
121      !!                    noso      : number for local neighboring processor
122      !!                    nono      : number for local neighboring processor
123      !!
124      !! History :
125      !!        !  94-11  (M. Guyon)  Original code
126      !!        !  95-04  (J. Escobar, M. Imbard)
127      !!        !  98-02  (M. Guyon)  FETI method
128      !!        !  98-05  (M. Imbard, J. Escobar, L. Colombet )  SHMEM and MPI versions
129      !!   8.5  !  02-08  (G. Madec)  F90 : free form
130      !!----------------------------------------------------------------------
131      !! * Local variables
132      INTEGER ::   ji, jj, jn               ! dummy loop indices
133      INTEGER ::   &
134         ii, ij, ifreq, il1, il2,        &  ! temporary integers
135         iresti, irestj, ijm1, imil,     &  !    "          "
136         inum                               ! temporary logical unit
137
138      INTEGER, DIMENSION(jpni,jpnj) ::   &
139         iimppt, ijmppt, ilcit, ilcjt       ! temporary workspace
140      REAL(wp) ::   zidom, zjdom            ! temporary scalars
141      !!----------------------------------------------------------------------
142
143#if defined key_mpp_shmem
144      IF(lwp) WRITE(numout,*)
145      IF(lwp) WRITE(numout,*) 'mpp_init : Message Passing PVM T3E + SHMEM'
146      IF(lwp) WRITE(numout,*) '~~~~~~~~'
147
148      CALL mppshmem                           ! Initialisation of shmem array
149
150#endif
151#if defined key_mpp_mpi
152      IF(lwp) WRITE(numout,*)
153      IF(lwp) WRITE(numout,*) 'mpp_init : Message Passing MPI'
154      IF(lwp) WRITE(numout,*) '~~~~~~~~'
155#endif
156
157
158      !  1. Dimension arrays for subdomains
159      ! -----------------------------------
160      !  Computation of local domain sizes ilcit() ilcjt()
161      !  These dimensions depend on global sizes jpni,jpnj and jpiglo,jpjglo
162      !  The subdomains are squares leeser than or equal to the global
163      !  dimensions divided by the number of processors minus the overlap
164      !  array (cf. par_oce.F90).
165     
166      nreci  = 2 * jpreci
167      nrecj  = 2 * jprecj
168      iresti = MOD( jpiglo - nreci , jpni )
169      irestj = MOD( jpjglo - nrecj , jpnj )
170
171      IF(  iresti == 0 )   iresti = jpni
172      DO jj = 1, jpnj
173         DO ji = 1, iresti
174            ilcit(ji,jj) = jpi
175         END DO
176         DO ji = iresti+1, jpni
177            ilcit(ji,jj) = jpi -1
178         END DO
179      END DO
180     
181      IF( irestj == 0 )   irestj = jpnj
182      DO ji = 1, jpni
183         DO jj = 1, irestj
184            ilcjt(ji,jj) = jpj
185         END DO
186         DO jj = irestj+1, jpnj
187            ilcjt(ji,jj) = jpj -1
188         END DO
189      END DO
190     
191      IF(lwp) THEN
192         WRITE(numout,*)
193         WRITE(numout,*) '           defines mpp subdomains'
194         WRITE(numout,*) '           ----------------------'
195         WRITE(numout,*) '           iresti=',iresti,' irestj=',irestj
196         WRITE(numout,*) '           jpni  =',jpni  ,' jpnj  =',jpnj
197         ifreq = 4
198         il1   = 1
199         DO jn = 1, (jpni-1)/ifreq+1
200            il2 = MIN( jpni, il1+ifreq-1 )
201            WRITE(numout,*)
202            WRITE(numout,9200) ('***',ji = il1,il2-1)
203            DO jj = jpnj, 1, -1
204               WRITE(numout,9203) ('   ',ji = il1,il2-1)
205               WRITE(numout,9202) jj, ( ilcit(ji,jj),ilcjt(ji,jj),ji = il1,il2 )
206               WRITE(numout,9203) ('   ',ji = il1,il2-1)
207               WRITE(numout,9200) ('***',ji = il1,il2-1)
208            END DO
209            WRITE(numout,9201) (ji,ji = il1,il2)
210            il1 = il1+ifreq
211         END DO
212 9200    FORMAT('     ***',20('*************',a3))
213 9203    FORMAT('     *     ',20('         *   ',a3))
214 9201    FORMAT('        ',20('   ',i3,'          '))
215 9202    FORMAT(' ',i3,' *  ',20(i3,'  x',i3,'   *   '))
216      ENDIF
217
218      zidom = nreci
219      DO ji = 1, jpni
220         zidom = zidom + ilcit(ji,1) - nreci
221      END DO
222      IF(lwp) WRITE(numout,*)
223      IF(lwp) WRITE(numout,*)' sum ilcit(i,1) = ', zidom, ' jpiglo = ', jpiglo
224     
225      zjdom = nrecj
226      DO jj = 1, jpnj
227         zjdom = zjdom + ilcjt(1,jj) - nrecj
228      END DO
229      IF(lwp) WRITE(numout,*)' sum ilcit(1,j) = ', zjdom, ' jpjglo = ', jpjglo
230      IF(lwp) WRITE(numout,*)
231     
232
233      !  2. Index arrays for subdomains
234      ! -------------------------------
235     
236      iimppt(:,:) = 1
237      ijmppt(:,:) = 1
238     
239      IF( jpni > 1 ) THEN
240         DO jj = 1, jpnj
241            DO ji = 2, jpni
242               iimppt(ji,jj) = iimppt(ji-1,jj) + ilcit(ji-1,jj) - nreci
243            END DO
244         END DO
245      ENDIF
246
247      IF( jpnj > 1 ) THEN
248         DO jj = 2, jpnj
249            DO ji = 1, jpni
250               ijmppt(ji,jj) = ijmppt(ji,jj-1)+ilcjt(ji,jj-1)-nrecj
251            END DO
252         END DO
253      ENDIF
254     
255      ! 3. Subdomain description
256      ! ------------------------
257
258      DO jn = 1, jpnij
259         ii = 1 + MOD( jn-1, jpni )
260         ij = 1 + (jn-1) / jpni
261         nimppt(jn) = iimppt(ii,ij)
262         njmppt(jn) = ijmppt(ii,ij)
263         nlcit (jn) = ilcit (ii,ij)     
264         nlci       = nlcit (jn)     
265         nlcjt (jn) = ilcjt (ii,ij)     
266         nlcj       = nlcjt (jn)
267         nbondj = -1                                   ! general case
268         IF( jn   >  jpni          )   nbondj = 0      ! first row of processor
269         IF( jn   >  (jpnj-1)*jpni )   nbondj = 1      ! last  row of processor
270         IF( jpnj == 1             )   nbondj = 2      ! one processor only in j-direction
271         ibonjt(jn) = nbondj
272         
273         nbondi = 0                                    !
274         IF( MOD( jn, jpni ) == 1 )   nbondi = -1      !
275         IF( MOD( jn, jpni ) == 0 )   nbondi =  1      !
276         IF( jpni            == 1 )   nbondi =  2      ! one processor only in i-direction
277         ibonit(jn) = nbondi
278         
279         nldi =  1   + jpreci
280         nlei = nlci - jpreci
281         IF( nbondi == -1 .OR. nbondi == 2 )   nldi = 1
282         IF( nbondi ==  1 .OR. nbondi == 2 )   nlei = nlci
283         nldj =  1   + jprecj
284         nlej = nlcj - jprecj
285         IF( nbondj == -1 .OR. nbondj == 2 )   nldj = 1
286         IF( nbondj ==  1 .OR. nbondj == 2 )   nlej = nlcj
287         nldit(jn) = nldi
288         nleit(jn) = nlei
289         nldjt(jn) = nldj
290         nlejt(jn) = nlej
291      END DO
292     
293
294      ! 4. From global to local
295      ! -----------------------
296
297      nperio = 0
298      IF( jperio == 2 .AND. nbondj == -1 )   nperio = 2
299
300
301      ! 5. Subdomain neighbours
302      ! ----------------------
303
304      nproc = narea - 1
305      noso  = nproc - jpni
306      nowe  = nproc - 1
307      noea  = nproc + 1
308      nono  = nproc + jpni
309      ! great neighbours
310      npnw = nono - 1
311      npne = nono + 1
312      npsw = noso - 1
313      npse = noso + 1
314      nbsw = 1
315      nbnw = 1
316      IF( MOD( nproc, jpni ) == 0 ) THEN
317         nbsw = 0
318         nbnw = 0
319      ENDIF
320      nbse = 1
321      nbne = 1
322      IF( MOD( nproc, jpni ) == jpni-1 ) THEN
323         nbse = 0
324         nbne = 0
325      ENDIF
326      IF(nproc < jpni) THEN
327         nbsw = 0
328         nbse = 0
329      ENDIF
330      IF( nproc >= (jpnj-1)*jpni ) THEN
331         nbnw = 0
332         nbne = 0
333      ENDIF
334      nlcj = nlcjt(narea) 
335      nlci = nlcit(narea) 
336      nldi = nldit(narea)
337      nlei = nleit(narea)
338      nldj = nldjt(narea)
339      nlej = nlejt(narea)
340      nbondi = ibonit(narea)
341      nbondj = ibonjt(narea)
342      nimpp  = nimppt(narea) 
343      njmpp  = njmppt(narea) 
344
345     ! Save processor layout in layout.dat file
346       IF (lwp) THEN
347        inum = 11   
348
349        OPEN(inum,FILE='layout.dat')
350        WRITE(inum,'(a)') '   jpnij     jpi     jpj     jpk  jpiglo  jpjglo'
351        WRITE(inum,'(6i8)') jpnij,jpi,jpj,jpk,jpiglo,jpjglo
352        WRITE(inum,'(a)') 'NAREA nlci nlcj nldi nldj nlei nlej nimpp njmpp'
353
354        DO  jn = 1, jpnij
355         WRITE(inum,'(9i5)') jn, nlcit(jn), nlcjt(jn), &
356                                      nldit(jn), nldjt(jn), &
357                                      nleit(jn), nlejt(jn), &
358                                      nimppt(jn), njmppt(jn)
359        END DO
360        CLOSE(inum)   
361      END IF
362
363
364      ! w a r n i n g  narea (zone) /= nproc (processors)!
365
366      IF( jperio == 1 .OR. jperio == 4 .OR. jperio == 6 ) THEN
367         IF( jpni == 1 )THEN
368            nbondi = 2
369            nperio = 1
370         ELSE
371            nbondi = 0
372         ENDIF
373         IF( MOD( narea, jpni ) == 0 ) THEN
374            noea = nproc-(jpni-1)
375            npne = npne-jpni
376            npse = npse-jpni
377         ENDIF
378         IF( MOD( narea, jpni ) == 1 ) THEN
379            nowe = nproc+(jpni-1)
380            npnw = npnw+jpni
381            npsw = npsw+jpni
382         ENDIF
383         nbsw = 1
384         nbnw = 1
385         nbse = 1
386         nbne = 1
387         IF( nproc < jpni ) THEN
388            nbsw = 0
389            nbse = 0
390         ENDIF
391         IF( nproc >= (jpnj-1)*jpni ) THEN
392            nbnw = 0
393            nbne = 0
394         ENDIF
395      ENDIF
396      npolj = 0
397      IF( jperio == 3 .OR. jperio == 4 ) THEN
398         ijm1 = jpni*(jpnj-1)
399         imil = ijm1+(jpni+1)/2
400         IF( narea > ijm1 ) npolj = 3
401         IF( MOD(jpni,2) == 1 .AND. narea == imil ) npolj = 4
402         IF( npolj == 3 ) nono = jpni*jpnj-narea+ijm1
403      ENDIF
404      IF( jperio == 5 .OR. jperio == 6 ) THEN
405          ijm1 = jpni*(jpnj-1)
406          imil = ijm1+(jpni+1)/2
407          IF( narea > ijm1) npolj = 5
408          IF( MOD(jpni,2) == 1 .AND. narea == imil ) npolj = 6
409          IF( npolj == 5 ) nono = jpni*jpnj-narea+ijm1
410      ENDIF
411
412      ! FETI method
413
414      IF( nperio == 1 .AND. nsolv == 3 ) THEN 
415         
416         ! general case : Earth == infinite tube
417         
418         nbnw = 1
419         npnw = narea
420         nbne = 1
421         npne = narea
422         nbsw = 1
423         npsw = (narea-2)
424         nbse = 1
425         npse = (narea-2)
426         
427         ! REAL boundary condition
428         
429         IF( nbondj == -1 .OR. nbondj == 2 ) THEN
430            nbsw = 0
431            nbse = 0
432         ENDIF
433         
434         IF( nbondj == -1 .OR. nbondj == 2 ) THEN
435            nbsw = 0
436            nbse = 0
437         ENDIF
438         
439         IF( nbondj == 1  .OR. nbondj == 2 ) THEN
440            nbnw = 0
441            nbne = 0
442         ENDIF
443      ENDIF
444
445      ! Periodicity : no corner if nbondi = 2 and nperio != 1
446
447      IF(lwp) THEN
448         WRITE(numout,*) ' nproc  = ', nproc
449         WRITE(numout,*) ' nowe   = ', nowe  , ' noea   =  ', noea
450         WRITE(numout,*) ' nono   = ', nono  , ' noso   =  ', noso
451         WRITE(numout,*) ' nbondi = ', nbondi
452         WRITE(numout,*) ' nbondj = ', nbondj
453         WRITE(numout,*) ' npolj  = ', npolj
454         WRITE(numout,*) ' nperio = ', nperio
455         WRITE(numout,*) ' nlci   = ', nlci
456         WRITE(numout,*) ' nlcj   = ', nlcj
457         WRITE(numout,*) ' nimpp  = ', nimpp
458         WRITE(numout,*) ' njmpp  = ', njmpp
459         WRITE(numout,*) ' nbse   = ', nbse  , ' npse   = ', npse
460         WRITE(numout,*) ' nbsw   = ', nbsw  , ' npsw   = ', npsw
461         WRITE(numout,*) ' nbne   = ', nbne  , ' npne   = ', npne
462         WRITE(numout,*) ' nbnw   = ', nbnw  , ' npnw   = ', npnw
463      ENDIF
464
465      IF( nperio == 1 .AND. jpni /= 1 ) CALL ctl_stop( ' mpp_init: error on cyclicity' )
466
467      ! Prepare mpp north fold
468
469      IF (jperio >= 3 .AND. jperio <= 6 .AND. jpni > 1 ) THEN
470         CALL mpp_ini_north
471      END IF
472
473      ! Prepare NetCDF output file (if necessary)
474      CALL mpp_init_ioipsl
475
476   END SUBROUTINE mpp_init
477
478#  include "mppini_2.h90"
479
480# if defined key_dimgout
481   !!----------------------------------------------------------------------
482   !!   'key_dimgout'                  NO use of NetCDF files
483   !!----------------------------------------------------------------------
484   SUBROUTINE mpp_init_ioipsl       ! Dummy routine
485   END SUBROUTINE mpp_init_ioipsl 
486# else
487   SUBROUTINE mpp_init_ioipsl
488      !!----------------------------------------------------------------------
489      !!                  ***  ROUTINE mpp_init_ioipsl  ***
490      !!
491      !! ** Purpose :   
492      !!
493      !! ** Method  :   
494      !!
495      !! History :
496      !!   9.0  !  04-03  (G. Madec)  MPP-IOIPSL
497      !!----------------------------------------------------------------------
498      !! Local declarations
499
500      INTEGER, DIMENSION(2) ::   &
501         iglo, iloc, iabsf, iabsl, ihals, ihale, idid
502      INTEGER ::   &
503         inbondi, inbondj
504      !!----------------------------------------------------------------------
505
506      ! The domain is splitted only horizontally along i- or/and j- direction
507      ! So we need at the most only 1D arrays with 2 elements
508      iglo(1) = jpiglo
509      iglo(2) = jpjglo
510      iloc(1) = nlci
511      iloc(2) = nlcj
512      iabsf(1) = nimppt(narea)
513      iabsf(2) = njmppt(narea)
514      iabsl(:) = iabsf(:) + iloc(:) - 1
515      ihals(1) = jpreci
516      ihals(2) = jprecj
517      ihale(1) = jpreci
518      ihale(2) = jprecj
519      idid(1) = 1
520      idid(2) = 2
521
522      inbondj = -1                                   ! general case
523      IF( narea   >  jpni          )   inbondj = 0      ! first row of processor
524      IF( narea   >  (jpnj-1)*jpni )   inbondj = 1      ! last  row of processor
525      IF( jpnj    == 1             )   inbondj = 2      ! one processor only in j-direction
526      IF( inbondj == -1 .OR. inbondj == 2 )   ihals(2) = 0
527      IF( inbondj ==  1 .OR. inbondj == 2 )   ihale(2) = 0
528         
529      inbondi = 0                                    !
530      IF( MOD( narea, jpni ) == 1 )   inbondi = -1      !
531      IF( MOD( narea, jpni ) == 0 )   inbondi =  1      !
532      IF( jpni               == 1 )   inbondi =  2      ! one processor only in i-direction
533      IF( inbondi == -1 .OR. inbondi == 2 )   ihals(1) = 0
534      IF( inbondi ==  1 .OR. inbondi == 2 )   ihale(1) = 0
535
536
537      IF(lwp) THEN
538          WRITE(numout,*)
539          WRITE(numout,*) 'mpp_init_ioipsl :   iloc  = ', iloc (1), iloc (2)
540          WRITE(numout,*) '~~~~~~~~~~~~~~~     iabsf = ', iabsf(1), iabsf(2)
541          WRITE(numout,*) '                    ihals = ', ihals(1), ihals(2)
542          WRITE(numout,*) '                    ihale = ', ihale(1), ihale(2)
543      ENDIF
544
545      CALL flio_dom_set ( jpnij, nproc, idid, iglo, iloc, iabsf, iabsl, ihals, ihale, 'BOX', nidom)
546
547   END SUBROUTINE mpp_init_ioipsl 
548
549# endif
550#endif
551
552   !!======================================================================
553END MODULE mppini
Note: See TracBrowser for help on using the repository browser.