New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_iso.F90 @ 247

Last change on this file since 247 was 247, checked in by opalod, 19 years ago

CL : Add CVS Header and CeCILL licence information
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 10.5 KB
Line 
1MODULE trcldf_iso
2   !!==============================================================================
3   !!                    ***  MODULE  trcldf_iso  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if key_passivetrc && defined key_ldfslp 
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'                  rotation of the lateral mixing tensor
9   !!----------------------------------------------------------------------
10   !!   trc_ldf_iso : update the tracer trend with the horizontal component
11   !!                 of iso neutral laplacian operator or horizontal
12   !!                 laplacian operator in s-coordinate
13   !!----------------------------------------------------------------------
14   !! * Modules used
15   USE oce_trc      ! ocean dynamics and tracers variables
16   USE trc          ! ocean passive tracers variables
17
18   IMPLICIT NONE
19   PRIVATE
20
21   !! * Routine accessibility
22   PUBLIC trc_ldf_iso  ! routine called by step.F90
23
24   !! * Substitutions
25#  include "passivetrc_substitute.h90"
26   !!----------------------------------------------------------------------
27   !!----------------------------------------------------------------------
28   !!  TOP 1.0 , LOCEAN-IPSL (2005)
29   !! $Header$
30   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
31   !!----------------------------------------------------------------------
32CONTAINS
33
34   SUBROUTINE trc_ldf_iso( kt )
35      !!----------------------------------------------------------------------
36      !!                  ***  ROUTINE trc_ldf_iso  ***
37      !!
38      !! ** Purpose :   Compute the before horizontal tracer  diffusive
39      !!      trend and add it to the general trend of tracer equation.
40      !!
41      !! ** Method  :   The horizontal component of the lateral diffusive trends
42      !!      is provided by a 2nd order operator rotated along neural or geopo-
43      !!      tential surfaces to which an eddy induced advection can be added
44      !!      It is computed using before fields (forward in time) and isopyc-
45      !!      nal or geopotential slopes computed in routine ldfslp.
46      !!
47      !!      horizontal fluxes associated with the rotated lateral mixing:
48      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
49      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
50      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
51      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
52      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
53      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
54      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
55      !!      take the horizontal divergence of the fluxes:
56      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
57      !!      Add this trend to the general trend tra :
58      !!         tra = tra + difft
59      !!
60      !! ** Action  : - Update tra arrays with the before isopycnal or
61      !!                geopotential s-coord harmonic mixing trend.
62      !!              - Save the trends in trtrd ('key_trc_diatrd')
63      !!
64      !! History :
65      !!        !  94-08  (G. Madec, M. Imbard)
66      !!        !  97-05  (G. Madec)  split into traldf and trazdf
67      !!        !  98-03  (L. Bopp, MA Foujols) passive tracer generalisation
68      !!        !  00-10  (MA Foujols E Kestenare) USE passive tracer coefficient
69      !!   8.5  !  02-08  (G. Madec)  Free form, F90
70      !!   9.0  !  04-03  (C. Ethe)  Free form, F90
71      !!----------------------------------------------------------------------
72      !! * Modules used
73      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
74         &                zfsu => va      ! use va as workspace
75
76      !! * Arguments
77      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
78
79      !! * Local declarations
80      INTEGER ::   ji, jj, jk,jn             ! dummy loop indices
81      REAL(wp) ::   &
82         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
83         zmsku, zmskv, zbtr,           &
84#if defined key_trcldf_eiv
85         zcg1, zcg2, zuwk, zvwk,       &
86         zuwk1, zvwk1,                 &
87#endif
88         ztra
89
90      REAL(wp), DIMENSION(jpi,jpj) ::   &
91         zdkt, zdk1t            ! workspace
92
93#if defined key_trcldf_eiv
94      REAL(wp), DIMENSION(jpi,jpj) ::   &
95         zftug, zftvg
96#endif
97
98      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
99         zftv                       ! workspace
100      !!----------------------------------------------------------------------
101
102      IF( kt == nittrc000 ) THEN
103         IF(lwp) WRITE(numout,*)
104         IF(lwp) WRITE(numout,*) 'trc_ldf_iso : iso neutral lateral diffusion or'
105         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   horizontal laplacian diffusion in s-coordinate'
106#if defined key_trcldf_eiv && defined key_diaeiv
107         u_trc_eiv(:,:,:) = 0.e0
108         v_trc_eiv(:,:,:) = 0.e0
109#endif
110      ENDIF
111
112
113      DO jn = 1, jptra
114
115         !                                                ! ===============
116         DO jk = 1, jpkm1                                 ! Horizontal slab
117            !                                             ! ===============
118            ! 1. Vertical tracer gradient at level jk and jk+1
119            ! ------------------------------------------------
120            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
121
122            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
123
124            IF( jk == 1 ) THEN
125               zdkt(:,:) = zdk1t(:,:)
126            ELSE
127               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
128            ENDIF
129
130
131            ! 2. Horizontal fluxes
132            ! --------------------
133
134            DO jj = 1 , jpjm1
135               DO ji = 1, fs_jpim1   ! vector opt.
136                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
137                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
138
139                  zmsku = 1. / MAX(   tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
140                     + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
141
142                  zmskv = 1. / MAX(   tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
143                     + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
144
145                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
146                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
147
148                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn)  )   &
149                     &                              + zcof1 * (   zdkt (ji+1,jj) + zdk1t(ji,jj)      &
150                     &                                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
151
152                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn)  )   &
153                     &                              + zcof2 * (   zdkt (ji,jj+1) + zdk1t(ji,jj)      &
154                     &                                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
155
156               END DO
157            END DO
158
159#   if defined key_trcldf_eiv
160            !                              ! ---------------------------------------!
161            !                              ! Eddy induced vertical advective fluxes !
162            !                              ! ---------------------------------------!
163            DO jj = 1, jpjm1
164               DO ji = 1, fs_jpim1   ! vector opt.
165                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
166                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
167                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
168                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
169
170                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
171                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
172
173                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
174                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
175
176                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
177                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
178
179#   if defined key_diaeiv
180                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
181                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
182#   endif
183               END DO
184            END DO
185#   endif
186
187            ! II.4 Second derivative (divergence) and add to the general trend
188            ! ----------------------------------------------------------------
189
190            DO jj = 2 , jpjm1
191               DO ji = fs_2, fs_jpim1   ! vector opt.
192                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
193                  ztra = zbtr * (  zftu(ji,jj,jk) - zftu(ji-1,jj  ,jk)   &
194                     &          + zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk)  )
195                  tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
196#if defined key_trc_diatrd
197                  trtrd (ji,jj,jk,jn,4) = ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk  ) ) * zbtr
198                  trtrd (ji,jj,jk,jn,5) = ( zftv(ji,jj,jk) - zftv(ji,jj-1,jk  ) ) * zbtr
199#endif
200               END DO
201            END DO
202            !                                          ! ===============
203         END DO                                        !   End of slab 
204         !                                             ! ===============
205         IF(l_ctl) THEN         ! print mean trends (used for debugging)
206            ztra = SUM( tra(2:nictl,2:njctl,1:jpkm1,jn) * tmask(2:nictl,2:njctl,1:jpkm1) )
207            WRITE(numout,*) ' trc/ldf  - ',ctrcnm(jn),' : ', ztra-tra_ctl(jn)
208            tra_ctl(jn) = ztra 
209         ENDIF
210
211      END DO
212
213   END SUBROUTINE trc_ldf_iso
214
215#else
216   !!----------------------------------------------------------------------
217   !!   Dummy module :             No rotation of the lateral mixing tensor
218   !!----------------------------------------------------------------------
219CONTAINS
220   SUBROUTINE trc_ldf_iso( kt )               ! Empty routine
221      INTEGER, INTENT(in) :: kt
222      WRITE(*,*) 'trc_ldf_iso: You should not have seen this print! error?', kt
223   END SUBROUTINE trc_ldf_iso
224#endif
225
226   !!==============================================================================
227END MODULE trcldf_iso
Note: See TracBrowser for help on using the repository browser.