New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_bilap.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_bilap.F90 @ 340

Last change on this file since 340 was 334, checked in by opalod, 19 years ago

nemo_v1_update_022 : CE + RB + CT : add print control possibility
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 9.9 KB
Line 
1MODULE trcldf_bilap
2   !!==============================================================================
3   !!                   ***  MODULE  trcldf_bilap  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if defined key_passivetrc
7   !!----------------------------------------------------------------------
8   !!   trc_ldf_bilap : update the tracer trend with the horizontal diffusion
9   !!                   using a iso-level biharmonic operator
10   !!----------------------------------------------------------------------
11   !! * Modules used
12   USE oce_trc         ! ocean dynamics and active tracers variables
13   USE trc             ! ocean passive tracers variables
14   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
15   USE prtctl_trc      ! Print control for debbuging
16
17   IMPLICIT NONE
18   PRIVATE
19
20   !! * Routine accessibility
21   PUBLIC trc_ldf_bilap   ! routine called by step.F90
22
23   !! * Substitutions
24#  include "passivetrc_substitute.h90"
25   !!----------------------------------------------------------------------
26   !!   OPA 9.0 , LODYC-IPSL (2003)
27   !!----------------------------------------------------------------------
28
29CONTAINS
30   
31   SUBROUTINE trc_ldf_bilap( kt )
32      !!----------------------------------------------------------------------
33      !!                  ***  ROUTINE trc_ldf_bilap  ***
34      !!
35      !! ** Purpose :   Compute the before horizontal tracer tra diffusive
36      !!      trend and add it to the general trend of tracer equation.
37      !!
38      !! ** Method  :   4th order diffusive operator along model level surfaces
39      !!      evaluated using before fields (forward time scheme). The hor.
40      !!      diffusive trends of passive tracer is given by:
41      !!       * s-coordinate ('key_s_coord' defined), the vertical scale
42      !!      factors e3. are inside the derivatives:
43      !!      Laplacian of trb:
44      !!         zlt   = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(trb) ]
45      !!                                  + dj-1[ e1v*e3v/e2v dj(trb) ]  }
46      !!      Multiply by the eddy diffusivity coef. and insure lateral bc:
47      !!        zlt   = ahtt * zlt
48      !!        call to lbc_lnk
49      !!      Bilaplacian (laplacian of zlt):
50      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ e2u*e3u/e1u di(zlt) ]
51      !!                                  + dj-1[ e1v*e3v/e2v dj(zlt) ]  }
52      !!       * z-coordinate (default key), e3t=e3u=e3v, the trend becomes:
53      !!      Laplacian of trb:
54      !!         zlt   = 1/(e1t*e2t) {  di-1[ e2u/e1u di(trb) ]
55      !!                              + dj-1[ e1v/e2v dj(trb) ] }
56      !!      Multiply by the eddy diffusivity coef. and insure lateral bc:
57      !!        zlt   = ahtt * zlt
58      !!        call to lbc_lnk
59      !!      Bilaplacian (laplacian of zlt):
60      !!         difft = 1/(e1t*e2t) {  di-1[ e2u/e1u di(zlt) ]
61      !!                              + dj-1[ e1v/e2v dj(zlt) ]  }
62      !!
63      !!      Add this trend to the general trend tra :
64      !!         tra = tra + difft
65      !!
66      !! ** Action : - Update tra arrays with the before iso-level
67      !!               biharmonic mixing trend.
68      !!             - Save the trends in trtrd ('key_trc_diatrd')
69      !!
70      !! History :
71      !!        !  91-11  (G. Madec)  Original code
72      !!        !  93-03  (M. Guyon)  symetrical conditions
73      !!        !  95-11  (G. Madec)  suppress volumetric scale factors
74      !!        !  96-01  (G. Madec)  statement function for e3
75      !!        !  96-01  (M. Imbard)  mpp exchange
76      !!        !  97-07  (G. Madec)  optimization, and ahtt
77      !!        !  00-05  (MA Foujols) add lbc for tracer trends
78      !!        !  00-10  (MA Foujols E. Kestenare) use passive tracer coefficient
79      !!   8.5  !  02-08  (G. Madec)  F90: Free form and module
80      !!   9.0  !  04-03  (C. Ethe )  F90: Free form and module
81      !!----------------------------------------------------------------------
82      !! * Arguments
83      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
84
85      !! * Local declarations
86      INTEGER ::   ji, jj, jk, jn             ! dummy loop indices
87#if defined key_partial_steps
88      INTEGER ::   iku, ikv                   ! temporary integers
89#endif
90      REAL(wp) ::   ztra     ! temporary scalars
91
92      REAL(wp), DIMENSION(jpi,jpj) ::   & 
93         zeeu, zeev, zbtr, zlt                 ! workspace
94      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
95         ztu, ztv                              ! workspace
96      CHARACTER (len=22) :: charout
97      !!----------------------------------------------------------------------
98
99      IF( kt == nittrc000 ) THEN
100         IF(lwp) WRITE(numout,*)
101         IF(lwp) WRITE(numout,*) 'trc_ldf_bilap : iso-level biharmonic operator'
102         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
103      ENDIF
104      !
105
106      DO jn = 1, jptra
107                                                          ! ===============
108         DO jk = 1, jpkm1                                 ! Horizontal slab
109            !                                             ! ===============
110
111            ! 0. Initialization of metric arrays (for z- or s-coordinates)
112            ! ----------------------------------
113
114            DO jj = 1, jpjm1
115               DO ji = 1, fs_jpim1   ! vector opt.
116#if defined key_s_coord || defined key_partial_steps
117                  ! s-coordinates, vertical scale factor are used
118                  zbtr(ji,jj) = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
119                  zeeu(ji,jj) = e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj) * umask(ji,jj,jk)
120                  zeev(ji,jj) = e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj) * vmask(ji,jj,jk)
121#else
122                  ! z-coordinates, no vertical scale factors
123                  zbtr(ji,jj) = 1. / ( e1t(ji,jj)*e2t(ji,jj) )
124                  zeeu(ji,jj) = e2u(ji,jj) / e1u(ji,jj) * umask(ji,jj,jk)
125                  zeev(ji,jj) = e1v(ji,jj) / e2v(ji,jj) * vmask(ji,jj,jk)
126#endif
127               END DO
128            END DO
129
130
131            ! 1. Laplacian
132            ! ------------
133
134            ! First derivative (gradient)
135            DO jj = 1, jpjm1
136               DO ji = 1, fs_jpim1   ! vector opt.
137                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( trb(ji+1,jj  ,jk,jn) - trb(ji,jj,jk,jn) )
138                  ztv(ji,jj,jk) = zeev(ji,jj) * ( trb(ji  ,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
139               END DO
140            END DO
141#if defined key_partial_steps
142
143            DO jj = 1, jpj-1
144               DO ji = 1, jpi-1
145                  ! last level
146                  iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
147                  ikv = MIN ( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
148                  IF( iku == jk ) THEN
149                     ztu(ji,jj,jk) = zeeu(ji,jj) * gtu(ji,jj)
150                  ENDIF
151                  IF( ikv == jk ) THEN
152                     ztv(ji,jj,jk) = zeev(ji,jj) * gtv(ji,jj)
153                  ENDIF
154               END DO
155            END DO
156#endif
157
158            ! Second derivative (divergence)
159            DO jj = 2, jpjm1
160               DO ji = fs_2, fs_jpim1   ! vector opt.
161                  zlt(ji,jj) = zbtr(ji,jj) * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
162               END DO
163            END DO
164
165            ! Multiply by the eddy diffusivity coefficient
166            DO jj = 2, jpjm1
167               DO ji = fs_2, fs_jpim1   ! vector opt.
168                  zlt(ji,jj) = fsahtrt(ji,jj,jk) * zlt(ji,jj)
169               END DO
170            END DO
171
172            ! Lateral boundary conditions on the laplacian zlt   (unchanged sgn)
173            CALL lbc_lnk( zlt, 'T', 1. ) 
174
175            ! 2. Bilaplacian
176            ! --------------
177
178            ! third derivative (gradient)
179            DO jj = 1, jpjm1
180               DO ji = 1, fs_jpim1   ! vector opt.
181                  ztu(ji,jj,jk) = zeeu(ji,jj) * ( zlt(ji+1,jj  ) - zlt(ji,jj) )
182                  ztv(ji,jj,jk) = zeev(ji,jj) * ( zlt(ji  ,jj+1) - zlt(ji,jj) )
183               END DO
184            END DO
185
186            ! fourth derivative (divergence) and add to the general tracer trend
187            DO jj = 2, jpjm1
188               DO ji = fs_2, fs_jpim1   ! vector opt.
189                  ! horizontal diffusive trends
190                  ztra = zbtr(ji,jj) * (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) + ztv(ji,jj,jk) - ztv(ji,jj-1,jk)  )
191                  ! add it to the general tracer trends
192                  tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra
193#if defined key_trc_diatrd
194                  ! save the horizontal diffusive trends
195                  trtrd(ji,jj,jk,jn,4) = (  ztu(ji,jj,jk) - ztu(ji-1,jj,jk) ) * zbtr(ji,jj)
196                  trtrd(ji,jj,jk,jn,5) = (  ztv(ji,jj,jk) - ztv(ji-1,jj,jk) ) * zbtr(ji,jj)
197#endif
198               END DO
199            END DO
200            !                                             ! ===============
201         END DO                                           ! Horizontal slab
202         !                                                ! ===============
203#if defined key_trc_diatrd
204         ! Lateral boundary conditions on the laplacian zlt   (unchanged sgn)
205         CALL lbc_lnk( trtrd(:,:,:,jn,5), 'T', 1. ) 
206#endif
207      END DO
208
209     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
210         WRITE(charout, FMT="('ldf - bilap')")
211         CALL prt_ctl_trc_info(charout)
212         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
213      ENDIF
214
215   END SUBROUTINE trc_ldf_bilap
216
217#else
218   !!----------------------------------------------------------------------
219   !!   Default option                                         Empty module
220   !!----------------------------------------------------------------------
221CONTAINS
222   SUBROUTINE trc_ldf_bilap( kt ) 
223      INTEGER, INTENT(in) :: kt
224      WRITE(*,*) 'trc_ldf_bilap: You should not have seen this print! error?', kt
225   END SUBROUTINE trc_ldf_bilap
226#endif
227   !!==============================================================================
228END MODULE trcldf_bilap
Note: See TracBrowser for help on using the repository browser.