New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_iso.F90 @ 340

Last change on this file since 340 was 334, checked in by opalod, 19 years ago

nemo_v1_update_022 : CE + RB + CT : add print control possibility
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 10.2 KB
Line 
1MODULE trcldf_iso
2   !!==============================================================================
3   !!                    ***  MODULE  trcldf_iso  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if key_passivetrc && defined key_ldfslp 
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'                  rotation of the lateral mixing tensor
9   !!----------------------------------------------------------------------
10   !!   trc_ldf_iso : update the tracer trend with the horizontal component
11   !!                 of iso neutral laplacian operator or horizontal
12   !!                 laplacian operator in s-coordinate
13   !!----------------------------------------------------------------------
14   !! * Modules used
15   USE oce_trc      ! ocean dynamics and tracers variables
16   USE trc          ! ocean passive tracers variables
17   USE prtctl_trc   ! Print control for debbuging
18
19   IMPLICIT NONE
20   PRIVATE
21
22   !! * Routine accessibility
23   PUBLIC trc_ldf_iso  ! routine called by step.F90
24
25   !! * Substitutions
26#  include "passivetrc_substitute.h90"
27   !!----------------------------------------------------------------------
28
29CONTAINS
30
31   SUBROUTINE trc_ldf_iso( kt )
32      !!----------------------------------------------------------------------
33      !!                  ***  ROUTINE trc_ldf_iso  ***
34      !!
35      !! ** Purpose :   Compute the before horizontal tracer  diffusive
36      !!      trend and add it to the general trend of tracer equation.
37      !!
38      !! ** Method  :   The horizontal component of the lateral diffusive trends
39      !!      is provided by a 2nd order operator rotated along neural or geopo-
40      !!      tential surfaces to which an eddy induced advection can be added
41      !!      It is computed using before fields (forward in time) and isopyc-
42      !!      nal or geopotential slopes computed in routine ldfslp.
43      !!
44      !!      horizontal fluxes associated with the rotated lateral mixing:
45      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
46      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
47      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
48      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
49      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
50      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
51      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
52      !!      take the horizontal divergence of the fluxes:
53      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
54      !!      Add this trend to the general trend tra :
55      !!         tra = tra + difft
56      !!
57      !! ** Action  : - Update tra arrays with the before isopycnal or
58      !!                geopotential s-coord harmonic mixing trend.
59      !!              - Save the trends in trtrd ('key_trc_diatrd')
60      !!
61      !! History :
62      !!        !  94-08  (G. Madec, M. Imbard)
63      !!        !  97-05  (G. Madec)  split into traldf and trazdf
64      !!        !  98-03  (L. Bopp, MA Foujols) passive tracer generalisation
65      !!        !  00-10  (MA Foujols E Kestenare) USE passive tracer coefficient
66      !!   8.5  !  02-08  (G. Madec)  Free form, F90
67      !!   9.0  !  04-03  (C. Ethe)  Free form, F90
68      !!----------------------------------------------------------------------
69      !! * Modules used
70      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
71         &                zfsu => va      ! use va as workspace
72
73      !! * Arguments
74      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
75
76      !! * Local declarations
77      INTEGER ::   ji, jj, jk,jn             ! dummy loop indices
78      REAL(wp) ::   &
79         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
80         zmsku, zmskv, zbtr,           &
81#if defined key_trcldf_eiv
82         zcg1, zcg2, zuwk, zvwk,       &
83         zuwk1, zvwk1,                 &
84#endif
85         ztra
86
87      REAL(wp), DIMENSION(jpi,jpj) ::   &
88         zdkt, zdk1t            ! workspace
89
90#if defined key_trcldf_eiv
91      REAL(wp), DIMENSION(jpi,jpj) ::   &
92         zftug, zftvg
93#endif
94
95      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
96         zftv                       ! workspace
97      CHARACTER (len=22) :: charout
98      !!----------------------------------------------------------------------
99
100      IF( kt == nittrc000 ) THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'trc_ldf_iso : iso neutral lateral diffusion or'
103         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   horizontal laplacian diffusion in s-coordinate'
104#if defined key_trcldf_eiv && defined key_diaeiv
105         u_trc_eiv(:,:,:) = 0.e0
106         v_trc_eiv(:,:,:) = 0.e0
107#endif
108      ENDIF
109
110
111      DO jn = 1, jptra
112
113         !                                                ! ===============
114         DO jk = 1, jpkm1                                 ! Horizontal slab
115            !                                             ! ===============
116            ! 1. Vertical tracer gradient at level jk and jk+1
117            ! ------------------------------------------------
118            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
119
120            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
121
122            IF( jk == 1 ) THEN
123               zdkt(:,:) = zdk1t(:,:)
124            ELSE
125               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
126            ENDIF
127
128
129            ! 2. Horizontal fluxes
130            ! --------------------
131
132            DO jj = 1 , jpjm1
133               DO ji = 1, fs_jpim1   ! vector opt.
134                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
135                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
136
137                  zmsku = 1. / MAX(   tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
138                     + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
139
140                  zmskv = 1. / MAX(   tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
141                     + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
142
143                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
144                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
145
146                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn)  )   &
147                     &                              + zcof1 * (   zdkt (ji+1,jj) + zdk1t(ji,jj)      &
148                     &                                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
149
150                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn)  )   &
151                     &                              + zcof2 * (   zdkt (ji,jj+1) + zdk1t(ji,jj)      &
152                     &                                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
153
154               END DO
155            END DO
156
157#   if defined key_trcldf_eiv
158            !                              ! ---------------------------------------!
159            !                              ! Eddy induced vertical advective fluxes !
160            !                              ! ---------------------------------------!
161            DO jj = 1, jpjm1
162               DO ji = 1, fs_jpim1   ! vector opt.
163                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
164                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
165                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
166                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
167
168                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
169                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
170
171                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
172                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
173
174                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
175                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
176
177#   if defined key_diaeiv
178                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
179                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
180#   endif
181               END DO
182            END DO
183#   endif
184
185            ! II.4 Second derivative (divergence) and add to the general trend
186            ! ----------------------------------------------------------------
187
188            DO jj = 2 , jpjm1
189               DO ji = fs_2, fs_jpim1   ! vector opt.
190                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
191                  ztra = zbtr * (  zftu(ji,jj,jk) - zftu(ji-1,jj  ,jk)   &
192                     &          + zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk)  )
193                  tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
194#if defined key_trc_diatrd
195                  trtrd (ji,jj,jk,jn,4) = ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk  ) ) * zbtr
196                  trtrd (ji,jj,jk,jn,5) = ( zftv(ji,jj,jk) - zftv(ji,jj-1,jk  ) ) * zbtr
197#endif
198               END DO
199            END DO
200            !                                          ! ===============
201         END DO                                        !   End of slab 
202         !                                             ! ===============
203
204      END DO
205
206      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
207         WRITE(charout, FMT="('ldf - iso')")
208         CALL prt_ctl_trc_info(charout)
209         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
210      ENDIF
211
212   END SUBROUTINE trc_ldf_iso
213
214#else
215   !!----------------------------------------------------------------------
216   !!   Dummy module :             No rotation of the lateral mixing tensor
217   !!----------------------------------------------------------------------
218CONTAINS
219   SUBROUTINE trc_ldf_iso( kt )               ! Empty routine
220      INTEGER, INTENT(in) :: kt
221      WRITE(*,*) 'trc_ldf_iso: You should not have seen this print! error?', kt
222   END SUBROUTINE trc_ldf_iso
223#endif
224
225   !!==============================================================================
226END MODULE trcldf_iso
Note: See TracBrowser for help on using the repository browser.