New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcldf_iso_zps.F90 in trunk/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMO/TOP_SRC/TRP/trcldf_iso_zps.F90 @ 1264

Last change on this file since 1264 was 1264, checked in by cetlod, 15 years ago

clean TOP model routines to avoid warning when compiling, see ticket:303
  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 16.7 KB
Line 
1MODULE trcldf_iso_zps
2   !!======================================================================
3   !!                   ***  MODULE  trcldf_iso_zps  ***
4   !! Ocean passive tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :       !  94-08  (G. Madec, M. Imbard)
7   !!                 !  97-05  (G. Madec)  split into traldf and trazdf
8   !!            8.5  !  02-08  (G. Madec)  Free form, F90
9   !!            9.0  !  04-03  (C. Ethe)  adapted for passive tracers
10   !!                 !  07-02  (C. Deltel)  Diagnose ML trends for passive tracers
11   !!----------------------------------------------------------------------
12#if key_top &&  defined key_ldfslp 
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   trc_ldf_iso_zps : update the tracer trend with the horizontal
17   !!                     component of a iso-neutral laplacian operator
18   !!----------------------------------------------------------------------
19   USE oce_trc             ! ocean dynamics and active tracers variables
20   USE trp_trc                 ! ocean passive tracers variables
21   USE prtctl_trc          ! Print control for debbuging
22   USE trdmld_trc
23   USE trdmld_trc_oce     
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC trc_ldf_iso_zps  ! routine called by step.F90
29
30   !! * Substitutions
31#  include "top_substitute.h90"
32   !!----------------------------------------------------------------------
33   !!   TOP 1.0 , LOCEAN-IPSL (2005)
34   !! $Header: /home/opalod/NEMOCVSROOT/NEMO/TOP_SRC/TRP/trcldf_iso_zps.F90,v 1.10 2006/09/12 11:10:14 opalod Exp $
35   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37
38CONTAINS
39
40   SUBROUTINE trc_ldf_iso_zps( kt )
41      !!----------------------------------------------------------------------
42      !!                  ***  ROUTINE trc_ldf_iso_zps  ***
43      !!
44      !! ** Purpose :   Compute the before horizontal tracer  diffusive
45      !!      trend and add it to the general trend of tracer equation.
46      !!
47      !! ** Method  :   The horizontal component of the lateral diffusive trends
48      !!      is provided by a 2nd order operator rotated along neural or geopo-
49      !!      tential surfaces to which an eddy induced advection can be added
50      !!      It is computed using before fields (forward in time) and isopyc-
51      !!      nal or geopotential slopes computed in routine ldfslp.
52      !!
53      !!      horizontal fluxes associated with the rotated lateral mixing:
54      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
55      !!               - aht       e2u*uslp    dk[ mi(mk(trb)) ]
56      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
57      !!               - aht       e2u*vslp    dk[ mj(mk(trb)) ]
58      !!      add horizontal Eddy Induced advective fluxes (lk_traldf_eiv=T):
59      !!         zftu = zftu - dk-1[ aht e2u mi(wslpi) ] mi( trb )
60      !!         zftv = zftv - dk-1[ aht e1v mj(wslpj) ] mj( trb )
61      !!      take the horizontal divergence of the fluxes:
62      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
63      !!      Add this trend to the general trend tra :
64      !!         tra = tra + difft
65      !!
66      !!      'key_trdtra' defined: the trend is saved for diagnostics.
67      !!
68      !!      macro-tasked on horizontal slab (jk-loop).
69      !!
70      !! ** Action :
71      !!         Update tra arrays with the before along level biharmonic
72      !!      mixing trend.
73      !!         Save the trends if 'key_trdmld_trc' defined
74      !!----------------------------------------------------------------------
75      USE oce_trc       , zftu => ua,  &  ! use ua as workspace
76         &                zfsu => va      ! use va as workspace
77      !!
78      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
79      INTEGER ::   ji, jj, jk,jn          ! dummy loop indices
80      INTEGER ::   iku, ikv               ! temporary integer
81      REAL(wp) ::   &
82         zabe1, zabe2, zcof1, zcof2,   &  ! temporary scalars
83         zmsku, zmskv, zbtr, ztra,     &
84         ztagu, ztagv
85
86      REAL(wp), DIMENSION(jpi,jpj) ::   &
87         zdkt , zdk1t                     ! temporary workspace
88
89      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   & 
90         zftv, zgtbu, zgtbv               ! temporary workspace
91
92#if defined key_trcldf_eiv
93      REAL(wp), DIMENSION(jpi,jpj) ::   &
94         zftug, zftvg                     ! temporary workspace
95      REAL(wp) ::   z_hdivn_x, z_hdivn_y
96      REAL(wp) ::   &
97         zuwk, zvwk,                   &
98         zuwk1, zvwk1,                 &
99         zcg1,zcg2
100#endif
101      CHARACTER (len=22) :: charout
102      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd
103      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd_xei
104      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd_yei
105      !!----------------------------------------------------------------------
106
107      IF( kt == nittrc000 ) THEN
108         IF(lwp) WRITE(numout,*)
109         IF(lwp) WRITE(numout,*) 'trc_ldf_iso_zps : iso neutral laplacian diffusion in '
110         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~   z-coordinates with partial steps'
111#if defined key_trcldf_eiv && defined key_diaeiv
112         u_trc_eiv(:,:,:) = 0.e0
113         v_trc_eiv(:,:,:) = 0.e0
114#endif
115      ENDIF
116
117      IF( l_trdtrc ) THEN
118         ALLOCATE( ztrtrd(jpi,jpj,jpk) )
119#   if defined key_trcldf_eiv
120         ALLOCATE( ztrtrd_xei(jpi,jpj,jpk) )
121         ALLOCATE( ztrtrd_yei(jpi,jpj,jpk) )
122#   endif
123      ENDIF
124
125      !                                                          ! ===========
126      DO jn = 1, jptra                                           ! tracer loop
127         !                                                       ! ===========
128         IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn)   ! save trends
129
130         ztagu = 0.e0    ;     ztagv = 0.e0
131
132         ! Horizontal passive tracer gradient
133         DO jk = 1, jpk
134            DO jj = 1, jpj-1
135               DO ji = 1, fs_jpim1   ! vector opt.
136                  zgtbu(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji+1,jj  ,jk,jn) - trb(ji,jj,jk,jn) )
137                  zgtbv(ji,jj,jk) = tmask(ji,jj,jk) * ( trb(ji  ,jj+1,jk,jn) - trb(ji,jj,jk,jn) )
138               END DO
139            END DO
140         END DO
141         ! partial steps correction at the last level
142         DO jj = 1, jpj-1
143            DO ji = 1, jpi-1
144               ! last level
145               iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
146               ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
147               zgtbu(ji,jj,iku) = gtru(ji,jj,jn)               
148               zgtbv(ji,jj,ikv) = gtrv(ji,jj,jn)               
149            END DO
150         END DO
151
152         !                                                ! ===============
153         DO jk = 1, jpkm1                                 ! Horizontal slab
154            !                                             ! ===============
155            ! 1. Vertical tracer gradient at level jk and jk+1
156            ! ------------------------------------------------
157            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
158
159            zdk1t(:,:) = ( trb(:,:,jk,jn) - trb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
160
161            IF( jk == 1 ) THEN
162               zdkt(:,:) = zdk1t(:,:)
163            ELSE
164               zdkt(:,:) = ( trb(:,:,jk-1,jn) - trb(:,:,jk,jn) ) * tmask(:,:,jk)
165            ENDIF
166
167            ! 2. Horizontal fluxes
168            ! --------------------
169
170            DO jj = 1 , jpjm1
171               DO ji = 1, fs_jpim1   ! vector opt.
172                  zabe1 = ( fsahtru(ji,jj,jk) + ahtrb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
173                  zabe2 = ( fsahtrv(ji,jj,jk) + ahtrb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
174
175                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
176                       &           + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
177
178                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
179                       &           + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
180
181                  zcof1 = -fsahtru(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
182                  zcof2 = -fsahtrv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
183
184                  zftu(ji,jj,jk) = umask(ji,jj,jk) * (  zabe1 * zgtbu(ji,jj,jk)   &
185                       &                              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
186                       &                                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  )
187                  zftv(ji,jj,jk) = vmask(ji,jj,jk) * (  zabe2 * zgtbv(ji,jj,jk)   &
188                       &                              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
189                       &                                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  )
190               END DO
191            END DO
192
193# if defined key_trcldf_eiv
194
195            ! ... Eddy induced horizontal advective fluxes
196            DO jj = 1, jpjm1
197               DO ji = 1, fs_jpim1   ! vector opt.
198                  zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
199                  zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
200                  zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
201                  zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
202
203                  zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
204                  zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
205
206                  zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
207                  zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
208
209                  zftu(ji,jj,jk) = zftu(ji,jj,jk) + zftug(ji,jj)
210                  zftv(ji,jj,jk) = zftv(ji,jj,jk) + zftvg(ji,jj)
211
212#   if defined key_diaeiv
213                  u_trc_eiv(ji,jj,jk) = -2. * zcg1 / ( e2u(ji,jj) * fse3u(ji,jj,jk) )
214                  v_trc_eiv(ji,jj,jk) = -2. * zcg2 / ( e1v(ji,jj) * fse3v(ji,jj,jk) )
215#   endif
216               END DO
217            END DO
218# endif
219
220            ! 3. Second derivative (divergence) and add to the general trend
221            ! --------------------------------------------------------------
222
223            DO jj = 2 , jpjm1
224               DO ji = fs_2, fs_jpim1   ! vector opt.
225                  zbtr= 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
226                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
227                  tra (ji,jj,jk,jn) = tra (ji,jj,jk,jn) + ztra
228#if defined key_trc_diatrd
229                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),4) = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,  jj,jk) )
230                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),5) = zbtr * ( zftv(ji,jj,jk) - zftv(ji  ,jj-1,jk) )
231#endif
232               END DO
233            END DO
234#if defined key_trc_diatrd
235#   if defined key_trcldf_eiv
236            DO jj = 2 , jpjm1
237               DO ji = fs_2, fs_jpim1   ! vector opt.
238                  zbtr= 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
239                  ztagu = ( zftug(ji,jj) - zftug(ji-1,jj  ) ) * zbtr
240                  ztagv = ( zftvg(ji,jj) - zftvg(ji  ,jj-1) ) * zbtr
241                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),4) = trtrd(ji,jj,jk,ikeep(jn),4) - ztagu
242                  IF (luttrd(jn)) trtrd (ji,jj,jk,ikeep(jn),5) = trtrd(ji,jj,jk,ikeep(jn),5) - ztagv
243               END DO
244            END DO
245#   endif
246#endif
247
248            !                                          ! ===============
249         END DO                                        !   End of slab 
250         !                                             ! ===============
251
252         ! 4. Save the horizontal diffusive and advective (eiv) trends for diagnostics
253         ! ---------------------------------------------------------------------------
254         IF( l_trdtrc ) THEN
255
256            ! 4.1) Compute the eiv ZONAL & MERIDIONAL advective trends
257
258#   if defined key_trcldf_eiv
259            !                                                ! ===============
260            DO jk = 1, jpkm1                                 ! Horizontal slab
261               !                                             ! ===============
262
263               DO jj = 1, jpjm1
264                  DO ji = 1, fs_jpim1   ! vector opt.
265                     zuwk = ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj  ,jk  ) ) * fsaeitru(ji,jj,jk  ) * umask(ji,jj,jk  )
266                     zuwk1= ( wslpi(ji,jj,jk+1) + wslpi(ji+1,jj  ,jk+1) ) * fsaeitru(ji,jj,jk+1) * umask(ji,jj,jk+1)
267                     zvwk = ( wslpj(ji,jj,jk  ) + wslpj(ji  ,jj+1,jk  ) ) * fsaeitrv(ji,jj,jk  ) * vmask(ji,jj,jk  )
268                     zvwk1= ( wslpj(ji,jj,jk+1) + wslpj(ji  ,jj+1,jk+1) ) * fsaeitrv(ji,jj,jk+1) * vmask(ji,jj,jk+1)
269                     
270                     zcg1= -0.25 * e2u(ji,jj) * umask(ji,jj,jk) * ( zuwk-zuwk1 )
271                     zcg2= -0.25 * e1v(ji,jj) * vmask(ji,jj,jk) * ( zvwk-zvwk1 )
272                     
273                     zftug(ji,jj) = zcg1 * ( trb(ji+1,jj,jk,jn) + trb(ji,jj,jk,jn) )
274                     zftvg(ji,jj) = zcg2 * ( trb(ji,jj+1,jk,jn) + trb(ji,jj,jk,jn) )
275                  END DO
276               END DO
277
278               DO jj = 2 , jpjm1
279                  DO ji = fs_2, fs_jpim1   ! vector opt.
280                 
281                     zbtr = 1. / ( e1t(ji,jj)*e2t(ji,jj)*fse3t(ji,jj,jk) )
282
283                     !-- Compute zonal & meridional divergences of the eiv field :
284                     !     d_x[u_trc_eiv] = 1/(e1t*e2t*e3t) ( di[e2u*e3u u_trc_eiv] )
285                     !     d_y[v_trc_eiv] = 1/(e1t*e2t*e3t) ( dj[e1v*e3v v_trc_eiv] )
286                     !   N.B.  This is only possible if key_diaeiv is switched on.
287#       if defined key_diaeiv
288                     z_hdivn_x = (  e2u(ji  ,jj) * fse3u(ji  ,jj,jk) * u_trc_eiv(ji  ,jj  ,jk)  &
289                          &       - e2u(ji-1,jj) * fse3u(ji-1,jj,jk) * u_trc_eiv(ji-1,jj  ,jk) ) * zbtr
290                     z_hdivn_y = (  e1v(ji,  jj) * fse3v(ji,jj  ,jk) * v_trc_eiv(ji,  jj  ,jk)  &
291                          &       - e1v(ji,jj-1) * fse3v(ji,jj-1,jk) * v_trc_eiv(ji  ,jj-1,jk) ) * zbtr
292#       else
293                     z_hdivn_x = 0.e0   ;   z_hdivn_y = 0.e0 
294#       endif
295                     !-- Compute the zonal advective trends associated with eiv
296                     ztrtrd_xei(ji,jj,jk) = zbtr * ( zftug(ji,jj) - zftug(ji-1,jj  ) )          &
297                          &                 - trn(ji,jj,jk,jn) * z_hdivn_x
298                     
299                     !-- Compute the merid. advective trends associated with eiv
300                     ztrtrd_yei(ji,jj,jk) = zbtr * ( zftvg(ji,jj) - zftvg(ji  ,jj-1) )          &
301                          &                 - trn(ji,jj,jk,jn) * z_hdivn_y
302
303                  END DO
304               END DO
305               !                                             ! ===============
306            END DO                                           !   End of slab 
307            !                                                ! ===============
308#   else
309            ztrtrd_xei(:,:,:) = 0.e0
310            ztrtrd_yei(:,:,:) = 0.e0
311#   endif
312            ! 4.2) Substract the eddy induced velocity
313            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:) - ztrtrd_xei(:,:,:) - ztrtrd_yei(:,:,:)
314
315            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd    , jn, jptrc_trd_ldf, kt )
316#   if defined key_trcldf_eiv
317            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_xei, jn, jptrc_trd_xei, kt )
318            IF (luttrd(jn)) CALL trd_mod_trc( ztrtrd_yei, jn, jptrc_trd_yei, kt )
319#   endif
320
321         ENDIF
322         !                                                       ! ===========
323      END DO                                                     ! tracer loop
324      !                                                          ! ===========
325
326      IF( ln_ctl ) THEN    ! print mean trends (used for debugging)
327         WRITE(charout, FMT="('ldf - iso/zps')")
328         CALL prt_ctl_trc_info( charout )
329         CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd' )
330      ENDIF
331
332   END SUBROUTINE trc_ldf_iso_zps
333
334#else
335   !!----------------------------------------------------------------------
336   !!   default option :   Dummy code   NO rotation of the diffusive tensor
337   !!----------------------------------------------------------------------
338CONTAINS
339   SUBROUTINE trc_ldf_iso_zps( kt )               ! Empty routine
340      INTEGER, INTENT(in) :: kt
341      WRITE(*,*) 'trc_ldf_iso_zps: You should not have seen this print! error?', kt
342   END SUBROUTINE trc_ldf_iso_zps
343#endif
344
345   !!==============================================================================
346END MODULE trcldf_iso_zps
Note: See TracBrowser for help on using the repository browser.