New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_muscl.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcadv_muscl.F90 @ 281

Last change on this file since 281 was 274, checked in by opalod, 19 years ago

nemo_v1_update_005:RB: update headers for the TOP component.
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 13.4 KB
Line 
1MODULE trcadv_muscl
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv_muscl  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6#if defined key_passivetrc
7   !!----------------------------------------------------------------------
8   !!   trc_adv_muscl : update the tracer trend with the horizontal
9   !!                   and vertical advection trends using MUSCL scheme
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE oce_trc         ! ocean dynamics and active tracers variables
13   USE trc             ! ocean passive tracers variables
14   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
15   USE trcbbl          ! advective passive tracers in the BBL
16   USE lib_mpp
17
18   IMPLICIT NONE
19   PRIVATE
20
21   !! * Accessibility
22   PUBLIC trc_adv_muscl  ! routine called by trcstp.F90
23
24   !! * Substitutions
25#  include "passivetrc_substitute.h90"
26   !!----------------------------------------------------------------------
27   !!  TOP 1.0,  LOCEAN-IPSL (2005)
28   !! $Header$
29   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
30   !!----------------------------------------------------------------------
31
32CONTAINS
33
34   SUBROUTINE trc_adv_muscl( kt )
35      !!----------------------------------------------------------------------
36      !!                    ***  ROUTINE trc_adv_muscl  ***
37      !!         
38      !! ** Purpose :   Compute the now trend due to total advection of any pas-
39      !!      sive tracer using a MUSCL scheme (Monotone Upstream-centered Scheme
40      !!      for Conservation Laws) and add it to the general tracer trend.
41      !!
42      !! ** Method  :
43      !!
44      !! ** Action  : - update tra with the now advective tracer trends
45      !!              - save trends in trtrd ('key_trc_diatrd')
46      !!
47      !! References :               
48      !!      Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
49      !! IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
50      !!
51      !! History :
52      !!        !  06-00  (A.Estublier)  for passive tracers
53      !!   9.0  !  03-04  (C. Ethe, G. Madec)  F90: Free form and module
54      !!----------------------------------------------------------------------
55      !! * modules used
56#if defined key_trcbbl_adv
57      USE oce_trc            , zun => ua,  &  ! use ua as workspace
58         &                     zvn => va      ! use va as workspace
59      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
60#else
61      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
62                               zvn => vn,  &  !              zvn == vn
63                               zwn => wn      !              zwn == wn
64#endif
65
66      !! * Arguments
67      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
68
69      !! * Local declarations
70      INTEGER ::   ji, jj, jk,jn            ! dummy loop indices
71      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   &
72         zt1, zt2, ztp1, ztp2
73
74      REAL(wp) ::   zu, zv, zw, zeu, zev, zew, zbtr, ztra
75      REAL(wp) ::   z0u, z0v, z0w
76      REAL(wp) ::   zzt1, zzt2, zalpha, z2dtt
77#if defined key_trc_diatrd
78      REAL(wp) ::   ztai, ztaj
79      REAL(wp) ::   zfui, zfvj
80#endif
81
82      !!----------------------------------------------------------------------
83
84
85      IF( kt == nittrc000 .AND. lwp ) THEN
86         WRITE(numout,*)
87         WRITE(numout,*) 'trc_adv : MUSCL advection scheme'
88         WRITE(numout,*) '~~~~~~~'
89      ENDIF
90
91 
92
93#if defined key_trcbbl_adv
94      ! Advective bottom boundary layer
95      ! -------------------------------
96      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
97      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
98      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:)
99#endif
100
101 
102
103      DO jn = 1, jptra
104
105         ! I. Horizontal advective fluxes
106         ! ------------------------------
107
108         ! first guess of the slopes
109         ! interior values
110         DO jk = 1, jpkm1
111            DO jj = 1, jpjm1     
112               DO ji = 1, fs_jpim1   ! vector opt.
113                  zt1(ji,jj,jk) = umask(ji,jj,jk) * ( trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn) )
114                  zt2(ji,jj,jk) = vmask(ji,jj,jk) * ( trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
115               END DO
116            END DO
117         END DO
118         ! bottom values
119         zt1(:,:,jpk) = 0.e0
120         zt2(:,:,jpk) = 0.e0
121
122         ! lateral boundary conditions on zt1, zt2
123         CALL lbc_lnk( zt1, 'U', -1. )   
124         CALL lbc_lnk( zt2, 'V', -1. ) 
125
126
127         ! Slopes
128         ! interior values
129         DO jk = 1, jpkm1
130            DO jj = 2, jpj
131               DO ji = fs_2, jpi   ! vector opt.
132                  ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji-1,jj  ,jk) )   &
133                     &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji-1,jj  ,jk) ) )
134                  ztp2(ji,jj,jk) =                    ( zt2(ji,jj,jk) + zt2(ji  ,jj-1,jk) )   &
135                     &           * ( 0.25 + SIGN( 0.25, zt2(ji,jj,jk) * zt2(ji  ,jj-1,jk) ) )
136               END DO
137            END DO
138         END DO
139         ! bottom values
140         ztp1(:,:,jpk) = 0.e0
141         ztp2(:,:,jpk) = 0.e0
142
143         ! Slopes limitation
144         DO jk = 1, jpkm1
145            DO jj = 2, jpj
146               DO ji = fs_2, jpi   ! vector opt.
147                  ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
148                     &           * MIN(    ABS( ztp1(ji  ,jj,jk) ),   &
149                     &                  2.*ABS( zt1 (ji-1,jj,jk) ),   &
150                     &                  2.*ABS( zt1 (ji  ,jj,jk) ) )
151
152                  ztp2(ji,jj,jk) = SIGN( 1., ztp2(ji,jj,jk) )   &
153                     &           * MIN(    ABS( ztp2(ji,jj  ,jk) ),   &
154                     &                  2.*ABS( zt2 (ji,jj-1,jk) ),   &
155                     &                  2.*ABS( zt2 (ji,jj  ,jk) ) )
156
157               END DO
158            END DO
159         END DO
160
161         ! Advection terms
162         ! interior values
163         DO jk = 1, jpkm1
164            DO jj = 2, jpjm1     
165               DO ji = fs_2, fs_jpim1   ! vector opt.
166                  ! volume fluxes
167#if defined key_s_coord || defined key_partial_steps
168                  zeu = e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
169                  zev = e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
170#else
171                  zeu = e2u(ji,jj) * zun(ji,jj,jk)
172                  zev = e1v(ji,jj) * zvn(ji,jj,jk)
173#endif
174                  ! MUSCL fluxes
175                  z2dtt = rdttra(jk) * FLOAT(ndttrc)
176                  z0u = SIGN( 0.5, zun(ji,jj,jk) )           
177                  zalpha = 0.5 - z0u
178                  zu  = z0u - 0.5 * zun(ji,jj,jk) * z2dtt / e1u(ji,jj)
179                  zzt1 = trb(ji+1,jj,jk,jn) + zu*ztp1(ji+1,jj,jk)
180                  zzt2 = trb(ji  ,jj,jk,jn) + zu*ztp1(ji  ,jj,jk)
181                  zt1(ji,jj,jk) = zeu * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
182                  z0v = SIGN( 0.5, zvn(ji,jj,jk) )           
183                  zalpha = 0.5 - z0v
184                  zv  = z0v - 0.5 * zvn(ji,jj,jk) * z2dtt / e2v(ji,jj)
185                  zzt1 = trb(ji,jj+1,jk,jn) + zv*ztp2(ji,jj+1,jk)
186                  zzt2 = trb(ji,jj  ,jk,jn) + zv*ztp2(ji,jj  ,jk)
187                  zt2(ji,jj,jk) = zev * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
188               END DO
189            END DO
190         END DO
191
192         ! lateral boundary conditions on zt1, zt2 (changed sign)
193         CALL lbc_lnk( zt1, 'U', -1. ) 
194         CALL lbc_lnk( zt2, 'V', -1. ) 
195
196         ! Compute and add the horizontal advective trend
197
198         DO jk = 1, jpkm1
199            DO jj = 2, jpjm1     
200               DO ji = fs_2, fs_jpim1   ! vector opt.
201#if defined key_s_coord || defined key_partial_steps
202                  zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
203#else
204                  zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj) )
205#endif
206                  ! horizontal advective trends
207                  ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji-1,jj  ,jk  )   &
208                     &            + zt2(ji,jj,jk) - zt2(ji  ,jj-1,jk  ) )
209                  ! add it to the general tracer trends
210                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra
211#if defined key_trc_diatrd
212                  ! recompute the trends in i- and j-direction as Uh gradh(T)
213#   if defined key_s_coord || defined key_partial_steps
214                  zfui =  e2u(ji  ,jj) * fse3u(ji,  jj,jk) * un(ji,  jj,jk)   &
215                     & -  e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk)
216                  zfvj =  e1v(ji,jj  ) * fse3v(ji,jj  ,jk) * vn(ji,jj  ,jk)   &
217                     & -  e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk)
218#   else
219                  zfui = e2u(ji  ,jj) * un(ji,  jj,jk)   &
220                     & - e2u(ji-1,jj) * un(ji-1,jj,jk)
221                  zfvj = e1v(ji,jj  ) * vn(ji,jj  ,jk)   &
222                     & - e1v(ji,jj-1) * vn(ji,jj-1,jk)
223#   endif
224                  ztai =-zbtr * (  zt1(ji,jj,jk) - zt1(ji-1,jj  ,jk) - trn(ji,jj,jk,jn) * zfui  )
225                  ztaj =-zbtr * (  zt2(ji,jj,jk) - zt2(ji  ,jj-1,jk) - trn(ji,jj,jk,jn) * zfvj  )
226                  ! save i- and j- advective trends computed as Uh gradh(T)
227                  trtrd(ji,jj,jk,jn,1) = ztai
228                  trtrd(ji,jj,jk,jn,2) = ztaj
229#endif
230               END DO
231            END DO
232         END DO
233
234         IF(ln_ctl) THEN         ! print mean trends (used for debugging)
235            ztra = SUM( tra(2:nictle,2:njctle,1:jpkm1,jn) * tmask(2:nictle,2:njctle,1:jpkm1) )
236            WRITE(numout,*) ' trc/had  - ',ctrcnm(jn),' : ', ztra-tra_ctl(jn), ' muscl' 
237            tra_ctl(jn) = ztra 
238         ENDIF
239
240         ! II. Vertical advective fluxes
241         ! -----------------------------
242
243         ! First guess of the slope
244         ! interior values
245         DO jk = 2, jpkm1
246            zt1(:,:,jk) = tmask(:,:,jk) * ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) )
247         END DO
248         ! surface and bottom boundary conditions
249         zt1 (:,:, 1 ) = 0.e0 
250         zt1 (:,:,jpk) = 0.e0
251         ! Slopes
252         DO jk = 2, jpkm1
253            DO jj = 1, jpj
254               DO ji = 1, jpi
255                  ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji,jj,jk+1) )   &
256                     &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji,jj,jk+1) ) )
257               END DO
258            END DO
259         END DO
260
261         ! Slopes limitation
262         ! interior values
263         DO jk = 2, jpkm1
264            DO jj = 1, jpj
265               DO ji = 1, jpi
266                  ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
267                     &           * MIN(    ABS( ztp1(ji,jj,jk  ) ),   &
268                     &                  2.*ABS( zt1 (ji,jj,jk+1) ),   &
269                     &                  2.*ABS( zt1 (ji,jj,jk  ) ) )
270               END DO
271            END DO
272         END DO
273         ! surface values
274         ztp1(:,:,1) = 0. 
275         ! vertical advective flux
276         ! interior values
277         DO jk = 1, jpkm1
278            DO jj = 2, jpjm1     
279               DO ji = fs_2, fs_jpim1   ! vector opt.
280                  z2dtt = rdttra(jk) * FLOAT(ndttrc)
281                  zew = zwn(ji,jj,jk+1)
282                  z0w = SIGN( 0.5, zwn(ji,jj,jk+1) )
283                  zalpha = 0.5 + z0w
284                  zw  = z0w - 0.5 * zwn(ji,jj,jk+1)*z2dtt / fse3w(ji,jj,jk+1)
285                  zzt1 = trb(ji,jj,jk+1,jn) + zw*ztp1(ji,jj,jk+1)
286                  zzt2 = trb(ji,jj,jk  ,jn) + zw*ztp1(ji,jj,jk  )
287                  zt1(ji,jj,jk+1) = zew * ( zalpha * zzt1 + (1.-zalpha)*zzt2 )
288               END DO
289            END DO
290         END DO
291         ! surface values
292         IF( lk_dynspg_fsc .OR. lk_dynspg_fsc_tsk ) THEN        ! free surface-constant volume
293            zt1(:,:, 1 ) = zwn(:,:,1) * trb(:,:,1,jn)
294         ELSE                                                   ! rigid lid : flux set to zero
295            zt1(:,:, 1 ) = 0.e0
296         ENDIF
297
298         ! bottom values
299         zt1(:,:,jpk) = 0.e0
300
301         ! Compute & add the vertical advective trend
302
303         DO jk = 1, jpkm1
304            DO jj = 2, jpjm1     
305               DO ji = fs_2, fs_jpim1   ! vector opt.
306                  zbtr = 1. / fse3t(ji,jj,jk)
307                  ! horizontal advective trends
308                  ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) )
309                  ! add it to the general tracer trends
310                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + ztra
311#if defined key_trc_diatrd
312                  ! save the vertical advective trends computed as w gradz(T)
313                  trtrd(ji,jj,jk,jn,3) = ztra - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk)
314#endif
315               END DO
316            END DO
317         END DO
318
319         IF(ln_ctl) THEN         ! print mean trends (used for debugging)
320            ztra = SUM( tra(2:nictle,2:njctle,1:jpkm1,jn) * tmask(2:nictle,2:njctle,1:jpkm1) )
321            WRITE(numout,*) ' trc/zad  - ',ctrcnm(jn),' : ', ztra-tra_ctl(jn), ' muscl' 
322            tra_ctl(jn) = ztra 
323         ENDIF
324
325      END DO
326
327END SUBROUTINE trc_adv_muscl
328
329#else
330   !!----------------------------------------------------------------------
331   !!   Default option                                         Empty module
332   !!----------------------------------------------------------------------
333CONTAINS
334   SUBROUTINE trc_adv_muscl( kt ) 
335      INTEGER, INTENT(in) :: kt
336      WRITE(*,*) 'trc_adv_muscl: You should not have seen this print! error?', kt
337   END SUBROUTINE trc_adv_muscl
338#endif
339
340   !!======================================================================
341END MODULE trcadv_muscl
Note: See TracBrowser for help on using the repository browser.