New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv_tvd.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcadv_tvd.F90 @ 340

Last change on this file since 340 was 334, checked in by opalod, 19 years ago

nemo_v1_update_022 : CE + RB + CT : add print control possibility
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 17.7 KB
Line 
1MODULE trcadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv_tvd  ***
4   !! Ocean passive tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6#if defined key_passivetrc
7   !!----------------------------------------------------------------------
8   !!   trc_adv_tvd  : update the passive tracer trend with the horizontal
9   !!                  and vertical advection trends using a TVD scheme
10   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
11   !!                  algorithm
12   !!----------------------------------------------------------------------
13   !! * Modules used
14   USE oce_trc             ! ocean dynamics and active tracers variables
15   USE trc                 ! ocean passive tracers variables
16   USE lbclnk              ! ocean lateral boundary conditions (or mpp link)
17   USE trcbbl              ! advective passive tracers in the BBL
18   USE prtctl_trc      ! Print control for debbuging
19
20   IMPLICIT NONE
21   PRIVATE
22
23   !! * Accessibility
24   PUBLIC trc_adv_tvd    ! routine called by trcstp.F90
25
26   !! * Substitutions
27#  include "passivetrc_substitute.h90"
28   !!----------------------------------------------------------------------
29   !!   OPA 9.0 , LODYC-IPSL (2003)
30   !!----------------------------------------------------------------------
31
32CONTAINS
33
34   SUBROUTINE trc_adv_tvd( kt )
35      !!----------------------------------------------------------------------
36      !!                  ***  ROUTINE trc_adv_tvd  ***
37      !!
38      !! **  Purpose :   Compute the now trend due to total advection of
39      !!       tracers and add it to the general trend of tracer equations
40      !!
41      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
42      !!       corrected flux (monotonic correction)
43      !!       note: - this advection scheme needs a leap-frog time scheme
44      !!
45      !! ** Action : - update tra with the now advective tracer trends
46      !!             - save the trends in trtrd ('key_trc_diatrd)
47      !!
48      !! History :
49      !!        !  95-12  (L. Mortier)  Original code
50      !!        !  00-01  (H. Loukos)  adapted to ORCA
51      !!        !  00-10  (MA Foujols E.Kestenare)  include file not routine
52      !!        !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
53      !!        !  01-07  (E. Durand G. Madec)  adaptation to ORCA config
54      !!   9.0  !  02-06  (C. Ethe, G. Madec)  F90: Free form and module
55      !!----------------------------------------------------------------------
56      !! * Modules used
57#if defined key_trcbbl_adv
58      USE oce_trc            , zun => ua,  &  ! use ua as workspace
59         &                     zvn => va      ! use va as workspace
60      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwn
61#else
62      USE oce_trc            , zun => un,  &  ! When no bbl, zun == un
63                               zvn => vn,  &  !             zvn == vn
64                               zwn => wn      !             zwn == wn
65#endif
66      !! * Arguments
67      INTEGER, INTENT( in ) ::   kt         ! ocean time-step
68
69      !! * Local declarations
70      INTEGER  ::   ji, jj, jk,jn           ! dummy loop indices
71      REAL(wp) ::   ztra                    ! temporary scalar
72
73      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
74         zti, ztu, ztv, ztw                ! temporary workspace
75
76      REAL(wp) ::   &
77         z2dtt, zbtr, zeu, zev, zew, z2, &  ! temporary scalar
78         zfp_ui, zfp_vj, zfp_wk,         &  !    "         "
79         zfm_ui, zfm_vj, zfm_wk             !    "         "
80
81      CHARACTER (len=22) :: charout
82      !!----------------------------------------------------------------------
83
84      IF( kt == nittrc000  .AND. lwp ) THEN
85         WRITE(numout,*)
86         WRITE(numout,*) 'trc_adv_tvd : TVD advection scheme'
87         WRITE(numout,*) '~~~~~~~~~~~'
88      ENDIF
89
90      IF( neuler == 0 .AND. kt == nittrc000 ) THEN
91         z2=1.
92      ELSE
93         z2=2.
94      ENDIF
95
96#if defined key_trcbbl_adv
97      ! Advective Bottom boundary layer: add the velocity
98      ! -------------------------------------------------
99      zun(:,:,:) = un (:,:,:) - u_trc_bbl(:,:,:)
100      zvn(:,:,:) = vn (:,:,:) - v_trc_bbl(:,:,:)
101      zwn(:,:,:) = wn (:,:,:) + w_trc_bbl(:,:,:)
102#endif
103
104      DO jn = 1, jptra
105
106         ! 1. Bottom value : flux set to zero
107         ! ---------------
108         ztu(:,:,jpk) = 0.e0
109         ztv(:,:,jpk) = 0.e0
110         ztw(:,:,jpk) = 0.e0
111         zti(:,:,jpk) = 0.e0
112
113
114         ! 2. upstream advection with initial mass fluxes & intermediate update
115         ! --------------------------------------------------------------------
116         ! upstream tracer flux in the i and j direction
117         DO jk = 1, jpkm1
118            DO jj = 1, jpjm1
119               DO ji = 1, fs_jpim1   ! vector opt.
120                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
121                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
122                  ! upstream scheme
123                  zfp_ui = zeu + ABS( zeu )
124                  zfm_ui = zeu - ABS( zeu )
125                  zfp_vj = zev + ABS( zev )
126                  zfm_vj = zev - ABS( zev )
127                  ztu(ji,jj,jk) = zfp_ui * trb(ji,jj,jk,jn) + zfm_ui * trb(ji+1,jj  ,jk,jn)
128                  ztv(ji,jj,jk) = zfp_vj * trb(ji,jj,jk,jn) + zfm_vj * trb(ji  ,jj+1,jk,jn)
129               END DO
130            END DO
131         END DO
132
133         ! upstream tracer flux in the k direction
134         ! Surface value
135         IF( lk_dynspg_fsc .OR. lk_dynspg_fsc_tsk ) THEN   ! free surface-constant volume
136            DO jj = 1, jpj
137               DO ji = 1, jpi
138                  zew = e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,1)
139                  ztw(ji,jj,1) = zew * trb(ji,jj,1,jn)
140               END DO
141            END DO
142         ELSE                                              ! rigid lid : flux set to zero
143            ztw(:,:,1) = 0.e0
144         ENDIF
145
146         ! Interior value
147         DO jk = 2, jpkm1
148            DO jj = 1, jpj
149               DO ji = 1, jpi
150                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
151                  zfp_wk = zew + ABS( zew )
152                  zfm_wk = zew - ABS( zew )
153                  ztw(ji,jj,jk) = zfp_wk * trb(ji,jj,jk,jn) + zfm_wk * trb(ji,jj,jk-1,jn)
154               END DO
155            END DO
156         END DO
157
158         ! total advective trend
159         DO jk = 1, jpkm1
160            DO jj = 2, jpjm1
161               DO ji = fs_2, fs_jpim1   ! vector opt.
162                  zbtr = 1./ ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
163                  zti(ji,jj,jk) = - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
164                     &              + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
165                     &              + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
166               END DO
167            END DO
168         END DO
169
170
171         ! update and guess with monotonic sheme
172         DO jk = 1, jpkm1
173            z2dtt = z2 * rdttra(jk) * FLOAT(ndttrc)
174            DO jj = 2, jpjm1
175               DO ji = fs_2, fs_jpim1   ! vector opt.
176                  tra(ji,jj,jk,jn) =  tra(ji,jj,jk,jn) + zti(ji,jj,jk)
177                  zti (ji,jj,jk) = ( trb(ji,jj,jk,jn) + z2dtt * zti(ji,jj,jk) ) * tmask(ji,jj,jk)
178               END DO
179            END DO
180         END DO
181
182         ! Lateral boundary conditions on zti, zsi   (unchanged sign)
183         CALL lbc_lnk( zti, 'T', 1. )
184
185         ! 3. antidiffusive flux : high order minus low order
186         ! --------------------------------------------------
187         ! antidiffusive flux on i and j
188         DO jk = 1, jpkm1
189            DO jj = 1, jpjm1
190               DO ji = 1, fs_jpim1   ! vector opt.
191                  zeu = 0.5 * e2u(ji,jj) * fse3u(ji,jj,jk) * zun(ji,jj,jk)
192                  zev = 0.5 * e1v(ji,jj) * fse3v(ji,jj,jk) * zvn(ji,jj,jk)
193                  ztu(ji,jj,jk) = zeu * ( trn(ji,jj,jk,jn) + trn(ji+1,jj,jk,jn) ) - ztu(ji,jj,jk)
194                  ztv(ji,jj,jk) = zev * ( trn(ji,jj,jk,jn) + trn(ji,jj+1,jk,jn) ) - ztv(ji,jj,jk)
195               END DO
196            END DO
197         END DO
198
199         ! antidiffusive flux on k
200         ! Surface value
201         ztw(:,:,1) = 0.
202
203         ! Interior value
204         DO jk = 2, jpkm1
205            DO jj = 1, jpj
206               DO ji = 1, jpi
207                  zew = 0.5 * e1t(ji,jj) * e2t(ji,jj) * zwn(ji,jj,jk)
208                  ztw(ji,jj,jk) = zew * ( trn(ji,jj,jk,jn) + trn(ji,jj,jk-1,jn) ) - ztw(ji,jj,jk)
209               END DO
210            END DO
211         END DO
212
213         ! Lateral bondary conditions
214         CALL lbc_lnk( ztu, 'U', -1. )
215         CALL lbc_lnk( ztv, 'V', -1. )
216         CALL lbc_lnk( ztw, 'W',  1. )
217
218         ! 4. monotonicity algorithm
219         ! -------------------------
220         CALL nonosc( trb, ztu, ztv, ztw, zti, z2 )
221
222
223         ! 5. final trend with corrected fluxes
224         ! ------------------------------------
225         DO jk = 1, jpkm1
226            DO jj = 2, jpjm1
227               DO ji = fs_2, fs_jpim1   ! vector opt.
228                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
229                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn)   &
230                     &         - ( ztu(ji,jj,jk) - ztu(ji-1,jj  ,jk  )   &
231                     &           + ztv(ji,jj,jk) - ztv(ji  ,jj-1,jk  )   &
232                     &           + ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) * zbtr
233               END DO
234            END DO
235         END DO
236
237      END DO
238
239      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
240         WRITE(charout, FMT="('tvd - adv')")
241         CALL prt_ctl_trc_info(charout)
242         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
243      ENDIF
244
245   END SUBROUTINE trc_adv_tvd
246
247
248   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
249      !!---------------------------------------------------------------------
250      !!                    ***  ROUTINE nonosc  ***
251      !!     
252      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
253      !!       scheme and the before field by a nonoscillatory algorithm
254      !!
255      !! **  Method  :   ... ???
256      !!       warning : pbef and paft must be masked, but the boundaries
257      !!       conditions on the fluxes are not necessary zalezak (1979)
258      !!       drange (1995) multi-dimensional forward-in-time and upstream-
259      !!       in-space based differencing for fluid
260      !!
261      !! History :
262      !!        !  97-04  (L. Mortier) Original code
263      !!        !  00-02  (H. Loukos)  rewritting for opa8
264      !!        !  00-10  (M.A Foujols, E. Kestenare)  lateral b.c.
265      !!        !  01-03  (E. Kestenare)  add key_passivetrc
266      !!        !  01-07  (E. Durand G. Madec)  adapted for T & S
267      !!   8.5  !  02-06  (G. Madec)  F90: Free form and module
268      !!----------------------------------------------------------------------
269      !! * Arguments
270      REAL(wp), INTENT( in ) ::   &
271         prdt                               ! ???
272      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
273         pbef,                            & ! before field
274         paft,                            & ! after field
275         paa,                             & ! monotonic flux in the i direction
276         pbb,                             & ! monotonic flux in the j direction
277         pcc                                ! monotonic flux in the k direction
278
279      !! * Local declarations
280      INTEGER ::   ji, jj, jk               ! dummy loop indices
281      INTEGER ::   ikm1
282      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
283      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
284      !!----------------------------------------------------------------------
285
286      zbig = 1.e+40
287      zrtrn = 1.e-15
288
289      ! Search local extrema
290      ! --------------------
291      ! large negative value (-zbig) inside land
292      ! large negative value (-zbig) inside land
293      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
294      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) - zbig * ( 1.e0 - tmask(:,:,:) )
295      ! search maximum in neighbourhood
296      DO jk = 1, jpkm1
297         ikm1 = MAX(jk-1,1)
298         DO jj = 2, jpjm1
299            DO ji = fs_2, fs_jpim1   ! vector opt.
300               zbetup(ji,jj,jk) = MAX(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
301                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
302                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
303                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
304                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
305                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
306                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
307            END DO
308         END DO
309      END DO
310      ! large positive value (+zbig) inside land
311      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
312      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:) + zbig * ( 1.e0 - tmask(:,:,:) )
313      ! search minimum in neighbourhood
314      DO jk = 1, jpkm1
315         ikm1 = MAX(jk-1,1)
316         DO jj = 2, jpjm1
317            DO ji = fs_2, fs_jpim1   ! vector opt.
318               zbetdo(ji,jj,jk) = MIN(  pbef(ji  ,jj  ,jk  ), paft(ji  ,jj  ,jk  ),   &
319                  &                     pbef(ji-1,jj  ,jk  ), pbef(ji+1,jj  ,jk  ),   &
320                  &                     paft(ji-1,jj  ,jk  ), paft(ji+1,jj  ,jk  ),   &
321                  &                     pbef(ji  ,jj-1,jk  ), pbef(ji  ,jj+1,jk  ),   &
322                  &                     paft(ji  ,jj-1,jk  ), paft(ji  ,jj+1,jk  ),   &
323                  &                     pbef(ji  ,jj  ,ikm1), pbef(ji  ,jj  ,jk+1),   &
324                  &                     paft(ji  ,jj  ,ikm1), paft(ji  ,jj  ,jk+1)  )
325            END DO
326         END DO
327      END DO
328
329      ! restore masked values to zero
330      pbef(:,:,:) = pbef(:,:,:) * tmask(:,:,:)
331      paft(:,:,:) = paft(:,:,:) * tmask(:,:,:)
332 
333
334      ! 2. Positive and negative part of fluxes and beta terms
335      ! ------------------------------------------------------
336
337      DO jk = 1, jpkm1
338         z2dtt = prdt * rdttra(jk) * FLOAT(ndttrc)
339         DO jj = 2, jpjm1
340            DO ji = fs_2, fs_jpim1   ! vector opt.
341               ! positive & negative part of the flux
342               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
343                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
344                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
345               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
346                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
347                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
348               ! up & down beta terms
349               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
350               zbetup(ji,jj,jk) = ( zbetup(ji,jj,jk) - paft(ji,jj,jk) ) / (zpos+zrtrn) * zbt
351               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zbetdo(ji,jj,jk) ) / (zneg+zrtrn) * zbt
352            END DO
353         END DO
354      END DO
355
356      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
357      CALL lbc_lnk( zbetup, 'T', 1. )
358      CALL lbc_lnk( zbetdo, 'T', 1. )
359
360
361      ! 3. monotonic flux in the i direction, i.e. paa
362      ! ----------------------------------------------
363      DO jk = 1, jpkm1
364         DO jj = 2, jpjm1
365            DO ji = fs_2, fs_jpim1   ! vector opt.
366               zc = paa(ji,jj,jk)
367               IF( zc >= 0. ) THEN
368                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
369                  paa(ji,jj,jk) = za * zc
370               ELSE
371                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
372                  paa(ji,jj,jk) = zb * zc
373               ENDIF
374            END DO
375         END DO
376      END DO
377
378      ! lateral boundary condition on paa   (changed sign)
379      CALL lbc_lnk( paa, 'U', -1. )
380
381
382      ! 4. monotonic flux in the j direction, i.e. pbb
383      ! ----------------------------------------------
384      DO jk = 1, jpkm1
385         DO jj = 2, jpjm1
386            DO ji = fs_2, fs_jpim1   ! vector opt.
387               zc = pbb(ji,jj,jk)
388               IF( zc >= 0. ) THEN
389                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
390                  pbb(ji,jj,jk) = za * zc
391               ELSE
392                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
393                  pbb(ji,jj,jk) = zb * zc
394               ENDIF
395            END DO
396         END DO
397      END DO
398
399      ! lateral boundary condition on pbb   (changed sign)
400      CALL lbc_lnk( pbb, 'V', -1. )
401
402
403      ! monotonic flux in the k direction, i.e. pcc
404      ! -------------------------------------------
405      DO jk = 2, jpkm1
406         DO jj = 2, jpjm1
407            DO ji = fs_2, fs_jpim1   ! vector opt.
408               zc = pcc(ji,jj,jk)
409               IF( zc >= 0. ) THEN
410                  za = MIN( 1., zbetdo(ji,jj,jk), zbetup(ji,jj,jk-1) )
411                  pcc(ji,jj,jk) = za * zc
412               ELSE
413                  zb = MIN( 1., zbetup(ji,jj,jk), zbetdo(ji,jj,jk-1) )
414                  pcc(ji,jj,jk) = zb * zc
415               ENDIF
416            END DO
417         END DO
418      END DO
419
420      ! lateral boundary condition on pcc   (unchanged sign)
421      CALL lbc_lnk( pcc, 'W', 1. )
422
423   END SUBROUTINE nonosc
424
425#else
426   !!----------------------------------------------------------------------
427   !!   Default option                                         Empty module
428   !!----------------------------------------------------------------------
429CONTAINS
430   SUBROUTINE trc_adv_tvd( kt ) 
431      INTEGER, INTENT(in) :: kt
432      WRITE(*,*) 'trc_adv_tvd: You should not have seen this print! error?', kt
433   END SUBROUTINE trc_adv_tvd
434#endif
435
436   !!======================================================================
437END MODULE trcadv_tvd
Note: See TracBrowser for help on using the repository browser.