source: trunk/NEMO/TOP_SRC/trclec.F90 @ 1573

MODULE trclec
   !!======================================================================
   !!                       ***  MODULE trclec  ***
   !! TOP :   Read and print options for the passive tracer run (namelist)
   !!======================================================================
   !! History :    -   !  1996-11  (M.A. Foujols, M. Levy)  original code
   !!              -   !  1998-04  (M.A Foujols, L. Bopp) ahtrb0 for isopycnal mixing
   !!              -   !  1999-10  (M.A. Foujols, M. Levy) separation of sms
   !!              -   !  2000-07  (A. Estublier) add TVD and MUSCL : Tests on ndttrc
   !!              -   !  2000-11  (M.A Foujols, E Kestenare) trcrat, ahtrc0 and aeivtr0
   !!              -   !  2001-01 (E Kestenare) suppress ndttrc=1 for CEN2 and TVD schemes
   !!             1.0  !  2005-03 (O. Aumont, A. El Moussaoui) F90
   !!----------------------------------------------------------------------
#if defined key_top
   !!----------------------------------------------------------------------
   !!   'key_top'                                                TOP models
   !!----------------------------------------------------------------------
   !!   trc_lec    :  Read and print options for the passive tracer run (namelist)
   !!----------------------------------------------------------------------
   USE oce_trc
   USE trc
   USE trp_trc
   USE trctrp_lec
   USE trclsm_lobster    ! LOBSTER namelist
   USE trclsm_pisces     ! PISCES namelist
   USE trclsm_cfc        ! CFC SMS namelist
   USE trclsm_c14b       ! C14 SMS namelist
   USE trclsm_my_trc     ! MY_TRC SMS namelist
   USE in_out_manager    ! I/O manager
   USE trdmld_trc_oce

   IMPLICIT NONE
   PRIVATE 

   PUBLIC trc_lec      ! called in ???

   !! * Substitutions
#  include "top_substitute.h90"
   !!----------------------------------------------------------------------
   !! NEMO/TOP 1.0 , LOCEAN-IPSL (2005) 
   !! $Id$ 
   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
   !!----------------------------------------------------------------------

