New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_bilap.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_bilap.F90 @ 247

Last change on this file since 247 was 247, checked in by opalod, 19 years ago

CL : Add CVS Header and CeCILL licence information
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 10.0 KB
Line 
1MODULE trcldf_bilap
2   !!==============================================================================
3   !!                   ***  MODULE  trcldf_bilap  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if defined key_passivetrc
7   !!----------------------------------------------------------------------
8   !!   trc_ldf_bilap : update the tracer trend with the horizontal diffusion
9   !!                   using a iso-level biharmonic operator
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE oce_trc         ! ocean dynamics and active tracers variables
13   USE trc             ! ocean passive tracers variables
14   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
15
16   IMPLICIT NONE
17   PRIVATE
18
19   !! * Routine accessibility
20   PUBLIC trc_ldf_bilap   ! routine called by step.F90
21
22   !! * Substitutions
23#  include "passivetrc_substitute.h90"
24   !!----------------------------------------------------------------------
25   !!   TOP 1.0 , LOCEAN-IPSL (2005)
26   !! $Header$
27   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
28   !!----------------------------------------------------------------------
29
30CONTAINS
31   
32   SUBROUTINE trc_ldf_bilap( kt )
33      !!----------------------------------------------------------------------
34      !!                  ***  ROUTINE trc_ldf_bilap  ***
35      !!
36      !! ** Purpose :   Compute the before horizontal tracer tra diffusive
37      !!      trend and add it to the general trend of tracer equation.
38      !!
39      !! ** Method  :   4th order diffusive operator along model level surfaces
40      !!      evaluated using before fields (forward time scheme). The hor.
41      !!      diffusive trends of passive tracer is given by:
42      !!       * s-coordinate ('key_s_coord' defined), the vertical scale
43      !!      factors e3. are inside the derivatives:
44      !!      Laplacian of trb:
45      !!         zlt   = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(trb) ]
46      !!                                  + dj-1[ e1v*e3v/e2v dj(trb) ]  }
47      !!      Multiply by the eddy diffusivity coef. and insure lateral bc:
48      !!        zlt   = ahtt * zlt
49      !!        call to lbc_lnk
50      !!      Bilaplacian (laplacian of zlt):
51      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(zlt) ]
52      !!                                  + dj-1[ e1v*e3v/e2v dj(zlt) ]  }
53      !!       * z-coordinate (default key), e3t=e3u=e3v, the trend becomes:
54      !!      Laplacian of trb:
55      !!         zlt   = 1/(e1t*e2t) {  di-1[ e2u/e1u di(trb) ]
56      !!                              + dj-1[ e1v/e2v dj(trb) ] }
57      !!      Multiply by the eddy diffusivity coef. and insure lateral bc:
58      !!        zlt   = ahtt * zlt
59      !!        call to lbc_lnk
60      !!      Bilaplacian (laplacian of zlt):
61      !!         difft = 1/(e1t*e2t) {  di-1[ e2u/e1u di(zlt) ]
62      !!                              + dj-1[ e1v/e2v dj(zlt) ]  }
63      !!
64      !!      Add this trend to the general trend tra :
65      !!         tra = tra + difft
66      !!
67      !! ** Action : - Update tra arrays with the before iso-level
68      !!               biharmonic mixing trend.
69      !!             - Save the trends in trtrd ('key_trc_diatrd')
70      !!
71      !! History :
72      !!        !  91-11  (G. Madec)  Original code
73      !!        !  93-03  (M. Guyon)  symetrical conditions
74      !!        !  95-11  (G. Madec)  suppress volumetric scale factors
75      !!        !  96-01  (G. Madec)  statement function for e3
76      !!        !  96-01  (M. Imbard)  mpp exchange
77      !!        !  97-07  (G. Madec)  optimization, and ahtt
78      !!        !  00-05  (MA Foujols) add lbc for tracer trends
79      !!        !  00-10  (MA Foujols E. Kestenare) use passive tracer coefficient
80      !!   8.5  !  02-08  (G. Madec)  F90: Free form and module
81      !!   9.0  !  04-03  (C. Ethe )  F90: Free form and module
82      !!----------------------------------------------------------------------
83      !! * Arguments
84      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
85
86      !! * Local declarations
87      INTEGER ::   ji, jj, jk, jn             ! dummy loop indices
88#if defined key_partial_steps
89      INTEGER ::   iku, ikv                   ! temporary integers
90#endif
91      REAL(wp) ::   ztra     ! temporary scalars
92
93      REAL(wp), DIMENSION(jpi,jpj) ::   & 
94         zeeu, zeev, zbtr, zlt                 ! workspace
95      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
96         ztu, ztv                              ! workspace
97      !!----------------------------------------------------------------------
98
99      IF( kt == nittrc000 ) THEN
100         IF(lwp) WRITE(numout,*)
101         IF(lwp) WRITE(numout,*) 'trc_ldf_bilap : iso-level biharmonic operator'
102         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
103      ENDIF
104      !
105
106      DO jn = 1, jptra
107                                                          ! ===============
108         DO jk = 1, jpkm1                                 ! Horizontal slab
109            !                                             ! ===============
110
111            ! 0. Initialization of metric arrays (for z- or s-coordinates)
112            ! ----------------------------------
113
114            DO jj = 1, jpjm1
115               DO ji = 1, fs_jpim1   ! vector opt.
116#if defined key_s_coord || defined key_partial_steps
117                  ! s-coordinates, vertical scale factor are used
118                  zbtr(ji,jj) = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
119                  zeeu(ji,jj) = e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj) * umask(ji,jj,jk)
120                  zeev(ji,jj) = e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj) * vmask(ji,jj,jk)
121#else
122                  ! z-coordinates, no vertical scale factors
123                  zbtr(ji,jj) = 1. / ( e1t(ji,jj)*e2t(ji,jj) )
124                  zeeu(ji,jj) = e2u(ji,jj) / e1u(ji,jj) * umask(ji,jj,jk)
125                  zeev(ji,jj) = e1v(ji,jj) / e2v(ji,jj) * vmask(ji,jj,jk)
126#endif
127               END DO
128            END DO
129
130
131            ! 1. Laplacian
132            ! ------------
133
134            ! First derivative (gradient)
135            DO jj = 1, jpjm1
136               DO ji = 1, fs_jpim1   ! vector opt.
137                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( trb(ji+1,jj  ,jk,jn) - trb(ji,jj,jk,jn) )
138                  ztv(ji,jj,jk) = zeev(ji,jj) * ( trb(ji  ,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
139               END DO
140            END DO
141#if defined key_partial_steps
142
143            DO jj = 1, jpj-1
144               DO ji = 1, jpi-1
145                  ! last level
146                  iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
147                  ikv = MIN ( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
148                  IF( iku == jk ) THEN
149                     ztu(ji,jj,jk) = zeeu(ji,jj) * gtu(ji,jj)
150                  ENDIF
151                  IF( ikv == jk ) THEN
152                     ztv(ji,jj,jk) = zeev(ji,jj) * gtv(ji,jj)
153                  ENDIF
154               END DO
155            END DO
156#endif
157
158            ! Second derivative (divergence)
159            DO jj = 2, jpjm1
160               DO ji = fs_2, fs_jpim1   ! vector opt.
161                  zlt(ji,jj) = zbtr(ji,jj) * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
162               END DO
163            END DO
164
165            ! Multiply by the eddy diffusivity coefficient
166            DO jj = 2, jpjm1
167               DO ji = fs_2, fs_jpim1   ! vector opt.
168                  zlt(ji,jj) = fsahtrt(ji,jj,jk) * zlt(ji,jj)
169               END DO
170            END DO
171
172            ! Lateral boundary conditions on the laplacian zlt   (unchanged sgn)
173            CALL lbc_lnk( zlt, 'T', 1. ) 
174
175            ! 2. Bilaplacian
176            ! --------------
177
178            ! third derivative (gradient)
179            DO jj = 1, jpjm1
180               DO ji = 1, fs_jpim1   ! vector opt.
181                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( zlt(ji+1,jj  ) - zlt(ji,jj) )
182                  ztv(ji,jj,jk) = zeev(ji,jj) * ( zlt(ji  ,jj+1) - zlt(ji,jj) )
183               END DO
184            END DO
185
186            ! fourth derivative (divergence) and add to the general tracer trend
187            DO jj = 2, jpjm1
188               DO ji = fs_2, fs_jpim1   ! vector opt.
189                  ! horizontal diffusive trends
190                  ztra = zbtr(ji,jj) * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
191                  ! add it to the general tracer trends
192                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra
193#if defined key_trc_diatrd
194                  ! save the horizontal diffusive trends
195                  trtrd(ji,jj,jk,jn,4) = (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr(ji,jj)
196                  trtrd(ji,jj,jk,jn,5) = (  ztv(ji,jj,jk) - ztv(ji-1,jj,jk) ) * zbtr(ji,jj)
197#endif
198               END DO
199            END DO
200            !                                             ! ===============
201         END DO                                           ! Horizontal slab
202         !                                                ! ===============
203#if defined key_trc_diatrd
204         ! Lateral boundary conditions on the laplacian zlt   (unchanged sgn)
205         CALL lbc_lnk( trtrd(1,1,1,jn,5), 'T', 1. ) 
206#endif
207         IF(l_ctl) THEN         ! print mean trends (used for debugging)
208            ztra = SUM( tra(2:nictl,2:njctl,1:jpkm1,jn) * tmask(2:nictl,2:njctl,1:jpkm1) )
209            WRITE(numout,*) ' trc/ldf  - ',ctrcnm(jn),' : ', ztra-tra_ctl(jn)
210            tra_ctl(jn) = ztra 
211         ENDIF
212
213      END DO
214
215   END SUBROUTINE trc_ldf_bilap
216
217#else
218   !!----------------------------------------------------------------------
219   !!   Default option                                         Empty module
220   !!----------------------------------------------------------------------
221CONTAINS
222   SUBROUTINE trc_ldf_bilap( kt ) 
223      INTEGER, INTENT(in) :: kt
224      WRITE(*,*) 'trc_ldf_bilap: You should not have seen this print! error?', kt
225   END SUBROUTINE trc_ldf_bilap
226#endif
227   !!==============================================================================
228END MODULE trcldf_bilap
Note: See TracBrowser for help on using the repository browser.