New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_muscl2.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcadv_muscl2.F90 @ 1193

Last change on this file since 1193 was 1193, checked in by cetlod, 16 years ago

Correction of transport module to ensure reproductibility for TOP configurations, see ticket:253
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 19.9 KB
Line 
1MODULE trcadv_muscl2
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv_muscl2  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6#if defined key_top
7   !!----------------------------------------------------------------------
8   !!   'key_top'                                                TOP models
9   !!----------------------------------------------------------------------
10   !!   tra_adv_muscl2 : update the tracer trend with the horizontal
11   !!                    and vertical advection trends using MUSCL2 scheme
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce_trc         ! ocean dynamics and active tracers variables
15   USE trp_trc             ! ocean passive tracers variables
16   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
17   USE trcbbl          ! advective passive tracers in the BBL
18   USE prtctl_trc          ! Print control for debbuging
19   USE trdmld_trc
20   USE trdmld_trc_oce          ! ocean variables trends
21
22   IMPLICIT NONE
23   PRIVATE
24
25   !! * Accessibility
26   PUBLIC trc_adv_muscl2        ! routine called by trcstp.F90
27
28   !! * Module variable
29   REAL(wp), DIMENSION(jpk) ::   &
30      rdttrc                     ! vertical profile of tracer time-step
31
32   !! * Substitutions
33#  include "top_substitute.h90"
34   !!----------------------------------------------------------------------
35   !!   TOP 1.0 , LOCEAN-IPSL (2005)
36   !! $Id$
37   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
38   !!----------------------------------------------------------------------
39
40CONTAINS
41
42   SUBROUTINE trc_adv_muscl2( kt )
43      !!----------------------------------------------------------------------
44      !!                   ***  ROUTINE trc_adv_muscl2  ***
45      !!
46      !! ** Purpose :   Compute the now trend due to total advection of passi-
47      !!      ve tracer using a MUSCL scheme (Monotone Upstream-
48      !!      Centered Scheme for Conservation Laws) and add it to the general
49      !!      tracer trend.
50      !!
51      !! ** Method : MUSCL scheme plus centered scheme at ocean boundaries
52      !!
53      !! ** Action : - update tra with the now advective tracer trends
54      !!             - save trends ('key_trdmld_trc')
55      !!
56      !! References :               
57      !!      Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
58      !! IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
59      !!
60      !! History :
61      !!        !  06-00  (A.Estublier)  for passive tracers
62      !!   9.0  !  03-04  (C. Ethe, G. Madec)  F90: Free form and module
63      !!----------------------------------------------------------------------
64      !! * modules used
65#if defined key_trcbbl_adv
66      USE oce_trc            , zun => ua,  &  ! use ua as workspace
67         &                     zvn => va      ! use va as workspace
68      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
69#else
70      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
71                               zvn => vn,  &  !              zvn == vn
72                               zwn => wn      !              zwn == wn
73#endif
74      !! * Arguments
75      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
76
77      !! * Local declarations
78      INTEGER ::   ji, jj, jk,jn               ! dummy loop indices
79      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   &
80         zt1, zt2, ztp1, ztp2
81      REAL(wp) ::   zu, zv, zw, zeu, zev, zew, zbtr, ztra
82      REAL(wp) ::   z0u, z0v, z0w
83      REAL(wp) ::   zzt1, zzt2, zalpha
84
85      REAL(wp) ::   ztai, ztaj
86      REAL(wp) ::   zfui, zfvj
87      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd
88      CHARACTER (len=22) :: charout
89      !!----------------------------------------------------------------------
90
91      IF( kt == nittrc000 .AND. lwp ) THEN
92         WRITE(numout,*)
93         WRITE(numout,*) 'trc_adv_muscl2 : MUSCL2 advection scheme'
94         WRITE(numout,*) '~~~~~~~~~~~~~~~'
95         rdttrc(:) =  rdttra(:) * FLOAT(ndttrc)
96      ENDIF
97     
98      IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) )
99
100#if defined key_trcbbl_adv       
101      ! Advective bottom boundary layer
102      ! -------------------------------
103      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
104      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
105      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl( :,:,:)
106#endif
107
108
109      DO jn = 1, jptra
110
111         ! I. Horizontal advective fluxes
112         ! ------------------------------
113
114         ! first guess of the slopes
115         ! interior values
116         DO jk = 1, jpkm1
117            DO jj = 1, jpjm1     
118               DO ji = 1, fs_jpim1   ! vector opt.
119                  zt1(ji,jj,jk) = umask(ji,jj,jk) * ( trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn) )
120                  zt2(ji,jj,jk) = vmask(ji,jj,jk) * ( trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
121               END DO
122            END DO
123         END DO
124         ! bottom values
125         zt1(:,:,jpk) = 0.e0
126         zt2(:,:,jpk) = 0.e0
127
128         ! lateral boundary conditions on zt1, zt2  (changed sign)
129         CALL lbc_lnk( zt1, 'U', -1. )
130         CALL lbc_lnk( zt2, 'V', -1. )
131
132         ! Slopes
133         ! interior values
134         DO jk = 1, jpkm1
135            DO jj = 2, jpj
136               DO ji = fs_2, jpi   ! vector opt.
137                  ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji-1,jj  ,jk) )   &
138                     &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji-1,jj  ,jk) ) )
139                  ztp2(ji,jj,jk) =                    ( zt2(ji,jj,jk) + zt2(ji  ,jj-1,jk) )   &
140                     &           * ( 0.25 + SIGN( 0.25, zt2(ji,jj,jk) * zt2(ji  ,jj-1,jk) ) )
141               END DO
142            END DO
143         END DO
144         ! bottom values
145         ztp1(:,:,jpk) = 0.e0 
146         ztp2(:,:,jpk) = 0.e0
147
148         ! Slopes limitation
149         DO jk = 1, jpkm1
150            DO jj = 2, jpj
151               DO ji = fs_2, fs_jpim1   ! vector opt.
152                  ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
153                     &           * MIN(    ABS( ztp1(ji  ,jj,jk) ),   &
154                     &                  2.*ABS( zt1 (ji-1,jj,jk) ),   &
155                     &                  2.*ABS( zt1 (ji  ,jj,jk) ) )
156
157                  ztp2(ji,jj,jk) = SIGN( 1., ztp2(ji,jj,jk) )   &
158                     &           * MIN(    ABS( ztp2(ji,jj  ,jk) ),   &
159                     &                  2.*ABS( zt2 (ji,jj-1,jk) ),   &
160                     &                  2.*ABS( zt2 (ji,jj  ,jk) ) )
161               END DO
162            END DO
163         END DO
164
165         ! Advection terms
166         ! interior values
167         DO jk = 1, jpkm1
168            DO jj = 2, jpjm1     
169               DO ji = fs_2, fs_jpim1   ! vector opt.
170                  ! volume fluxes
171#if ! defined key_zco
172                  zeu = e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
173                  zev = e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
174#else
175                  zeu = e2u(ji,jj) * zun(ji,jj,jk)
176                  zev = e1v(ji,jj) * zvn(ji,jj,jk)
177#endif
178                  ! MUSCL fluxes
179                  z0u = SIGN( 0.5, zun(ji,jj,jk) )           
180                  zalpha = 0.5 - z0u
181                  zu  = z0u - 0.5 * zun(ji,jj,jk) * rdttrc(jk) / e1u(ji,jj)
182                  zzt1 = trb(ji+1,jj,jk,jn) + zu*ztp1(ji+1,jj,jk)
183                  zzt2 = trb(ji  ,jj,jk,jn) + zu*ztp1(ji  ,jj,jk)
184                  zt1(ji,jj,jk) = zeu * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
185
186                  z0v = SIGN( 0.5, zvn(ji,jj,jk) )           
187                  zalpha = 0.5 - z0v
188                  zv  = z0v - 0.5 * zvn(ji,jj,jk) * rdttrc(jk) / e2v(ji,jj)
189                  zzt1 = trb(ji,jj+1,jk,jn) + zv*ztp2(ji,jj+1,jk)
190                  zzt2 = trb(ji,jj  ,jk,jn) + zv*ztp2(ji,jj  ,jk)
191                  zt2(ji,jj,jk) = zev * ( zalpha * zzt1 + (1.-zalpha) * zzt2 )
192
193               END DO
194            END DO
195         END DO
196
197
198         DO jk = 1, jpkm1
199            DO jj = 2, jpjm1
200               DO ji = fs_2, fs_jpim1   ! vector opt.
201#if ! defined key_zco
202                  zev = e1v(ji,jj) * fse3v(ji,jj,jk)
203                  IF( umask(ji,jj,jk) == 0. ) THEN
204                     IF( zun(ji+1,jj,jk) > 0. .AND. ji /= jpi ) THEN
205                        zt1(ji+1,jj,jk) = e2u(ji+1,jj)* fse3u(ji+1,jj,jk)   &
206                           &            * zun(ji+1,jj,jk) * ( trb(ji+1,jj,jk,jn) + trb(ji+2,jj,jk,jn) ) * 0.5
207                     ENDIF
208                     IF( zun(ji-1,jj,jk) < 0. ) THEN
209                        zt1(ji-1,jj,jk) = e2u(ji-1,jj)* fse3u(ji-1,jj,jk)   &
210                           &            * zun(ji-1,jj,jk) * ( trb(ji-1,jj,jk,jn) + trb(ji  ,jj,jk,jn) ) * 0.5
211                     ENDIF
212                  ENDIF
213                  IF( vmask(ji,jj,jk) == 0. ) THEN
214                     IF( zvn(ji,jj+1,jk) > 0. .AND. jj /= jpj ) THEN
215                        zt2(ji,jj+1,jk) = e1v(ji,jj+1) * fse3v(ji,jj+1,jk)   &
216                           &            * zvn(ji,jj+1,jk) * ( trb(ji,jj+1,jk,jn) + trb(ji,jj+2,jk,jn) ) * 0.5
217                     ENDIF
218                     IF( zvn(ji,jj-1,jk) < 0. ) THEN
219                        zt2(ji,jj-1,jk) = e1v(ji,jj-1)* fse3v(ji,jj-1,jk)   &
220                           &            * zvn(ji,jj-1,jk) * ( trb(ji,jj-1,jk,jn) + trb(ji  ,jj,jk,jn) ) * 0.5
221                     ENDIF
222                  ENDIF
223
224#else
225                  IF( umask(ji,jj,jk) == 0. ) THEN
226                     IF( zun(ji+1,jj,jk) > 0. .AND. ji /= jpi ) THEN
227                        zt1(ji+1,jj,jk) = e2u(ji+1,jj) * zun(ji+1,jj,jk) * ( trb(ji+1,jj,jk,jn) + trb(ji+2,jj,jk,jn) ) * 0.5
228                     ENDIF
229                     IF( zun(ji-1,jj,jk) < 0. ) THEN
230                        zt1(ji-1,jj,jk) = e2u(ji-1,jj) * zun(ji-1,jj,jk) * ( trb(ji-1,jj,jk,jn) + trb(ji  ,jj,jk,jn) ) * 0.5
231                     ENDIF
232                  ENDIF
233                  IF( vmask(ji,jj,jk) == 0. ) THEN
234                     IF( zvn(ji,jj+1,jk) > 0. .AND. jj /= jpj ) THEN
235                        zt2(ji,jj+1,jk) = e1v(ji,jj+1) * zvn(ji,jj+1,jk) * ( trb(ji,jj+1,jk,jn) + trb(ji,jj+2,jk,jn) ) * 0.5
236                     ENDIF
237                     IF( zvn(ji,jj-1,jk) < 0. ) THEN
238                        zt2(ji,jj-1,jk) = e1v(ji,jj-1) * zvn(ji,jj-1,jk) * ( trb(ji,jj-1,jk,jn) + trb(ji  ,jj,jk,jn) ) * 0.5
239                     ENDIF
240                  ENDIF
241#endif
242               END DO
243            END DO
244         END DO
245
246         ! lateral boundary conditions on zt1, zt2   (changed sign)
247         CALL lbc_lnk( zt1, 'U', -1. )
248         CALL lbc_lnk( zt2, 'V', -1. )
249
250         ! Compute and add the horizontal advective trend
251
252         DO jk = 1, jpkm1
253            DO jj = 2, jpjm1     
254               DO ji = fs_2, fs_jpim1   ! vector opt.
255#if ! defined key_zco
256                  zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
257#else
258                  zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj) )
259#endif
260                  ! horizontal advective trends
261                  ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji-1,jj  ,jk  )   &
262                     &            + zt2(ji,jj,jk) - zt2(ji  ,jj-1,jk  ) )
263                  ! add it to the general tracer trends
264                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra
265#if defined key_trc_diatrd
266                  ! recompute the trends in i- and j-direction as Uh gradh(T)
267#   if defined key_s_coord || defined key_partial_steps
268                  zfui =  e2u(ji  ,jj) * fse3u(ji,  jj,jk) * un(ji,  jj,jk)   &
269                     & -  e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk)
270                  zfvj =  e1v(ji,jj  ) * fse3v(ji,jj  ,jk) * vn(ji,jj  ,jk)   &
271                     & -  e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk)
272#   else
273                  zfui = e2u(ji  ,jj) * un(ji,  jj,jk)   &
274                     & - e2u(ji-1,jj) * un(ji-1,jj,jk)
275                  zfvj = e1v(ji,jj  ) * vn(ji,jj  ,jk)   &
276                     & - e1v(ji,jj-1) * vn(ji,jj-1,jk)
277#   endif
278                  ztai =-zbtr * (  zt1(ji,jj,jk) - zt1(ji-1,jj  ,jk) - trn(ji,jj,jk,jn) * zfui  )
279                  ztaj =-zbtr * (  zt2(ji,jj,jk) - zt2(ji  ,jj-1,jk) - trn(ji,jj,jk,jn) * zfvj  )
280                  ! save i- and j- advective trends computed as Uh gradh(T)
281                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),1) = ztai
282                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),2) = ztaj
283
284#endif
285
286               END DO
287            END DO
288         END DO
289
290         ! 3. Save the horizontal advective trends for diagnostics
291         ! -------------------------------------------------------
292
293         TRDTRC_XY : IF( l_trdtrc ) THEN
294
295            ! 3.1) Passive tracer ZONAL advection trends
296            DO jk = 1, jpkm1
297               DO jj = 2, jpjm1
298                  DO ji = fs_2, fs_jpim1   ! vector opt. 
299#if ! defined key_zco
300                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
301                     zfui = e2u(ji  ,jj) * fse3u(ji,  jj,jk) * un(ji,  jj,jk)   &
302                        & - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * un(ji-1,jj,jk)
303#else
304                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) )
305                     zfui = e2u(ji  ,jj) * un(ji,  jj,jk)   &
306                        & - e2u(ji-1,jj) * un(ji-1,jj,jk)
307#endif
308                     ! recompute the trends in i- direction as Uh gradh(T)
309                     ztrtrd(ji,jj,jk) = - zbtr*( zt1(ji,jj,jk) - zt1(ji-1,jj,jk) - trn(ji,jj,jk,jn)*zfui )
310                  END DO
311               END DO
312            END DO
313
314            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd, jn, jptrc_trd_xad, kt )
315
316            ! 3.2)  Passive tracer MERIDIONAL advection trends
317            DO jk = 1, jpkm1
318               DO jj = 2, jpjm1
319                  DO ji = fs_2, fs_jpim1   ! vector opt.
320                     ! recompute the trends in i- and j-direction as Uh gradh(T)
321#if ! defined key_zco
322                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
323                     zfvj = e1v(ji,jj  ) * fse3v(ji,jj  ,jk) * vn(ji,jj  ,jk)   &
324                        & - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * vn(ji,jj-1,jk)
325#else
326                     zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) )
327                     zfvj = e1v(ji,jj  ) * vn(ji,jj  ,jk)   &
328                        & - e1v(ji,jj-1) * vn(ji,jj-1,jk)
329#endif
330                     ztrtrd(ji,jj,jk) = - zbtr*( zt2(ji,jj,jk) - zt2(ji,jj-1,jk) - trn(ji,jj,jk,jn)*zfvj )
331                  END DO
332               END DO
333            END DO
334
335            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd, jn, jptrc_trd_yad, kt )
336
337         ENDIF TRDTRC_XY
338
339         !                           !=============
340      END DO                         ! tracer loop
341      !                              !=============
342
343      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
344         WRITE(charout, FMT="('muscl2 - had')")
345         CALL prt_ctl_trc_info(charout)
346         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
347      ENDIF
348
349      ! II. Vertical advective fluxes
350      ! -----------------------------
351
352      DO jn = 1, jptra
353
354         ! First guess of the slope
355         ! interior values
356         DO jk = 2, jpkm1
357            zt1(:,:,jk) = tmask(:,:,jk) * ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) )
358         END DO
359         ! surface and bottom boundary conditions
360         zt1 (:,:, 1 ) = 0.e0 
361         zt1 (:,:,jpk) = 0.e0
362
363         ! Slopes
364         DO jk = 2, jpkm1
365            DO jj = 1, jpj
366               DO ji = 1, jpi
367                  ztp1(ji,jj,jk) =                    ( zt1(ji,jj,jk) + zt1(ji,jj,jk+1) )   &
368                     &           * ( 0.25 + SIGN( 0.25, zt1(ji,jj,jk) * zt1(ji,jj,jk+1) ) )
369               END DO
370            END DO
371         END DO
372
373         ! Slopes limitation
374         ! interior values
375         DO jk = 2, jpkm1
376            DO jj = 1, jpj
377               DO ji = 1, jpi
378                  ztp1(ji,jj,jk) = SIGN( 1., ztp1(ji,jj,jk) )   &
379                     &           * MIN(    ABS( ztp1(ji,jj,jk  ) ),   &
380                     &                  2.*ABS( zt1 (ji,jj,jk+1) ),   &
381                     &                  2.*ABS( zt1 (ji,jj,jk  ) ) )
382               END DO
383            END DO
384         END DO
385
386         ! surface values
387         ztp1(:,:,1) = 0. 
388
389         ! vertical advective flux
390         ! interior values
391         DO jk = 1, jpkm1
392            DO jj = 2, jpjm1     
393               DO ji = fs_2, fs_jpim1   ! vector opt.
394                  zew = zwn(ji,jj,jk+1)
395                  z0w = SIGN( 0.5, zwn(ji,jj,jk+1) )
396                  zalpha = 0.5 + z0w
397                  zw  = z0w - 0.5 * zwn(ji,jj,jk+1)* rdttrc(jk)/ fse3w(ji,jj,jk+1)
398                  zzt1 = trb(ji,jj,jk+1,jn) + zw*ztp1(ji,jj,jk+1)
399                  zzt2 = trb(ji,jj,jk  ,jn) + zw*ztp1(ji,jj,jk  )
400                  zt1(ji,jj,jk+1) = zew * ( zalpha * zzt1 + (1.-zalpha)*zzt2 )
401               END DO
402            END DO
403         END DO
404         DO jk = 2, jpkm1
405            DO jj = 2, jpjm1
406               DO ji = fs_2, fs_jpim1   ! vector opt.
407                  IF( tmask(ji,jj,jk+1) == 0. ) THEN
408                     IF( zwn(ji,jj,jk) > 0. ) THEN
409                        zt1(ji,jj,jk) = zwn(ji,jj,jk) * ( trb(ji,jj,jk-1,jn) + trb(ji,jj,jk,jn) ) * 0.5
410                     ENDIF
411                  ENDIF
412               END DO
413            END DO
414         END DO
415
416         ! surface values
417         IF( lk_dynspg_rl ) THEN        ! rigid lid : flux set to zero
418            zt1(:,:, 1 ) = 0.e0
419         ELSE                           ! free surface
420            zt1(:,:, 1 ) = zwn(:,:,1) * trb(:,:,1,jn)
421         ENDIF
422
423         ! bottom values
424         zt1(:,:,jpk) = 0.e0
425
426         ! Compute & add the vertical advective trend
427
428         DO jk = 1, jpkm1
429            DO jj = 2, jpjm1     
430               DO ji = fs_2, fs_jpim1   ! vector opt.
431                  zbtr = 1. / fse3t(ji,jj,jk)
432                  ! horizontal advective trends
433                  ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) )
434                  ! add it to the general tracer trends
435                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + ztra
436#if defined key_trc_diatrd
437                  ! save the vertical advective trends computed as w gradz(T)
438                  IF (luttrd(jn)) trtrd(ji,jj,jk,ikeep(jn),3) = ztra - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk)
439#endif
440
441               END DO
442            END DO
443         END DO
444
445
446         ! 3. Save the vertical advective trends for diagnostic
447         ! ----------------------------------------------------
448
449         TRDTRC_Z : IF( l_trdtrc )THEN
450
451            ! Compute T/S vertical advection trends
452            DO jk = 1, jpkm1
453               DO jj = 2, jpjm1
454                  DO ji = fs_2, fs_jpim1   ! vector opt.
455                     zbtr = 1. / fse3t(ji,jj,jk)
456                     ! horizontal advective trends
457                     ztra = - zbtr * ( zt1(ji,jj,jk) - zt1(ji,jj,jk+1) )
458                     ! save the vertical advective trends computed as w gradz(T)
459                     ztrtrd(ji,jj,jk) = ztra - trn(ji,jj,jk,jn) * hdivn(ji,jj,jk)
460                  END DO
461               END DO
462            END DO
463
464            IF (luttrd(jn)) CALL trd_mod_trc(ztrtrd, jn, jptrc_trd_zad, kt)
465
466         END IF TRDTRC_Z
467
468         !                            !=============
469      END DO                          ! tracer loop
470      !                               !=============
471
472
473      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
474         WRITE(charout, FMT="('muscl2 - zad')")
475         CALL prt_ctl_trc_info(charout)
476         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
477      ENDIF
478
479      IF( l_trdtrc ) DEALLOCATE( ztrtrd )
480
481   END SUBROUTINE trc_adv_muscl2
482
483#else
484
485   !!----------------------------------------------------------------------
486   !!   Default option                                         Empty module
487   !!----------------------------------------------------------------------
488CONTAINS
489   SUBROUTINE trc_adv_muscl2( kt ) 
490      INTEGER, INTENT(in) :: kt
491      WRITE(*,*) 'trc_adv_muscl2: You should not have seen this print! error?', kt
492   END SUBROUTINE trc_adv_muscl2
493#endif
494
495   !!======================================================================
496END MODULE trcadv_muscl2
Note: See TracBrowser for help on using the repository browser.