New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_iso.F90 @ 936

Last change on this file since 936 was 724, checked in by cetlod, 17 years ago

Update modules for passive tracers transport trends computation, see ticket:13
  • Property svn:eol-style set to native
  • Property svn:executable set to *
  • Property svn:keywords set to Author Date Id Revision
File size: 11.4 KB
Line 
1MODULE trcldf_iso
2   !!==============================================================================
3   !!                    ***  MODULE  trcldf_iso  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!==============================================================================
6#if key_passivetrc && defined key_ldfslp 
7   !!----------------------------------------------------------------------
8   !!   'key_ldfslp'                  rotation of the lateral mixing tensor
9   !!----------------------------------------------------------------------
10   !!   trc_ldf_iso : update the tracer trend with the horizontal component
11   !!                 of iso neutral laplacian operator or horizontal
12   !!                 laplacian operator in s-coordinate
13   !!----------------------------------------------------------------------
14   !! * Modules used
15   USE oce_trc      ! ocean dynamics and tracers variables
16   USE trc          ! ocean passive tracers variables
17   USE prtctl_trc   ! Print control for debbuging
18
19   IMPLICIT NONE
20   PRIVATE
21
22   !! * Routine accessibility
23   PUBLIC trc_ldf_iso  ! routine called by step.F90
24
25   !! * Substitutions
26#  include "passivetrc_substitute.h90"
27   !!----------------------------------------------------------------------
28   !!   TOP 1.0 , LOCEAN-IPSL (2005)
29   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcldf_iso.F90,v 1.10 2007/10/12 09:26:30 opalod Exp $
30   !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt
31   !!----------------------------------------------------------------------
32
33CONTAINS
34
35   SUBROUTINE trc_ldf_iso( kt )
36      !!----------------------------------------------------------------------
37      !!                  ***  ROUTINE trc_ldf_iso  ***
38      !!
39      !! ** Purpose :   Compute the before horizontal tracer  diffusive
40      !!      trend and add it to the general trend of tracer equation.
41      !!
42      !! ** Method  :   The horizontal component of the lateral diffusive trends
43      !!      is provided by a 2nd order operator rotated along neural or geopo-
44      !!      tential surfaces to which an eddy induced advection can be added
45      !!      It is computed using before fields (forward in time) and isopyc-
46      !!      nal or geopotential slopes computed in routine ldfslp.
47      !!
48      !!      horizontal fluxes associated with the rotated lateral mixing:
49      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
50      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
51      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
52      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
53      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
54      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( tb )
55      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( tb )
56      !!      take the horizontal divergence of the fluxes:
57      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
58      !!      Add this trend to the general trend tra :
59      !!         tra = tra + difft
60      !!
61      !! ** Action  : - Update tra arrays with the before isopycnal or
62      !!                geopotential s-coord harmonic mixing trend.
63      !!              - Save the trends in trtrd ('key_trc_diatrd')
64      !!
65      !! History :
66      !!        !  94-08  (G. Madec, M. Imbard)
67      !!        !  97-05  (G. Madec)  split into traldf and trazdf
68      !!        !  98-03  (L. Bopp, MA Foujols) passive tracer generalisation
69      !!        !  00-10  (MA Foujols E Kestenare) USE passive tracer coefficient
70      !!   8.5  !  02-08  (G. Madec)  Free form, F90
71      !!   9.0  !  04-03  (C. Ethe)  Free form, F90
72      !!----------------------------------------------------------------------
73      !! * Modules used
74      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
75         &                zfsu => va      ! use va as workspace
76
77      !! * Arguments
78      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
79
80      !! * Local declarations
81      INTEGER ::   ji, jj, jk,jn             ! dummy loop indices
82      REAL(wp) ::   &
83         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
84         zmsku, zmskv, zbtr,           &
85#if defined key_trcldf_eiv
86         zcg1, zcg2, zuwk, zvwk,       &
87         zuwk1, zvwk1,                 &
88#endif
89         ztra
90
91      REAL(wp), DIMENSION(jpi,jpj) ::   &
92         zdkt, zdk1t            ! workspace
93
94#if defined key_trcldf_eiv
95      REAL(wp), DIMENSION(jpi,jpj) ::   &
96         zftug, zftvg
97
98#if defined key_trc_diatrd
99      REAL(wp) ::   &
100         ztagu, ztagv
101#endif
102
103#endif
104
105      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   &
106         zftv                       ! workspace
107      CHARACTER (len=22) :: charout
108      !!----------------------------------------------------------------------
109
110      IF( kt == nittrc000 ) THEN
111         IF(lwp) WRITE(numout,*)
112         IF(lwp) WRITE(numout,*) 'trc_ldf_iso : iso neutral lateral diffusion or'
113         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   horizontal laplacian diffusion in s-coordinate'
114#if defined key_trcldf_eiv && defined key_diaeiv
115         u_trc_eiv(:,:,:) = 0.e0
116         v_trc_eiv(:,:,:) = 0.e0
117#endif
118      ENDIF
119
120
121      DO jn = 1, jptra
122
123         !                                                ! ===============
124         DO jk = 1, jpkm1                                 ! Horizontal slab
125            !                                             ! ===============
126            ! 1. Vertical tracer gradient at level jk and jk+1
127            ! ------------------------------------------------
128            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
129
130            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
131
132            IF( jk == 1 ) THEN
133               zdkt(:,:) = zdk1t(:,:)
134            ELSE
135               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
136            ENDIF
137
138
139            ! 2. Horizontal fluxes
140            ! --------------------
141
142            DO jj = 1 , jpjm1
143               DO ji = 1, fs_jpim1   ! vector opt.
144                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
145                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
146
147                  zmsku = 1. / MAX(   tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
148                     + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
149
150                  zmskv = 1. / MAX(   tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
151                     + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
152
153                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
154                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
155
156                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (   zabe1 * (   trb(ji+1,jj,jk,jn) - trb(ji,jj,jk,jn)  )   &
157                     &                              + zcof1 * (   zdkt (ji+1,jj) + zdk1t(ji,jj)      &
158                     &                                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
159
160                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (   zabe2 * (   trb(ji,jj+1,jk,jn) - trb(ji,jj,jk,jn)  )   &
161                     &                              + zcof2 * (   zdkt (ji,jj+1) + zdk1t(ji,jj)      &
162                     &                                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
163
164               END DO
165            END DO
166
167#   if defined key_trcldf_eiv
168            !                              ! ---------------------------------------!
169            !                              ! Eddy induced vertical advective fluxes !
170            !                              ! ---------------------------------------!
171            DO jj = 1, jpjm1
172               DO ji = 1, fs_jpim1   ! vector opt.
173                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
174                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
175                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
176                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
177
178                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
179                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
180
181                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
182                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
183
184                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
185                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
186
187#   if defined key_diaeiv
188                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
189                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
190#   endif
191               END DO
192            END DO
193#   endif
194
195            ! II.4 Second derivative (divergence) and add to the general trend
196            ! ----------------------------------------------------------------
197
198            DO jj = 2 , jpjm1
199               DO ji = fs_2, fs_jpim1   ! vector opt.
200                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
201                  ztra = zbtr * (  zftu(ji,jj,jk) - zftu(ji-1,jj  ,jk)   &
202                     &          + zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk)  )
203                  tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
204#if defined key_trc_diatrd
205                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),4) = ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk  ) ) * zbtr
206                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),5) = ( zftv(ji,jj,jk) - zftv(ji,jj-1,jk  ) ) * zbtr
207#endif
208               END DO
209            END DO
210
211#if defined key_trc_diatrd
212#   if defined key_trcldf_eiv
213            DO jj = 2 , jpjm1
214               DO ji = fs_2, fs_jpim1   ! vector opt.
215                  zbtr= 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
216                  ztagu = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
217                  ztagv = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
218                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),4) = trtrd(ji,jj,jk,ikeep(jn),4) - ztagu
219                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),5) = trtrd(ji,jj,jk,ikeep(jn),5) - ztagv
220                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),7) = ztagu
221                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),8) = ztagv
222               END DO
223             END DO
224#   endif
225#endif
226
227            !                                          ! ===============
228         END DO                                        !   End of slab 
229         !                                             ! ===============
230
231      END DO
232
233      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
234         WRITE(charout, FMT="('ldf - iso')")
235         CALL prt_ctl_trc_info(charout)
236         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
237      ENDIF
238
239   END SUBROUTINE trc_ldf_iso
240
241#else
242   !!----------------------------------------------------------------------
243   !!   Dummy module :             No rotation of the lateral mixing tensor
244   !!----------------------------------------------------------------------
245CONTAINS
246   SUBROUTINE trc_ldf_iso( kt )               ! Empty routine
247      INTEGER, INTENT(in) :: kt
248      WRITE(*,*) 'trc_ldf_iso: You should not have seen this print! error?', kt
249   END SUBROUTINE trc_ldf_iso
250#endif
251
252   !!==============================================================================
253END MODULE trcldf_iso
Note: See TracBrowser for help on using the repository browser.