source: trunk/NEMO/OPA_SRC/step.F90 @ 703

Last change on this file since 703 was 703, checked in by smasson, 12 years ago

code modifications associated with the new routines, see ticket:4

  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 20.9 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :        !  91-03  (G. Madec)  Original code
7   !!                  !  92-06  (M. Imbard)  add a first output record
8   !!                  !  96-04  (G. Madec)  introduction of dynspg
9   !!                  !  96-04  (M.A. Foujols)  introduction of passive tracer
10   !!             8.0  !  97-06  (G. Madec)  new architecture of call
11   !!             8.2  !  97-06  (G. Madec, M. Imbard, G. Roullet)  free surface
12   !!             8.2  !  99-02  (G. Madec, N. Grima)  hpg implicit
13   !!             8.2  !  00-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
14   !!             9.0  !  02-06  (G. Madec)  free form, suppress macro-tasking
15   !!             " "  !  04-08  (C. Talandier) New trends organization
16   !!             " "  !  05-01  (C. Ethe) Add the KPP closure scheme
17   !!             " "  !  05-11  (V. Garnier) Surface pressure gradient organization
18   !!             " "  !  05-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             " "  !  06-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             " "  !  06-07  (S. Masson)  restart using iom
21   !!             " "  !  06-08  (G. Madec)  surface module
22   !!----------------------------------------------------------------------
23
24   !!----------------------------------------------------------------------
25   !!   stp            : OPA system time-stepping
26   !!----------------------------------------------------------------------
27   USE oce             ! ocean dynamics and tracers variables
28   USE dom_oce         ! ocean space and time domain variables
29   USE zdf_oce         ! ocean vertical physics variables
30   USE ldftra_oce      ! ocean tracer   - trends
31   USE ldfdyn_oce      ! ocean dynamics - trends
32   USE cpl_oce         ! coupled ocean-atmosphere variables
33   USE in_out_manager  ! I/O manager
34   USE iom             !
35   USE lbclnk
36
37   USE daymod          ! calendar                         (day     routine)
38
39   USE dtatem          ! ocean temperature data           (dta_tem routine)
40   USE dtasal          ! ocean salinity    data           (dta_sal routine)
41   USE sbcmod          ! surface boundary condition       (sbc     routine)
42   USE sbcrnf          ! surface boundary condition: runoff variables
43   USE ocfzpt          ! surface ocean freezing point    (oc_fz_pt routine)
44
45   USE trcstp          ! passive tracer time-stepping      (trc_stp routine)
46
47   USE traqsr          ! solar radiation penetration      (tra_qsr routine)
48   USE trasbc          ! surface boundary condition       (tra_sbc routine)
49   USE trabbc          ! bottom boundary condition        (tra_bbc routine)
50   USE trabbl          ! bottom boundary layer            (tra_bbl routine)
51   USE tradmp          ! internal damping                 (tra_dmp routine)
52   USE traadv          ! advection scheme control     (tra_adv_ctl routine)
53   USE traldf          ! lateral mixing                   (tra_ldf routine)
54   USE cla             ! cross land advection             (tra_cla routine)
55   !   zdfkpp          ! KPP non-local tracer fluxes      (tra_kpp routine)
56   USE trazdf          ! vertical mixing                  (tra_zdf routine)
57   USE tranxt          ! time-stepping                    (tra_nxt routine)
58   USE tranpc          ! non-penetrative convection       (tra_npc routine)
59
60   USE eosbn2          ! equation of state                (eos_bn2 routine)
61
62   USE dynadv          ! advection                        (dyn_adv routine)
63   USE dynvor          ! vorticity term                   (dyn_vor routine)
64   USE dynhpg          ! hydrostatic pressure grad.       (dyn_hpg routine)
65   USE dynldf          ! lateral momentum diffusion       (dyn_ldf routine)
66   USE dynzdf          ! vertical diffusion               (dyn_zdf routine)
67   USE dynspg_oce      ! surface pressure gradient        (dyn_spg routine)
68   USE dynspg          ! surface pressure gradient        (dyn_spg routine)
69   USE dynnxt          ! time-stepping                    (dyn_nxt routine)
70
71   USE obc_par         ! open boundary condition variables
72   USE obcdta          ! open boundary condition data     (obc_dta routine)
73   USE obcrst          ! open boundary cond. restart      (obc_rst routine)
74   USE obcrad          ! open boundary cond. radiation    (obc_rad routine)
75   USE obcspg          ! open boundary cond  spg          (obc_spg routine)
76
77   USE divcur          ! hor. divergence and curl      (div & cur routines)
78   USE cla_div         ! cross land: hor. divergence      (div_cla routine)
79   USE wzvmod          ! vertical velocity                (wzv     routine)
80
81   USE ldfslp          ! iso-neutral slopes               (ldf_slp routine)
82   USE ldfeiv          ! eddy induced velocity coef.      (ldf_eiv routine)
83
84   USE zdfbfr          ! bottom friction                  (zdf_bfr routine)
85   USE zdftke          ! TKE vertical mixing              (zdf_tke routine)
86   USE zdftke_jki      ! TKE vertical mixing              (zdf_tke routine)
87   USE zdfkpp          ! KPP vertical mixing              (zdf_kpp routine)
88   USE zdfddm          ! double diffusion mixing          (zdf_ddm routine)
89   USE zdfevd          ! enhanced vertical diffusion      (zdf_evd routine)
90   USE zdfric          ! Richardson vertical mixing       (zdf_ric routine)
91   USE zdfmxl          ! Mixed-layer depth                (zdf_mxl routine)
92
93   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
94   USE ice_oce         ! sea-ice variable
95   USE icestp          ! sea-ice time-stepping             (ice_stp routine)
96
97   USE diawri          ! Standard run outputs             (dia_wri routine)
98   USE trdicp          ! Ocean momentum/tracers trends    (trd_wri routine)
99   USE trdmld          ! mixed-layer trends               (trd_mld routine)
100   USE trdmld_rst      ! restart for mixed-layer trends
101   USE trdmod_oce      ! ocean momentum/tracers trends
102   USE trdvor          ! vorticity budget                 (trd_vor routine)
103   USE diagap          ! hor. mean model-data gap         (dia_gap routine)
104   USE diahdy          ! dynamic height                   (dia_hdy routine)
105   USE diaptr          ! poleward transports              (dia_ptr routine)
106   USE diahth          ! thermocline depth                (dia_hth routine)
107   USE diafwb          ! freshwater budget                (dia_fwb routine)
108   USE diaspr          ! suface pressure (rigid-lid)      (dia_spr routine)
109   USE flo_oce         ! floats variables
110   USE floats          ! floats computation               (flo_stp routine)
111
112   USE stpctl          ! time stepping control            (stp_ctl routine)
113   USE restart         ! ocean restart                    (rst_wri routine)
114   USE cpl             ! exchanges in coupled mode        (cpl_stp routine)
115   USE prtctl          ! Print control                    (prt_ctl routine)
116   USE domvvl          ! variable volume                  (dom_vvl routine)
117
118#if defined key_agrif
119   USE agrif_opa_sponge ! Momemtum and tracers sponges
120#endif
121
122   IMPLICIT NONE
123   PRIVATE
124
125   PUBLIC stp            ! called by opa.F90
126
127   !! * Substitutions
128#  include "domzgr_substitute.h90"
129#  include "zdfddm_substitute.h90"
130   !!----------------------------------------------------------------------
131   !!   OPA 9.0 , LOCEAN-IPSL (2005)
132   !! $Id$
133   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
134   !!----------------------------------------------------------------------
135
136CONTAINS
137
138#if defined key_agrif
139   SUBROUTINE stp( )
140#else
141   SUBROUTINE stp( kstp )
142#endif
143      !!----------------------------------------------------------------------
144      !!                     ***  ROUTINE stp  ***
145      !!                     
146      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
147      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
148      !!              - Tme stepping  of TRC (passive tracer eqs.)
149      !!
150      !! ** Method  : -1- Update forcings and data 
151      !!              -2- Update ocean physics
152      !!              -3- Compute the t and s trends
153      !!              -4- Update t and s
154      !!              -5- Compute the momentum trends
155      !!              -6- Update the horizontal velocity
156      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
157      !!              -8- Outputs and diagnostics
158      !!----------------------------------------------------------------------
159#if defined key_agrif   
160      INTEGER             ::   kstp   ! ocean time-step index
161#else
162      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
163#endif     
164      INTEGER ::   jk       ! dummy loop indice
165      INTEGER ::   indic    ! error indicator if < 0
166      !! ---------------------------------------------------------------------
167
168#if defined key_agrif
169      kstp = nit000 + Agrif_Nb_Step()
170!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
171!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
172#endif   
173      indic = 1                    ! reset to no error condition
174
175!!gm: attention n'est plus ds le step de gm
176      adatrj = adatrj + rdt/86400._wp
177!!gm: attention n'est plus ds le step de gm
178
179      CALL day( kstp )             ! Calendar
180
181      CALL rst_opn( kstp )         ! Open the restart file
182
183      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
184      ! Update data, open boundaries, surface boundary condition (including sea-ice)
185      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
186
187      IF( lk_dtatem  )   CALL dta_tem( kstp )         ! update 3D temperature data
188      IF( lk_dtasal  )   CALL dta_sal( kstp )         ! update 3D salinity data
189
190                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
191
192      IF( lk_obc     )   CALL obc_dta( kstp )         ! update dynamic and tracer data at open boundaries
193      IF( lk_obc     )   CALL obc_rad( kstp )         ! compute phase velocities at open boundaries
194
195      IF( ninist == 1 ) THEN                       ! Output the initial state and forcings
196                        CALL dia_wri_state( 'output.init' )
197                        ninist = 0
198      ENDIF
199
200
201      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
202      ! Ocean physics update
203      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
204      !-----------------------------------------------------------------------
205      !  VERTICAL PHYSICS
206      !-----------------------------------------------------------------------
207      ! N.B. ua, va, ta, sa arrays are used as workspace in this section
208      !-----------------------------------------------------------------------
209
210                        CALL bn2( tb, sb, rn2 )              ! before Brunt-Vaisala frequency
211     
212      !                                                     ! Vertical eddy viscosity and diffusivity coefficients
213      IF( lk_zdfric )   CALL zdf_ric( kstp )                       ! Richardson number dependent Kz
214#if defined key_mpp_omp
215      IF( lk_zdftke )   CALL zdf_tke_jki( kstp )                   ! TKE closure scheme for Kz - j-k-i loops
216#else
217      IF( lk_zdftke )   CALL zdf_tke( kstp )                       ! TKE closure scheme for Kz
218#endif
219      IF( lk_zdfkpp )   CALL zdf_kpp( kstp )                       ! KPP closure scheme for Kz
220
221      IF( lk_zdfcst )   THEN                                       ! Constant Kz (reset avt, avm[uv] to the background value)
222         avt (:,:,:) = avt0 * tmask(:,:,:)
223         avmu(:,:,:) = avm0 * umask(:,:,:)
224         avmv(:,:,:) = avm0 * vmask(:,:,:)
225      ENDIF
226
227      IF( nn_runoff /=0 ) THEN                              ! increase diffusivity at rivers mouths
228         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + rn_avt_rnf * rnfmsk(:,:)   ;   END DO
229      ENDIF
230
231      IF( ln_zdfevd )   CALL zdf_evd( kstp )                 ! enhanced vertical eddy diffusivity
232
233      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
234         &              CALL zdf_ddm( kstp )                 ! double diffusive mixing
235
236                        CALL zdf_bfr( kstp )                 ! bottom friction
237
238                        CALL zdf_mxl( kstp )                 ! mixed layer depth
239
240
241      !-----------------------------------------------------------------------
242      !  LATERAL PHYSICS
243      !-----------------------------------------------------------------------
244      ! N.B. ua, va, ta, sa arrays are used as workspace in this section
245      !-----------------------------------------------------------------------
246      IF( lk_ldfslp     )   CALL ldf_slp( kstp, rhd, rn2 )       ! before slope of the lateral mixing
247#if defined key_traldf_c2d
248      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )                 ! eddy induced velocity coefficient
249#endif
250
251#if defined key_passivetrc
252      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
253      ! Passive Tracer Model
254      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
255      ! N.B. ua, va, ta, sa arrays are used as workspace in this section
256      !-----------------------------------------------------------------------
257                             CALL trc_stp( kstp, indic )            ! time-stepping
258#endif
259
260      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
261      ! Active tracers
262      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
263      ! N.B. ua, va arrays are used as workspace in this section
264      !-----------------------------------------------------------------------
265                             ta(:,:,:) = 0.e0               ! set tracer trends to zero
266                             sa(:,:,:) = 0.e0
267
268                             CALL tra_sbc    ( kstp )       ! surface boundary condition
269      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
270      IF( lk_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
271      IF( lk_trabbl_dif  )   CALL tra_bbl_dif( kstp )       ! diffusive bottom boundary layer scheme
272      IF( lk_trabbl_adv  )   CALL tra_bbl_adv( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
273      IF( lk_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
274                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
275      IF( n_cla == 1     )   CALL tra_cla    ( kstp )       ! Cross Land Advection (Update Hor. advection)
276      IF( lk_zdfkpp )        CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
277                             CALL tra_ldf    ( kstp )       ! lateral mixing
278#if defined key_agrif
279      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra( kstp )  ! tracers sponge
280#endif
281                             CALL tra_zdf    ( kstp )       ! vertical mixing
282                             CALL tra_nxt( kstp )           ! tracer fields at next time step
283      IF( ln_zdfnpc      )   CALL tra_npc( kstp )           ! update the new (t,s) fields by non
284      !                                                     ! penetrative convective adjustment
285
286      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg
287                               CALL eos( ta, sa, rhd, rhop )          ! Time-filtered in situ density used in dynhpg module
288         IF( ln_zps    )       CALL zps_hde( kstp, ta, sa, rhd,   &   ! Partial steps: time filtered hor. gradient
289            &                                     gtu, gsu, gru,  &   ! of t, s, rd at the bottom ocean level
290            &                                     gtv, gsv, grv )
291      ELSE                                                  ! centered hpg (default case)
292                               CALL eos( tb, sb, rhd, rhop )          ! now (swap=before) in situ density for dynhpg module
293         IF( ln_zps    )       CALL zps_hde( kstp, tb, sb, rhd,   &   ! Partial steps: now horizontal gradient
294            &                                     gtu, gsu, gru,  &   ! of t, s, rd at the bottom ocean level
295            &                                     gtv, gsv, grv )
296      ENDIF
297
298      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
299      ! Dynamics
300      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
301      ! N.B. ta, sa arrays are used as workspace in this section
302      !-----------------------------------------------------------------------
303                               ua(:,:,:) = 0.e0               ! set dynamics trends to zero
304                               va(:,:,:) = 0.e0
305
306                               CALL dyn_adv( kstp )           ! advection (vector or flux form)
307                               CALL dyn_vor( kstp )           ! vorticity term including Coriolis
308                               CALL dyn_ldf( kstp )           ! lateral mixing
309#if defined key_agrif
310      IF(.NOT. Agrif_Root())   CALL Agrif_Sponge_dyn( kstp )  ! momemtum sponge
311#endif
312                               CALL dyn_hpg( kstp )           ! horizontal gradient of Hydrostatic pressure
313                               CALL dyn_zdf( kstp )           ! vertical diffusion
314      IF( lk_dynspg_rl ) THEN
315         IF( lk_obc    )       CALL obc_spg( kstp )           ! surface pressure gradient at open boundaries
316      ENDIF
317                               indic=0
318                               CALL dyn_spg( kstp, indic )    ! surface pressure gradient
319                               CALL dyn_nxt( kstp )           ! lateral velocity at next time step
320      IF( lk_vvl )             CALL dom_vvl                   ! vertical mesh at next time step
321
322
323      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
324      ! Computation of diagnostic variables
325      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
326      ! N.B. ua, va, ta, sa arrays are used as workspace in this section
327      !-----------------------------------------------------------------------
328                       CALL oc_fz_pt                        ! ocean surface freezing temperature
329                       CALL div_cur( kstp )                 ! Horizontal divergence & Relative vorticity
330      IF( n_cla == 1 ) CALL div_cla( kstp )                 ! Cross Land Advection (Update Hor. divergence)
331                       CALL wzv( kstp )                     ! Vertical velocity
332
333      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
334      ! Control and restarts
335      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
336                                 CALL stp_ctl( kstp, indic )
337      IF( indic < 0          )   CALL ctl_stop( 'step: indic < 0' )
338      IF( kstp == nit000     )   CALL iom_close( numror )             ! close input  ocean restart file
339      IF( lrst_oce           )   CALL rst_write  ( kstp )             ! write output ocean restart file
340      IF( lk_obc             )   CALL obc_rst_wri( kstp )             ! write open boundary restart file
341
342      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
343      ! diagnostics and outputs
344      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
345      ! N.B. ua, va, ta, sa arrays are used as workspace in this section
346      !-----------------------------------------------------------------------
347
348      IF( nstop == 0 ) THEN                                 ! Diagnostics:
349         IF( lk_floats  )   CALL flo_stp( kstp )                 ! drifting Floats
350         IF( lk_trddyn  )   CALL trd_dwr( kstp )                 ! trends: dynamics
351         IF( lk_trdtra  )   CALL trd_twr( kstp )                 ! trends: active tracers
352         IF( lk_trdmld  )   CALL trd_mld( kstp )                 ! trends: Mixed-layer
353         IF( lk_trdvor  )   CALL trd_vor( kstp )                 ! trends: vorticity budget
354         IF( lk_diaspr  )   CALL dia_spr( kstp )                 ! Surface pressure diagnostics
355         IF( lk_diahth  )   CALL dia_hth( kstp )                 ! Thermocline depth (20 degres isotherm depth)
356         IF( lk_diagap  )   CALL dia_gap( kstp )                 ! basin averaged diagnostics
357         IF( lk_diahdy  )   CALL dia_hdy( kstp )                 ! dynamical heigh diagnostics
358         IF( lk_diafwb  )   CALL dia_fwb( kstp )                 ! Fresh water budget diagnostics
359         IF( ln_diaptr  )   CALL dia_ptr( kstp )                 ! Poleward TRansports diagnostics
360         !                                                 ! outputs
361                            CALL dia_wri( kstp, indic )          ! ocean model: outputs
362      ENDIF
363
364      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
365      ! Coupled mode
366      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
367
368      IF( lk_cpl    )   CALL cpl_stp( kstp )                 ! coupled mode : field exchanges
369      !
370   END SUBROUTINE stp
371
372   !!======================================================================
373END MODULE step
Note: See TracBrowser for help on using the repository browser.