source: trunk/NEMO/TOP_SRC/SMS/p4zrem.F @ 247

CCC $Header$ 
CCC  TOP 1.0 , LOCEAN-IPSL (2005) 
C This software is governed by CeCILL licence see modipsl/doc/NEMO_CeCILL.txt 
C ---------------------------------------------------------------------------
CDIR$ LIST
      SUBROUTINE p4zrem
#if defined key_passivetrc && defined key_trc_pisces
CCC---------------------------------------------------------------------
CCC
CCC          ROUTINE p4zrem : PISCES MODEL
CCC          *****************************
CCC
CCC  PURPOSE :
CCC  ---------
CCC         Compute remineralization/scavenging of organic compounds
CCC
CC   INPUT :
CC   -----
CC      common
CC              all the common defined in opa
CC
CC
CC   OUTPUT :                   : no
CC   ------
CC
CC   EXTERNAL :
CC   --------
CC            None
CC
CC   MODIFICATIONS:
CC   --------------
CC      original  : 2004 - O. Aumont 
CC----------------------------------------------------------------------
CC parameters and commons
CC ======================
CDIR$ NOLIST
      USE oce_trc
      USE trp_trc
      USE sms
      IMPLICIT NONE
CDIR$ LIST
CC----------------------------------------------------------------------
CC local declarations
CC ==================
      INTEGER ji, jj, jk
      REAL remip,remik,xlam1b
      REAL xkeq,xfeequi,siremin
      REAL zsatur,zsatur2,znusil
      REAL fesatur(jpi,jpj,jpk)
CC----------------------------------------------------------------------
CC statement functions
CC ===================
CDIR$ NOLIST
#include "domzgr_substitute.h90"
CDIR$ LIST
C
C      Computation of the mean phytoplankton concentration as
C      a crude estimate of the bacterial biomass
C      --------------------------------------------------
C
         DO jj=1,jpj
           DO ji=1,jpi
         phymoy(ji,jj)=min((trn(ji,jj,1,jpphy)+trn(ji,jj,1,jpdia))
     .     ,3.E-6)
           END DO
         END DO

         DO jk = 1,jpk-1
           DO jj = 1,jpj
             DO ji = 1,jpi
C
C    DENITRIFICATION FACTOR COMPUTED FROM O2 LEVELS
C    ----------------------------------------------
C
          nitrfac(ji,jj,jk)=
     &      max(0.,0.4*(6.E-6-trn(ji,jj,jk,jpoxy))/(oxymin+
     &      trn(ji,jj,jk,jpoxy)))
          nitrfac(ji,jj,jk)=min(1.,nitrfac(ji,jj,jk))
             END DO
           END DO
         END DO

         DO jk = 1,jpkm1
           DO jj = 1,jpj
             DO ji = 1,jpi
C
C     DOC ammonification. Depends on depth, phytoplankton biomass
C     and a limitation term which is supposed to be a parameterization
C     of the bacterial activity. 
C     ----------------------------------------------------------------
         remik=
     &     xremik*rfact2/(rjjss*1.E-6)*tmask(ji,jj,jk)
     &     *xlimbac(ji,jj,jk)*phymoy(ji,jj)*max(0.1
     &     ,exp(-max(0.,(fsdept(ji,jj,jk)-hmld(ji,jj)))/200.))
#    if defined key_off_degrad
     &     *facvol(ji,jj,jk)
#    endif
C
C     Ammonification in oxic waters with oxygen consumption
C     -----------------------------------------------------
C
         olimi(ji,jj,jk)=min((trn(ji,jj,jk,jpoxy)-rtrn)/o2ut,
     &     remik*(1.-nitrfac(ji,jj,jk))*trn(ji,jj,jk,jpdoc)) 
         olimi(ji,jj,jk)=max(0.,olimi(ji,jj,jk))
C
C     Ammonification in suboxic waters with denitrification
C     -------------------------------------------------------
C
         denitr(ji,jj,jk)=min((trn(ji,jj,jk,jpno3)-rtrn)/6.1,
     &     remik*nitrfac(ji,jj,jk)*trn(ji,jj,jk,jpdoc))
             END DO
           END DO
         END DO

         DO jk = 1,jpkm1
           DO jj = 1,jpj
             DO ji = 1,jpi
C
C    NH4 nitrification to NO3. Ceased for oxygen concentrations
C    below 2 umol/L. Inhibited at strong light 
C    ----------------------------------------------------------
C
         onitr(ji,jj,jk)=nitrif*rfact2/rjjss*trn(ji,jj,jk,jpnh4)
     &     *1./(1.+emoy(ji,jj,jk))*tmask(ji,jj,jk)
     &     *(1.-nitrfac(ji,jj,jk))
#    if defined key_off_degrad
     &     *facvol(ji,jj,jk)
#    endif
             END DO
           END DO
         END DO

         DO jk = 1,jpkm1
           DO jj = 1,jpj
             DO ji = 1,jpi
