source: trunk/NEMO/TOP_SRC/SMS/p4zmeso.F @ 247

CCC $Header$ 
CCC  TOP 1.0 , LOCEAN-IPSL (2005) 
C This software is governed by CeCILL licence see modipsl/doc/NEMO_CeCILL.txt 
C ---------------------------------------------------------------------------
CDIR$ LIST
      SUBROUTINE p4zmeso
#if defined key_passivetrc && defined key_trc_pisces
CCC---------------------------------------------------------------------
CCC
CCC            ROUTINE p4zmeso : PISCES MODEL
CCC            ******************************
CCC
CCC  PURPOSE :
CCC  ---------
CCC         Compute the sources/sinks for mesozooplankton
CCC
CC   METHOD :
CC   -------
CC      
CC
CC   INPUT :
CC   -----
CC      argument
CC              None
CC      common
CC              all the common defined in opa
CC
CC
CC   OUTPUT :                   : no
CC   ------
CC
CC   EXTERNAL :
CC   --------
CC          None
CC
CC   MODIFICATIONS:
CC   --------------
CC      original  : O. Aumont (2002)
CC----------------------------------------------------------------------
CC parameters and commons
CC ======================
CDIR$ NOLIST
      USE oce_trc
      USE trp_trc
      USE sms
      IMPLICIT NONE
CDIR$ LIST
CC----------------------------------------------------------------------
CC local declarations
CC ==================
      INTEGER ji, jj, jk
      REAL compadi,compaph,compapoc,compaz
      REAL compam,zdenom,graze2
C
        DO jk = 1,jpkm1
          DO jj = 1,jpj
            DO ji = 1,jpi
C
        compam=max((trn(ji,jj,jk,jpmes)-1.E-9),0.)
C
C     Respiration rates of both zooplankton
C     -------------------------------------
C
        respz2(ji,jj,jk) = resrat2*rfact2/rjjss
     &    *trn(ji,jj,jk,jpmes)/(xkmort+trn(ji,jj,jk,jpmes))
     &    *compam*tmask(ji,jj,jk)
#    if defined key_off_degrad
     &    *facvol(ji,jj,jk)
#    endif
C
C     Zooplankton mortality. A square function has been selected with
C     no real reason except that it seems to be more stable and may
C     mimic predation.
C     ---------------------------------------------------------------
C
        tortz2(ji,jj,jk) = mzrat2*1E6*rfact2/rjjss*tgfunc(ji,jj,jk)
     &    *trn(ji,jj,jk,jpmes)*compam*tmask(ji,jj,jk)
#    if defined key_off_degrad
     &    *facvol(ji,jj,jk)
#    endif
C
            END DO
          END DO
        END DO

        DO jk = 1,jpkm1
          DO jj = 1,jpj
            DO ji = 1,jpi
C
        compadi = max((trn(ji,jj,jk,jpdia)-1E-8),0.)
        compaz = max((trn(ji,jj,jk,jpzoo)-1.E-9),0.)
        compaph = max((trn(ji,jj,jk,jpphy)-1E-8),0.)
        compapoc=max((trn(ji,jj,jk,jppoc)-1E-9),0.)
C
C     Microzooplankton grazing
C     ------------------------
C
        graze2 = grazrat2/rjjss*rfact2*tmask(ji,jj,jk)
     &    *Tgfunc(ji,jj,jk)
#    if defined key_off_degrad
     &    *facvol(ji,jj,jk)