CONTAINS

   SUBROUTINE trc_lec
      !!---------------------------------------------------------------------
      !!                     ***  ROUTINE trc_lec  ***
      !!
      !! ** Purpose :   READ and PRINT options for the passive tracer run (namelist) 
      !!
      !! ** Method  : - read passive tracer namelist 
      !!              - read namelist of each defined SMS model
      !!                ( (LOBSTER, PISCES, CFC, MY_TRC )
      !!---------------------------------------------------------------------
      INTEGER ::  jn
      CHARACTER (len=32) ::   clname

      ! Definition of a tracer as a structure
      TYPE PTRACER
         CHARACTER(len = 20)  :: sname  !: short name
         CHARACTER(len = 80 ) :: lname  !: long name
         CHARACTER(len = 20 ) :: unit   !: unit
         LOGICAL              :: lini   !: read in a file or not
         LOGICAL              :: lsav   !: ouput the tracer or not 
      END TYPE PTRACER

      TYPE(PTRACER) , DIMENSION(jptra) :: tracer

      !!
      NAMELIST/namtoptrc/ ndttrc, nwritetrc, ln_rsttr, nrsttr, &
                          cn_trcrst_in, cn_trcrst_out, tracer
#if defined key_trdmld_trc || defined key_trc_diatrd
      NAMELIST/namtoptrd/ ntrd_trc, nctls_trc, ucf_trc, &
                         ln_trdmld_trc_restart, ln_trdmld_trc_instant, &
                         cn_trdrst_trc_in, cn_trdrst_trc_out, luttrd
#endif

      !!---------------------------------------------------------------------

      IF(lwp) WRITE(numout,*) 'trc_lec : read the passive tracer namelists'
      IF(lwp) WRITE(numout,*) '~~~~~~~'

      clname = 'namelist_top'
      CALL ctlopn( numnat, clname, 'OLD', 'FORMATTED', 'SEQUENTIAL', 1, numout, .FALSE., 1 )

      ! Namelist nattrc (files)
      ! ----------------------------------------------
      ndttrc    = 1                 ! default values
      nwritetrc = 10      
      ln_rsttr    = .FALSE.
      nrsttr    =  0
      cn_trcrst_in  = 'restart_trc'
      cn_trcrst_out = 'restart_trc'
      DO jn = 1, jptra
         WRITE(ctrcnm(jn),'("TR_",I1)'           ) jn
         WRITE(ctrcnl(jn),'("TRACER NUMBER ",I1)') jn
         ctrcun(jn) = 'mmole/m3'
         lutini(jn) = .FALSE. 
         lutsav(jn) = .TRUE.
      END DO

      REWIND( numnat )               ! read nattrc
      READ  ( numnat, namtoptrc )

      !!Chris  computes the first time step of tracer model
      nittrc000 = nit000 + ndttrc - 1

      DO jn = 1, jptra
         ctrcnm(jn) = tracer(jn)%sname
         ctrcnl(jn) = tracer(jn)%lname
         ctrcun(jn) = tracer(jn)%unit
         lutini(jn) = tracer(jn)%lini
         lutsav(jn) = tracer(jn)%lsav
      END DO


      IF(lwp) THEN                   ! control print
         WRITE(numout,*)
         WRITE(numout,*) ' Namelist : namtoptrc'
         WRITE(numout,*) '    time step freq. for pass. trac. ndttrc             = ', ndttrc
         WRITE(numout,*) '    1st time step for pass. trac. nittrc000            = ', nittrc000
         WRITE(numout,*) '    frequency of outputs for passive tracers nwritetrc = ', nwritetrc  
         WRITE(numout,*) '    restart LOGICAL for passive tr. ln_rsttr           = ', ln_rsttr
         WRITE(numout,*) '    control of time step for p. tr. nrsttr             = ', nrsttr
         WRITE(numout,*) ' '
         DO jn = 1, jptra
            WRITE(numout,*) '   tracer nb             : ', jn 
            WRITE(numout,*) '   short name            : ', TRIM(ctrcnm(jn))
            WRITE(numout,*) '   long name             : ', TRIM(ctrcnl(jn))
            WRITE(numout,*) '   unit                  : ', TRIM(ctrcun(jn))
            WRITE(numout,*) '   initial value in FILE : ', lutini(jn) 
            WRITE(numout,*) '   output of tracer      : ', lutsav(jn)
            WRITE(numout,*) ' '
         END DO
      ENDIF

#if defined key_trdmld_trc || defined key_trc_diatrd

      ! Namelist natrtd (transport trends)
      ! ----------------------------------------------
      ntrd_trc  = 20
      nctls_trc =  6
      ucf_trc   =  1.
      ln_trdmld_trc_instant = .TRUE.
      ln_trdmld_trc_restart =.FALSE.
      cn_trdrst_trc_in  = "restart_mld_trc"
      cn_trdrst_trc_out = "restart_mld_trc"
      DO jn = 1, jptra
         luttrd(jn) = .FALSE.
      END DO

      REWIND( numnat )               !  namelist namtoptrd : passive tracer trends diagnostic
      READ  ( numnat, namtoptrd )

#if defined key_trc_diatrd
      nkeep    = 0
      ikeep(:) = 0
      DO jn = 1, jptra
         IF( luttrd(jn) ) THEN 
             nkeep     = nkeep + 1
             ikeep(jn) = nkeep
         END IF 
      END DO
      IF( nkeep > 0 ) THEN  
        IF(.NOT. ALLOCATED( trtrd ) )   ALLOCATE( trtrd(jpi,jpj,jpk,nkeep,jpdiatrc) ) 
        trtrd(:,:,:,:,:) = 0.e0
      ENDIF 

      nwritetrd = ntrd_trc
#endif

     IF(lwp) THEN
         WRITE(numout,*)
         WRITE(numout,*) ' trd_mld_trc_init : read namelist namtoptrd                        '
         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~                                               '
         WRITE(numout,*) '   * frequency of trends diagnostics   ntrd_trc               = ', ntrd_trc
         WRITE(numout,*) '   * control surface type              nctls_trc              = ', nctls_trc
         WRITE(numout,*) '   * restart for ML diagnostics        ln_trdmld_trc_restart  = ', ln_trdmld_trc_restart
         WRITE(numout,*) '   * flag to diagnose trends of                                 '
         WRITE(numout,*) '     instantantaneous or mean ML T/S   ln_trdmld_trc_instant  = ', ln_trdmld_trc_instant
         WRITE(numout,*) '   * unit conversion factor            ucf_trc                = ', ucf_trc
#if defined key_trdmld_trc
         DO jn = 1, jptra
            WRITE(numout,*) '    keep dynamical trends for tracer number :', jn, luttrd(jn)
         END DO
#else
         DO jn = 1, jptra
            WRITE(numout,*) '    keep dynamical trends for tracer number :', jn, luttrd(jn), ikeep(jn)
         END DO

         WRITE(numout,*)
         WRITE(numout,*) '    total = ', nkeep, ' tracers dyn trends saved'
         WRITE(numout,*) '    size of trtrd = ', jpi*jpj*jpk*nkeep*jpdiatrc
#endif
      ENDIF

#endif


      ! namelist of transport
      ! ---------------------
      CALL trc_trp_lec

      ! namelist of SMS
      ! ---------------      
      IF( lk_lobster ) THEN   ;   CALL trc_lsm_lobster      ! LOBSTER bio-model
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          LOBSTER not used'
      ENDIF

      IF( lk_pisces  ) THEN   ;   CALL trc_lsm_pisces      ! PISCES  bio-model
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          PISCES not used'
      ENDIF

      IF( lk_cfc     ) THEN   ;   CALL trc_lsm_cfc         ! CFC     tracers
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          CFC not used'
      ENDIF

      IF( lk_c14b     ) THEN   ;   CALL trc_lsm_c14b         ! C14 bomb     tracers
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          C14 not used'
      ENDIF

      IF( lk_my_trc  ) THEN   ;   CALL trc_lsm_my_trc      ! MY_TRC  tracers
      ELSE                    ;   IF(lwp) WRITE(numout,*) '          MY_TRC not used'
      ENDIF
      !
   END SUBROUTINE trc_lec

#else
   !!----------------------------------------------------------------------
   !!  Dummy module :                                     No passive tracer
   !!----------------------------------------------------------------------
CONTAINS
   SUBROUTINE trc_lec                      ! Empty routine   
   END SUBROUTINE trc_lec
#endif

   !!======================================================================
END MODULE  trclec