New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_tvd.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcadv_tvd.F90 @ 204

Last change on this file since 204 was 204, checked in by opalod, 19 years ago

CT : UPDATE142 : Check the consistency between passive tracers transport modules (in TRP directory) and those used for the active tracers
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 17.6 KB
Line 
1MODULE trcadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv_tvd  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6#if defined key_passivetrc
7   !!----------------------------------------------------------------------
8   !!   trc_adv_tvd  : update the passive tracer trend with the horizontal
9   !!                  and vertical advection trends using a TVD scheme
10   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
11   !!                  algorithm
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce_trc             ! ocean dynamics and active tracers variables
15   USE trc                 ! ocean passive tracers variables
16   USE lbclnk              ! ocean lateral boundary conditions (or mpp link)
17   USE trcbbl              ! advective passive tracers in the BBL
18
19   IMPLICIT NONE
20   PRIVATE
21
22   !! * Accessibility
23   PUBLIC trc_adv_tvd    ! routine called by trcstp.F90
24
25   !! * Substitutions
26#  include "passivetrc_substitute.h90"
27   !!----------------------------------------------------------------------
28   !!   OPA 9.0 , LODYC-IPSL (2003)
29   !!----------------------------------------------------------------------
30
31CONTAINS
32
33   SUBROUTINE trc_adv_tvd( kt )
34      !!----------------------------------------------------------------------
35      !!                  ***  ROUTINE trc_adv_tvd  ***
36      !!
37      !! **  Purpose :   Compute the now trend due to total advection of
38      !!       tracers and add it to the general trend of tracer equations
39      !!
40      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
41      !!       corrected flux (monotonic correction)
42      !!       note: - this advection scheme needs a leap-frog time scheme
43      !!
44      !! ** Action : - update tra with the now advective tracer trends
45      !!             - save the trends in trtrd ('key_trc_diatrd)
46      !!
47      !! History :
48      !!        !  95-12  (L. Mortier)  Original code
49      !!        !  00-01  (H. Loukos)  adapted to ORCA
50      !!        !  00-10  (MA Foujols E.Kestenare)  include file not routine
51      !!        !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
52      !!        !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
53      !!   9.0  !  02-06  (C. Ethe, G. Madec)  F90: Free form and module
54      !!----------------------------------------------------------------------
55      !! * Modules used
56#if defined key_trcbbl_adv
57      USE oce_trc            , zun => ua,  &  ! use ua as workspace
58         &                     zvn => va      ! use va as workspace
59      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
60#else
61      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
62                               zvn => vn,  &  !             zvn == vn
63                               zwn => wn      !             zwn == wn
64#endif
65      !! * Arguments
66      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
67
68      !! * Local declarations
69      INTEGER  ::   ji, jj, jk,jn           ! dummy loop indices
70      REAL(wp) ::   ztra                    ! temporary scalar
71
72      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
73         zti, ztu, ztv, ztw                ! temporary workspace
74
75      REAL(wp) ::   &
76         z2dtt, zbtr, zeu, zev, zew, z2, &  ! temporary scalar
77         zfp_ui, zfp_vj, zfp_wk,         &  !    "         "
78         zfm_ui, zfm_vj, zfm_wk             !    "         "
79      !!----------------------------------------------------------------------
80
81      IF( kt == nittrc000  .AND. lwp ) THEN
82         WRITE(numout,*)
83         WRITE(numout,*) 'trc_adv_tvd : TVD advection scheme'
84         WRITE(numout,*) '~~~~~~~~~~~'
85      ENDIF
86
87      IF( neuler == 0 .AND. kt == nittrc000 ) THEN
88         z2=1.
89      ELSE
90         z2=2.
91      ENDIF
92
93#if defined key_trcbbl_adv
94      ! Advective Bottom boundary layer: add the velocity
95      ! -------------------------------------------------
96      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
97      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
98      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:)
99#endif
100
101      DO jn = 1, jptra
102
103         ! 1. Bottom value : flux set to zero
104         ! ---------------
105         ztu(:,:,jpk) = 0.e0
106         ztv(:,:,jpk) = 0.e0
107         ztw(:,:,jpk) = 0.e0
108         zti(:,:,jpk) = 0.e0
109
110
111         ! 2. upstream advection with initial mass fluxes & intermediate update
112         ! --------------------------------------------------------------------
113         ! upstream tracer flux in the i and j direction
114         DO jk = 1, jpkm1
115            DO jj = 1, jpjm1
116               DO ji = 1, fs_jpim1   ! vector opt.
117                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
118                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
119                  ! upstream scheme
120                  zfp_ui = zeu + ABS( zeu )
121                  zfm_ui = zeu - ABS( zeu )
122                  zfp_vj = zev + ABS( zev )
123                  zfm_vj = zev - ABS( zev )
124                  ztu(ji,jj,jk) = zfp_ui * trb(ji,jj,jk,jn) + zfm_ui * trb(ji+1,jj  ,jk,jn)
125                  ztv(ji,jj,jk) = zfp_vj * trb(ji,jj,jk,jn) + zfm_vj * trb(ji  ,jj+1,jk,jn)
126               END DO
127            END DO
128         END DO
129
130         ! upstream tracer flux in the k direction
131         ! Surface value
132         IF( lk_dynspg_fsc .OR. lk_dynspg_fsc_tsk ) THEN   ! free surface-constant volume
133            DO jj = 1, jpj
134               DO ji = 1, jpi
135                  zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1)
136                  ztw(ji,jj,1) = zew * trb(ji,jj,1,jn)
137               END DO
138            END DO
139         ELSE                                              ! rigid lid : flux set to zero
140            ztw(:,:,1) = 0.e0
141         ENDIF
142
143         ! Interior value
144         DO jk = 2, jpkm1
145            DO jj = 1, jpj
146               DO ji = 1, jpi
147                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
148                  zfp_wk = zew + ABS( zew )
149                  zfm_wk = zew - ABS( zew )
150                  ztw(ji,jj,jk) = zfp_wk * trb(ji,jj,jk,jn) + zfm_wk * trb(ji,jj,jk-1,jn)
151               END DO
152            END DO
153         END DO
154
155         ! total advective trend
156         DO jk = 1, jpkm1
157            DO jj = 2, jpjm1
158               DO ji = fs_2, fs_jpim1   ! vector opt.
159                  zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
160                  zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
161                     &              + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
162                     &              + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
163               END DO
164            END DO
165         END DO
166
167
168         ! update and guess with monotonic sheme
169         DO jk = 1, jpkm1
170            z2dtt = z2 * rdttra(jk) * FLOAT(ndttrc)
171            DO jj = 2, jpjm1
172               DO ji = fs_2, fs_jpim1   ! vector opt.
173                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + zti(ji,jj,jk)
174                  zti (ji,jj,jk) = ( trb(ji,jj,jk,jn) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk)
175               END DO
176            END DO
177         END DO
178
179         ! Lateral boundary conditions on zti, zsi   (unchanged sign)
180         CALL lbc_lnk( zti, 'T', 1. )
181
182         ! 3. antidiffusive flux : high order minus low order
183         ! --------------------------------------------------
184         ! antidiffusive flux on i and j
185         DO jk = 1, jpkm1
186            DO jj = 1, jpjm1
187               DO ji = 1, fs_jpim1   ! vector opt.
188                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
189                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
190                  ztu(ji,jj,jk) = zeu * ( trn(ji,jj,jk,jn) + trn(ji+1,jj,jk,jn) ) - ztu(ji,jj,jk)
191                  ztv(ji,jj,jk) = zev * ( trn(ji,jj,jk,jn) + trn(ji,jj+1,jk,jn) ) - ztv(ji,jj,jk)
192               END DO
193            END DO
194         END DO
195
196         ! antidiffusive flux on k
197         ! Surface value
198         ztw(:,:,1) = 0.
199
200         ! Interior value
201         DO jk = 2, jpkm1
202            DO jj = 1, jpj
203               DO ji = 1, jpi
204                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
205                  ztw(ji,jj,jk) = zew * ( trn(ji,jj,jk,jn) + trn(ji,jj,jk-1,jn) ) - ztw(ji,jj,jk)
206               END DO
207            END DO
208         END DO
209
210         ! Lateral bondary conditions
211         CALL lbc_lnk( ztu, 'U', -1. )
212         CALL lbc_lnk( ztv, 'V', -1. )
213         CALL lbc_lnk( ztw, 'W',  1. )
214
215         ! 4. monotonicity algorithm
216         ! -------------------------
217         CALL nonosc( trb, ztu, ztv, ztw, zti, z2 )
218
219
220         ! 5. final trend with corrected fluxes
221         ! ------------------------------------
222         DO jk = 1, jpkm1
223            DO jj = 2, jpjm1
224               DO ji = fs_2, fs_jpim1   ! vector opt.
225                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
226                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn)   &
227                     &         - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
228                     &           + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
229                     &           + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
230               END DO
231            END DO
232         END DO
233
234         IF(l_ctl) THEN         ! print mean trends (used for debugging)
235            ztra = SUM( tra(2:nictl,2:njctl,1:jpkm1,jn) * tmask(2:nictl,2:njctl,1:jpkm1) )
236            WRITE(numout,*) ' trc/zad  - ',ctrcnm(jn),' : ', ztra-tra_ctl(jn), ' tvd' 
237            tra_ctl(jn) = ztra 
238         ENDIF
239
240      END DO
241
242   END SUBROUTINE trc_adv_tvd
243
244
245   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
246      !!---------------------------------------------------------------------
247      !!                    ***  ROUTINE nonosc  ***
248      !!     
249      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
250      !!       scheme and the before field by a nonoscillatory algorithm
251      !!
252      !! **  Method  :   ... ???
253      !!       warning : pbef and paft must be masked, but the boundaries
254      !!       conditions on the fluxes are not necessary zalezak (1979)
255      !!       drange (1995) multi-dimensional forward-in-time and upstream-
256      !!       in-space based differencing for fluid
257      !!
258      !! History :
259      !!        !  97-04  (L. Mortier) Original code
260      !!        !  00-02  (H. Loukos)  rewritting for opa8
261      !!        !  00-10  (M.A Foujols, E. Kestenare)  lateral b.c.
262      !!        !  01-03  (E. Kestenare)  add key_passivetrc
263      !!        !  01-07  (E. Durand G. Madec)  adapted for T & S
264      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
265      !!----------------------------------------------------------------------
266      !! * Arguments
267      REAL(wp), INTENT( in ) ::   &
268         prdt                               ! ???
269      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
270         pbef,                            & ! before field
271         paft,                            & ! after field
272         paa,                             & ! monotonic flux in the i direction
273         pbb,                             & ! monotonic flux in the j direction
274         pcc                                ! monotonic flux in the k direction
275
276      !! * Local declarations
277      INTEGER ::   ji, jj, jk               ! dummy loop indices
278      INTEGER ::   ikm1
279      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
280      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
281      !!----------------------------------------------------------------------
282
283      zbig = 1.e+40
284      zrtrn = 1.e-15
285
286      ! Search local extrema
287      ! --------------------
288      ! large negative value (-zbig) inside land
289      WHERE( tmask(:,:,:) == 0. )
290         pbef(:,:,:) = -zbig
291         paft(:,:,:) = -zbig
292      ENDWHERE 
293      ! search maximum in neighbourhood
294      DO jk = 1, jpkm1
295         ikm1 = MAX(jk-1,1)
296         DO jj = 2, jpjm1
297            DO ji = fs_2, fs_jpim1   ! vector opt.
298               zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
299                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
300                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
301                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
302                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
303                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
304                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
305            END DO
306         END DO
307      END DO
308      ! large positive value (+zbig) inside land
309      WHERE( tmask(:,:,:) == 0. )
310         pbef(:,:,:) = +zbig
311         paft(:,:,:) = +zbig
312      ENDWHERE
313      ! search minimum in neighbourhood
314      DO jk = 1, jpkm1
315         ikm1 = MAX(jk-1,1)
316         DO jj = 2, jpjm1
317            DO ji = fs_2, fs_jpim1   ! vector opt.
318               zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
319                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
320                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
321                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
322                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
323                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
324                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
325            END DO
326         END DO
327      END DO
328
329      ! restore masked values to zero
330      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
331      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
332 
333
334      ! 2. Positive and negative part of fluxes and beta terms
335      ! ------------------------------------------------------
336
337      DO jk = 1, jpkm1
338         z2dtt = prdt * rdttra(jk) * FLOAT(ndttrc)
339         DO jj = 2, jpjm1
340            DO ji = fs_2, fs_jpim1   ! vector opt.
341               ! positive & negative part of the flux
342               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
343                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
344                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
345               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
346                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
347                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
348               ! up & down beta terms
349               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
350               zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
351               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
352            END DO
353         END DO
354      END DO
355
356      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
357      CALL lbc_lnk( zbetup, 'T', 1. )
358      CALL lbc_lnk( zbetdo, 'T', 1. )
359
360
361      ! 3. monotonic flux in the i direction, i.e. paa
362      ! ----------------------------------------------
363      DO jk = 1, jpkm1
364         DO jj = 2, jpjm1
365            DO ji = fs_2, fs_jpim1   ! vector opt.
366               zc = paa(ji,jj,jk)
367               IF( zc >= 0. ) THEN
368                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
369                  paa(ji,jj,jk) = za * zc
370               ELSE
371                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
372                  paa(ji,jj,jk) = zb * zc
373               ENDIF
374            END DO
375         END DO
376      END DO
377
378      ! lateral boundary condition on paa   (changed sign)
379      CALL lbc_lnk( paa, 'U', -1. )
380
381
382      ! 4. monotonic flux in the j direction, i.e. pbb
383      ! ----------------------------------------------
384      DO jk = 1, jpkm1
385         DO jj = 2, jpjm1
386            DO ji = fs_2, fs_jpim1   ! vector opt.
387               zc = pbb(ji,jj,jk)
388               IF( zc >= 0. ) THEN
389                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
390                  pbb(ji,jj,jk) = za * zc
391               ELSE
392                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
393                  pbb(ji,jj,jk) = zb * zc
394               ENDIF
395            END DO
396         END DO
397      END DO
398
399      ! lateral boundary condition on pbb   (changed sign)
400      CALL lbc_lnk( pbb, 'V', -1. )
401
402
403      ! monotonic flux in the k direction, i.e. pcc
404      ! -------------------------------------------
405      DO jk = 2, jpkm1
406         DO jj = 2, jpjm1
407            DO ji = fs_2, fs_jpim1   ! vector opt.
408               zc = pcc(ji,jj,jk)
409               IF( zc >= 0. ) THEN
410                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
411                  pcc(ji,jj,jk) = za * zc
412               ELSE
413                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
414                  pcc(ji,jj,jk) = zb * zc
415               ENDIF
416            END DO
417         END DO
418      END DO
419
420      ! lateral boundary condition on pcc   (unchanged sign)
421      CALL lbc_lnk( pcc, 'W', 1. )
422
423   END SUBROUTINE nonosc
424
425#else
426   !!----------------------------------------------------------------------
427   !!   Default option                                         Empty module
428   !!----------------------------------------------------------------------
429CONTAINS
430   SUBROUTINE trc_adv_tvd( kt ) 
431      INTEGER, INTENT(in) :: kt
432      WRITE(*,*) 'trc_adv_tvd: You should not have seen this print! error?', kt
433   END SUBROUTINE trc_adv_tvd
434#endif
435
436   !!======================================================================
437END MODULE trcadv_tvd
Note: See TracBrowser for help on using the repository browser.