#    endif

        zdenom=1./(xkgraz2+xprefc*trn(ji,jj,jk,jpdia)
     &    +xprefz*trn(ji,jj,jk,jpzoo)
     &    +xprefp*trn(ji,jj,jk,jpphy)
     &    +xprefpoc*trn(ji,jj,jk,jppoc))

        grazd(ji,jj,jk) = graze2*xprefc*compadi*zdenom
     &    *trn(ji,jj,jk,jpmes)

        grazz(ji,jj,jk) = graze2*xprefz*compaz*zdenom
     &    *trn(ji,jj,jk,jpmes)

        grazn(ji,jj,jk) = graze2*xprefp*compaph*zdenom
     &    *trn(ji,jj,jk,jpmes)

        grazpoc(ji,jj,jk) = graze2*xprefpoc*compapoc*zdenom
     &    *trn(ji,jj,jk,jpmes)

        graznf(ji,jj,jk) = grazn(ji,jj,jk)
     &    *trn(ji,jj,jk,jpnfe)/(trn(ji,jj,jk,jpphy)+rtrn)

        graznch(ji,jj,jk) = grazn(ji,jj,jk)
     &    *trn(ji,jj,jk,jpnch)/(trn(ji,jj,jk,jpphy)+rtrn)

        grazs(ji,jj,jk) = grazd(ji,jj,jk)
     &    *trn(ji,jj,jk,jpbsi)/(trn(ji,jj,jk,jpdia)+rtrn)

        grazf(ji,jj,jk) = grazd(ji,jj,jk)
     &    *trn(ji,jj,jk,jpdfe)/(trn(ji,jj,jk,jpdia)+rtrn)

        grazdch(ji,jj,jk) = grazd(ji,jj,jk)
     &    *trn(ji,jj,jk,jpdch)/(trn(ji,jj,jk,jpdia)+rtrn)

        grazpof(ji,jj,jk) = grazpoc(ji,jj,jk)
     &    *trn(ji,jj,jk,jpsfe)/(trn(ji,jj,jk,jppoc)+rtrn)
C
            END DO
          END DO
        END DO

        DO jk = 1,jpkm1
          DO jj = 1,jpj
            DO ji = 1,jpi
C
C    Mesozooplankton flux feeding on GOC
C    ----------------------------------
C
        grazffe(ji,jj,jk) = 1.3E-2/5.6E-7*rfact2/rjjss
     &    *wsbio4(ji,jj,jk)*trn(ji,jj,jk,jpgoc)*trn(ji,jj,jk,jpmes)
#    if defined key_off_degrad
     &    *facvol(ji,jj,jk)
#    endif

        grazfff(ji,jj,jk) = grazffe(ji,jj,jk)
     &    *trn(ji,jj,jk,jpbfe)/(trn(ji,jj,jk,jpgoc)+rtrn)
C
            END DO
          END DO
        END DO

        DO jk = 1,jpkm1
          DO jj = 1,jpj
            DO ji = 1,jpi
C
C    Mesozooplankton efficiency
C    --------------------------
C
        grarem2(ji,jj,jk)=(grazd(ji,jj,jk)+grazz(ji,jj,jk)
     &    +grazn(ji,jj,jk)+grazpoc(ji,jj,jk)+grazffe(ji,jj,jk))
     &    *(1.-epsher2-unass2)

        grafer2(ji,jj,jk)=(grazf(ji,jj,jk)+graznf(ji,jj,jk)
     &    +grazz(ji,jj,jk)*ferat3+grazpof(ji,jj,jk)
     &    +grazfff(ji,jj,jk))*(1.-epsher2-unass2)
     &    +epsher2*(grazd(ji,jj,jk)*max(
     &    (trn(ji,jj,jk,jpdfe)/(trn(ji,jj,jk,jpdia)+rtrn)
     &    -ferat3),0.)+grazn(ji,jj,jk)*max(
     &    (trn(ji,jj,jk,jpnfe)/(trn(ji,jj,jk,jpphy)+rtrn)
     &    -ferat3),0.)+grazpoc(ji,jj,jk)*max(
     &    (trn(ji,jj,jk,jpsfe)/(trn(ji,jj,jk,jppoc)+rtrn)
     &    -ferat3),0.)+grazffe(ji,jj,jk)*max(
     &    (trn(ji,jj,jk,jpbfe)/(trn(ji,jj,jk,jpgoc)+rtrn)
     &    -ferat3),0.))

        grapoc2(ji,jj,jk)=(grazd(ji,jj,jk)+grazz(ji,jj,jk)
     &    +grazn(ji,jj,jk)+grazpoc(ji,jj,jk)+grazffe(ji,jj,jk))*unass2

            END DO
          END DO
        END DO
C
#endif
      RETURN
      END