C
C    Bacterial uptake of iron. No iron is available in DOC. So
C    Bacteries are obliged to take up iron from the water. Some
C    studies (especially at Papa) have shown this uptake to be
C    significant
C    ----------------------------------------------------------
C
         xbactfer(ji,jj,jk)=0.02*20E-6*rfact2
     &     *prmax(ji,jj,jk)*tmask(ji,jj,jk)*xlimphy(ji,jj,jk)
     &     *xlimdia(ji,jj,jk)*phymoy(ji,jj)*exp(-max
     &     (fsdept(ji,jj,jk)-hmld(ji,jj),0.)/200.)
             END DO
           END DO
         END DO
C
         DO jk = 1,jpkm1
           DO jj = 1,jpj
             DO ji = 1,jpi
C
C    POC disaggregation by turbulence and bacterial activity. 
C    -------------------------------------------------------------
C
         remip=xremip/rjjss*rfact2*tmask(ji,jj,jk)*(0.25+0.75
     &     *exp(-max((fsdept(ji,jj,jk)-150.),0.)/1000.))
#    if defined key_off_degrad
     &     *facvol(ji,jj,jk)
#    endif
C
C    POC disaggregation rate is reduced in anoxic zone as shown by
C    sediment traps data. In oxic area, the exponent of the martin's
C    law is around -0.87. In anoxic zone, it is around -0.35. This
C    means a disaggregation constant about 0.5 the value in oxic zones
C    -----------------------------------------------------------------
C
         remip=remip*(1.-0.5*nitrfac(ji,jj,jk))
C
         orem(ji,jj,jk)=remip*trn(ji,jj,jk,jppoc)
         orem2(ji,jj,jk)=remip*trn(ji,jj,jk,jpgoc)
         ofer(ji,jj,jk)=remip*trn(ji,jj,jk,jpsfe)
         ofer2(ji,jj,jk)=remip*trn(ji,jj,jk,jpbfe)
C
             END DO
           END DO
         END DO

         DO jk = 1,jpkm1
           DO jj = 1,jpj
             DO ji = 1,jpi
C
C     Remineralization rate of BSi depedant on T and saturation
C     ---------------------------------------------------------
C
         zsatur=(sio3eq(ji,jj,jk)-trn(ji,jj,jk,jpsil))/
     &     (sio3eq(ji,jj,jk)+rtrn)
         zsatur2=zsatur*(1.+tn(ji,jj,jk)/400.)**2*
     &     (1.+tn(ji,jj,jk)/400.)**2
         znusil=0.225*(1.+tn(ji,jj,jk)/15.)*zsatur+0.775
     &     *exp(9.25*log(zsatur2))

         siremin=xsirem/rjjss*rfact2*tmask(ji,jj,jk)*znusil
#    if defined key_off_degrad
     &     *facvol(ji,jj,jk)
#    endif
C
         osil(ji,jj,jk)=siremin*trn(ji,jj,jk,jpdsi)
             END DO
           END DO
         END DO

         DO jk = 1,jpkm1
           DO jj = 1,jpj
             DO ji = 1,jpi
C
C     scavenging rate of iron. this scavenging rate depends on the
C     load in particles on which they are adsorbed. The
C     parameterization has been taken from studies on Th
C     ------------------------------------------------------------
C
         xkeq=fekeq(ji,jj,jk)
         fesatur(ji,jj,jk)=0.6E-9
         xfeequi=(-(1.+fesatur(ji,jj,jk)*xkeq-xkeq*trn(ji,jj,jk,jpfer))+
     &     sqrt((1.+fesatur(ji,jj,jk)*xkeq-xkeq*trn(ji,jj,jk,jpfer))**2
     &     +4.*trn(ji,jj,jk,jpfer)*xkeq))/(2.*xkeq)

         xlam1b=3E-5+xlam1*(trn(ji,jj,jk,jppoc)
     &     +trn(ji,jj,jk,jpgoc)+trn(ji,jj,jk,jpcal)+
     &      trn(ji,jj,jk,jpdsi))*1E6

         xscave(ji,jj,jk)=xfeequi*xlam1b/rjjss*rfact2*tmask(ji,jj,jk)
#    if defined key_off_degrad
     &     *facvol(ji,jj,jk)
#    endif
C
C  Increased scavenging for very high iron concentrations
C  found near the coasts due to increased lithogenic particles
C  and let's say it unknown processes (precipitation, ...)
C  -----------------------------------------------------------
C
         xaggdfe(ji,jj,jk)=2.*xlam1*rfact2/rjjss*max(0.,
     &     (trn(ji,jj,jk,jpfer)*1E9-1.))*trn(ji,jj,jk,jpfer)
     &     *tmask(ji,jj,jk)
#    if defined key_off_degrad
     &     *facvol(ji,jj,jk)
#    endif
C
             END DO
           END DO
         END DO
C
#endif
      RETURN
      END