New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limtrp_2.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_2 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_2/limtrp_2.F90 @ 3319

Last change on this file since 3319 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk
  • Property svn:keywords set to Id
File size: 16.8 KB
Line 
1MODULE limtrp_2
2   !!======================================================================
3   !!                       ***  MODULE limtrp_2   ***
4   !! LIM 2.0 transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6   !! History :  LIM  !  2000-01 (UCL)  Original code
7   !!            2.0  !  2001-05 (G. Madec, R. Hordoir) opa norm
8   !!             -   !  2004-01 (G. Madec, C. Ethe)  F90, mpp
9   !!            3.3  !  2009-05  (G. Garric, C. Bricaud) addition of the lim2_evp case
10   !!----------------------------------------------------------------------
11#if defined key_lim2
12   !!----------------------------------------------------------------------
13   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_trp_2      : advection/diffusion process of sea ice
16   !!   lim_trp_init_2 : initialization and namelist read
17   !!----------------------------------------------------------------------
18   USE phycst          ! physical constant
19   USE sbc_oce         ! ocean surface boundary condition
20   USE dom_oce         ! ocean domain
21   USE in_out_manager  ! I/O manager
22   USE dom_ice_2       ! LIM-2 domain
23   USE ice_2           ! LIM-2 variables
24   USE limistate_2     ! LIM-2 initial state
25   USE limadv_2        ! LIM-2 advection
26   USE limhdf_2        ! LIM-2 horizontal diffusion
27   USE lbclnk          ! lateral boundary conditions -- MPP exchanges
28   USE lib_mpp         ! MPP library
29   USE wrk_nemo        ! work arrays
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   lim_trp_2   ! called by sbc_ice_lim_2
35
36   REAL(wp), PUBLIC ::   bound  = 0.e0          !: boundary condit. (0.0 no-slip, 1.0 free-slip)
37
38   REAL(wp)  ::   epsi06 = 1.e-06   ! constant values
39   REAL(wp)  ::   epsi03 = 1.e-03 
40   REAL(wp)  ::   epsi16 = 1.e-16 
41   REAL(wp)  ::   rzero  = 0.e0   
42   REAL(wp)  ::   rone   = 1.e0
43
44   !! * Substitution
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE lim_trp_2( kt )
55      !!-------------------------------------------------------------------
56      !!                   ***  ROUTINE lim_trp_2 ***
57      !!                   
58      !! ** purpose : advection/diffusion process of sea ice
59      !!
60      !! ** method  : variables included in the process are scalar,   
61      !!     other values are considered as second order.
62      !!     For advection, a second order Prather scheme is used. 
63      !!
64      !! ** action :
65      !!---------------------------------------------------------------------
66      INTEGER, INTENT(in) ::   kt     ! number of iteration
67      !!
68      INTEGER  ::   ji, jj, jk   ! dummy loop indices
69      INTEGER  ::   initad       ! number of sub-timestep for the advection
70      REAL(wp) ::   zindb  , zindsn , zindic, zacrith   ! local scalars
71      REAL(wp) ::   zusvosn, zusvoic, zignm , zindhe    !   -      -
72      REAL(wp) ::   zvbord , zcfl   , zusnit            !   -      -
73      REAL(wp) ::   zrtt   , ztsn   , ztic1 , ztic2     !   -      -
74      REAL(wp), POINTER, DIMENSION(:,:)  ::   zui_u , zvi_v , zsm             ! 2D workspace
75      REAL(wp), POINTER, DIMENSION(:,:)  ::   zs0ice, zs0sn , zs0a            !  -      -
76      REAL(wp), POINTER, DIMENSION(:,:)  ::   zs0c0 , zs0c1 , zs0c2 , zs0st   !  -      -
77      !---------------------------------------------------------------------
78
79      CALL wrk_alloc( jpi, jpj, zui_u , zvi_v , zsm, zs0ice, zs0sn , zs0a, zs0c0 , zs0c1 , zs0c2 , zs0st )
80
81      IF( kt == nit000  )   CALL lim_trp_init_2      ! Initialization (first time-step only)
82
83      zsm(:,:) = area(:,:)
84     
85      IF( ln_limdyn ) THEN
86         !-------------------------------------!
87         !   Advection of sea ice properties   !
88         !-------------------------------------!
89
90         ! ice velocities at ocean U- and V-points (zui_u,zvi_v)
91         ! ---------------------------------------
92         IF( lk_lim2_vp ) THEN      ! VP rheology : B-grid sea-ice dynamics (I-point ice velocity)
93            zvbord = 1._wp + ( 1._wp - bound )      ! zvbord=2 no-slip, =0 free slip boundary conditions       
94            DO jj = 1, jpjm1
95               DO ji = 1, jpim1   ! NO vector opt.
96                  zui_u(ji,jj) = ( u_ice(ji+1,jj) + u_ice(ji+1,jj+1) ) / ( MAX( tmu(ji+1,jj)+tmu(ji+1,jj+1), zvbord ) )
97                  zvi_v(ji,jj) = ( v_ice(ji,jj+1) + v_ice(ji+1,jj+1) ) / ( MAX( tmu(ji,jj+1)+tmu(ji+1,jj+1), zvbord ) )
98               END DO
99            END DO
100            CALL lbc_lnk( zui_u, 'U', -1. )   ;   CALL lbc_lnk( zvi_v, 'V', -1. )      ! Lateral boundary conditions
101            !
102         ELSE                       ! EVP rheology : C-grid sea-ice dynamics (u- & v-points ice velocity)
103            zui_u(:,:) = u_ice(:,:)      ! EVP rheology: ice (u,v) at u- and v-points
104            zvi_v(:,:) = v_ice(:,:)
105         ENDIF
106
107         ! CFL test for stability
108         ! ----------------------
109         zcfl  = 0._wp
110         zcfl  = MAX( zcfl, MAXVAL( ABS( zui_u(1:jpim1, :     ) ) * rdt_ice / e1u(1:jpim1, :     ) ) )
111         zcfl  = MAX( zcfl, MAXVAL( ABS( zvi_v( :     ,1:jpjm1) ) * rdt_ice / e2v( :     ,1:jpjm1) ) )
112         !
113         IF(lk_mpp)   CALL mpp_max( zcfl )
114         !
115         IF( zcfl > 0.5 .AND. lwp )   WRITE(numout,*) 'lim_trp_2 : violation of cfl criterion the ',nday,'th day, cfl = ', zcfl
116
117         ! content of properties
118         ! ---------------------
119         zs0sn (:,:) =  hsnm(:,:)              * area  (:,:)  ! Snow volume.
120         zs0ice(:,:) =  hicm(:,:)              * area  (:,:)  ! Ice volume.
121         zs0a  (:,:) =  ( 1.0 - frld(:,:) )    * area  (:,:)  ! Surface covered by ice.
122         zs0c0 (:,:) =  tbif(:,:,1) / rt0_snow * zs0sn (:,:)  ! Heat content of the snow layer.
123         zs0c1 (:,:) =  tbif(:,:,2) / rt0_ice  * zs0ice(:,:)  ! Heat content of the first ice layer.
124         zs0c2 (:,:) =  tbif(:,:,3) / rt0_ice  * zs0ice(:,:)  ! Heat content of the second ice layer.
125         zs0st (:,:) =  qstoif(:,:) / xlic     * zs0a  (:,:)  ! Heat reservoir for brine pockets.
126         
127 
128         ! Advection (Prather scheme)
129         ! ---------
130         initad = 1 + INT( MAX( rzero, SIGN( rone, zcfl-0.5 ) ) )   ! If ice drift field is too fast,         
131         zusnit = 1.0 / REAL( initad )                              ! split the ice time step in two
132         !
133         IF( MOD( ( kt - 1) / nn_fsbc , 2 ) == 0) THEN        !==  odd ice time step:  adv_x then adv_y  ==!
134            DO jk = 1, initad
135               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
136               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
137               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
138               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
139               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
140               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
141               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
142               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
143               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
144               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
145               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
146               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
147               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
148               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
149            END DO
150         ELSE                                                 !==  even ice time step:  adv_x then adv_y  ==!
151            DO jk = 1, initad
152               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
153               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
154               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
155               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
156               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
157               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
158               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
159               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
160               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
161               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
162               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
163               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
164               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
165               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
166            END DO
167         ENDIF
168                       
169         ! recover the properties from their contents
170         ! ------------------------------------------
171!!gm Define in limmsh one for all area = 1 /area  (CPU time saved !)
172         zs0ice(:,:) = zs0ice(:,:) / area(:,:)
173         zs0sn (:,:) = zs0sn (:,:) / area(:,:)
174         zs0a  (:,:) = zs0a  (:,:) / area(:,:)
175         zs0c0 (:,:) = zs0c0 (:,:) / area(:,:)
176         zs0c1 (:,:) = zs0c1 (:,:) / area(:,:)
177         zs0c2 (:,:) = zs0c2 (:,:) / area(:,:)
178         zs0st (:,:) = zs0st (:,:) / area(:,:)
179
180
181         !-------------------------------------!
182         !   Diffusion of sea ice properties   !
183         !-------------------------------------!
184
185         ! Masked eddy diffusivity coefficient at ocean U- and V-points
186         ! ------------------------------------------------------------
187         DO jj = 1, jpjm1          ! NB: has not to be defined on jpj line and jpi row
188            DO ji = 1 , fs_jpim1   ! vector opt.
189               pahu(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji  ,jj) ) ) )   &
190                  &        * ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji+1,jj) ) ) ) * ahiu(ji,jj)
191               pahv(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji,jj  ) ) ) )   &
192                  &        * ( 1.0 - MAX( rzero, SIGN( rone,- zs0a(ji,jj+1) ) ) ) * ahiv(ji,jj)
193            END DO
194         END DO
195!!gm more readable coding: (and avoid an error in F90 with sign of zero)
196!        DO jj = 1, jpjm1          ! NB: has not to be defined on jpj line and jpi row
197!           DO ji = 1 , fs_jpim1   ! vector opt.
198!              IF( MIN( zs0a(ji,jj) , zs0a(ji+1,jj) ) == 0.e0 )   pahu(ji,jj) = 0._wp
199!              IF( MIN( zs0a(ji,jj) , zs0a(ji,jj+1) ) == 0.e0 )   pahv(ji,jj) = 0._wp
200!           END DO
201!        END DO
202!!gm end
203
204         ! diffusion
205         ! ---------
206         CALL lim_hdf_2( zs0ice )
207         CALL lim_hdf_2( zs0sn  )
208         CALL lim_hdf_2( zs0a   )
209         CALL lim_hdf_2( zs0c0  )
210         CALL lim_hdf_2( zs0c1  )
211         CALL lim_hdf_2( zs0c2  )
212         CALL lim_hdf_2( zs0st  )
213
214!!gm see comment this can be skipped
215         zs0ice(:,:) = MAX( rzero, zs0ice(:,:) * area(:,:) )    !!bug:  useless
216         zs0sn (:,:) = MAX( rzero, zs0sn (:,:) * area(:,:) )    !!bug:  cf /area  just below
217         zs0a  (:,:) = MAX( rzero, zs0a  (:,:) * area(:,:) )    !! caution: the suppression of the 2 changes
218         zs0c0 (:,:) = MAX( rzero, zs0c0 (:,:) * area(:,:) )    !! the last digit of the results
219         zs0c1 (:,:) = MAX( rzero, zs0c1 (:,:) * area(:,:) )
220         zs0c2 (:,:) = MAX( rzero, zs0c2 (:,:) * area(:,:) )
221         zs0st (:,:) = MAX( rzero, zs0st (:,:) * area(:,:) )
222
223
224         !-------------------------------------------------------------------!
225         !   Updating and limitation of sea ice properties after transport   !
226         !-------------------------------------------------------------------!
227         DO jj = 1, jpj
228            zindhe = MAX( 0.e0, SIGN( 1.e0, fcor(1,jj) ) )              ! = 0 for SH, =1 for NH
229            DO ji = 1, jpi
230               !
231               ! Recover mean values over the grid squares.
232               zs0sn (ji,jj) = MAX( rzero, zs0sn (ji,jj)/area(ji,jj) )
233               zs0ice(ji,jj) = MAX( rzero, zs0ice(ji,jj)/area(ji,jj) )
234               zs0a  (ji,jj) = MAX( rzero, zs0a  (ji,jj)/area(ji,jj) )
235               zs0c0 (ji,jj) = MAX( rzero, zs0c0 (ji,jj)/area(ji,jj) )
236               zs0c1 (ji,jj) = MAX( rzero, zs0c1 (ji,jj)/area(ji,jj) )
237               zs0c2 (ji,jj) = MAX( rzero, zs0c2 (ji,jj)/area(ji,jj) )
238               zs0st (ji,jj) = MAX( rzero, zs0st (ji,jj)/area(ji,jj) )
239
240               ! Recover in situ values.
241               zindb         = MAX( rzero, SIGN( rone, zs0a(ji,jj) - epsi06 ) )
242               zacrith       = 1.0 - ( zindhe * acrit(1) + ( 1.0 - zindhe ) * acrit(2) )
243               zs0a (ji,jj)  = zindb * MIN( zs0a(ji,jj), zacrith )
244               hsnif(ji,jj)  = zindb * ( zs0sn(ji,jj) /MAX( zs0a(ji,jj), epsi16 ) )
245               hicif(ji,jj)  = zindb * ( zs0ice(ji,jj)/MAX( zs0a(ji,jj), epsi16 ) )
246               zindsn        = MAX( rzero, SIGN( rone, hsnif(ji,jj) - epsi06 ) )
247               zindic        = MAX( rzero, SIGN( rone, hicif(ji,jj) - epsi03 ) )
248               zindb         = MAX( zindsn, zindic )
249               zs0a (ji,jj)  = zindb * zs0a(ji,jj)
250               frld (ji,jj)  = 1.0 - zs0a(ji,jj)
251               hsnif(ji,jj)  = zindsn * hsnif(ji,jj)
252               hicif(ji,jj)  = zindic * hicif(ji,jj)
253               zusvosn       = 1.0/MAX( hsnif(ji,jj) * zs0a(ji,jj), epsi16 )
254               zusvoic       = 1.0/MAX( hicif(ji,jj) * zs0a(ji,jj), epsi16 )
255               zignm         = MAX( rzero,  SIGN( rone, hsndif - hsnif(ji,jj) ) )
256               zrtt          = 173.15 * rone 
257               ztsn          =          zignm   * tbif(ji,jj,1)  &
258                              + ( 1.0 - zignm ) * MIN( MAX( zrtt, rt0_snow * zusvosn * zs0c0(ji,jj)) , tfu(ji,jj) ) 
259               ztic1          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c1(ji,jj) ) , tfu(ji,jj) )
260               ztic2          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c2(ji,jj) ) , tfu(ji,jj) )
261 
262               tbif(ji,jj,1) = zindsn * ztsn  + ( 1.0 - zindsn ) * tfu(ji,jj)               
263               tbif(ji,jj,2) = zindic * ztic1 + ( 1.0 - zindic ) * tfu(ji,jj)
264               tbif(ji,jj,3) = zindic * ztic2 + ( 1.0 - zindic ) * tfu(ji,jj)
265               qstoif(ji,jj) = zindb  * xlic * zs0st(ji,jj) /  MAX( zs0a(ji,jj), epsi16 )
266            END DO
267         END DO
268         !
269      ENDIF
270      !
271      CALL wrk_dealloc( jpi, jpj, zui_u , zvi_v , zsm, zs0ice, zs0sn , zs0a, zs0c0 , zs0c1 , zs0c2 , zs0st )
272      !
273   END SUBROUTINE lim_trp_2
274
275
276   SUBROUTINE lim_trp_init_2
277      !!-------------------------------------------------------------------
278      !!                  ***  ROUTINE lim_trp_init_2  ***
279      !!
280      !! ** Purpose :   initialization of ice advection parameters
281      !!
282      !! ** Method  :   Read the namicetrp namelist and check the parameter
283      !!              values called at the first timestep (nit000)
284      !!
285      !! ** input   :   Namelist namicetrp
286      !!-------------------------------------------------------------------
287      NAMELIST/namicetrp/ bound
288      !!-------------------------------------------------------------------
289      !
290      REWIND ( numnam_ice )      ! Read Namelist namicetrp
291      READ   ( numnam_ice  , namicetrp )
292      IF(lwp) THEN
293         WRITE(numout,*)
294         WRITE(numout,*) 'lim_trp_init_2 : Ice parameters for advection '
295         WRITE(numout,*) '~~~~~~~~~~~~~~'
296         WRITE(numout,*) '   boundary conditions (0. no-slip, 1. free-slip) bound  = ', bound
297      ENDIF
298      !
299   END SUBROUTINE lim_trp_init_2
300
301#else
302   !!----------------------------------------------------------------------
303   !!   Default option         Empty Module                No sea-ice model
304   !!----------------------------------------------------------------------
305CONTAINS
306   SUBROUTINE lim_trp_2        ! Empty routine
307   END SUBROUTINE lim_trp_2
308#endif
309
310   !!======================================================================
311END MODULE limtrp_2
Note: See TracBrowser for help on using the repository browser.