New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_tvd.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcadv_tvd.F90 @ 281

Last change on this file since 281 was 274, checked in by opalod, 19 years ago

nemo_v1_update_005:RB: update headers for the TOP component.
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 17.7 KB
Line 
1MODULE trcadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv_tvd  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6#if defined key_passivetrc
7   !!----------------------------------------------------------------------
8   !!   trc_adv_tvd  : update the passive tracer trend with the horizontal
9   !!                  and vertical advection trends using a TVD scheme
10   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
11   !!                  algorithm
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce_trc             ! ocean dynamics and active tracers variables
15   USE trc                 ! ocean passive tracers variables
16   USE lbclnk              ! ocean lateral boundary conditions (or mpp link)
17   USE trcbbl              ! advective passive tracers in the BBL
18
19   IMPLICIT NONE
20   PRIVATE
21
22   !! * Accessibility
23   PUBLIC trc_adv_tvd    ! routine called by trcstp.F90
24
25   !! * Substitutions
26#  include "passivetrc_substitute.h90"
27   !!----------------------------------------------------------------------
28   !!  TOP 1.0,  LOCEAN-IPSL (2005)
29   !! $Header$
30   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
31   !!----------------------------------------------------------------------
32
33CONTAINS
34
35   SUBROUTINE trc_adv_tvd( kt )
36      !!----------------------------------------------------------------------
37      !!                  ***  ROUTINE trc_adv_tvd  ***
38      !!
39      !! **  Purpose :   Compute the now trend due to total advection of
40      !!       tracers and add it to the general trend of tracer equations
41      !!
42      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
43      !!       corrected flux (monotonic correction)
44      !!       note: - this advection scheme needs a leap-frog time scheme
45      !!
46      !! ** Action : - update tra with the now advective tracer trends
47      !!             - save the trends in trtrd ('key_trc_diatrd)
48      !!
49      !! History :
50      !!        !  95-12  (L. Mortier)  Original code
51      !!        !  00-01  (H. Loukos)  adapted to ORCA
52      !!        !  00-10  (MA Foujols E.Kestenare)  include file not routine
53      !!        !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
54      !!        !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
55      !!   9.0  !  02-06  (C. Ethe, G. Madec)  F90: Free form and module
56      !!----------------------------------------------------------------------
57      !! * Modules used
58#if defined key_trcbbl_adv
59      USE oce_trc            , zun => ua,  &  ! use ua as workspace
60         &                     zvn => va      ! use va as workspace
61      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
62#else
63      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
64                               zvn => vn,  &  !             zvn == vn
65                               zwn => wn      !             zwn == wn
66#endif
67      !! * Arguments
68      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
69
70      !! * Local declarations
71      INTEGER  ::   ji, jj, jk,jn           ! dummy loop indices
72      REAL(wp) ::   ztra                    ! temporary scalar
73
74      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
75         zti, ztu, ztv, ztw                ! temporary workspace
76
77      REAL(wp) ::   &
78         z2dtt, zbtr, zeu, zev, zew, z2, &  ! temporary scalar
79         zfp_ui, zfp_vj, zfp_wk,         &  !    "         "
80         zfm_ui, zfm_vj, zfm_wk             !    "         "
81      !!----------------------------------------------------------------------
82
83      IF( kt == nittrc000  .AND. lwp ) THEN
84         WRITE(numout,*)
85         WRITE(numout,*) 'trc_adv_tvd : TVD advection scheme'
86         WRITE(numout,*) '~~~~~~~~~~~'
87      ENDIF
88
89      IF( neuler == 0 .AND. kt == nittrc000 ) THEN
90         z2=1.
91      ELSE
92         z2=2.
93      ENDIF
94
95#if defined key_trcbbl_adv
96      ! Advective Bottom boundary layer: add the velocity
97      ! -------------------------------------------------
98      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
99      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
100      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:)
101#endif
102
103      DO jn = 1, jptra
104
105         ! 1. Bottom value : flux set to zero
106         ! ---------------
107         ztu(:,:,jpk) = 0.e0
108         ztv(:,:,jpk) = 0.e0
109         ztw(:,:,jpk) = 0.e0
110         zti(:,:,jpk) = 0.e0
111
112
113         ! 2. upstream advection with initial mass fluxes & intermediate update
114         ! --------------------------------------------------------------------
115         ! upstream tracer flux in the i and j direction
116         DO jk = 1, jpkm1
117            DO jj = 1, jpjm1
118               DO ji = 1, fs_jpim1   ! vector opt.
119                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
120                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
121                  ! upstream scheme
122                  zfp_ui = zeu + ABS( zeu )
123                  zfm_ui = zeu - ABS( zeu )
124                  zfp_vj = zev + ABS( zev )
125                  zfm_vj = zev - ABS( zev )
126                  ztu(ji,jj,jk) = zfp_ui * trb(ji,jj,jk,jn) + zfm_ui * trb(ji+1,jj  ,jk,jn)
127                  ztv(ji,jj,jk) = zfp_vj * trb(ji,jj,jk,jn) + zfm_vj * trb(ji  ,jj+1,jk,jn)
128               END DO
129            END DO
130         END DO
131
132         ! upstream tracer flux in the k direction
133         ! Surface value
134         IF( lk_dynspg_fsc .OR. lk_dynspg_fsc_tsk ) THEN   ! free surface-constant volume
135            DO jj = 1, jpj
136               DO ji = 1, jpi
137                  zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1)
138                  ztw(ji,jj,1) = zew * trb(ji,jj,1,jn)
139               END DO
140            END DO
141         ELSE                                              ! rigid lid : flux set to zero
142            ztw(:,:,1) = 0.e0
143         ENDIF
144
145         ! Interior value
146         DO jk = 2, jpkm1
147            DO jj = 1, jpj
148               DO ji = 1, jpi
149                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
150                  zfp_wk = zew + ABS( zew )
151                  zfm_wk = zew - ABS( zew )
152                  ztw(ji,jj,jk) = zfp_wk * trb(ji,jj,jk,jn) + zfm_wk * trb(ji,jj,jk-1,jn)
153               END DO
154            END DO
155         END DO
156
157         ! total advective trend
158         DO jk = 1, jpkm1
159            DO jj = 2, jpjm1
160               DO ji = fs_2, fs_jpim1   ! vector opt.
161                  zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
162                  zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
163                     &              + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
164                     &              + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
165               END DO
166            END DO
167         END DO
168
169
170         ! update and guess with monotonic sheme
171         DO jk = 1, jpkm1
172            z2dtt = z2 * rdttra(jk) * FLOAT(ndttrc)
173            DO jj = 2, jpjm1
174               DO ji = fs_2, fs_jpim1   ! vector opt.
175                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + zti(ji,jj,jk)
176                  zti (ji,jj,jk) = ( trb(ji,jj,jk,jn) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk)
177               END DO
178            END DO
179         END DO
180
181         ! Lateral boundary conditions on zti, zsi   (unchanged sign)
182         CALL lbc_lnk( zti, 'T', 1. )
183
184         ! 3. antidiffusive flux : high order minus low order
185         ! --------------------------------------------------
186         ! antidiffusive flux on i and j
187         DO jk = 1, jpkm1
188            DO jj = 1, jpjm1
189               DO ji = 1, fs_jpim1   ! vector opt.
190                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
191                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
192                  ztu(ji,jj,jk) = zeu * ( trn(ji,jj,jk,jn) + trn(ji+1,jj,jk,jn) ) - ztu(ji,jj,jk)
193                  ztv(ji,jj,jk) = zev * ( trn(ji,jj,jk,jn) + trn(ji,jj+1,jk,jn) ) - ztv(ji,jj,jk)
194               END DO
195            END DO
196         END DO
197
198         ! antidiffusive flux on k
199         ! Surface value
200         ztw(:,:,1) = 0.
201
202         ! Interior value
203         DO jk = 2, jpkm1
204            DO jj = 1, jpj
205               DO ji = 1, jpi
206                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
207                  ztw(ji,jj,jk) = zew * ( trn(ji,jj,jk,jn) + trn(ji,jj,jk-1,jn) ) - ztw(ji,jj,jk)
208               END DO
209            END DO
210         END DO
211
212         ! Lateral bondary conditions
213         CALL lbc_lnk( ztu, 'U', -1. )
214         CALL lbc_lnk( ztv, 'V', -1. )
215         CALL lbc_lnk( ztw, 'W',  1. )
216
217         ! 4. monotonicity algorithm
218         ! -------------------------
219         CALL nonosc( trb, ztu, ztv, ztw, zti, z2 )
220
221
222         ! 5. final trend with corrected fluxes
223         ! ------------------------------------
224         DO jk = 1, jpkm1
225            DO jj = 2, jpjm1
226               DO ji = fs_2, fs_jpim1   ! vector opt.
227                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
228                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn)   &
229                     &         - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
230                     &           + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
231                     &           + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
232               END DO
233            END DO
234         END DO
235
236         IF(ln_ctl) THEN         ! print mean trends (used for debugging)
237            ztra = SUM( tra(2:nictle,2:njctle,1:jpkm1,jn) * tmask(2:nictle,2:njctle,1:jpkm1) )
238            WRITE(numout,*) ' trc/zad  - ',ctrcnm(jn),' : ', ztra-tra_ctl(jn), ' tvd' 
239            tra_ctl(jn) = ztra 
240         ENDIF
241
242      END DO
243
244   END SUBROUTINE trc_adv_tvd
245
246
247   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
248      !!---------------------------------------------------------------------
249      !!                    ***  ROUTINE nonosc  ***
250      !!     
251      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
252      !!       scheme and the before field by a nonoscillatory algorithm
253      !!
254      !! **  Method  :   ... ???
255      !!       warning : pbef and paft must be masked, but the boundaries
256      !!       conditions on the fluxes are not necessary zalezak (1979)
257      !!       drange (1995) multi-dimensional forward-in-time and upstream-
258      !!       in-space based differencing for fluid
259      !!
260      !! History :
261      !!        !  97-04  (L. Mortier) Original code
262      !!        !  00-02  (H. Loukos)  rewritting for opa8
263      !!        !  00-10  (M.A Foujols, E. Kestenare)  lateral b.c.
264      !!        !  01-03  (E. Kestenare)  add key_passivetrc
265      !!        !  01-07  (E. Durand G. Madec)  adapted for T & S
266      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
267      !!----------------------------------------------------------------------
268      !! * Arguments
269      REAL(wp), INTENT( in ) ::   &
270         prdt                               ! ???
271      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
272         pbef,                            & ! before field
273         paft,                            & ! after field
274         paa,                             & ! monotonic flux in the i direction
275         pbb,                             & ! monotonic flux in the j direction
276         pcc                                ! monotonic flux in the k direction
277
278      !! * Local declarations
279      INTEGER ::   ji, jj, jk               ! dummy loop indices
280      INTEGER ::   ikm1
281      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
282      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
283      !!----------------------------------------------------------------------
284
285      zbig = 1.e+40
286      zrtrn = 1.e-15
287
288      ! Search local extrema
289      ! --------------------
290      ! large negative value (-zbig) inside land
291      WHERE( tmask(:,:,:) == 0. )
292         pbef(:,:,:) = -zbig
293         paft(:,:,:) = -zbig
294      ENDWHERE 
295      ! search maximum in neighbourhood
296      DO jk = 1, jpkm1
297         ikm1 = MAX(jk-1,1)
298         DO jj = 2, jpjm1
299            DO ji = fs_2, fs_jpim1   ! vector opt.
300               zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
301                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
302                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
303                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
304                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
305                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
306                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
307            END DO
308         END DO
309      END DO
310      ! large positive value (+zbig) inside land
311      WHERE( tmask(:,:,:) == 0. )
312         pbef(:,:,:) = +zbig
313         paft(:,:,:) = +zbig
314      ENDWHERE
315      ! search minimum in neighbourhood
316      DO jk = 1, jpkm1
317         ikm1 = MAX(jk-1,1)
318         DO jj = 2, jpjm1
319            DO ji = fs_2, fs_jpim1   ! vector opt.
320               zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
321                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
322                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
323                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
324                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
325                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
326                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
327            END DO
328         END DO
329      END DO
330
331      ! restore masked values to zero
332      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
333      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
334 
335
336      ! 2. Positive and negative part of fluxes and beta terms
337      ! ------------------------------------------------------
338
339      DO jk = 1, jpkm1
340         z2dtt = prdt * rdttra(jk) * FLOAT(ndttrc)
341         DO jj = 2, jpjm1
342            DO ji = fs_2, fs_jpim1   ! vector opt.
343               ! positive & negative part of the flux
344               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
345                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
346                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
347               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
348                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
349                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
350               ! up & down beta terms
351               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
352               zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
353               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
354            END DO
355         END DO
356      END DO
357
358      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
359      CALL lbc_lnk( zbetup, 'T', 1. )
360      CALL lbc_lnk( zbetdo, 'T', 1. )
361
362
363      ! 3. monotonic flux in the i direction, i.e. paa
364      ! ----------------------------------------------
365      DO jk = 1, jpkm1
366         DO jj = 2, jpjm1
367            DO ji = fs_2, fs_jpim1   ! vector opt.
368               zc = paa(ji,jj,jk)
369               IF( zc >= 0. ) THEN
370                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
371                  paa(ji,jj,jk) = za * zc
372               ELSE
373                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
374                  paa(ji,jj,jk) = zb * zc
375               ENDIF
376            END DO
377         END DO
378      END DO
379
380      ! lateral boundary condition on paa   (changed sign)
381      CALL lbc_lnk( paa, 'U', -1. )
382
383
384      ! 4. monotonic flux in the j direction, i.e. pbb
385      ! ----------------------------------------------
386      DO jk = 1, jpkm1
387         DO jj = 2, jpjm1
388            DO ji = fs_2, fs_jpim1   ! vector opt.
389               zc = pbb(ji,jj,jk)
390               IF( zc >= 0. ) THEN
391                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
392                  pbb(ji,jj,jk) = za * zc
393               ELSE
394                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
395                  pbb(ji,jj,jk) = zb * zc
396               ENDIF
397            END DO
398         END DO
399      END DO
400
401      ! lateral boundary condition on pbb   (changed sign)
402      CALL lbc_lnk( pbb, 'V', -1. )
403
404
405      ! monotonic flux in the k direction, i.e. pcc
406      ! -------------------------------------------
407      DO jk = 2, jpkm1
408         DO jj = 2, jpjm1
409            DO ji = fs_2, fs_jpim1   ! vector opt.
410               zc = pcc(ji,jj,jk)
411               IF( zc >= 0. ) THEN
412                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
413                  pcc(ji,jj,jk) = za * zc
414               ELSE
415                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
416                  pcc(ji,jj,jk) = zb * zc
417               ENDIF
418            END DO
419         END DO
420      END DO
421
422      ! lateral boundary condition on pcc   (unchanged sign)
423      CALL lbc_lnk( pcc, 'W', 1. )
424
425   END SUBROUTINE nonosc
426
427#else
428   !!----------------------------------------------------------------------
429   !!   Default option                                         Empty module
430   !!----------------------------------------------------------------------
431CONTAINS
432   SUBROUTINE trc_adv_tvd( kt ) 
433      INTEGER, INTENT(in) :: kt
434      WRITE(*,*) 'trc_adv_tvd: You should not have seen this print! error?', kt
435   END SUBROUTINE trc_adv_tvd
436#endif
437
438   !!======================================================================
439END MODULE trcadv_tvd
Note: See TracBrowser for help on using the repository browser.