1 | MODULE p4zflx |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zflx *** |
---|
4 | !! TOP : PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
---|
5 | !!====================================================================== |
---|
6 | !! History : - ! 1988-07 (E. MAIER-REIMER) Original code |
---|
7 | !! - ! 1998 (O. Aumont) additions |
---|
8 | !! - ! 1999 (C. Le Quere) modifications |
---|
9 | !! 1.0 ! 2004 (O. Aumont) modifications |
---|
10 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | #if defined key_pisces |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! 'key_pisces' PISCES bio-model |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | !! p4z_flx : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
---|
17 | !! p4z_flx_init : Read the namelist |
---|
18 | !!---------------------------------------------------------------------- |
---|
19 | USE trc |
---|
20 | USE oce_trc ! |
---|
21 | USE trp_trc |
---|
22 | USE sms |
---|
23 | USE prtctl_trc |
---|
24 | USE p4zche |
---|
25 | |
---|
26 | IMPLICIT NONE |
---|
27 | PRIVATE |
---|
28 | |
---|
29 | PUBLIC p4z_flx ! called in p4zprg.F90 |
---|
30 | |
---|
31 | REAL(wp) :: & ! pre-industrial atmospheric [co2] (ppm) |
---|
32 | atcox = 0.20946 , & !: |
---|
33 | atcco2 = 278. !: |
---|
34 | |
---|
35 | REAL(wp) :: & |
---|
36 | tco2flx = 0. !: Total flux of carbon per year |
---|
37 | |
---|
38 | !!* Substitution |
---|
39 | # include "domzgr_substitute.h90" |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007) |
---|
42 | !! $Header:$ |
---|
43 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | |
---|
46 | CONTAINS |
---|
47 | |
---|
48 | SUBROUTINE p4z_flx ( kt ) |
---|
49 | !!--------------------------------------------------------------------- |
---|
50 | !! *** ROUTINE p4z_flx *** |
---|
51 | !! |
---|
52 | !! ** Purpose : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
---|
53 | !! |
---|
54 | !! ** Method : - ??? |
---|
55 | !!--------------------------------------------------------------------- |
---|
56 | INTEGER, INTENT(in) :: kt |
---|
57 | INTEGER :: ji, jj, jrorr, nspyr |
---|
58 | REAL(wp) :: zttc, zws, zkgwan |
---|
59 | REAL(wp) :: zfld, zflu, zfld16, zflu16, zfact |
---|
60 | REAL(wp) :: zph, zah2, zbot, zdic, zalk, zschmitto2, zalka, zschmittco2 |
---|
61 | REAL(wp), DIMENSION(jpi,jpj) :: zkgco2, zkgo2, zh2co3, ztco2flx |
---|
62 | CHARACTER (len=25) :: charout |
---|
63 | |
---|
64 | !!--------------------------------------------------------------------- |
---|
65 | |
---|
66 | |
---|
67 | IF( kt == nittrc000 ) CALL p4z_flx_init ! Initialization (first time-step only) |
---|
68 | |
---|
69 | |
---|
70 | ! ----------------------------------------------------- |
---|
71 | ! ASSIGNATION TO EXPONENTS IN THE LISS AND MERLIVAT |
---|
72 | ! FORMULATION OF THE GAS EXCHANGE RATE |
---|
73 | ! ----------------------------------------------------- |
---|
74 | |
---|
75 | nspyr = INT( raass / rdt ) |
---|
76 | |
---|
77 | ! SURFACE CHEMISTRY (PCO2 AND [H+] IN |
---|
78 | ! SURFACE LAYER); THE RESULT OF THIS CALCULATION |
---|
79 | ! IS USED TO COMPUTE AIR-SEA FLUX OF CO2 |
---|
80 | |
---|
81 | DO jrorr = 1, 10 |
---|
82 | |
---|
83 | !CDIR NOVERRCHK |
---|
84 | DO jj = 1, jpj |
---|
85 | !CDIR NOVERRCHK |
---|
86 | DO ji = 1, jpi |
---|
87 | |
---|
88 | ! DUMMY VARIABLES FOR DIC, H+, AND BORATE |
---|
89 | zbot = borat(ji,jj,1) |
---|
90 | zfact = rhop(ji,jj,1) / 1000. + rtrn |
---|
91 | zdic = trn(ji,jj,1,jpdic) / zfact |
---|
92 | zph = MAX( hi(ji,jj,1), 1.e-10 ) / zfact |
---|
93 | zalka = trn(ji,jj,1,jptal) / zfact |
---|
94 | |
---|
95 | ! CALCULATE [ALK]([CO3--], [HCO3-]) |
---|
96 | zalk = zalka - ( akw3(ji,jj,1) / zph - zph + zbot / ( 1.+ zph / akb3(ji,jj,1) ) ) |
---|
97 | |
---|
98 | ! CALCULATE [H+] AND [H2CO3] |
---|
99 | zah2 = SQRT( (zdic-zalk)**2 + 4.* ( zalk * ak23(ji,jj,1) & |
---|
100 | & / ak13(ji,jj,1) ) * ( 2.* zdic - zalk ) ) |
---|
101 | zah2 = 0.5 * ak13(ji,jj,1) / zalk * ( ( zdic - zalk ) + zah2 ) |
---|
102 | zh2co3(ji,jj) = ( 2.* zdic - zalk ) / ( 2.+ ak13(ji,jj,1) / zah2 ) * zfact |
---|
103 | hi(ji,jj,1) = zah2 * zfact |
---|
104 | END DO |
---|
105 | END DO |
---|
106 | END DO |
---|
107 | |
---|
108 | |
---|
109 | ! -------------- |
---|
110 | ! COMPUTE FLUXES |
---|
111 | ! -------------- |
---|
112 | |
---|
113 | ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS |
---|
114 | ! ------------------------------------------- |
---|
115 | |
---|
116 | !CDIR NOVERRCHK |
---|
117 | DO jj = 1, jpj |
---|
118 | !CDIR NOVERRCHK |
---|
119 | DO ji = 1, jpi |
---|
120 | |
---|
121 | zttc = MIN( 35., tn(ji,jj,1) ) |
---|
122 | |
---|
123 | ! Compute the schmidt Number both O2 and CO2 |
---|
124 | ! ------------------------------------------ |
---|
125 | |
---|
126 | zschmittco2 = 2073.1 - 125.62 * zttc + 3.6276 * zttc**2 - 0.043126 * zttc**3 |
---|
127 | zschmitto2 = 1953.4 - 128.0 * zttc + 3.9918 * zttc**2 - 0.050091 * zttc**3 |
---|
128 | |
---|
129 | ! wind speed |
---|
130 | zws = wndm(ji,jj) |
---|
131 | |
---|
132 | ! Compute the piston velocity for O2 and CO2 |
---|
133 | ! ------------------------------------------ |
---|
134 | |
---|
135 | zkgwan = ( 0.3 * zws * zws & |
---|
136 | & + 2.5 * ( 0.5246 + zttc * ( 0.016256+zttc*0.00049946 ) ) ) & |
---|
137 | # if defined key_off_degrad |
---|
138 | & * facvol(ji,jj,1) & |
---|
139 | # endif |
---|
140 | & / (100. * 3600.)* ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1) |
---|
141 | |
---|
142 | ! COMPUTE GAS EXCHANGE FOR CO2 |
---|
143 | zkgco2(ji,jj) = zkgwan * SQRT( 660./ zschmittco2 ) |
---|
144 | zkgo2(ji,jj) = zkgwan * SQRT( 660./ zschmitto2 ) |
---|
145 | |
---|
146 | END DO |
---|
147 | END DO |
---|
148 | |
---|
149 | ztco2flx(:,:) = 0. |
---|
150 | DO jj = 1, jpj |
---|
151 | DO ji = 1, jpi |
---|
152 | |
---|
153 | ! Compute CO2 flux for the sea and air |
---|
154 | zfld = atcco2 * tmask(ji,jj,1) * chemc(ji,jj,1) * zkgco2(ji,jj) |
---|
155 | zflu = zh2co3(ji,jj) * tmask(ji,jj,1) * zkgco2(ji,jj) |
---|
156 | tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) / fse3t(ji,jj,1) |
---|
157 | |
---|
158 | ! compute flux of carbon |
---|
159 | ztco2flx(ji,jj) = ( zfld - zflu ) * rfact & |
---|
160 | & * e1t(ji,jj) * e2t(ji,jj) * tmask(ji,jj,1) * 1000. |
---|
161 | |
---|
162 | ! Compute O2 flux |
---|
163 | zfld16 = atcox * chemc(ji,jj,2) *tmask(ji,jj,1) * zkgo2(ji,jj) |
---|
164 | zflu16 = trn(ji,jj,1,jpoxy) * tmask(ji,jj,1) * zkgo2(ji,jj) |
---|
165 | tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + ( zfld16 - zflu16 ) / fse3t(ji,jj,1) |
---|
166 | |
---|
167 | # if defined key_trc_diaadd |
---|
168 | ! Save diagnostics |
---|
169 | trc2d(ji,jj,1) = ( zfld - zflu ) * 1000. |
---|
170 | trc2d(ji,jj,2) = ( zfld16 - zflu16 ) * 1000. |
---|
171 | trc2d(ji,jj,3) = zkgco2(ji,jj) |
---|
172 | trc2d(ji,jj,4) = atcco2 - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn ) |
---|
173 | # endif |
---|
174 | END DO |
---|
175 | END DO |
---|
176 | ! |
---|
177 | |
---|
178 | ! Total Flux of Carbon |
---|
179 | DO jj = 1, jpj |
---|
180 | DO ji = 1, jpi |
---|
181 | tco2flx = tco2flx + ztco2flx(ji,jj) * tmask_i(ji,jj) |
---|
182 | END DO |
---|
183 | END DO |
---|
184 | |
---|
185 | IF( MOD( kt, nspyr ) == 0 ) THEN |
---|
186 | WRITE(numout,*) ' Atmospheric pCO2 :' |
---|
187 | WRITE(numout,*) '-------------------- : ',kt,' ',atcco2 |
---|
188 | WRITE(numout,*) '(ppm)' |
---|
189 | WRITE(numout,*) 'Total Flux of Carbon :' |
---|
190 | WRITE(numout,*) '-------------------- : ',tco2flx * 12./1E15 |
---|
191 | WRITE(numout,*) '(GtC/an)' |
---|
192 | tco2flx = 0. |
---|
193 | ENDIF |
---|
194 | |
---|
195 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
196 | WRITE(charout, FMT="('flx ')") |
---|
197 | CALL prt_ctl_trc_info(charout) |
---|
198 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
---|
199 | ENDIF |
---|
200 | |
---|
201 | |
---|
202 | END SUBROUTINE p4z_flx |
---|
203 | |
---|
204 | SUBROUTINE p4z_flx_init |
---|
205 | |
---|
206 | !!---------------------------------------------------------------------- |
---|
207 | !! *** ROUTINE p4z_flx_init *** |
---|
208 | !! |
---|
209 | !! ** Purpose : Initialization of atmospheric conditions |
---|
210 | !! |
---|
211 | !! ** Method : Read the natext namelist and check the parameters |
---|
212 | !! called at the first timestep (nittrc000) |
---|
213 | !! ** input : Namelist natext |
---|
214 | !! |
---|
215 | !!---------------------------------------------------------------------- |
---|
216 | |
---|
217 | NAMELIST/natext/ atcco2 |
---|
218 | |
---|
219 | REWIND( numnat ) ! read numnat |
---|
220 | READ ( numnat, natext ) |
---|
221 | |
---|
222 | IF(lwp) THEN ! control print |
---|
223 | WRITE(numout,*) ' ' |
---|
224 | WRITE(numout,*) ' Namelist parameters for air-sea exchange, natext' |
---|
225 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
---|
226 | WRITE(numout,*) ' Atmospheric pCO2 atcco2 =', atcco2 |
---|
227 | ENDIF |
---|
228 | |
---|
229 | END SUBROUTINE p4z_flx_init |
---|
230 | |
---|
231 | #else |
---|
232 | !!====================================================================== |
---|
233 | !! Dummy module : No PISCES bio-model |
---|
234 | !!====================================================================== |
---|
235 | CONTAINS |
---|
236 | SUBROUTINE p4z_flx( kt ) ! Empty routine |
---|
237 | INTEGER, INTENT( in ) :: kt |
---|
238 | WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt |
---|
239 | END SUBROUTINE p4z_flx |
---|
240 | #endif |
---|
241 | |
---|
242 | !!====================================================================== |
---|
243 | END MODULE p4zflx |
---|