| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | #if defined key_lim3 |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 17 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE par_oce ! ocean parameters |
|---|
| 20 | USE par_ice ! ice parameters |
|---|
| 21 | USE dom_oce ! ocean domain |
|---|
| 22 | USE sbc_ice ! Surface boundary condition: sea-ice fields |
|---|
| 23 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 24 | USE phycst ! physical constants |
|---|
| 25 | USE albedo ! albedo parameters |
|---|
| 26 | USE ice ! LIM sea-ice variables |
|---|
| 27 | USE lbclnk ! ocean lateral boundary condition |
|---|
| 28 | USE in_out_manager ! I/O manager |
|---|
| 29 | USE prtctl ! Print control |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC lim_sbc_flx ! called by sbc_ice_lim |
|---|
| 35 | PUBLIC lim_sbc_tau ! called by sbc_ice_lim |
|---|
| 36 | |
|---|
| 37 | REAL(wp) :: r1_rdtice ! = 1. / rdt_ice |
|---|
| 38 | REAL(wp) :: epsi16 = 1.e-16_wp ! constant values |
|---|
| 39 | REAL(wp) :: rzero = 0._wp |
|---|
| 40 | REAL(wp) :: rone = 1._wp |
|---|
| 41 | |
|---|
| 42 | REAL(wp), DIMENSION(jpi,jpj) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 43 | REAL(wp), DIMENSION(jpi,jpj) :: tmod_io ! modulus of the ice-ocean relative velocity [m/s] |
|---|
| 44 | |
|---|
| 45 | REAL(wp), DIMENSION(jpi,jpj) :: soce_0, sice_0 ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 46 | |
|---|
| 47 | !! * Substitutions |
|---|
| 48 | # include "vectopt_loop_substitute.h90" |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010) |
|---|
| 51 | !! $Id$ |
|---|
| 52 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | CONTAINS |
|---|
| 55 | |
|---|
| 56 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 57 | !!------------------------------------------------------------------- |
|---|
| 58 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 59 | !! |
|---|
| 60 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 61 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 62 | !! |
|---|
| 63 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 64 | !! at the ice-ocean interface. |
|---|
| 65 | !! - Update the ocean sbc |
|---|
| 66 | !! |
|---|
| 67 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 68 | !! - qns : sea heat flux: non solar |
|---|
| 69 | !! - emp : freshwater budget: volume flux |
|---|
| 70 | !! - emps : freshwater budget: concentration/dillution |
|---|
| 71 | !! - fr_i : ice fraction |
|---|
| 72 | !! - tn_ice : sea-ice surface temperature |
|---|
| 73 | !! - alb_ice : sea-ice alberdo (lk_cpl=T) |
|---|
| 74 | !! |
|---|
| 75 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 76 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 77 | !!--------------------------------------------------------------------- |
|---|
| 78 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 79 | !! |
|---|
| 80 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 81 | INTEGER :: ifvt, i1mfr, idfr ! some switches |
|---|
| 82 | INTEGER :: iflt, ial, iadv, ifral, ifrdv |
|---|
| 83 | REAL(wp) :: zinda ! switch for testing the values of ice concentration |
|---|
| 84 | REAL(wp) :: zfons ! salt exchanges at the ice/ocean interface |
|---|
| 85 | REAL(wp) :: zpme ! freshwater exchanges at the ice/ocean interface |
|---|
| 86 | REAL(wp), DIMENSION(jpi,jpj) :: zfcm1 , zfcm2 ! solar/non solar heat fluxes |
|---|
| 87 | #if defined key_coupled |
|---|
| 88 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalb ! albedo of ice under overcast sky |
|---|
| 89 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalbp ! albedo of ice under clear sky |
|---|
| 90 | #endif |
|---|
| 91 | !!--------------------------------------------------------------------- |
|---|
| 92 | |
|---|
| 93 | IF( kt == nit000 ) THEN |
|---|
| 94 | IF(lwp) WRITE(numout,*) |
|---|
| 95 | IF(lwp) WRITE(numout,*) 'lim_sbc_flx : LIM 3.0 sea-ice - heat salt and mass ocean surface fluxes' |
|---|
| 96 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ ' |
|---|
| 97 | ! |
|---|
| 98 | r1_rdtice = 1. / rdt_ice |
|---|
| 99 | ! |
|---|
| 100 | soce_0(:,:) = soce |
|---|
| 101 | sice_0(:,:) = sice |
|---|
| 102 | ! |
|---|
| 103 | IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 104 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 105 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 106 | soce_0(:,:) = 4._wp |
|---|
| 107 | sice_0(:,:) = 2._wp |
|---|
| 108 | END WHERE |
|---|
| 109 | ENDIF |
|---|
| 110 | ! |
|---|
| 111 | ENDIF |
|---|
| 112 | |
|---|
| 113 | !------------------------------------------! |
|---|
| 114 | ! heat flux at the ocean surface ! |
|---|
| 115 | !------------------------------------------! |
|---|
| 116 | ! pfrld is the lead fraction at the previous time step (actually between TRP and THD) |
|---|
| 117 | ! changed to old_frld and old ht_i |
|---|
| 118 | |
|---|
| 119 | DO jj = 1, jpj |
|---|
| 120 | DO ji = 1, jpi |
|---|
| 121 | zinda = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 122 | ifvt = zinda * MAX( rzero , SIGN( rone, -phicif (ji,jj) ) ) !subscripts are bad here |
|---|
| 123 | i1mfr = 1.0 - MAX( rzero , SIGN( rone , - ( at_i(ji,jj) ) ) ) |
|---|
| 124 | idfr = 1.0 - MAX( rzero , SIGN( rone , ( 1.0 - at_i(ji,jj) ) - pfrld(ji,jj) ) ) |
|---|
| 125 | iflt = zinda * (1 - i1mfr) * (1 - ifvt ) |
|---|
| 126 | ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
|---|
| 127 | iadv = ( 1 - i1mfr ) * zinda |
|---|
| 128 | ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
|---|
| 129 | ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
|---|
| 130 | |
|---|
| 131 | ! switch --- 1.0 ---------------- 0.0 -------------------- |
|---|
| 132 | ! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ |
|---|
| 133 | ! zinda | if pfrld = 1 | if pfrld < 1 | |
|---|
| 134 | ! -> ifvt| if pfrld old_ht_i |
|---|
| 135 | ! i1mfr | if frld = 1 | if frld < 1 | |
|---|
| 136 | ! idfr | if frld <= pfrld | if frld > pfrld | |
|---|
| 137 | ! iflt | |
|---|
| 138 | ! ial | |
|---|
| 139 | ! iadv | |
|---|
| 140 | ! ifral |
|---|
| 141 | ! ifrdv |
|---|
| 142 | |
|---|
| 143 | ! computation the solar flux at ocean surface |
|---|
| 144 | zfcm1(ji,jj) = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 145 | ! fstric Solar flux transmitted trough the ice |
|---|
| 146 | ! qsr Net short wave heat flux on free ocean |
|---|
| 147 | ! new line |
|---|
| 148 | fscmbq(ji,jj) = ( 1.0 - pfrld(ji,jj) ) * fstric(ji,jj) |
|---|
| 149 | |
|---|
| 150 | ! computation the non solar heat flux at ocean surface |
|---|
| 151 | zfcm2(ji,jj) = - zfcm1(ji,jj) & |
|---|
| 152 | & + iflt * ( fscmbq(ji,jj) ) & ! total abl -> fscmbq is given to the ocean |
|---|
| 153 | ! fscmbq and ffltbif are obsolete |
|---|
| 154 | ! & + iflt * ffltbif(ji,jj) !!! only if one category is used |
|---|
| 155 | & + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice & |
|---|
| 156 | & + ifrdv * ( qfvbq(ji,jj) + qdtcn(ji,jj) ) * r1_rdtice & |
|---|
| 157 | & + fhmec(ji,jj) & ! new contribution due to snow melt in ridging!! |
|---|
| 158 | & + fheat_rpo(ji,jj) & ! contribution from ridge formation |
|---|
| 159 | & + fheat_res(ji,jj) |
|---|
| 160 | ! fscmbq Part of the solar radiation transmitted through the ice and going to the ocean |
|---|
| 161 | ! computed in limthd_zdf.F90 |
|---|
| 162 | ! ffltbif Total heat content of the ice (brine pockets+ice) / delta_t |
|---|
| 163 | ! qcmif Energy needed to bring the ocean surface layer until its freezing (ok) |
|---|
| 164 | ! qldif heat balance of the lead (or of the open ocean) |
|---|
| 165 | ! qfvbq i think this is wrong! |
|---|
| 166 | ! ---> Array used to store energy in case of total lateral ablation |
|---|
| 167 | ! qfvbq latent heat uptake/release after accretion/ablation |
|---|
| 168 | ! qdtcn Energy from the turbulent oceanic heat flux heat flux coming in the lead |
|---|
| 169 | |
|---|
| 170 | IF ( num_sal .EQ. 2 ) zfcm2(ji,jj) = zfcm2(ji,jj) + & |
|---|
| 171 | fhbri(ji,jj) ! new contribution due to brine drainage |
|---|
| 172 | |
|---|
| 173 | ! bottom radiative component is sent to the computation of the |
|---|
| 174 | ! oceanic heat flux |
|---|
| 175 | fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj) |
|---|
| 176 | |
|---|
| 177 | ! used to compute the oceanic heat flux at the next time step |
|---|
| 178 | qsr(ji,jj) = zfcm1(ji,jj) ! solar heat flux |
|---|
| 179 | qns(ji,jj) = zfcm2(ji,jj) - fdtcn(ji,jj) ! non solar heat flux |
|---|
| 180 | ! ! fdtcn : turbulent oceanic heat flux |
|---|
| 181 | |
|---|
| 182 | !!gm this IF prevents the vertorisation of the whole loop |
|---|
| 183 | IF ( ( ji .EQ. jiindx ) .AND. ( jj .EQ. jjindx) ) THEN |
|---|
| 184 | WRITE(numout,*) ' lim_sbc : heat fluxes ' |
|---|
| 185 | WRITE(numout,*) ' qsr : ', qsr(jiindx,jjindx) |
|---|
| 186 | WRITE(numout,*) ' zfcm1 : ', zfcm1(jiindx,jjindx) |
|---|
| 187 | WRITE(numout,*) ' pfrld : ', pfrld(jiindx,jjindx) |
|---|
| 188 | WRITE(numout,*) ' fstric : ', fstric (jiindx,jjindx) |
|---|
| 189 | WRITE(numout,*) |
|---|
| 190 | WRITE(numout,*) ' qns : ', qns(jiindx,jjindx) |
|---|
| 191 | WRITE(numout,*) ' zfcm2 : ', zfcm2(jiindx,jjindx) |
|---|
| 192 | WRITE(numout,*) ' zfcm1 : ', zfcm1(jiindx,jjindx) |
|---|
| 193 | WRITE(numout,*) ' ifral : ', ifral |
|---|
| 194 | WRITE(numout,*) ' ial : ', ial |
|---|
| 195 | WRITE(numout,*) ' qcmif : ', qcmif(jiindx,jjindx) |
|---|
| 196 | WRITE(numout,*) ' qldif : ', qldif(jiindx,jjindx) |
|---|
| 197 | WRITE(numout,*) ' qcmif / dt: ', qcmif(jiindx,jjindx) * r1_rdtice |
|---|
| 198 | WRITE(numout,*) ' qldif / dt: ', qldif(jiindx,jjindx) * r1_rdtice |
|---|
| 199 | WRITE(numout,*) ' ifrdv : ', ifrdv |
|---|
| 200 | WRITE(numout,*) ' qfvbq : ', qfvbq(jiindx,jjindx) |
|---|
| 201 | WRITE(numout,*) ' qdtcn : ', qdtcn(jiindx,jjindx) |
|---|
| 202 | WRITE(numout,*) ' qfvbq / dt: ', qfvbq(jiindx,jjindx) * r1_rdtice |
|---|
| 203 | WRITE(numout,*) ' qdtcn / dt: ', qdtcn(jiindx,jjindx) * r1_rdtice |
|---|
| 204 | WRITE(numout,*) ' ' |
|---|
| 205 | WRITE(numout,*) ' fdtcn : ', fdtcn(jiindx,jjindx) |
|---|
| 206 | WRITE(numout,*) ' fhmec : ', fhmec(jiindx,jjindx) |
|---|
| 207 | WRITE(numout,*) ' fheat_rpo : ', fheat_rpo(jiindx,jjindx) |
|---|
| 208 | WRITE(numout,*) ' fhbri : ', fhbri(jiindx,jjindx) |
|---|
| 209 | WRITE(numout,*) ' fheat_res : ', fheat_res(jiindx,jjindx) |
|---|
| 210 | ENDIF |
|---|
| 211 | !!gm end |
|---|
| 212 | END DO |
|---|
| 213 | END DO |
|---|
| 214 | |
|---|
| 215 | !------------------------------------------! |
|---|
| 216 | ! mass flux at the ocean surface ! |
|---|
| 217 | !------------------------------------------! |
|---|
| 218 | |
|---|
| 219 | !!gm optimisation: this loop have to be merged with the previous one |
|---|
| 220 | DO jj = 1, jpj |
|---|
| 221 | DO ji = 1, jpi |
|---|
| 222 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 223 | ! ------------------------------------------------------------------------------------- |
|---|
| 224 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 225 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 226 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 227 | ! Associated to Ice formation AND Ice melting |
|---|
| 228 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 229 | ! |
|---|
| 230 | |
|---|
| 231 | ! computing freshwater exchanges at the ice/ocean interface |
|---|
| 232 | zpme = - emp(ji,jj) * ( 1.0 - at_i(ji,jj) ) & ! evaporation over oceanic fraction |
|---|
| 233 | & + tprecip(ji,jj) * at_i(ji,jj) & ! all precipitation reach the ocean |
|---|
| 234 | & - sprecip(ji,jj) * ( 1. - (pfrld(ji,jj)**betas) ) & ! except solid precip intercepted by sea-ice |
|---|
| 235 | & - rdmsnif(ji,jj) * r1_rdtice & ! freshwaterflux due to snow melting |
|---|
| 236 | & + fmmec(ji,jj) ! snow falling when ridging |
|---|
| 237 | |
|---|
| 238 | |
|---|
| 239 | ! computing salt exchanges at the ice/ocean interface |
|---|
| 240 | ! sice should be the same as computed with the ice model |
|---|
| 241 | zfons = ( soce_0(ji,jj) - sice_0(ji,jj) ) * rdmicif(ji,jj) * r1_rdtice |
|---|
| 242 | ! SOCE |
|---|
| 243 | zfons = ( sss_m (ji,jj) - sice_0(ji,jj) ) * rdmicif(ji,jj) * r1_rdtice |
|---|
| 244 | |
|---|
| 245 | !CT useless ! salt flux for constant salinity |
|---|
| 246 | !CT useless fsalt(ji,jj) = zfons / ( sss_m(ji,jj) + epsi16 ) + fsalt_res(ji,jj) |
|---|
| 247 | ! salt flux for variable salinity |
|---|
| 248 | zinda = 1.0 - MAX( rzero , SIGN( rone , - ( 1.0 - pfrld(ji,jj) ) ) ) |
|---|
| 249 | ! correcting brine and salt fluxes |
|---|
| 250 | fsbri(ji,jj) = zinda*fsbri(ji,jj) |
|---|
| 251 | ! converting the salt fluxes from ice to a freshwater flux from ocean |
|---|
| 252 | fsalt_res(ji,jj) = fsalt_res(ji,jj) / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 253 | fseqv(ji,jj) = fseqv(ji,jj) / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 254 | fsbri(ji,jj) = fsbri(ji,jj) / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 255 | fsalt_rpo(ji,jj) = fsalt_rpo(ji,jj) / ( sss_m(ji,jj) + epsi16 ) |
|---|
| 256 | |
|---|
| 257 | ! freshwater mass exchange (positive to the ice, negative for the ocean ?) |
|---|
| 258 | ! actually it's a salt flux (so it's minus freshwater flux) |
|---|
| 259 | ! if sea ice grows, zfons is positive, fsalt also |
|---|
| 260 | ! POSITIVE SALT FLUX FROM THE ICE TO THE OCEAN |
|---|
| 261 | ! POSITIVE FRESHWATER FLUX FROM THE OCEAN TO THE ICE [kg.m-2.s-1] |
|---|
| 262 | |
|---|
| 263 | emp(ji,jj) = - zpme |
|---|
| 264 | END DO |
|---|
| 265 | END DO |
|---|
| 266 | |
|---|
| 267 | IF( num_sal == 2 ) THEN ! variable ice salinity: brine drainage included in the salt flux |
|---|
| 268 | emps(:,:) = fsbri(:,:) + fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) + emp(:,:) |
|---|
| 269 | ELSE ! constant ice salinity: |
|---|
| 270 | emps(:,:) = fseqv(:,:) + fsalt_res(:,:) + fsalt_rpo(:,:) + emp(:,:) |
|---|
| 271 | ENDIF |
|---|
| 272 | |
|---|
| 273 | !-----------------------------------------------! |
|---|
| 274 | ! Storing the transmitted variables ! |
|---|
| 275 | !-----------------------------------------------! |
|---|
| 276 | |
|---|
| 277 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 278 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 279 | |
|---|
| 280 | #if defined key_coupled |
|---|
| 281 | !------------------------------------------------! |
|---|
| 282 | ! Computation of snow/ice and ocean albedo ! |
|---|
| 283 | !------------------------------------------------! |
|---|
| 284 | zalb (:,:,:) = 0.e0 |
|---|
| 285 | zalbp (:,:,:) = 0.e0 |
|---|
| 286 | |
|---|
| 287 | CALL albedo_ice( t_su, ht_i, ht_s, zalbp, zalb ) |
|---|
| 288 | |
|---|
| 289 | alb_ice(:,:,:) = 0.5 * zalbp(:,:,:) + 0.5 * zalb (:,:,:) ! Ice albedo (mean clear and overcast skys) |
|---|
| 290 | #endif |
|---|
| 291 | |
|---|
| 292 | IF(ln_ctl) THEN |
|---|
| 293 | CALL prt_ctl( tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ' ) |
|---|
| 294 | CALL prt_ctl( tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=emps, clinfo2=' emps : ' ) |
|---|
| 295 | CALL prt_ctl( tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ' ) |
|---|
| 296 | CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl ) |
|---|
| 297 | ENDIF |
|---|
| 298 | ! |
|---|
| 299 | END SUBROUTINE lim_sbc_flx |
|---|
| 300 | |
|---|
| 301 | |
|---|
| 302 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 303 | !!------------------------------------------------------------------- |
|---|
| 304 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 305 | !! |
|---|
| 306 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 307 | !! |
|---|
| 308 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 309 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 310 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 311 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 312 | !! - update the modulus of stress at ocean surface |
|---|
| 313 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
|---|
| 314 | !! * at each ocean time step (every kt): |
|---|
| 315 | !! compute linearized ice-ocean stresses as |
|---|
| 316 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 317 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 318 | !! |
|---|
| 319 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 320 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 321 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 322 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 323 | !! |
|---|
| 324 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 325 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 326 | !!--------------------------------------------------------------------- |
|---|
| 327 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 328 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 329 | !! |
|---|
| 330 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 331 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 332 | REAL(wp) :: zat_v, zvtau_ice, zv_t ! - - |
|---|
| 333 | !!--------------------------------------------------------------------- |
|---|
| 334 | |
|---|
| 335 | IF( kt == nit000 ) THEN |
|---|
| 336 | IF(lwp) WRITE(numout,*) |
|---|
| 337 | IF(lwp) WRITE(numout,*) 'lim_sbc_tau : LIM-3 sea-ice - surface ocean momentum fluxes' |
|---|
| 338 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ ' |
|---|
| 339 | ENDIF |
|---|
| 340 | |
|---|
| 341 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 342 | !CDIR NOVERRCHK |
|---|
| 343 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 344 | !CDIR NOVERRCHK |
|---|
| 345 | DO ji = fs_2, fs_jpim1 |
|---|
| 346 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 347 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 348 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 349 | ! ! |U_ice-U_oce|^2 |
|---|
| 350 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 351 | ! ! update the ocean stress modulus |
|---|
| 352 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt |
|---|
| 353 | tmod_io(ji,jj) = rhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 354 | END DO |
|---|
| 355 | END DO |
|---|
| 356 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
|---|
| 357 | ! |
|---|
| 358 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 359 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 360 | ! |
|---|
| 361 | ENDIF |
|---|
| 362 | ! |
|---|
| 363 | ! !== every ocean time-step ==! |
|---|
| 364 | ! |
|---|
| 365 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 366 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 367 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 368 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 369 | ! ! linearized quadratic drag formulation |
|---|
| 370 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 371 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 372 | ! ! stresses at the ocean surface |
|---|
| 373 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 374 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 375 | END DO |
|---|
| 376 | END DO |
|---|
| 377 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 378 | ! |
|---|
| 379 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
|---|
| 380 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
|---|
| 381 | ! |
|---|
| 382 | END SUBROUTINE lim_sbc_tau |
|---|
| 383 | |
|---|
| 384 | #else |
|---|
| 385 | !!---------------------------------------------------------------------- |
|---|
| 386 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 387 | !!---------------------------------------------------------------------- |
|---|
| 388 | CONTAINS |
|---|
| 389 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 390 | END SUBROUTINE lim_sbc |
|---|
| 391 | #endif |
|---|
| 392 | |
|---|
| 393 | !!====================================================================== |
|---|
| 394 | END MODULE limsbc |
|---|
