New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

step.F90 in trunk/NEMO/OPA_SRC – NEMO

Context Navigation

source: trunk/NEMO/OPA_SRC/step.F90 @ 868

Last change on this file since 868 was 833, checked in by rblod, 16 years ago
Merge branche dev_002_LIM back to trunk ticket #70 and #71
Property svn:eol-style set to `native` Property svn:keywords set to `Author Date Id Revision`
File size: 23.4 KB

Line
1	MODULE step
2	!!======================================================================
3	!! * MODULE step *
4	!! Time-stepping : manager of the ocean, tracer and ice time stepping
5	!!======================================================================
6	!! History : ! 91-03 () Original code
7	!! ! 91-11 (G. Madec)
8	!! ! 92-06 (M. Imbard) add a first output record
9	!! ! 96-04 (G. Madec) introduction of dynspg
10	!! ! 96-04 (M.A. Foujols) introduction of passive tracer
11	!! 8.0 ! 97-06 (G. Madec) new architecture of call
12	!! 8.2 ! 97-06 (G. Madec, M. Imbard, G. Roullet) free surface
13	!! 8.2 ! 99-02 (G. Madec, N. Grima) hpg implicit
14	!! 8.2 ! 00-07 (J-M Molines, M. Imbard) Open Bondary Conditions
15	!! 9.0 ! 02-06 (G. Madec) free form, suppress macro-tasking
16	!! " " ! 04-08 (C. Talandier) New trends organization
17	!! " " ! 05-01 (C. Ethe) Add the KPP closure scheme
18	!! " " ! 05-11 (V. Garnier) Surface pressure gradient organization
19	!! " " ! 05-11 (G. Madec) Reorganisation of tra and dyn calls
20	!! " " ! 06-01 (L. Debreu, C. Mazauric) Agrif implementation
21	!! " " ! 06-07 (S. Masson) restart using iom
22	!!----------------------------------------------------------------------
23	!! stp : OPA system time-stepping
24	!!----------------------------------------------------------------------
25	USE oce ! ocean dynamics and tracers variables
26	USE dom_oce ! ocean space and time domain variables
27	USE zdf_oce ! ocean vertical physics variables
28	USE ldftra_oce ! ocean tracer - trends
29	USE ldfdyn_oce ! ocean dynamics - trends
30	USE cpl_oce ! coupled ocean-atmosphere variables
31	USE in_out_manager ! I/O manager
32	USE iom
33	USE lbclnk
34
35	USE daymod ! calendar (day routine)
36
37	USE dtatem ! ocean temperature data (dta_tem routine)
38	USE dtasal ! ocean salinity data (dta_sal routine)
39	USE dtasst ! ocean sea surface temperature (dta_sst routine)
40	USE dtasss ! ocean sea surface salinity (dta_sss routine)
41	USE taumod ! surface stress (tau routine)
42	USE flxmod ! thermohaline fluxes (flx routine)
43	USE ocesbc ! thermohaline fluxes (oce_sbc routine)
44	USE flxrnf ! runoffs (flx_rnf routine)
45	USE flxfwb ! freshwater budget correction (flx_fwb routine)
46	USE closea ! closed sea freshwater budget (flx_clo routine)
47	USE ocfzpt ! surface ocean freezing point (oc_fz_pt routine)
48
49	USE trcstp ! passive tracer time-stepping (trc_stp routine)
50
51	USE traqsr ! solar radiation penetration (tra_qsr routine)
52	USE trasbc ! surface boundary condition (tra_sbc routine)
53	USE trabbc ! bottom boundary condition (tra_bbc routine)
54	USE trabbl ! bottom boundary layer (tra_bbl routine)
55	USE tradmp ! internal damping (tra_dmp routine)
56	USE traadv ! advection scheme control (tra_adv_ctl routine)
57	USE traldf ! lateral mixing (tra_ldf routine)
58	USE cla ! cross land advection (tra_cla routine)
59	! zdfkpp ! KPP non-local tracer fluxes (tra_kpp routine)
60	USE trazdf ! vertical mixing (tra_zdf routine)
61	USE tranxt ! time-stepping (tra_nxt routine)
62	USE tranpc ! non-penetrative convection (tra_npc routine)
63
64	USE eosbn2 ! equation of state (eos_bn2 routine)
65
66	USE dynadv ! advection (dyn_adv routine)
67	USE dynvor ! vorticity term (dyn_vor routine)
68	USE dynhpg ! hydrostatic pressure grad. (dyn_hpg routine)
69	USE dynldf ! lateral momentum diffusion (dyn_ldf routine)
70	USE dynzdf ! vertical diffusion (dyn_zdf routine)
71	USE dynspg_oce ! surface pressure gradient (dyn_spg routine)
72	USE dynspg ! surface pressure gradient (dyn_spg routine)
73	USE dynnxt ! time-stepping (dyn_nxt routine)
74
75	USE obc_par ! open boundary condition variables
76	USE obcdta ! open boundary condition data (obc_dta routine)
77	USE obcrst ! open boundary cond. restart (obc_rst routine)
78	USE obcrad ! open boundary cond. radiation (obc_rad routine)
79	USE obcspg ! open boundary cond spg (obc_spg routine)
80
81	USE divcur ! hor. divergence and curl (div & cur routines)
82	USE cla_div ! cross land: hor. divergence (div_cla routine)
83	USE wzvmod ! vertical velocity (wzv routine)
84
85	USE ldfslp ! iso-neutral slopes (ldf_slp routine)
86	USE ldfeiv ! eddy induced velocity coef. (ldf_eiv routine)
87
88	USE zdfbfr ! bottom friction (zdf_bfr routine)
89	USE zdftke ! TKE vertical mixing (zdf_tke routine)
90	USE zdfkpp ! KPP vertical mixing (zdf_kpp routine)
91	USE zdfddm ! double diffusion mixing (zdf_ddm routine)
92	USE zdfevd ! enhanced vertical diffusion (zdf_evd routine)
93	USE zdfric ! Richardson vertical mixing (zdf_ric routine)
94	USE zdfmxl ! Mixed-layer depth (zdf_mxl routine)
95
96	USE zpshde ! partial step: hor. derivative (zps_hde routine)
97	USE ice_oce ! sea-ice variable
98	#if defined key_lim3
99	USE icestp ! sea-ice time-stepping (ice_stp routine)
100	#endif
101	#if defined key_lim2
102	USE icestp_2 ! sea-ice time-stepping (ice_stp_2 routine)
103	#endif
104	USE diawri ! Standard run outputs (dia_wri routine)
105	USE trdicp ! Ocean momentum/tracers trends (trd_wri routine)
106	USE trdmld ! mixed-layer trends (trd_mld routine)
107	USE trdmld_rst ! restart for mixed-layer trends
108	USE trdmod_oce ! ocean momentum/tracers trends
109	USE trdvor ! vorticity budget (trd_vor routine)
110	USE diagap ! hor. mean model-data gap (dia_gap routine)
111	USE diahdy ! dynamic height (dia_hdy routine)
112	USE diaptr ! poleward transports (dia_ptr routine)
113	USE diahth ! thermocline depth (dia_hth routine)
114	USE diafwb ! freshwater budget (dia_fwb routine)
115	USE diaspr ! suface pressure (rigid-lid) (dia_spr routine)
116	USE flo_oce ! floats variables
117	USE floats ! floats computation (flo_stp routine)
118
119	USE stpctl ! time stepping control (stp_ctl routine)
120	USE restart ! ocean restart (rst_wri routine)
121	USE cpl ! exchanges in coupled mode (cpl_stp routine)
122	USE prtctl ! Print control (prt_ctl routine)
123	USE domvvl ! variable volume (dom_vvl routine)
124
125	#if defined key_agrif
126	USE agrif_opa_sponge ! Momemtum and tracers sponges
127	#endif
128
129	IMPLICIT NONE
130	PRIVATE
131
132	PUBLIC stp ! called by opa.F90
133
134	!! * Substitutions
135	# include "domzgr_substitute.h90"
136	# include "zdfddm_substitute.h90"
137	!!----------------------------------------------------------------------
138	!! OPA 9.0 , LOCEAN-IPSL (2005)
139	!! $Header: /home/opalod/NEMOCVSROOT/NEMO/OPA_SRC/step.F90,v 1.35 2007/06/01 16:55:39 opalod Exp $
140	!! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
141	!!----------------------------------------------------------------------
142
143	CONTAINS
144
145	#if defined key_agrif
146	SUBROUTINE stp( )
147	#else
148	SUBROUTINE stp( kstp )
149	#endif
150	!!----------------------------------------------------------------------
151	!! * ROUTINE stp *
152	!!
153	!! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
154	!! - Time stepping of LIM (dynamic and thermodynamic eqs.)
155	!! - Tme stepping of TRC (passive tracer eqs.)
156	!!
157	!! ** Method : -1- Update forcings and data
158	!! -2- Update ocean physics
159	!! -3- Compute the t and s trends
160	!! -4- Update t and s
161	!! -5- Compute the momentum trends
162	!! -6- Update the horizontal velocity
163	!! -7- Compute the diagnostics variables (rd,N2, div,cur,w)
164	!! -8- Outputs and diagnostics
165	!!----------------------------------------------------------------------
166	!! * Arguments
167	#if defined key_agrif
168	INTEGER :: kstp ! ocean time-step index
169	#else
170	INTEGER, INTENT( in ) :: kstp ! ocean time-step index
171	#endif
172
173	!! * local declarations
174	INTEGER :: indic ! error indicator if < 0
175	!! ---------------------------------------------------------------------
176
177	#if defined key_agrif
178	kstp = nit000 + Agrif_Nb_Step()
179	! IF ( Agrif_Root() .and. lwp) Write(,) '---'
180	! IF (lwp) Write(,) 'Grid Number',Agrif_Fixed(),' time step ',kstp
181	#endif
182	indic = 1 ! reset to no error condition
183
184	adatrj = adatrj + rdt/86400._wp
185
186	CALL day( kstp ) ! Calendar
187
188	CALL rst_opn( kstp ) ! Open the restart file
189
190	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
191	! Update data, open boundaries and Forcings
192	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
193
194	IF( lk_dtatem ) CALL dta_tem( kstp ) ! update 3D temperature data
195
196	IF( lk_dtasal ) CALL dta_sal( kstp ) ! Salinity data
197
198	IF( lk_dtasst ) CALL dta_sst( kstp ) ! Sea Surface Temperature data
199
200	IF( lk_dtasss ) CALL dta_sss( kstp ) ! Sea Surface Salinity data
201
202	IF( lk_obc ) CALL obc_dta( kstp ) ! update dynamic and tracer data at open boundaries
203
204	IF( lk_obc ) CALL obc_rad( kstp ) ! compute phase velocities at open boundaries
205
206	IF( .NOT. lk_core ) CALL tau( kstp ) ! wind stress
207
208	CALL flx_rnf( kstp ) ! runoff data
209
210	CALL flx( kstp ) ! heat and freshwater fluxes
211
212	#if defined key_lim3
213	CALL ice_stp( kstp ) ! sea-ice model (Update stress & fluxes)
214	#endif
215	#if defined key_lim2
216	CALL ice_stp_2( kstp ) ! sea-ice model (Update stress & fluxes)
217	#endif
218
219	CALL oce_sbc( kstp ) ! ocean surface boudaries
220
221	IF( ln_fwb ) CALL flx_fwb( kstp ) ! freshwater budget
222
223	IF( nclosea == 1 ) CALL flx_clo( kstp ) ! closed sea in the domain (update freshwater fluxes)
224
225	IF( kstp == nit000 ) THEN
226	IF( ninist == 1 ) THEN ! Output the initial state and forcings
227	CALL dia_wri_state( 'output.init' )
228	ENDIF
229	ENDIF
230
231	IF(ln_ctl) THEN ! print mean trends (used for debugging)
232	CALL prt_ctl(tab2d_1=emp , clinfo1=' emp - : ', mask1=tmask, ovlap=1)
233	CALL prt_ctl(tab2d_1=emps , clinfo1=' emps - : ', mask1=tmask, ovlap=1)
234	CALL prt_ctl(tab2d_1=qt , clinfo1=' qt - : ', mask1=tmask, ovlap=1)
235	CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1)
236	CALL prt_ctl(tab2d_1=runoff , clinfo1=' runoff : ', mask1=tmask, ovlap=1)
237	CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask : ', mask1=tmask, ovlap=1, kdim=jpk)
238	CALL prt_ctl(tab3d_1=tn , clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1)
239	CALL prt_ctl(tab3d_1=sn , clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1)
240	CALL prt_ctl(tab2d_1=taux , clinfo1=' tau - x : ', mask1=umask, &
241	& tab2d_2=tauy , clinfo2=' - y : ', mask2=vmask,ovlap=1)
242	ENDIF
243
244
245	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
246	! Ocean physics update
247	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
248	!-----------------------------------------------------------------------
249	! VERTICAL PHYSICS
250	!-----------------------------------------------------------------------
251	! N.B. ua, va, ta, sa arrays are used as workspace in this section
252	!-----------------------------------------------------------------------
253
254	CALL bn2( tb, sb, rn2 ) ! before Brunt-Vaisala frequency
255
256	! ! Vertical eddy viscosity and diffusivity coefficients
257	IF( lk_zdfric ) CALL zdf_ric( kstp ) ! Richardson number dependent Kz
258
259	IF( lk_zdftke ) CALL zdf_tke( kstp ) ! TKE closure scheme for Kz
260
261	IF( lk_zdfkpp ) CALL zdf_kpp( kstp ) ! KPP closure scheme for Kz
262
263	IF( lk_zdfcst ) THEN ! Constant Kz (reset avt, avm[uv] to the background value)
264	avt (:,:,:) = avt0 * tmask(:,:,:)
265	avmu(:,:,:) = avm0 * umask(:,:,:)
266	avmv(:,:,:) = avm0 * vmask(:,:,:)
267	ENDIF
268
269	IF( cp_cfg == "orca" ) THEN ! ORCA: Reduce vertical mixing in some specific areas
270	SELECT CASE ( jp_cfg )
271	CASE ( 05 ) ! ORCA R2 configuration
272	avt (:,:,2) = avt (:,:,2) + 1.e-3 * upsrnfh(:,:) ! increase diffusivity of rivers mouths
273	CASE ( 025 ) ! ORCA R025 configuration
274	avt (:,:,2) = avt (:,:,2) + 2.e-3 * upsrnfh(:,:) ! increase diffusivity of rivers mouths
275	END SELECT
276	ENDIF
277
278	IF( ln_zdfevd ) CALL zdf_evd( kstp ) ! enhanced vertical eddy diffusivity
279
280	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp) &
281	& CALL zdf_ddm( kstp ) ! double diffusive mixing
282
283	CALL zdf_bfr( kstp ) ! bottom friction
284
285	CALL zdf_mxl( kstp ) ! mixed layer depth
286
287
288	!-----------------------------------------------------------------------
289	! LATERAL PHYSICS
290	!-----------------------------------------------------------------------
291	! N.B. ua, va, ta, sa arrays are used as workspace in this section
292	!-----------------------------------------------------------------------
293
294	IF( lk_ldfslp ) CALL ldf_slp( kstp, rhd, rn2 ) ! before slope of the lateral mixing
295
296	#if defined key_traldf_c2d
297	IF( lk_traldf_eiv ) CALL ldf_eiv( kstp ) ! eddy induced velocity coefficient
298	#endif
299
300
301	#if defined key_passivetrc
302	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
303	! Passive Tracer Model
304	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
305	! N.B. ua, va, ta, sa arrays are used as workspace in this section
306	!-----------------------------------------------------------------------
307
308	CALL trc_stp( kstp, indic ) ! time-stepping
309
310	#endif
311
312
313	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
314	! Active tracers
315	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
316	! N.B. ua, va arrays are used as workspace in this section
317	!-----------------------------------------------------------------------
318
319	ta(:,:,:) = 0.e0 ! set tracer trends to zero
320	sa(:,:,:) = 0.e0
321
322	CALL tra_sbc ( kstp ) ! surface boundary condition
323
324	IF( ln_traqsr ) CALL tra_qsr ( kstp ) ! penetrative solar radiation qsr
325
326	IF( lk_trabbc ) CALL tra_bbc ( kstp ) ! bottom heat flux
327
328	IF( lk_trabbl_dif ) CALL tra_bbl_dif( kstp ) ! diffusive bottom boundary layer scheme
329	IF( lk_trabbl_adv ) CALL tra_bbl_adv( kstp ) ! advective (and/or diffusive) bottom boundary layer scheme
330
331	IF( lk_tradmp ) CALL tra_dmp ( kstp ) ! internal damping trends
332
333	CALL tra_adv ( kstp ) ! horizontal & vertical advection
334
335	IF( n_cla == 1 ) CALL tra_cla ( kstp ) ! Cross Land Advection (Update Hor. advection)
336
337	IF( lk_zdfkpp ) CALL tra_kpp ( kstp ) ! KPP non-local tracer fluxes
338
339	CALL tra_ldf ( kstp ) ! lateral mixing
340	#if defined key_agrif
341	IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra ! tracers sponge
342	#endif
343	CALL tra_zdf ( kstp ) ! vertical mixing
344
345	CALL tra_nxt( kstp ) ! tracer fields at next time step
346
347	IF( ln_zdfnpc ) CALL tra_npc( kstp ) ! update the new (t,s) fields by non
348	! ! penetrative convective adjustment
349
350	IF( ln_dynhpg_imp ) THEN ! semi-implicit hpg
351	CALL eos( ta, sa, rhd, rhop ) ! Time-filtered in situ density used in dynhpg module
352	IF( ln_zps ) CALL zps_hde( kstp, ta, sa, rhd, & ! Partial steps: time filtered hor. gradient
353	& gtu, gsu, gru, & ! of t, s, rd at the bottom ocean level
354	& gtv, gsv, grv )
355	ELSE ! centered hpg (default case)
356	CALL eos( tb, sb, rhd, rhop ) ! now (swap=before) in situ density for dynhpg module
357	IF( ln_zps ) CALL zps_hde( kstp, tb, sb, rhd, & ! Partial steps: now horizontal gradient
358	& gtu, gsu, gru, & ! of t, s, rd at the bottom ocean level
359	& gtv, gsv, grv )
360	ENDIF
361
362	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
363	! Dynamics
364	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
365	! N.B. ta, sa arrays are used as workspace in this section
366	!-----------------------------------------------------------------------
367
368
369	ua(:,:,:) = 0.e0 ! set dynamics trends to zero
370	va(:,:,:) = 0.e0
371
372	CALL dyn_adv( kstp ) ! advection (vector or flux form)
373
374	CALL dyn_vor( kstp ) ! vorticity term including Coriolis
375
376	CALL dyn_ldf( kstp ) ! lateral mixing
377	#if defined key_agrif
378	IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momemtum sponge
379	#endif
380	CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure
381
382	CALL dyn_zdf( kstp ) ! vertical diffusion
383
384	IF( lk_dynspg_rl ) THEN
385	IF( lk_obc ) CALL obc_spg( kstp ) ! surface pressure gradient at open boundaries
386	ENDIF
387	indic=0
388	!i bug lbc sur emp
389	CALL lbc_lnk( emp, 'T', 1. )
390	!i
391	CALL dyn_spg( kstp, indic ) ! surface pressure gradient
392
393	CALL dyn_nxt( kstp ) ! lateral velocity at next time step
394
395	IF( lk_vvl ) CALL dom_vvl ! vertical mesh at next time step
396
397
398	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
399	! Computation of diagnostic variables
400	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
401	! N.B. ua, va, ta, sa arrays are used as workspace in this section
402	!-----------------------------------------------------------------------
403
404	CALL oc_fz_pt ! ocean surface freezing temperature
405
406	CALL div_cur( kstp ) ! Horizontal divergence & Relative vorticity
407
408	IF( n_cla == 1 ) CALL div_cla( kstp ) ! Cross Land Advection (Update Hor. divergence)
409
410	CALL wzv( kstp ) ! Vertical velocity
411
412
413
414	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
415	! Control, and restarts
416	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
417	! N.B. ua, va, ta, sa arrays are used as workspace in this section
418	!-----------------------------------------------------------------------
419	! ! Time loop: control and print
420	CALL stp_ctl( kstp, indic )
421	IF( indic < 0 ) CALL ctl_stop( 'step: indic < 0' )
422
423	IF( kstp == nit000 ) CALL iom_close( numror ) ! close input ocean restart file
424	IF( lrst_oce ) CALL rst_write ( kstp ) ! write output ocean restart file
425	IF( lk_obc ) CALL obc_rst_wri( kstp ) ! write open boundary restart file
426
427	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
428	! diagnostics and outputs
429	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
430	! N.B. ua, va, ta, sa arrays are used as workspace in this section
431	!-----------------------------------------------------------------------
432
433	IF ( nstop == 0 ) THEN ! Diagnostics
434	IF( lk_floats ) CALL flo_stp( kstp ) ! drifting Floats
435	IF( lk_trddyn ) CALL trd_dwr( kstp ) ! trends: dynamics
436	IF( lk_trdtra ) CALL trd_twr( kstp ) ! trends: active tracers
437	IF( lk_trdmld ) CALL trd_mld( kstp ) ! trends: Mixed-layer
438	IF( lk_trdvor ) CALL trd_vor( kstp ) ! trends: vorticity budget
439	IF( lk_diaspr ) CALL dia_spr( kstp ) ! Surface pressure diagnostics
440	IF( lk_diahth ) CALL dia_hth( kstp ) ! Thermocline depth (20 degres isotherm depth)
441	IF( lk_diagap ) CALL dia_gap( kstp ) ! basin averaged diagnostics
442	IF( lk_diahdy ) CALL dia_hdy( kstp ) ! dynamical heigh diagnostics
443	IF( lk_diafwb ) CALL dia_fwb( kstp ) ! Fresh water budget diagnostics
444	IF( ln_diaptr ) CALL dia_ptr( kstp ) ! Poleward TRansports diagnostics
445
446	! ! Outputs
447	CALL dia_wri ( kstp, indic ) ! ocean model: outputs
448	ENDIF
449
450	!>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
451	! Coupled mode
452	!<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
453
454	IF( lk_cpl ) CALL cpl_stp( kstp ) ! coupled mode : field exchanges
455	!
456	END SUBROUTINE stp
457
458	!!======================================================================
459	END MODULE step

Note: See TracBrowser for help on using the repository browser.

Download in other formats: