New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_muscl.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcadv_muscl.F90 @ 1193

Last change on this file since 1193 was 1193, checked in by cetlod, 16 years ago

Correction of transport module to ensure reproductibility for TOP configurations, see ticket:253
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 16.5 KB
Line 
1MODULE trcadv_muscl
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv_muscl  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6#if defined key_top
7   !!----------------------------------------------------------------------
8   !!   'key_top'                                                TOP models
9   !!----------------------------------------------------------------------
10   !!   trc_adv_muscl : update the tracer trend with the horizontal
11   !!                   and vertical advection trends using MUSCL scheme
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce_trc         ! ocean dynamics and active tracers variables
15   USE trp_trc             ! ocean passive tracers variables
16   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
17   USE trcbbl          ! advective passive tracers in the BBL
18   USE lib_mpp
19   USE prtctl_trc      ! Print control for debbuging
20   USE trdmld_trc
21   USE trdmld_trc_oce          ! ocean variables trends
22
23   IMPLICIT NONE
24   PRIVATE
25
26   !! * Accessibility
27   PUBLIC trc_adv_muscl  ! routine called by trcstp.F90
28
29   !! * Substitutions
30#  include "top_substitute.h90"
31   !!----------------------------------------------------------------------
32   !!   TOP 1.0 , LOCEAN-IPSL (2005)
33   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcadv_muscl.F90,v 1.13 2007/10/12 09:26:30 opalod Exp $
34   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
35   !!----------------------------------------------------------------------
36
37CONTAINS
38
39   SUBROUTINE trc_adv_muscl( kt )
40      !!----------------------------------------------------------------------
41      !!                    ***  ROUTINE trc_adv_muscl  ***
42      !!         
43      !! ** Purpose :   Compute the now trend due to total advection of any pas-
44      !!      sive tracer using a MUSCL scheme (Monotone Upstream-centered Scheme
45      !!      for Conservation Laws) and add it to the general tracer trend.
46      !!
47      !! ** Method  :
48      !!
49      !! ** Action  : - update tra with the now advective tracer trends
50      !!              - save trends ('key_trdmld_trc')
51      !!
52      !! References :               
53      !!      Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
54      !! IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
55      !!
56      !! History :
57      !!        !  06-00  (A.Estublier)  for passive tracers
58      !!   9.0  !  03-04  (C. Ethe, G. Madec)  F90: Free form and module
59      !!----------------------------------------------------------------------
60      !! * modules used
61#if defined key_trcbbl_adv
62      USE oce_trc            , zun => ua,  &  ! use ua as workspace
63         &                     zvn => va      ! use va as workspace
64      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
65#else
66      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
67                               zvn => vn,  &  !              zvn == vn
68                               zwn => wn      !              zwn == wn
69#endif
70
71      !! * Arguments
72      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
73
74      !! * Local declarations
75      INTEGER ::   ji, jj, jk,jn            ! dummy loop indices
76      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   &
77         zt1, zt2, ztp1, ztp2
78
79      REAL(wp) ::   zu, zv, zw, zeu, zev, zew, zbtr, ztra
80      REAL(wp) ::   z0u, z0v, z0w
81      REAL(wp) ::   zzt1, zzt2, zalpha, z2dtt
82      REAL(wp) ::   ztai, ztaj, zfui, zfvj
83      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd
84      CHARACTER (len=22) :: charout
85      !!----------------------------------------------------------------------
86
87
88      IF( kt == nittrc000 .AND. lwp ) THEN
89         WRITE(numout,*)
90         WRITE(numout,*) 'trc_adv : MUSCL advection scheme'
91         WRITE(numout,*) '~~~~~~~'
92      ENDIF
93
94       IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) )
95
96#if defined key_trcbbl_adv
97      ! Advective bottom boundary layer
98      ! -------------------------------
99      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
100      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
101      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:)
102#endif
103
104 
105
106      DO jn = 1, jptra
107
108         ! I. Horizontal advective fluxes
109         ! ------------------------------
110
111         ! first guess of the slopes
112         ! interior values
113         DO jk = 1, jpkm1
114            DO jj = 1, jpjm1     
115               DO ji = 1, fs_jpim1   ! vector opt.
116                  zt1(ji,jj,jk) = umask(ji,jj,jk) * ( trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn) )
117                  zt2(ji,jj,jk) = vmask(ji,jj,jk) * ( trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
118               END DO
119            END DO
120         END DO
121         ! bottom values
122         zt1(:,:,jpk) = 0.e0
123         zt2(:,:,jpk) = 0.e0
124
125         ! lateral boundary conditions on zt1, zt2
126         CALL lbc_lnk( zt1, 'U', -1. )   
127         CALL lbc_lnk( zt2, 'V', -1. ) 
128
129
130         ! Slopes
131         ! interior values
132         DO jk = 1, jpkm1
133            DO jj = 2, jpj
134               DO ji = fs_2, jpi   ! vector opt.
135                  ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji-1,jj  ,jk) )   &
136                     &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji-1,jj  ,jk) ) )
137                  ztp2(ji,jj,jk) =                    ( zt2(ji,jj,jk) + zt2(ji  ,jj-1,jk) )   &
138                     &           * ( 0.25 + SIGN( 0.25, zt2(ji,jj,jk) * zt2(ji  ,jj-1,jk) ) )
139               END DO
140            END DO
141         END DO
142         ! bottom values
143         ztp1(:,:,jpk) = 0.e0
144         ztp2(:,:,jpk) = 0.e0
145
146         ! Slopes limitation
147         DO jk = 1, jpkm1
148            DO jj = 2, jpj
149               DO ji = fs_2, jpi   ! vector opt.
150                  ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
151                     &           * MIN(    ABS( ztp1(ji  ,jj,jk) ),   &
152                     &                  2.*ABS( zt1 (ji-1,jj,jk) ),   &
153                     &                  2.*ABS( zt1 (ji  ,jj,jk) ) )
154
155                  ztp2(ji,jj,jk) = SIGN( 1., ztp2(ji,jj,jk) )   &
156                     &           * MIN(    ABS( ztp2(ji,jj  ,jk) ),   &
157                     &                  2.*ABS( zt2 (ji,jj-1,jk) ),   &
158                     &                  2.*ABS( zt2 (ji,jj  ,jk) ) )
159
160               END DO
161            END DO
162         END DO
163
164         ! Advection terms
165         ! interior values
166         DO jk = 1, jpkm1
167            DO jj = 2, jpjm1     
168               DO ji = fs_2, fs_jpim1   ! vector opt.
169                  ! volume fluxes
170#if ! defined key_zco
171                  zeu = e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
172                  zev = e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
173#else
174                  zeu = e2u(ji,jj) * zun(ji,jj,jk)
175                  zev = e1v(ji,jj) * zvn(ji,jj,jk)
176#endif
177                  ! MUSCL fluxes
178                  z2dtt = rdttra(jk) * FLOAT(ndttrc)
179                  z0u = SIGN( 0.5, zun(ji,jj,jk) )           
180                  zalpha = 0.5 - z0u
181                  zu  = z0u - 0.5 * zun(ji,jj,jk) * z2dtt / e1u(ji,jj)
182                  zzt1 = trb(ji+1,jj,jk,jn) + zu*ztp1(ji+1,jj,jk)
183                  zzt2 = trb(ji  ,jj,jk,jn) + zu*ztp1(ji  ,jj,jk)
184                  zt1(ji,jj,jk) = zeu * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
185                  z0v = SIGN( 0.5, zvn(ji,jj,jk) )           
186                  zalpha = 0.5 - z0v
187                  zv  = z0v - 0.5 * zvn(ji,jj,jk) * z2dtt / e2v(ji,jj)
188                  zzt1 = trb(ji,jj+1,jk,jn) + zv*ztp2(ji,jj+1,jk)
189                  zzt2 = trb(ji,jj  ,jk,jn) + zv*ztp2(ji,jj  ,jk)
190                  zt2(ji,jj,jk) = zev * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
191               END DO
192            END DO
193         END DO
194
195         ! lateral boundary conditions on zt1, zt2 (changed sign)
196         CALL lbc_lnk( zt1, 'U', -1. ) 
197         CALL lbc_lnk( zt2, 'V', -1. ) 
198
199         ! Compute and add the horizontal advective trend
200
201         DO jk = 1, jpkm1
202            DO jj = 2, jpjm1     
203               DO ji = fs_2, fs_jpim1   ! vector opt.
204#if ! defined key_zco
205                  zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
206#else
207                  zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj) )
208#endif
209                  ! horizontal advective trends
210                  ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji-1,jj  ,jk  )   &
211                     &            + zt2(ji,jj,jk) - zt2(ji  ,jj-1,jk  ) )
212                  ! add it to the general tracer trends
213                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra
214#if defined key_trc_diatrd
215                  ! recompute the trends in i- and j-direction as Uh gradh(T)
216#   if defined key_s_coord || defined key_partial_steps
217                  zfui =  e2u(ji  ,jj) * fse3u(ji,  jj,jk) * un(ji,  jj,jk)   &
218                     & -  e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk)
219                  zfvj =  e1v(ji,jj  ) * fse3v(ji,jj  ,jk) * vn(ji,jj  ,jk)   &
220                     & -  e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk)
221#   else
222                  zfui = e2u(ji  ,jj) * un(ji,  jj,jk)   &
223                     & - e2u(ji-1,jj) * un(ji-1,jj,jk)
224                  zfvj = e1v(ji,jj  ) * vn(ji,jj  ,jk)   &
225                     & - e1v(ji,jj-1) * vn(ji,jj-1,jk)
226#   endif
227                  ztai =-zbtr * (  zt1(ji,jj,jk) - zt1(ji-1,jj  ,jk) - trn(ji,jj,jk,jn) * zfui  )
228                  ztaj =-zbtr * (  zt2(ji,jj,jk) - zt2(ji  ,jj-1,jk) - trn(ji,jj,jk,jn) * zfvj  )
229                  ! save i- and j- advective trends computed as Uh gradh(T)
230                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),1) = ztai
231                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),2) = ztaj
232#endif
233
234               END DO
235            END DO
236         END DO
237
238         ! 3. Save the horizontal advective trends for diagnostics
239         ! -------------------------------------------------------
240         TRDTRC_XY : IF( l_trdtrc ) THEN
241
242            ! 3.1) Passive tracer ZONAL advection trends
243            DO jk = 1, jpkm1
244               DO jj = 2, jpjm1
245                  DO ji = fs_2, fs_jpim1   ! vector opt.
246#if ! defined key_zco
247                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
248                     zfui = e2u(ji  ,jj) * fse3u(ji,  jj,jk) * zun(ji,  jj,jk)   &
249                        & - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * zun(ji-1,jj,jk)
250#else
251                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) )
252                     zfui = e2u(ji  ,jj) * zun(ji,  jj,jk)  - e2u(ji-1,jj) * zun(ji-1,jj,jk)
253#endif
254                     ! recompute the trends in i- direction as Uh gradh(T)
255                     ztrtrd(ji,jj,jk) = - zbtr*( zt1(ji,jj,jk) - zt1(ji-1,jj,jk) - trn(ji,jj,jk,jn)*zfui )
256                  END DO
257               END DO
258            END DO
259
260            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd, jn, jptrc_trd_xad, kt )
261
262            ! 3.2)  Passive tracer MERIDIONAL advection trends
263            DO jk = 1, jpkm1
264               DO jj = 2, jpjm1
265                  DO ji = fs_2, fs_jpim1   ! vector opt.
266                     ! recompute the trends in i- and j-direction as Uh gradh(T)
267#if ! defined key_zco
268                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
269                     zfvj = e1v(ji,jj  ) * fse3v(ji,jj  ,jk) * zvn(ji,jj  ,jk)   &
270                        & - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * zvn(ji,jj-1,jk)
271#else
272                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) )
273                     zfvj = e1v(ji,jj  ) * zvn(ji,jj  ,jk) - e1v(ji,jj-1) * zvn(ji,jj-1,jk)
274#endif
275                     ztrtrd(ji,jj,jk) = - zbtr*( zt2(ji,jj,jk) - zt2(ji,jj-1,jk) - trn(ji,jj,jk,jn)*zfvj )
276                  END DO
277               END DO
278            END DO
279
280            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd, jn, jptrc_trd_yad, kt )
281
282         ENDIF TRDTRC_XY
283
284      ENDDO
285
286      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
287         WRITE(charout, FMT="('muscl - had')")
288         CALL prt_ctl_trc_info(charout)
289         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
290      ENDIF
291
292         ! II. Vertical advective fluxes
293         ! -----------------------------
294
295      DO jn = 1, jptra
296         ! First guess of the slope
297         ! interior values
298         DO jk = 2, jpkm1
299            zt1(:,:,jk) = tmask(:,:,jk) * ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) )
300         END DO
301         ! surface and bottom boundary conditions
302         zt1 (:,:, 1 ) = 0.e0 
303         zt1 (:,:,jpk) = 0.e0
304         ! Slopes
305         DO jk = 2, jpkm1
306            DO jj = 1, jpj
307               DO ji = 1, jpi
308                  ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji,jj,jk+1) )   &
309                     &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji,jj,jk+1) ) )
310               END DO
311            END DO
312         END DO
313
314         ! Slopes limitation
315         ! interior values
316         DO jk = 2, jpkm1
317            DO jj = 1, jpj
318               DO ji = 1, jpi
319                  ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
320                     &           * MIN(    ABS( ztp1(ji,jj,jk  ) ),   &
321                     &                  2.*ABS( zt1 (ji,jj,jk+1) ),   &
322                     &                  2.*ABS( zt1 (ji,jj,jk  ) ) )
323               END DO
324            END DO
325         END DO
326         ! surface values
327         ztp1(:,:,1) = 0. 
328         ! vertical advective flux
329         ! interior values
330         DO jk = 1, jpkm1
331            DO jj = 2, jpjm1     
332               DO ji = fs_2, fs_jpim1   ! vector opt.
333                  z2dtt = rdttra(jk) * FLOAT(ndttrc)
334                  zew = zwn(ji,jj,jk+1)
335                  z0w = SIGN( 0.5, zwn(ji,jj,jk+1) )
336                  zalpha = 0.5 + z0w
337                  zw  = z0w - 0.5 * zwn(ji,jj,jk+1)*z2dtt / fse3w(ji,jj,jk+1)
338                  zzt1 = trb(ji,jj,jk+1,jn) + zw*ztp1(ji,jj,jk+1)
339                  zzt2 = trb(ji,jj,jk  ,jn) + zw*ztp1(ji,jj,jk  )
340                  zt1(ji,jj,jk+1) = zew * ( zalpha * zzt1 + (1.-zalpha)*zzt2 )
341               END DO
342            END DO
343         END DO
344         ! surface values
345         IF( lk_dynspg_rl ) THEN        ! rigid lid : flux set to zero
346            zt1(:,:, 1 ) = 0.e0
347         ELSE                           ! free surface
348            zt1(:,:, 1 ) = zwn(:,:,1) * trb(:,:,1,jn)
349         ENDIF
350
351         ! bottom values
352         zt1(:,:,jpk) = 0.e0
353
354         ! Compute & add the vertical advective trend
355
356         DO jk = 1, jpkm1
357            DO jj = 2, jpjm1     
358               DO ji = fs_2, fs_jpim1   ! vector opt.
359                  zbtr = 1. / fse3t(ji,jj,jk)
360                  ! horizontal advective trends
361                  ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) )
362                  ! add it to the general tracer trends
363                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + ztra
364#if defined key_trc_diatrd
365                  ! save the vertical advective trends computed as w gradz(T)
366                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),3) = ztra - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk)
367#endif
368
369               END DO
370            END DO
371         END DO
372
373         ! 3. Save the vertical advective trends for diagnostic
374         ! ----------------------------------------------------
375         TRDTRC_Z : IF( l_trdtrc )THEN
376
377            ! Compute T/S vertical advection trends
378            DO jk = 1, jpkm1
379               DO jj = 2, jpjm1
380                  DO ji = fs_2, fs_jpim1   ! vector opt.
381                     zbtr = 1. / fse3t(ji,jj,jk)
382                     ! horizontal advective trends
383                     ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) )
384                     ! save the vertical advective trends computed as w gradz(T)
385                     ztrtrd(ji,jj,jk) = ztra - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk)
386                  END DO
387               END DO
388            END DO
389
390            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt)
391
392         END IF TRDTRC_Z
393      END DO
394
395      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
396         WRITE(charout, FMT="('muscl - zad')")
397         CALL prt_ctl_trc_info(charout)
398         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
399      ENDIF
400
401END SUBROUTINE trc_adv_muscl
402
403#else
404   !!----------------------------------------------------------------------
405   !!   Default option                                         Empty module
406   !!----------------------------------------------------------------------
407CONTAINS
408   SUBROUTINE trc_adv_muscl( kt ) 
409      INTEGER, INTENT(in) :: kt
410      WRITE(*,*) 'trc_adv_muscl: You should not have seen this print! error?', kt
411   END SUBROUTINE trc_adv_muscl
412#endif
413
414   !!======================================================================
415END MODULE trcadv_muscl
Note: See TracBrowser for help on using the repository browser.