New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in trunk/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMO/TOP_SRC/PISCES/p4zprod.F90 @ 1836

Last change on this file since 1836 was 1836, checked in by cetlod, 14 years ago

improvment of PISCES model, see ticket:661
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 18.8 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_prod       : 
14   !!----------------------------------------------------------------------
15   USE trc
16   USE oce_trc         !
17   USE sms_pisces      !
18   USE prtctl_trc
19   USE p4zopt
20   USE p4zint
21   USE p4zlim
22   USE iom
23
24   USE lib_mpp
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod    ! called in p4zbio.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::   &
33     pislope   = 3.0_wp          ,  &  !:
34     pislope2  = 3.0_wp          ,  &  !:
35     excret    = 10.e-5_wp       , &   !:
36     excret2   = 0.05_wp         , &   !:
37     chlcnm    = 0.033_wp        , &   !:
38     chlcdm    = 0.05_wp         , &   !:
39     fecnm     = 10.E-6_wp       , &   !:
40     fecdm     = 15.E-6_wp       , &   !:
41     grosip    = 0.151_wp
42
43   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk)  ::        &
44     &                   prmax
45   
46   REAL(wp) ::   &
47      texcret                    ,  &  !: 1 - excret
48      texcret2                   ,  &  !: 1 - excret2       
49      rpis180                    ,  &  !: rpi / 180
50      tpp                              !: Total primary production
51
52   INTEGER  ::  nspyr                  !: number of timesteps per year
53
54   !!* Substitution
55#  include "top_substitute.h90"
56   !!----------------------------------------------------------------------
57   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
58   !! $Id$
59   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61
62CONTAINS
63
64   SUBROUTINE p4z_prod( kt , jnt )
65      !!---------------------------------------------------------------------
66      !!                     ***  ROUTINE p4z_prod  ***
67      !!
68      !! ** Purpose :   Compute the phytoplankton production depending on
69      !!              light, temperature and nutrient availability
70      !!
71      !! ** Method  : - ???
72      !!---------------------------------------------------------------------
73      INTEGER, INTENT(in) :: kt, jnt
74      INTEGER  ::   ji, jj, jk
75      REAL(wp) ::   zsilfac, zfact
76      REAL(wp) ::   zprdiachl, zprbiochl, zsilim, ztn, zadap, zadap2
77      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zetot2, zmax, zproreg, zproreg2
78      REAL(wp) ::   zmxltst, zmxlday, zlim1
79      REAL(wp) ::   zpislopen  , zpislope2n
80      REAL(wp) ::   zrum, zcodel, zargu, zvol
81#if defined key_trc_diaadd && defined key_trc_dia3d
82      REAL(wp) ::   zrfact2
83#endif
84      REAL(wp), DIMENSION(jpi,jpj)     ::   zmixnano   , zmixdiat, zstrn
85      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpislopead , zpislopead2
86      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprdia     , zprbio, zysopt
87      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprorca    , zprorcad, zprofed
88      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zprofen   , zprochln, zprochld
89      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpronew    , zpronewd
90      CHARACTER (len=25) :: charout
91      !!---------------------------------------------------------------------
92
93
94      IF( ( kt * jnt ) == nittrc000  )   CALL p4z_prod_init      ! Initialization (first time-step only)
95
96
97      zprorca (:,:,:) = 0.0
98      zprorcad(:,:,:) = 0.0
99      zprofed(:,:,:) = 0.0
100      zprofen(:,:,:) = 0.0
101      zprochln(:,:,:) = 0.0
102      zprochld(:,:,:) = 0.0
103      zpronew (:,:,:) = 0.0
104      zpronewd(:,:,:) = 0.0
105      zprdia  (:,:,:) = 0.0
106      zprbio  (:,:,:) = 0.0
107      zysopt  (:,:,:) = 0.0
108
109      ! Computation of the optimal production
110
111# if defined key_off_degrad
112      prmax(:,:,:) = 0.6 / rday * tgfunc(:,:,:) * facvol(:,:,:)
113# else
114      prmax(:,:,:) = 0.6 / rday * tgfunc(:,:,:)
115# endif
116
117      ! compute the day length depending on latitude and the day
118      IF(lwp) write(numout,*)
119      IF(lwp) write(numout,*) 'p4zday : - Julian day ', nday_year
120      IF(lwp) write(numout,*) '~~~~~~'
121
122      IF( nleapy == 1 .AND. MOD( nyear, 4 ) == 0 ) THEN
123         zrum = FLOAT( nday_year - 80 ) / 366.
124      ELSE
125         zrum = FLOAT( nday_year - 80 ) / 365.
126      ENDIF
127      zcodel = ASIN(  SIN( zrum * rpi * 2. ) * SIN( rpis180 * 23.5 )  )
128
129      ! day length in hours
130      zstrn(:,:) = 0.
131      DO jj = 1, jpj
132         DO ji = 1, jpi
133            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rpis180 )
134            zargu = MAX( -1., MIN(  1., zargu ) )
135            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rpis180 / 15. )
136         END DO
137      END DO
138
139
140!CDIR NOVERRCHK
141      DO jk = 1, jpkm1
142!CDIR NOVERRCHK
143         DO jj = 1, jpj
144!CDIR NOVERRCHK
145            DO ji = 1, jpi
146
147               ! Computation of the P-I slope for nanos and diatoms
148               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
149                   ztn    = MAX( 0., tn(ji,jj,jk) - 15. )
150                   zadap  = 0.+ 1.* ztn / ( 2.+ ztn )
151                   zadap2 = 0.e0
152
153                   zfact  = EXP( -0.21 * emoy(ji,jj,jk) )
154
155                   zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * zfact )
156                   zpislopead2(ji,jj,jk) = pislope2 * ( 1.+ zadap2 * zfact )
157
158                   zpislopen = zpislopead(ji,jj,jk) * trn(ji,jj,jk,jpnch)                 &
159                     &         / ( trn(ji,jj,jk,jpphy) * 12.                   + rtrn )   &
160                     &         / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
161
162                   zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)                &
163                     &          / ( trn(ji,jj,jk,jpdia) * 12.                   + rtrn )   &
164                     &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
165
166                   ! Computation of production function
167                   zprbio(ji,jj,jk) = prmax(ji,jj,jk) * &
168                     &                (  1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
169                   zprdia(ji,jj,jk) = prmax(ji,jj,jk) * &
170                     &                (  1.- EXP( -zpislope2n * ediat(ji,jj,jk) )  )
171               ENDIF
172            END DO
173         END DO
174      END DO
175
176
177      DO jk = 1, jpkm1
178         DO jj = 1, jpj
179            DO ji = 1, jpi
180
181                IF( etot(ji,jj,jk) > 1.E-3 ) THEN
182                   !    Si/C of diatoms
183                   !    ------------------------
184                   !    Si/C increases with iron stress and silicate availability
185                   !    Si/C is arbitrariliy increased for very high Si concentrations
186                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
187
188                  zlim1  = trn(ji,jj,jk,jpsil) / ( trn(ji,jj,jk,jpsil) + xksi1 )
189                  zlim   = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
190
191                  zsilim = MIN( zprdia(ji,jj,jk)    / ( rtrn + prmax(ji,jj,jk) ),                 &
192                  &          trn(ji,jj,jk,jpfer) / ( concdfe(ji,jj,jk) + trn(ji,jj,jk,jpfer) ),   &
193                  &          trn(ji,jj,jk,jppo4) / ( concdnh4 + trn(ji,jj,jk,jppo4) ),            &
194                  &          zlim )
195                  zsilfac = 5.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim1 - 0.5 ) )  ) + 1.e0
196                  zsiborn = MAX( 0.e0, ( trn(ji,jj,jk,jpsil) - 15.e-6 ) )
197                  zsilfac2 = 1.+ 3.* zsiborn / ( zsiborn + xksi2 )
198                  zsilfac = MIN( 6.4,zsilfac * zsilfac2)
199                  zysopt(ji,jj,jk) = grosip * zlim1 * zsilfac
200
201              ENDIF
202            END DO
203         END DO
204      END DO
205
206      !  Computation of the limitation term due to
207      !  A mixed layer deeper than the euphotic depth
208      DO jj = 1, jpj
209         DO ji = 1, jpi
210            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
211            zmxlday = zmxltst**2 / rday
212            zmixnano(ji,jj) = 1.- zmxlday / ( 1.+ zmxlday )
213            zmixdiat(ji,jj) = 1.- zmxlday / ( 3.+ zmxlday )
214         END DO
215      END DO
216 
217      !  Mixed-layer effect on production                                                                               
218      DO jk = 1, jpkm1
219         DO jj = 1, jpj
220            DO ji = 1, jpi
221               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
222                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
223                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
224               ENDIF
225            END DO
226         END DO
227      END DO
228
229
230      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
231      zstrn(:,:) = 24. / zstrn(:,:)
232
233!CDIR NOVERRCHK
234      DO jk = 1, jpkm1
235!CDIR NOVERRCHK
236         DO jj = 1, jpj
237!CDIR NOVERRCHK
238            DO ji = 1, jpi
239
240               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
241                  !     Computation of the various production terms for nanophyto.
242                  zetot2 = enano(ji,jj,jk) * zstrn(ji,jj)
243                  zmax = MAX( 0.1, xlimphy(ji,jj,jk) )
244                  zpislopen = zpislopead(ji,jj,jk)          &
245                  &         * trn(ji,jj,jk,jpnch) / ( rtrn + trn(ji,jj,jk,jpphy) * 12.)         &
246                  &         / ( prmax(ji,jj,jk) * rday * zmax + rtrn )
247
248                  zprbiochl = prmax(ji,jj,jk) * (  1.- EXP( -zpislopen * zetot2 )  )
249
250                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trn(ji,jj,jk,jpphy) * rfact2
251
252                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk)    &
253                  &             / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
254                  zprod = rday * zprorca(ji,jj,jk) * zprbiochl * trn(ji,jj,jk,jpphy) *zmax
255
256                  zprofen(ji,jj,jk) = (fecnm)**2 * zprod / chlcnm            &
257                  &              / (  zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnfe) + rtrn  )
258
259                  zprochln(ji,jj,jk) = chlcnm * 144. * zprod                  &
260                  &              / (  zpislopead(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpnch) + rtrn  )
261               ENDIF
262            END DO
263         END DO
264      END DO
265
266!CDIR NOVERRCHK
267      DO jk = 1, jpkm1
268!CDIR NOVERRCHK
269         DO jj = 1, jpj
270!CDIR NOVERRCHK
271            DO ji = 1, jpi
272               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
273                  !  Computation of the various production terms for diatoms
274                  zetot2 = ediat(ji,jj,jk) * zstrn(ji,jj)
275                  zmax = MAX( 0.1, xlimdia(ji,jj,jk) )
276                  zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)        &
277                  &           / ( rtrn + trn(ji,jj,jk,jpdia) * 12.)        &
278                  &           / ( prmax(ji,jj,jk) * rday * zmax + rtrn )
279
280                  zprdiachl = prmax(ji,jj,jk) * (  1.- EXP( -zetot2 * zpislope2n )  )
281
282                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trn(ji,jj,jk,jpdia) * rfact2
283
284                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk)     &
285                  &              / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
286
287                  zprod = rday * zprorcad(ji,jj,jk) * zprdiachl * trn(ji,jj,jk,jpdia) * zmax
288
289                  zprofed(ji,jj,jk) = (fecdm)**2 * zprod / chlcdm                   &
290                  &              / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdfe) + rtrn )
291
292                  zprochld(ji,jj,jk) = chlcdm * 144. * zprod       &
293                  &              / ( zpislopead2(ji,jj,jk) * zetot2 * trn(ji,jj,jk,jpdch) + rtrn )
294
295               ENDIF
296            END DO
297         END DO
298      END DO
299      !
300
301      !   Update the arrays TRA which contain the biological sources and sinks
302      DO jk = 1, jpkm1
303         DO jj = 1, jpj
304           DO ji =1 ,jpi
305              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
306              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
307              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
308              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
309              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
310              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
311              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
312              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
313              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
314              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
315              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
316              tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
317              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + &
318              &                     excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
319              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
320              &                    + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
321              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) &
322              &                     - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
323              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) &
324              &                     - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
325              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
326              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) &
327              &                    + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
328          END DO
329        END DO
330     END DO
331
332     ! Total primary production per year
333     DO jk = 1, jpkm1
334        DO jj = 1, jpj
335          DO ji = 1, jpi
336             zvol = cvol(ji,jj,jk)
337#if defined key_off_degrad
338             zvol = zvol * facvol(ji,jj,jk)
339#endif
340             tpp  = tpp + ( zprorca(ji,jj,jk) + zprorcad(ji,jj,jk) ) &
341                          * zvol * tmask(ji,jj,jk) * tmask_i(ji,jj)
342          END DO
343        END DO
344      END DO
345
346
347      IF( MOD( kt, nspyr ) == 0 .AND. jnt == nrdttrc ) THEN
348        IF( lk_mpp ) CALL mpp_sum( tpp )
349        WRITE(numout,*) 'Total PP :'
350        WRITE(numout,*) '-------------------- : ',tpp * 12. / 1.E12
351        WRITE(numout,*) '(GtC/yr)'
352        tpp = 0.
353      ENDIF
354
355#if defined key_trc_diaadd && defined key_trc_dia3d && ! defined key_iomput
356      !   Supplementary diagnostics
357      zrfact2 = 1.e3 * rfact2r
358      trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zrfact2 * tmask(:,:,:)
359      trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
360      trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zrfact2 * tmask(:,:,:)
361      trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
362      trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
363      trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
364#  if ! defined key_kriest
365      trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
366#  endif
367#endif
368
369#if defined key_trc_diaadd && defined key_trc_dia3d && defined key_iomput
370      zrfact2 = 1.e3 * rfact2r
371      IF ( jnt == nrdttrc ) then
372         CALL iom_put( "PPPHY" , zprorca (:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by nanophyto
373         CALL iom_put( "PPPHY2", zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by diatom
374         CALL iom_put( "PPNEWN", zpronew (:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by nanophyto
375         CALL iom_put( "PPNEWD", zpronewd(:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by diatom
376         CALL iom_put( "PBSi"  , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:) ) ! biogenic silica production
377         CALL iom_put( "PFeD"  , zprofed (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by diatom
378         CALL iom_put( "PFeN"  , zprofen (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by nanophyto
379      ENDIF
380#endif
381
382       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
383         WRITE(charout, FMT="('prod')")
384         CALL prt_ctl_trc_info(charout)
385         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
386       ENDIF
387
388   END SUBROUTINE p4z_prod
389
390   SUBROUTINE p4z_prod_init
391
392      !!----------------------------------------------------------------------
393      !!                  ***  ROUTINE p4z_prod_init  ***
394      !!
395      !! ** Purpose :   Initialization of phytoplankton production parameters
396      !!
397      !! ** Method  :   Read the nampisprod namelist and check the parameters
398      !!      called at the first timestep (nittrc000)
399      !!
400      !! ** input   :   Namelist nampisprod
401      !!
402      !!----------------------------------------------------------------------
403
404      NAMELIST/nampisprod/ pislope, pislope2, excret, excret2, chlcnm, chlcdm,   &
405         &              fecnm, fecdm, grosip
406
407      REWIND( numnat )                     ! read numnat
408      READ  ( numnat, nampisprod )
409
410      IF(lwp) THEN                         ! control print
411         WRITE(numout,*) ' '
412         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
413         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
414         WRITE(numout,*) '    mean Si/C ratio                           grosip    =', grosip
415         WRITE(numout,*) '    P-I slope                                 pislope   =', pislope
416         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret    =', excret
417         WRITE(numout,*) '    excretion ratio of diatoms                excret2   =', excret2
418         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2  =', pislope2
419         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm    =', chlcnm
420         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm    =', chlcdm
421         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm     =', fecnm
422         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm     =', fecdm
423      ENDIF
424
425      ! number of timesteps per year
426      nspyr  = INT( nyear_len(1) * rday / rdt )
427
428      rpis180   = rpi / 180.
429      texcret   = 1.0 - excret
430      texcret2  = 1.0 - excret2
431      tpp       = 0.
432
433   END SUBROUTINE p4z_prod_init
434
435
436
437#else
438   !!======================================================================
439   !!  Dummy module :                                   No PISCES bio-model
440   !!======================================================================
441CONTAINS
442   SUBROUTINE p4z_prod                    ! Empty routine
443   END SUBROUTINE p4z_prod
444#endif 
445
446   !!======================================================================
447END MODULE  p4zprod
Note: See TracBrowser for help on using the repository browser.