1 | MODULE trcadv_muscl |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE trcadv_muscl *** |
---|
4 | !! Ocean passive tracers: horizontal & vertical advective trend |
---|
5 | !!============================================================================== |
---|
6 | #if defined key_top |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! 'key_top' TOP models |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! trc_adv_muscl : update the tracer trend with the horizontal |
---|
11 | !! and vertical advection trends using MUSCL scheme |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! * Modules used |
---|
14 | USE oce_trc ! ocean dynamics and active tracers variables |
---|
15 | USE trp_trc ! ocean passive tracers variables |
---|
16 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
17 | USE trcbbl ! advective passive tracers in the BBL |
---|
18 | USE lib_mpp |
---|
19 | USE prtctl_trc ! Print control for debbuging |
---|
20 | USE trdmld_trc |
---|
21 | USE trdmld_trc_oce ! ocean variables trends |
---|
22 | |
---|
23 | IMPLICIT NONE |
---|
24 | PRIVATE |
---|
25 | |
---|
26 | !! * Accessibility |
---|
27 | PUBLIC trc_adv_muscl ! routine called by trcstp.F90 |
---|
28 | |
---|
29 | !! * Substitutions |
---|
30 | # include "top_substitute.h90" |
---|
31 | !!---------------------------------------------------------------------- |
---|
32 | !! TOP 1.0 , LOCEAN-IPSL (2005) |
---|
33 | !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcadv_muscl.F90,v 1.13 2007/10/12 09:26:30 opalod Exp $ |
---|
34 | !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt |
---|
35 | !!---------------------------------------------------------------------- |
---|
36 | |
---|
37 | CONTAINS |
---|
38 | |
---|
39 | SUBROUTINE trc_adv_muscl( kt ) |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | !! *** ROUTINE trc_adv_muscl *** |
---|
42 | !! |
---|
43 | !! ** Purpose : Compute the now trend due to total advection of any pas- |
---|
44 | !! sive tracer using a MUSCL scheme (Monotone Upstream-centered Scheme |
---|
45 | !! for Conservation Laws) and add it to the general tracer trend. |
---|
46 | !! |
---|
47 | !! ** Method : |
---|
48 | !! |
---|
49 | !! ** Action : - update tra with the now advective tracer trends |
---|
50 | !! - save trends ('key_trdmld_trc') |
---|
51 | !! |
---|
52 | !! References : |
---|
53 | !! Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation |
---|
54 | !! IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa) |
---|
55 | !! |
---|
56 | !! History : |
---|
57 | !! ! 06-00 (A.Estublier) for passive tracers |
---|
58 | !! 9.0 ! 03-04 (C. Ethe, G. Madec) F90: Free form and module |
---|
59 | !!---------------------------------------------------------------------- |
---|
60 | !! * modules used |
---|
61 | #if defined key_trcbbl_adv |
---|
62 | USE oce_trc , zun => ua, & ! use ua as workspace |
---|
63 | & zvn => va ! use va as workspace |
---|
64 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn |
---|
65 | #else |
---|
66 | USE oce_trc , zun => un, & ! When no bbl, zun == un |
---|
67 | zvn => vn, & ! zvn == vn |
---|
68 | zwn => wn ! zwn == wn |
---|
69 | #endif |
---|
70 | |
---|
71 | !! * Arguments |
---|
72 | INTEGER, INTENT( in ) :: kt ! ocean time-step |
---|
73 | |
---|
74 | !! * Local declarations |
---|
75 | INTEGER :: ji, jj, jk,jn ! dummy loop indices |
---|
76 | REAL(wp), DIMENSION (jpi,jpj,jpk) :: & |
---|
77 | zt1, zt2, ztp1, ztp2 |
---|
78 | |
---|
79 | REAL(wp) :: zu, zv, zw, zeu, zev, zew, zbtr, ztra |
---|
80 | REAL(wp) :: z0u, z0v, z0w |
---|
81 | REAL(wp) :: zzt1, zzt2, zalpha, z2dtt |
---|
82 | REAL(wp) :: zfui, zfvj |
---|
83 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrtrd |
---|
84 | #if defined key_trc_diatrd |
---|
85 | REAL(wp) :: ztai, ztaj |
---|
86 | #endif |
---|
87 | CHARACTER (len=22) :: charout |
---|
88 | !!---------------------------------------------------------------------- |
---|
89 | |
---|
90 | |
---|
91 | IF( kt == nittrc000 .AND. lwp ) THEN |
---|
92 | WRITE(numout,*) |
---|
93 | WRITE(numout,*) 'trc_adv : MUSCL advection scheme' |
---|
94 | WRITE(numout,*) '~~~~~~~' |
---|
95 | ENDIF |
---|
96 | |
---|
97 | IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) ) |
---|
98 | |
---|
99 | #if defined key_trcbbl_adv |
---|
100 | ! Advective bottom boundary layer |
---|
101 | ! ------------------------------- |
---|
102 | zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:) |
---|
103 | zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:) |
---|
104 | zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:) |
---|
105 | #endif |
---|
106 | |
---|
107 | |
---|
108 | |
---|
109 | DO jn = 1, jptra |
---|
110 | |
---|
111 | ! I. Horizontal advective fluxes |
---|
112 | ! ------------------------------ |
---|
113 | |
---|
114 | ! first guess of the slopes |
---|
115 | ! interior values |
---|
116 | DO jk = 1, jpkm1 |
---|
117 | DO jj = 1, jpjm1 |
---|
118 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
119 | zt1(ji,jj,jk) = umask(ji,jj,jk) * ( trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn) ) |
---|
120 | zt2(ji,jj,jk) = vmask(ji,jj,jk) * ( trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn) ) |
---|
121 | END DO |
---|
122 | END DO |
---|
123 | END DO |
---|
124 | ! bottom values |
---|
125 | zt1(:,:,jpk) = 0.e0 |
---|
126 | zt2(:,:,jpk) = 0.e0 |
---|
127 | |
---|
128 | ! lateral boundary conditions on zt1, zt2 |
---|
129 | CALL lbc_lnk( zt1, 'U', -1. ) |
---|
130 | CALL lbc_lnk( zt2, 'V', -1. ) |
---|
131 | |
---|
132 | |
---|
133 | ! Slopes |
---|
134 | ! interior values |
---|
135 | DO jk = 1, jpkm1 |
---|
136 | DO jj = 2, jpj |
---|
137 | DO ji = fs_2, jpi ! vector opt. |
---|
138 | ztp1(ji,jj,jk) = ( zt1(ji,jj,jk) + zt1(ji-1,jj ,jk) ) & |
---|
139 | & * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji-1,jj ,jk) ) ) |
---|
140 | ztp2(ji,jj,jk) = ( zt2(ji,jj,jk) + zt2(ji ,jj-1,jk) ) & |
---|
141 | & * ( 0.25 + SIGN( 0.25, zt2(ji,jj,jk) * zt2(ji ,jj-1,jk) ) ) |
---|
142 | END DO |
---|
143 | END DO |
---|
144 | END DO |
---|
145 | ! bottom values |
---|
146 | ztp1(:,:,jpk) = 0.e0 |
---|
147 | ztp2(:,:,jpk) = 0.e0 |
---|
148 | |
---|
149 | ! Slopes limitation |
---|
150 | DO jk = 1, jpkm1 |
---|
151 | DO jj = 2, jpj |
---|
152 | DO ji = fs_2, jpi ! vector opt. |
---|
153 | ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) ) & |
---|
154 | & * MIN( ABS( ztp1(ji ,jj,jk) ), & |
---|
155 | & 2.*ABS( zt1 (ji-1,jj,jk) ), & |
---|
156 | & 2.*ABS( zt1 (ji ,jj,jk) ) ) |
---|
157 | |
---|
158 | ztp2(ji,jj,jk) = SIGN( 1., ztp2(ji,jj,jk) ) & |
---|
159 | & * MIN( ABS( ztp2(ji,jj ,jk) ), & |
---|
160 | & 2.*ABS( zt2 (ji,jj-1,jk) ), & |
---|
161 | & 2.*ABS( zt2 (ji,jj ,jk) ) ) |
---|
162 | |
---|
163 | END DO |
---|
164 | END DO |
---|
165 | END DO |
---|
166 | |
---|
167 | ! Advection terms |
---|
168 | ! interior values |
---|
169 | DO jk = 1, jpkm1 |
---|
170 | DO jj = 2, jpjm1 |
---|
171 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
172 | ! volume fluxes |
---|
173 | #if ! defined key_zco |
---|
174 | zeu = e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk) |
---|
175 | zev = e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk) |
---|
176 | #else |
---|
177 | zeu = e2u(ji,jj) * zun(ji,jj,jk) |
---|
178 | zev = e1v(ji,jj) * zvn(ji,jj,jk) |
---|
179 | #endif |
---|
180 | ! MUSCL fluxes |
---|
181 | z2dtt = rdttra(jk) * FLOAT(ndttrc) |
---|
182 | z0u = SIGN( 0.5, zun(ji,jj,jk) ) |
---|
183 | zalpha = 0.5 - z0u |
---|
184 | zu = z0u - 0.5 * zun(ji,jj,jk) * z2dtt / e1u(ji,jj) |
---|
185 | zzt1 = trb(ji+1,jj,jk,jn) + zu*ztp1(ji+1,jj,jk) |
---|
186 | zzt2 = trb(ji ,jj,jk,jn) + zu*ztp1(ji ,jj,jk) |
---|
187 | zt1(ji,jj,jk) = zeu * ( zalpha * zzt1 + (1.-zalpha) * zzt2 ) |
---|
188 | z0v = SIGN( 0.5, zvn(ji,jj,jk) ) |
---|
189 | zalpha = 0.5 - z0v |
---|
190 | zv = z0v - 0.5 * zvn(ji,jj,jk) * z2dtt / e2v(ji,jj) |
---|
191 | zzt1 = trb(ji,jj+1,jk,jn) + zv*ztp2(ji,jj+1,jk) |
---|
192 | zzt2 = trb(ji,jj ,jk,jn) + zv*ztp2(ji,jj ,jk) |
---|
193 | zt2(ji,jj,jk) = zev * ( zalpha * zzt1 + (1.-zalpha) * zzt2 ) |
---|
194 | END DO |
---|
195 | END DO |
---|
196 | END DO |
---|
197 | |
---|
198 | ! lateral boundary conditions on zt1, zt2 (changed sign) |
---|
199 | CALL lbc_lnk( zt1, 'U', -1. ) |
---|
200 | CALL lbc_lnk( zt2, 'V', -1. ) |
---|
201 | |
---|
202 | ! Compute and add the horizontal advective trend |
---|
203 | |
---|
204 | DO jk = 1, jpkm1 |
---|
205 | DO jj = 2, jpjm1 |
---|
206 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
207 | #if ! defined key_zco |
---|
208 | zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) ) |
---|
209 | #else |
---|
210 | zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj) ) |
---|
211 | #endif |
---|
212 | ! horizontal advective trends |
---|
213 | ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji-1,jj ,jk ) & |
---|
214 | & + zt2(ji,jj,jk) - zt2(ji ,jj-1,jk ) ) |
---|
215 | ! add it to the general tracer trends |
---|
216 | tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra |
---|
217 | #if defined key_trc_diatrd |
---|
218 | ! recompute the trends in i- and j-direction as Uh gradh(T) |
---|
219 | # if ! defined key_zco |
---|
220 | zfui = e2u(ji ,jj) * fse3u(ji, jj,jk) * un(ji, jj,jk) & |
---|
221 | & - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk) |
---|
222 | zfvj = e1v(ji,jj ) * fse3v(ji,jj ,jk) * vn(ji,jj ,jk) & |
---|
223 | & - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk) |
---|
224 | # else |
---|
225 | zfui = e2u(ji ,jj) * un(ji, jj,jk) & |
---|
226 | & - e2u(ji-1,jj) * un(ji-1,jj,jk) |
---|
227 | zfvj = e1v(ji,jj ) * vn(ji,jj ,jk) & |
---|
228 | & - e1v(ji,jj-1) * vn(ji,jj-1,jk) |
---|
229 | # endif |
---|
230 | ztai =-zbtr * ( zt1(ji,jj,jk) - zt1(ji-1,jj ,jk) - trn(ji,jj,jk,jn) * zfui ) |
---|
231 | ztaj =-zbtr * ( zt2(ji,jj,jk) - zt2(ji ,jj-1,jk) - trn(ji,jj,jk,jn) * zfvj ) |
---|
232 | ! save i- and j- advective trends computed as Uh gradh(T) |
---|
233 | IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),1) = ztai |
---|
234 | IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),2) = ztaj |
---|
235 | #endif |
---|
236 | |
---|
237 | END DO |
---|
238 | END DO |
---|
239 | END DO |
---|
240 | |
---|
241 | ! 3. Save the horizontal advective trends for diagnostics |
---|
242 | ! ------------------------------------------------------- |
---|
243 | TRDTRC_XY : IF( l_trdtrc ) THEN |
---|
244 | |
---|
245 | ! 3.1) Passive tracer ZONAL advection trends |
---|
246 | DO jk = 1, jpkm1 |
---|
247 | DO jj = 2, jpjm1 |
---|
248 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
249 | #if ! defined key_zco |
---|
250 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
251 | zfui = e2u(ji ,jj) * fse3u(ji, jj,jk) * zun(ji, jj,jk) & |
---|
252 | & - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * zun(ji-1,jj,jk) |
---|
253 | #else |
---|
254 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) ) |
---|
255 | zfui = e2u(ji ,jj) * zun(ji, jj,jk) - e2u(ji-1,jj) * zun(ji-1,jj,jk) |
---|
256 | #endif |
---|
257 | ! recompute the trends in i- direction as Uh gradh(T) |
---|
258 | ztrtrd(ji,jj,jk) = - zbtr*( zt1(ji,jj,jk) - zt1(ji-1,jj,jk) - trn(ji,jj,jk,jn)*zfui ) |
---|
259 | END DO |
---|
260 | END DO |
---|
261 | END DO |
---|
262 | |
---|
263 | IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd, jn, jptrc_trd_xad, kt ) |
---|
264 | |
---|
265 | ! 3.2) Passive tracer MERIDIONAL advection trends |
---|
266 | DO jk = 1, jpkm1 |
---|
267 | DO jj = 2, jpjm1 |
---|
268 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
269 | ! recompute the trends in i- and j-direction as Uh gradh(T) |
---|
270 | #if ! defined key_zco |
---|
271 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
272 | zfvj = e1v(ji,jj ) * fse3v(ji,jj ,jk) * zvn(ji,jj ,jk) & |
---|
273 | & - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * zvn(ji,jj-1,jk) |
---|
274 | #else |
---|
275 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) ) |
---|
276 | zfvj = e1v(ji,jj ) * zvn(ji,jj ,jk) - e1v(ji,jj-1) * zvn(ji,jj-1,jk) |
---|
277 | #endif |
---|
278 | ztrtrd(ji,jj,jk) = - zbtr*( zt2(ji,jj,jk) - zt2(ji,jj-1,jk) - trn(ji,jj,jk,jn)*zfvj ) |
---|
279 | END DO |
---|
280 | END DO |
---|
281 | END DO |
---|
282 | |
---|
283 | IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd, jn, jptrc_trd_yad, kt ) |
---|
284 | |
---|
285 | ENDIF TRDTRC_XY |
---|
286 | |
---|
287 | ENDDO |
---|
288 | |
---|
289 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
290 | WRITE(charout, FMT="('muscl - had')") |
---|
291 | CALL prt_ctl_trc_info(charout) |
---|
292 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd') |
---|
293 | ENDIF |
---|
294 | |
---|
295 | ! II. Vertical advective fluxes |
---|
296 | ! ----------------------------- |
---|
297 | |
---|
298 | DO jn = 1, jptra |
---|
299 | ! First guess of the slope |
---|
300 | ! interior values |
---|
301 | DO jk = 2, jpkm1 |
---|
302 | zt1(:,:,jk) = tmask(:,:,jk) * ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) |
---|
303 | END DO |
---|
304 | ! surface and bottom boundary conditions |
---|
305 | zt1 (:,:, 1 ) = 0.e0 |
---|
306 | zt1 (:,:,jpk) = 0.e0 |
---|
307 | ! Slopes |
---|
308 | DO jk = 2, jpkm1 |
---|
309 | DO jj = 1, jpj |
---|
310 | DO ji = 1, jpi |
---|
311 | ztp1(ji,jj,jk) = ( zt1(ji,jj,jk) + zt1(ji,jj,jk+1) ) & |
---|
312 | & * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji,jj,jk+1) ) ) |
---|
313 | END DO |
---|
314 | END DO |
---|
315 | END DO |
---|
316 | |
---|
317 | ! Slopes limitation |
---|
318 | ! interior values |
---|
319 | DO jk = 2, jpkm1 |
---|
320 | DO jj = 1, jpj |
---|
321 | DO ji = 1, jpi |
---|
322 | ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) ) & |
---|
323 | & * MIN( ABS( ztp1(ji,jj,jk ) ), & |
---|
324 | & 2.*ABS( zt1 (ji,jj,jk+1) ), & |
---|
325 | & 2.*ABS( zt1 (ji,jj,jk ) ) ) |
---|
326 | END DO |
---|
327 | END DO |
---|
328 | END DO |
---|
329 | ! surface values |
---|
330 | ztp1(:,:,1) = 0. |
---|
331 | ! vertical advective flux |
---|
332 | ! interior values |
---|
333 | DO jk = 1, jpkm1 |
---|
334 | DO jj = 2, jpjm1 |
---|
335 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
336 | z2dtt = rdttra(jk) * FLOAT(ndttrc) |
---|
337 | zew = zwn(ji,jj,jk+1) |
---|
338 | z0w = SIGN( 0.5, zwn(ji,jj,jk+1) ) |
---|
339 | zalpha = 0.5 + z0w |
---|
340 | zw = z0w - 0.5 * zwn(ji,jj,jk+1)*z2dtt / fse3w(ji,jj,jk+1) |
---|
341 | zzt1 = trb(ji,jj,jk+1,jn) + zw*ztp1(ji,jj,jk+1) |
---|
342 | zzt2 = trb(ji,jj,jk ,jn) + zw*ztp1(ji,jj,jk ) |
---|
343 | zt1(ji,jj,jk+1) = zew * ( zalpha * zzt1 + (1.-zalpha)*zzt2 ) |
---|
344 | END DO |
---|
345 | END DO |
---|
346 | END DO |
---|
347 | ! surface values |
---|
348 | IF( lk_vvl ) THEN |
---|
349 | ! variable volume: flux set to zero |
---|
350 | zt1(:,:, 1 ) = 0.e0 |
---|
351 | ELSE |
---|
352 | ! free surface-constant volume |
---|
353 | zt1(:,:, 1 ) = zwn(:,:,1) * trb(:,:,1,jn) |
---|
354 | ENDIF |
---|
355 | |
---|
356 | ! bottom values |
---|
357 | zt1(:,:,jpk) = 0.e0 |
---|
358 | |
---|
359 | ! Compute & add the vertical advective trend |
---|
360 | |
---|
361 | DO jk = 1, jpkm1 |
---|
362 | DO jj = 2, jpjm1 |
---|
363 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
364 | zbtr = 1. / fse3t(ji,jj,jk) |
---|
365 | ! horizontal advective trends |
---|
366 | ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) ) |
---|
367 | ! add it to the general tracer trends |
---|
368 | tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra |
---|
369 | #if defined key_trc_diatrd |
---|
370 | ! save the vertical advective trends computed as w gradz(T) |
---|
371 | IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),3) = ztra - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk) |
---|
372 | #endif |
---|
373 | |
---|
374 | END DO |
---|
375 | END DO |
---|
376 | END DO |
---|
377 | |
---|
378 | ! 3. Save the vertical advective trends for diagnostic |
---|
379 | ! ---------------------------------------------------- |
---|
380 | TRDTRC_Z : IF( l_trdtrc )THEN |
---|
381 | |
---|
382 | ! Compute T/S vertical advection trends |
---|
383 | DO jk = 1, jpkm1 |
---|
384 | DO jj = 2, jpjm1 |
---|
385 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
386 | zbtr = 1. / fse3t(ji,jj,jk) |
---|
387 | ! horizontal advective trends |
---|
388 | ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) ) |
---|
389 | ! save the vertical advective trends computed as w gradz(T) |
---|
390 | ztrtrd(ji,jj,jk) = ztra - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk) |
---|
391 | END DO |
---|
392 | END DO |
---|
393 | END DO |
---|
394 | |
---|
395 | IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt) |
---|
396 | |
---|
397 | END IF TRDTRC_Z |
---|
398 | END DO |
---|
399 | |
---|
400 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
401 | WRITE(charout, FMT="('muscl - zad')") |
---|
402 | CALL prt_ctl_trc_info(charout) |
---|
403 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd') |
---|
404 | ENDIF |
---|
405 | |
---|
406 | END SUBROUTINE trc_adv_muscl |
---|
407 | |
---|
408 | #else |
---|
409 | !!---------------------------------------------------------------------- |
---|
410 | !! Default option Empty module |
---|
411 | !!---------------------------------------------------------------------- |
---|
412 | CONTAINS |
---|
413 | SUBROUTINE trc_adv_muscl( kt ) |
---|
414 | INTEGER, INTENT(in) :: kt |
---|
415 | WRITE(*,*) 'trc_adv_muscl: You should not have seen this print! error?', kt |
---|
416 | END SUBROUTINE trc_adv_muscl |
---|
417 | #endif |
---|
418 | |
---|
419 | !!====================================================================== |
---|
420 | END MODULE trcadv_muscl |
---|