1 | MODULE opa |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE opa *** |
---|
4 | !! Ocean system : OPA ocean dynamics (including on-line tracers and sea-ice) |
---|
5 | !!============================================================================== |
---|
6 | |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! opa_model : solve ocean dynamics, tracer and/or sea-ice |
---|
9 | !! opa_init : initialization of the opa model |
---|
10 | !! opa_flg : initialisation of algorithm flag |
---|
11 | !! opa_closefile : close remaining files |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! History : |
---|
14 | !! 4.0 ! 90-10 (C. Levy, G. Madec) Original code |
---|
15 | !! 7.0 ! 91-11 (M. Imbard, C. Levy, G. Madec) |
---|
16 | !! 7.1 ! 93-03 (M. Imbard, C. Levy, G. Madec, O. Marti, |
---|
17 | !! M. Guyon, A. Lazar, P. Delecluse, C. Perigaud, |
---|
18 | !! G. Caniaux, B. Colot, C. Maes ) release 7.1 |
---|
19 | !! ! 92-06 (L.Terray) coupling implementation |
---|
20 | !! ! 93-11 (M.A. Filiberti) IGLOO sea-ice |
---|
21 | !! 8.0 ! 96-03 (M. Imbard, C. Levy, G. Madec, O. Marti, |
---|
22 | !! M. Guyon, A. Lazar, P. Delecluse, L.Terray, |
---|
23 | !! M.A. Filiberti, J. Vialar, A.M. Treguier, |
---|
24 | !! M. Levy) release 8.0 |
---|
25 | !! 8.1 ! 97-06 (M. Imbard, G. Madec) |
---|
26 | !! 8.2 ! 99-11 (M. Imbard, H. Goosse) LIM sea-ice model |
---|
27 | !! ! 99-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP |
---|
28 | !! ! 00-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER) |
---|
29 | !! 9.0 ! 02-08 (G. Madec) F90: Free form and modules |
---|
30 | !! " ! 04-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces |
---|
31 | !! " ! 04-08 (C. Talandier) New trends organization |
---|
32 | !! " ! 05-06 (C. Ethe) Add the 1D configuration possibility |
---|
33 | !! " ! 05-11 (V. Garnier) Surface pressure gradient organization |
---|
34 | !! " ! 06-03 (L. Debreu, C. Mazauric) Agrif implementation |
---|
35 | !! " ! 06-04 (G. Madec, R. Benshila) Step reorganization |
---|
36 | !! " ! 07-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY) |
---|
37 | !!---------------------------------------------------------------------- |
---|
38 | !! * Modules used |
---|
39 | USE oce ! dynamics and tracers variables |
---|
40 | USE dom_oce ! ocean space domain variables |
---|
41 | USE sbc_oce ! surface boundary condition: ocean |
---|
42 | USE trdmod_oce ! ocean variables trends |
---|
43 | USE daymod ! calendar |
---|
44 | USE in_out_manager ! I/O manager |
---|
45 | USE lib_mpp ! distributed memory computing |
---|
46 | |
---|
47 | USE domcfg ! domain configuration (dom_cfg routine) |
---|
48 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
---|
49 | USE domain ! domain initialization (dom_init routine) |
---|
50 | USE obc_par ! open boundary cond. parameters |
---|
51 | USE obcini ! open boundary cond. initialization (obc_ini routine) |
---|
52 | USE bdy_par ! unstructured open boundary cond. parameters |
---|
53 | USE bdyini ! unstructured open boundary cond. initialization (bdy_init routine) |
---|
54 | USE istate ! initial state setting (istate_init routine) |
---|
55 | USE eosbn2 ! equation of state (eos bn2 routine) |
---|
56 | USE zpshde ! partial step: hor. derivative (zps_hde routine) |
---|
57 | |
---|
58 | ! ocean physics |
---|
59 | USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine) |
---|
60 | USE ldftra ! lateral diffusivity setting (ldftra_init routine) |
---|
61 | USE zdfini |
---|
62 | |
---|
63 | USE phycst ! physical constant (par_cst routine) |
---|
64 | USE trdmod ! momentum/tracers trends (trd_mod_init routine) |
---|
65 | |
---|
66 | USE diaptr ! poleward transports (dia_ptr_init routine) |
---|
67 | |
---|
68 | USE step ! OPA time-stepping (stp routine) |
---|
69 | #if defined key_oasis3 |
---|
70 | USE cpl_oasis3 ! OASIS3 coupling |
---|
71 | #elif defined key_oasis4 |
---|
72 | USE cpl_oasis4 ! OASIS4 coupling (not working) |
---|
73 | #endif |
---|
74 | USE dynspg_oce ! Control choice of surface pressure gradient schemes |
---|
75 | USE prtctl ! Print control (prt_ctl_init routine) |
---|
76 | USE c1d ! 1D configuration |
---|
77 | USE dyncor_c1d ! Coriolis factor at T-point |
---|
78 | USE step_c1d ! Time stepping loop for the 1D configuration |
---|
79 | |
---|
80 | USE trcini ! Initialization of the passive tracers |
---|
81 | USE iom |
---|
82 | #if defined key_ioserver |
---|
83 | USE io_interface |
---|
84 | #endif |
---|
85 | |
---|
86 | IMPLICIT NONE |
---|
87 | PRIVATE |
---|
88 | |
---|
89 | !! * Module variables |
---|
90 | CHARACTER (len=64) :: & |
---|
91 | cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
---|
92 | |
---|
93 | !! * Routine accessibility |
---|
94 | PUBLIC opa_model ! called by model.F90 |
---|
95 | PUBLIC opa_init |
---|
96 | !!---------------------------------------------------------------------- |
---|
97 | !! OPA 9.0 , LOCEAN-IPSL (2005) |
---|
98 | !! $Id$ |
---|
99 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
100 | !!---------------------------------------------------------------------- |
---|
101 | |
---|
102 | CONTAINS |
---|
103 | |
---|
104 | SUBROUTINE opa_model |
---|
105 | !!---------------------------------------------------------------------- |
---|
106 | !! *** ROUTINE opa *** |
---|
107 | !! |
---|
108 | !! ** Purpose : opa solves the primitive equations on an orthogonal |
---|
109 | !! curvilinear mesh on the sphere. |
---|
110 | !! |
---|
111 | !! ** Method : - model general initialization |
---|
112 | !! - launch the time-stepping (stp routine) |
---|
113 | !! |
---|
114 | !! References : |
---|
115 | !! Madec, Delecluse,Imbard, and Levy, 1997: reference manual. |
---|
116 | !! internal report, IPSL. |
---|
117 | !!---------------------------------------------------------------------- |
---|
118 | INTEGER :: istp ! time step index |
---|
119 | !!---------------------------------------------------------------------- |
---|
120 | |
---|
121 | #if defined key_agrif |
---|
122 | CALL Agrif_Init_Grids() |
---|
123 | #endif |
---|
124 | |
---|
125 | CALL opa_init ! Initializations |
---|
126 | |
---|
127 | ! check that all process are still there... If some process have an error, |
---|
128 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
---|
129 | IF( lk_mpp ) CALL mpp_max( nstop ) |
---|
130 | |
---|
131 | istp = nit000 |
---|
132 | IF( lk_c1d ) THEN ! 1D configuration (no AGRIF zoom) |
---|
133 | ! |
---|
134 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) |
---|
135 | CALL stp_c1d( istp ) |
---|
136 | istp = istp + 1 |
---|
137 | END DO |
---|
138 | ELSE ! 3D ocean with or without AGRIF zoom |
---|
139 | ! |
---|
140 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) |
---|
141 | #if defined key_agrif |
---|
142 | CALL Agrif_Step( stp ) |
---|
143 | #else |
---|
144 | CALL stp( istp ) |
---|
145 | #endif |
---|
146 | istp = istp + 1 |
---|
147 | IF( lk_mpp ) CALL mpp_max( nstop ) |
---|
148 | END DO |
---|
149 | ENDIF |
---|
150 | ! ! ========= ! |
---|
151 | ! ! Job end ! |
---|
152 | ! ! ========= ! |
---|
153 | |
---|
154 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
155 | |
---|
156 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
---|
157 | WRITE(numout,cform_err) |
---|
158 | WRITE(numout,*) nstop, ' error have been found' |
---|
159 | ENDIF |
---|
160 | |
---|
161 | CALL opa_closefile |
---|
162 | #if defined key_oasis3 || defined key_oasis4 |
---|
163 | call cpl_prism_finalize |
---|
164 | #else |
---|
165 | IF( lk_mpp ) CALL mppstop ! Close all files (mpp) |
---|
166 | #endif |
---|
167 | ! |
---|
168 | END SUBROUTINE opa_model |
---|
169 | |
---|
170 | |
---|
171 | SUBROUTINE opa_init |
---|
172 | !!---------------------------------------------------------------------- |
---|
173 | !! *** ROUTINE opa_init *** |
---|
174 | !! |
---|
175 | !! ** Purpose : initialization of the opa model |
---|
176 | !! |
---|
177 | !!---------------------------------------------------------------------- |
---|
178 | #if defined key_oasis3 || defined key_oasis4 || defined key_ioserver |
---|
179 | INTEGER :: localComm |
---|
180 | #endif |
---|
181 | CHARACTER (len=20) :: namelistname |
---|
182 | CHARACTER (len=28) :: file_out |
---|
183 | NAMELIST/namctl/ ln_ctl, nprint, nictls, nictle, & |
---|
184 | & isplt , jsplt , njctls, njctle, nbench, nbit_cmp |
---|
185 | !!---------------------------------------------------------------------- |
---|
186 | |
---|
187 | ! Initializations |
---|
188 | ! =============== |
---|
189 | |
---|
190 | file_out = 'ocean.output' |
---|
191 | |
---|
192 | ! open listing and namelist units |
---|
193 | CALL ctlopn( numout, file_out, 'UNKNOWN', 'FORMATTED', & |
---|
194 | & 'SEQUENTIAL', 1, 6, .FALSE., 1 ) |
---|
195 | |
---|
196 | WRITE(numout,*) |
---|
197 | WRITE(numout,*) ' L O D Y C - I P S L' |
---|
198 | WRITE(numout,*) ' O P A model' |
---|
199 | WRITE(numout,*) ' Ocean General Circulation Model' |
---|
200 | WRITE(numout,*) ' version OPA 9.0 (2005) ' |
---|
201 | WRITE(numout,*) |
---|
202 | WRITE(numout,*) |
---|
203 | |
---|
204 | namelistname = 'namelist' |
---|
205 | CALL ctlopn( numnam, namelistname, 'OLD', 'FORMATTED', 'SEQUENTIAL', & |
---|
206 | & 1, numout, .FALSE., 1 ) |
---|
207 | |
---|
208 | ! Namelist namctl : Control prints & Benchmark |
---|
209 | REWIND( numnam ) |
---|
210 | READ ( numnam, namctl ) |
---|
211 | |
---|
212 | #if defined key_oasis3 || defined key_oasis4 |
---|
213 | call cpl_prism_init(localComm) |
---|
214 | ! Nodes selection |
---|
215 | narea = mynode(localComm) |
---|
216 | #elif key_ioserver |
---|
217 | CALL init_ioserver(localcomm, .FALSE.) |
---|
218 | narea = mynode(localComm) |
---|
219 | #else |
---|
220 | ! Nodes selection |
---|
221 | narea = mynode() |
---|
222 | #endif |
---|
223 | narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 ) |
---|
224 | lwp = narea == 1 |
---|
225 | |
---|
226 | ! open additionnal listing |
---|
227 | IF( ln_ctl ) THEN |
---|
228 | IF( narea-1 > 0 ) THEN |
---|
229 | WRITE(file_out,FMT="('ocean.output_',I4.4)") narea-1 |
---|
230 | CALL ctlopn( numout, file_out, 'UNKNOWN', 'FORMATTED', & |
---|
231 | & 'SEQUENTIAL', 1, numout, .FALSE., 1 ) |
---|
232 | lwp = .TRUE. |
---|
233 | ! |
---|
234 | WRITE(numout,*) |
---|
235 | WRITE(numout,*) ' L O D Y C - I P S L' |
---|
236 | WRITE(numout,*) ' O P A model' |
---|
237 | WRITE(numout,*) ' Ocean General Circulation Model' |
---|
238 | WRITE(numout,*) ' version OPA 9.0 (2005) ' |
---|
239 | WRITE(numout,*) ' MPI Ocean output ' |
---|
240 | WRITE(numout,*) |
---|
241 | WRITE(numout,*) |
---|
242 | ENDIF |
---|
243 | ENDIF |
---|
244 | |
---|
245 | ! ! ============================== ! |
---|
246 | ! ! Model general initialization ! |
---|
247 | ! ! ============================== ! |
---|
248 | |
---|
249 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
250 | |
---|
251 | CALL opa_flg ! Control prints & Benchmark |
---|
252 | |
---|
253 | ! Domain decomposition |
---|
254 | IF( jpni*jpnj == jpnij ) THEN |
---|
255 | CALL mpp_init ! standard cutting out |
---|
256 | ELSE |
---|
257 | CALL mpp_init2 ! eliminate land processors |
---|
258 | ENDIF |
---|
259 | |
---|
260 | CALL phy_cst ! Physical constants |
---|
261 | |
---|
262 | CALL dom_cfg ! Domain configuration |
---|
263 | |
---|
264 | CALL dom_init ! Domain |
---|
265 | |
---|
266 | IF( lk_c1d ) THEN ! adaptation for 1D configuration |
---|
267 | CALL cor_c1d ! redefine Coriolis at T-point |
---|
268 | umask(:,:,:) = tmask(:,:,:) ! U, V and T-points are the same |
---|
269 | vmask(:,:,:) = tmask(:,:,:) ! |
---|
270 | ENDIF |
---|
271 | |
---|
272 | IF( ln_ctl ) CALL prt_ctl_init ! Print control |
---|
273 | |
---|
274 | IF( lk_obc ) CALL obc_init ! Open boundaries |
---|
275 | |
---|
276 | IF( lk_bdy ) CALL bdy_init ! Unstructured open boundaries |
---|
277 | |
---|
278 | CALL istate_init ! ocean initial state (Dynamics and tracers) |
---|
279 | |
---|
280 | ! ! Ocean physics |
---|
281 | |
---|
282 | CALL ldf_dyn_init ! Lateral ocean momentum physics |
---|
283 | |
---|
284 | CALL ldf_tra_init ! Lateral ocean tracer physics |
---|
285 | |
---|
286 | CALL zdf_init ! Vertical ocean physics |
---|
287 | |
---|
288 | CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends |
---|
289 | |
---|
290 | |
---|
291 | #if defined key_top |
---|
292 | CALL trc_ini ! Passive tracers |
---|
293 | #endif |
---|
294 | |
---|
295 | CALL dia_ptr_init ! Poleward TRansports initialization |
---|
296 | |
---|
297 | CALL iom_init( fjulday - adatrj ) ! iom_put initialization |
---|
298 | |
---|
299 | ! ! =============== ! |
---|
300 | ! ! time stepping ! |
---|
301 | ! ! =============== ! |
---|
302 | |
---|
303 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
304 | |
---|
305 | END SUBROUTINE opa_init |
---|
306 | |
---|
307 | |
---|
308 | SUBROUTINE opa_flg |
---|
309 | !!---------------------------------------------------------------------- |
---|
310 | !! *** ROUTINE opa *** |
---|
311 | !! |
---|
312 | !! ** Purpose : Initialize logical flags that control the choice of |
---|
313 | !! some algorithm or control print |
---|
314 | !! |
---|
315 | !! ** Method : Read in namilist namflg logical flags |
---|
316 | !! |
---|
317 | !! History : |
---|
318 | !! 9.0 ! 03-11 (G. Madec) Original code |
---|
319 | !!---------------------------------------------------------------------- |
---|
320 | !! * Local declarations |
---|
321 | |
---|
322 | NAMELIST/namflg/ ln_dynhpg_imp, nn_dynhpg_rst |
---|
323 | !!---------------------------------------------------------------------- |
---|
324 | |
---|
325 | ! Parameter control and print |
---|
326 | ! --------------------------- |
---|
327 | IF(lwp) THEN |
---|
328 | WRITE(numout,*) |
---|
329 | WRITE(numout,*) 'opa_flg: Control prints & Benchmark' |
---|
330 | WRITE(numout,*) '~~~~~~~ ' |
---|
331 | WRITE(numout,*) ' Namelist namctl' |
---|
332 | WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl |
---|
333 | WRITE(numout,*) ' level of print nprint = ', nprint |
---|
334 | WRITE(numout,*) ' Start i indice for SUM control nictls = ', nictls |
---|
335 | WRITE(numout,*) ' End i indice for SUM control nictle = ', nictle |
---|
336 | WRITE(numout,*) ' Start j indice for SUM control njctls = ', njctls |
---|
337 | WRITE(numout,*) ' End j indice for SUM control njctle = ', njctle |
---|
338 | WRITE(numout,*) ' number of proc. following i isplt = ', isplt |
---|
339 | WRITE(numout,*) ' number of proc. following j jsplt = ', jsplt |
---|
340 | WRITE(numout,*) ' benchmark parameter (0/1) nbench = ', nbench |
---|
341 | WRITE(numout,*) ' bit comparison mode (0/1) nbit_cmp = ', nbit_cmp |
---|
342 | ENDIF |
---|
343 | |
---|
344 | ! ... Control the sub-domain area indices for the control prints |
---|
345 | IF( ln_ctl ) THEN |
---|
346 | IF( lk_mpp ) THEN |
---|
347 | ! the domain is forced to the real splitted domain in MPI |
---|
348 | isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj |
---|
349 | ELSE |
---|
350 | IF( isplt == 1 .AND. jsplt == 1 ) THEN |
---|
351 | CALL ctl_warn( ' - isplt & jsplt are equal to 1', & |
---|
352 | & ' - the print control will be done over the whole domain' ) |
---|
353 | ENDIF |
---|
354 | |
---|
355 | ! compute the total number of processors ijsplt |
---|
356 | ijsplt = isplt*jsplt |
---|
357 | ENDIF |
---|
358 | |
---|
359 | IF(lwp) WRITE(numout,*)' - The total number of processors over which the' |
---|
360 | IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt |
---|
361 | |
---|
362 | ! Control the indices used for the SUM control |
---|
363 | IF( nictls+nictle+njctls+njctle == 0 ) THEN |
---|
364 | ! the print control is done over the default area |
---|
365 | lsp_area = .FALSE. |
---|
366 | ELSE |
---|
367 | ! the print control is done over a specific area |
---|
368 | lsp_area = .TRUE. |
---|
369 | IF( nictls < 1 .OR. nictls > jpiglo ) THEN |
---|
370 | CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' ) |
---|
371 | nictls = 1 |
---|
372 | ENDIF |
---|
373 | |
---|
374 | IF( nictle < 1 .OR. nictle > jpiglo ) THEN |
---|
375 | CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' ) |
---|
376 | nictle = jpiglo |
---|
377 | ENDIF |
---|
378 | |
---|
379 | IF( njctls < 1 .OR. njctls > jpjglo ) THEN |
---|
380 | CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' ) |
---|
381 | njctls = 1 |
---|
382 | ENDIF |
---|
383 | |
---|
384 | IF( njctle < 1 .OR. njctle > jpjglo ) THEN |
---|
385 | CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' ) |
---|
386 | njctle = jpjglo |
---|
387 | ENDIF |
---|
388 | |
---|
389 | ENDIF ! IF( nictls+nictle+njctls+njctle == 0 ) |
---|
390 | ENDIF ! IF(ln_ctl) |
---|
391 | |
---|
392 | IF( nbench == 1 ) THEN |
---|
393 | SELECT CASE ( cp_cfg ) |
---|
394 | CASE ( 'gyre' ) |
---|
395 | CALL ctl_warn( ' The Benchmark is activated ' ) |
---|
396 | CASE DEFAULT |
---|
397 | CALL ctl_stop( ' The Benchmark is based on the GYRE configuration: key_gyre must & |
---|
398 | & be used or set nbench = 0' ) |
---|
399 | END SELECT |
---|
400 | ENDIF |
---|
401 | |
---|
402 | IF( nbit_cmp == 1 ) THEN |
---|
403 | CALL ctl_warn( ' Bit comparison enabled. Single and multiple processor results must bit compare', & |
---|
404 | & ' WARNING: RESULTS ARE NOT PHYSICAL.' ) |
---|
405 | ENDIF |
---|
406 | |
---|
407 | |
---|
408 | ! Read Namelist namflg : algorithm FLaG |
---|
409 | ! -------------------- |
---|
410 | REWIND ( numnam ) |
---|
411 | READ ( numnam, namflg ) |
---|
412 | |
---|
413 | ! Parameter control and print |
---|
414 | ! --------------------------- |
---|
415 | IF(lwp) THEN |
---|
416 | WRITE(numout,*) |
---|
417 | WRITE(numout,*) 'opa_flg : Hydrostatic pressure gradient algorithm' |
---|
418 | WRITE(numout,*) '~~~~~~~' |
---|
419 | WRITE(numout,*) ' Namelist namflg : set algorithm flags' |
---|
420 | WRITE(numout,*) ' centered (F) or semi-implicit (T) ln_dynhpg_imp = ', ln_dynhpg_imp |
---|
421 | WRITE(numout,*) ' hydrostatic pressure gradient' |
---|
422 | WRITE(numout,*) ' add dynhpg implicit variable nn_dynhpg_rst = ', nn_dynhpg_rst |
---|
423 | WRITE(numout,*) ' in restart ot not nn_dynhpg_rst' |
---|
424 | ENDIF |
---|
425 | IF( .NOT. ln_dynhpg_imp ) nn_dynhpg_rst = 0 ! force no adding dynhpg implicit variables in restart |
---|
426 | |
---|
427 | END SUBROUTINE opa_flg |
---|
428 | |
---|
429 | |
---|
430 | SUBROUTINE opa_closefile |
---|
431 | !!---------------------------------------------------------------------- |
---|
432 | !! *** ROUTINE opa_closefile *** |
---|
433 | !! |
---|
434 | !! ** Purpose : Close the files |
---|
435 | !! |
---|
436 | !! ** Method : |
---|
437 | !! |
---|
438 | !! History : |
---|
439 | !! 9.0 ! 05-01 (O. Le Galloudec) Original code |
---|
440 | !!---------------------------------------------------------------------- |
---|
441 | !! * Modules used |
---|
442 | USE dtatem ! temperature data |
---|
443 | USE dtasal ! salinity data |
---|
444 | !!---------------------------------------------------------------------- |
---|
445 | |
---|
446 | IF ( lk_mpp ) CALL mppsync |
---|
447 | |
---|
448 | CLOSE( numnam ) ! namelist |
---|
449 | CLOSE( numout ) ! standard model output file |
---|
450 | |
---|
451 | IF(lwp) CLOSE( numstp ) ! time-step file |
---|
452 | IF(lwp) CLOSE( numsol ) ! solver file |
---|
453 | |
---|
454 | CALL iom_close ! close all input/output files |
---|
455 | |
---|
456 | END SUBROUTINE opa_closefile |
---|
457 | |
---|
458 | !!====================================================================== |
---|
459 | END MODULE opa |
---|