New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 5167

Last change on this file since 5167 was 5167, checked in by clem, 9 years ago

LIM3 bug fix. see ticket #1492 (forthcoming update) which also solve ticket #1497
  • Property svn:keywords set to Id
File size: 40.0 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE oce     , ONLY : fraqsr_1lev 
25   USE ice            ! LIM: sea-ice variables
26   USE sbc_oce        ! Surface boundary condition: ocean fields
27   USE sbc_ice        ! Surface boundary condition: ice fields
28   USE thd_ice        ! LIM thermodynamic sea-ice variables
29   USE dom_ice        ! LIM sea-ice domain
30   USE domvvl         ! domain: variable volume level
31   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
32   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
33   USE limthd_sal     ! LIM: thermodynamics, ice salinity
34   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
35   USE limthd_lac     ! LIM-3 lateral accretion
36   USE limitd_th      ! remapping thickness distribution
37   USE limtab         ! LIM: 1D <==> 2D transformation
38   USE limvar         ! LIM: sea-ice variables
39   USE lbclnk         ! lateral boundary condition - MPP links
40   USE lib_mpp        ! MPP library
41   USE wrk_nemo       ! work arrays
42   USE in_out_manager ! I/O manager
43   USE prtctl         ! Print control
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45   USE timing         ! Timing
46   USE limcons        ! conservation tests
47   USE limctl
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   lim_thd        ! called by limstp module
53   PUBLIC   lim_thd_init   ! called by sbc_lim_init
54
55   !! * Substitutions
56#  include "domzgr_substitute.h90"
57#  include "vectopt_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE lim_thd( kt )
66      !!-------------------------------------------------------------------
67      !!                ***  ROUTINE lim_thd  ***       
68      !! 
69      !! ** Purpose : This routine manages ice thermodynamics
70      !!         
71      !! ** Action : - Initialisation of some variables
72      !!             - Some preliminary computation (oceanic heat flux
73      !!               at the ice base, snow acc.,heat budget of the leads)
74      !!             - selection of the icy points and put them in an array
75      !!             - call lim_thd_dif  for vertical heat diffusion
76      !!             - call lim_thd_dh   for vertical ice growth and melt
77      !!             - call lim_thd_ent  for enthalpy remapping
78      !!             - call lim_thd_sal  for ice desalination
79      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
80      !!             - back to the geographic grid
81      !!     
82      !! ** References :
83      !!---------------------------------------------------------------------
84      INTEGER, INTENT(in) :: kt    ! number of iteration
85      !!
86      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
87      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
88      INTEGER  :: ii, ij           ! temporary dummy loop index
89      REAL(wp) :: zfric_u, zqld, zqfr
90      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
91      REAL(wp), PARAMETER :: zfric_umin = 0._wp        ! lower bound for the friction velocity (cice value=5.e-04)
92      REAL(wp), PARAMETER :: zch        = 0.0057_wp    ! heat transfer coefficient
93      !
94      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
95      !!-------------------------------------------------------------------
96      CALL wrk_alloc( jpi,jpj, zqsr, zqns )
97
98      IF( nn_timing == 1 )  CALL timing_start('limthd')
99
100      ! conservation test
101      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
102
103      CALL lim_var_glo2eqv
104      !------------------------------------------------------------------------!
105      ! 1) Initialization of some variables                                    !
106      !------------------------------------------------------------------------!
107      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
108
109      !--------------------
110      ! 1.2) Heat content   
111      !--------------------
112      ! Change the units of heat content; from J/m2 to J/m3
113      DO jl = 1, jpl
114         DO jk = 1, nlay_i
115            DO jj = 1, jpj
116               DO ji = 1, jpi
117                  !0 if no ice and 1 if yes
118                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_i(ji,jj,jl) - epsi20 )  )
119                  !Energy of melting q(S,T) [J.m-3]
120                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
121               END DO
122            END DO
123         END DO
124         DO jk = 1, nlay_s
125            DO jj = 1, jpj
126               DO ji = 1, jpi
127                  !0 if no ice and 1 if yes
128                  rswitch = MAX(  0._wp , SIGN( 1._wp , v_s(ji,jj,jl) - epsi20 )  )
129                  !Energy of melting q(S,T) [J.m-3]
130                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
131               END DO
132            END DO
133         END DO
134      END DO
135
136      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
137      !-----------------------------------------------------------------------------!
138
139      !--- Ocean solar and non solar fluxes to be used in zqld
140      IF ( .NOT. lk_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
141         !
142         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
143         !
144      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
145         !
146         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
147         !
148         DO jl = 1, jpl
149            DO jj = 1, jpj
150               DO ji = 1, jpi
151                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
152                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
153               END DO
154            END DO
155         END DO
156         !
157      ENDIF
158
159      DO jj = 1, jpj
160         DO ji = 1, jpi
161            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
162            !
163            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
164            !           !  practically no "direct lateral ablation"
165            !           
166            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
167            !           !  temperature and turbulent mixing (McPhee, 1992)
168            !
169
170            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
171            ! REMARK valid at least in forced mode from clem
172            ! precip is included in qns but not in qns_ice
173            IF ( lk_cpl ) THEN
174               zqld =  tmask(ji,jj,1) * rdt_ice *  &
175                  &    (   zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj)               &   ! pfrld already included in coupled mode
176                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *     &   ! heat content of precip
177                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )   &
178                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
179            ELSE
180               zqld =  tmask(ji,jj,1) * rdt_ice *  &
181                  &      ( pfrld(ji,jj) * ( zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj) )    &
182                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *             &  ! heat content of precip
183                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )           &
184                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 ) )
185            ENDIF
186
187            ! --- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
188            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
189
190            ! --- Energy from the turbulent oceanic heat flux (W/m2) --- !
191            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
192            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
193            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
194            ! upper bound for fhtur: the heat retrieved from the ocean must be smaller than the heat necessary to reach
195            !                        the freezing point, so that we do not have SST < T_freeze
196            !                        This implies: - ( fhtur(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
197
198            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
199            qlead(ji,jj) = MIN( 0._wp , zqld - ( fhtur(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
200
201            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
202            IF( zqld > 0._wp ) THEN
203               fhld (ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
204               qlead(ji,jj) = 0._wp
205            ELSE
206               fhld (ji,jj) = 0._wp
207            ENDIF
208            !
209            ! -----------------------------------------
210            ! Net heat flux on top of ice-ocean [W.m-2]
211            ! -----------------------------------------
212            !     heat flux at the ocean surface + precip
213            !   + heat flux at the ice   surface
214            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
215               ! heat flux above the ocean
216               &    +             pfrld(ji,jj)   * ( zqns(ji,jj) + zqsr(ji,jj) )                                                  &
217               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
218               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
219               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )          &
220               ! heat flux above the ice
221               &    +   SUM(    a_i_b(ji,jj,:)   * ( qns_ice(ji,jj,:) + qsr_ice(ji,jj,:) ) )
222
223            ! -----------------------------------------------------------------------------
224            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
225            ! -----------------------------------------------------------------------------
226            !     First  step here              :  non solar + precip - qlead - qturb
227            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
228            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
229            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                       & 
230               ! Non solar heat flux received by the ocean
231               &    +        pfrld(ji,jj) * zqns(ji,jj)                                                                            &
232               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
233               &    +      ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)       &
234               &         * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rt0 ) - lfus )  &
235               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rt0 )       &
236               ! heat flux taken from the ocean where there is open water ice formation
237               &    -      qlead(ji,jj) * r1_rdtice                                                                               &
238               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
239               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                             &
240               &    -      at_i(ji,jj) *  fhld(ji,jj)
241
242         END DO
243      END DO
244
245      !------------------------------------------------------------------------------!
246      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
247      !------------------------------------------------------------------------------!
248
249      DO jl = 1, jpl      !loop over ice categories
250
251         IF( kt == nit000 .AND. lwp ) THEN
252            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
253            WRITE(numout,*) ' ~~~~~~~~'
254         ENDIF
255
256         nbpb = 0
257         DO jj = 1, jpj
258            DO ji = 1, jpi
259               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
260                  nbpb      = nbpb  + 1
261                  npb(nbpb) = (jj - 1) * jpi + ji
262               ENDIF
263            END DO
264         END DO
265
266         ! debug point to follow
267         jiindex_1d = 0
268         IF( ln_icectl ) THEN
269            DO ji = mi0(iiceprt), mi1(iiceprt)
270               DO jj = mj0(jiceprt), mj1(jiceprt)
271                  jiindex_1d = (jj - 1) * jpi + ji
272                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
273               END DO
274            END DO
275         ENDIF
276
277         !------------------------------------------------------------------------------!
278         ! 4) Thermodynamic computation
279         !------------------------------------------------------------------------------!
280
281         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
282
283         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
284
285            !-------------------------!
286            ! --- Move to 1D arrays ---
287            !-------------------------!
288            CALL lim_thd_1d2d( nbpb, jl, 1 )
289
290            !--------------------------------------!
291            ! --- Ice/Snow Temperature profile --- !
292            !--------------------------------------!
293            CALL lim_thd_dif( 1, nbpb )
294
295            !---------------------------------!
296            ! --- Ice/Snow thickness ---      !
297            !---------------------------------!
298            CALL lim_thd_dh( 1, nbpb )   
299
300            ! --- Ice enthalpy remapping --- !
301            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
302                                           
303            !---------------------------------!
304            ! --- Ice salinity ---            !
305            !---------------------------------!
306            CALL lim_thd_sal( 1, nbpb )   
307
308            !---------------------------------!
309            ! --- temperature update ---      !
310            !---------------------------------!
311            CALL lim_thd_temp( 1, nbpb )
312
313            !------------------------------------!
314            ! --- lateral melting if monocat --- !
315            !------------------------------------!
316            IF ( ( nn_monocat == 1 .OR. nn_monocat == 4 ) .AND. jpl == 1 ) THEN
317               CALL lim_thd_lam( 1, nbpb )
318            END IF
319
320            !-------------------------!
321            ! --- Move to 2D arrays ---
322            !-------------------------!
323            CALL lim_thd_1d2d( nbpb, jl, 2 )
324
325            !
326            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
327         ENDIF
328         !
329      END DO !jl
330
331      !------------------------------------------------------------------------------!
332      ! 5) Global variables, diagnostics
333      !------------------------------------------------------------------------------!
334
335      !------------------------
336      ! Ice heat content             
337      !------------------------
338      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
339      DO jl = 1, jpl
340         DO jk = 1, nlay_i
341            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) * r1_nlay_i
342         END DO
343      END DO
344
345      !------------------------
346      ! Snow heat content             
347      !------------------------
348      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
349      DO jl = 1, jpl
350         DO jk = 1, nlay_s
351            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) * r1_nlay_s
352         END DO
353      END DO
354 
355      !------------------------
356      ! Ice natural aging             
357      !------------------------
358      oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * rdt_ice /rday
359
360      !----------------------------------
361      ! Change thickness to volume
362      !----------------------------------
363      v_i(:,:,:)   = ht_i(:,:,:) * a_i(:,:,:)
364      v_s(:,:,:)   = ht_s(:,:,:) * a_i(:,:,:)
365      smv_i(:,:,:) = sm_i(:,:,:) * v_i(:,:,:)
366
367      CALL lim_var_zapsmall
368      !--------------------------------------------
369      ! Diagnostic thermodynamic growth rates
370      !--------------------------------------------
371      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ' )   ! control print
372
373      IF(ln_ctl) THEN            ! Control print
374         CALL prt_ctl_info(' ')
375         CALL prt_ctl_info(' - Cell values : ')
376         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
377         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_thd  : cell area :')
378         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
379         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
380         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
381         DO jl = 1, jpl
382            CALL prt_ctl_info(' ')
383            CALL prt_ctl_info(' - Category : ', ivar1=jl)
384            CALL prt_ctl_info('   ~~~~~~~~~~')
385            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
386            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
387            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
388            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
389            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
390            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
391            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
392            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
393            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
394            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
395            DO jk = 1, nlay_i
396               CALL prt_ctl_info(' ')
397               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
398               CALL prt_ctl_info('   ~~~~~~~')
399               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
400               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
401            END DO
402         END DO
403      ENDIF
404      !
405      !
406      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
407
408      CALL wrk_dealloc( jpi,jpj, zqsr, zqns )
409
410      !------------------------------------------------------------------------------|
411      !  6) Transport of ice between thickness categories.                           |
412      !------------------------------------------------------------------------------|
413      ! Given thermodynamic growth rates, transport ice between thickness categories.
414      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
415
416      IF( jpl > 1 )      CALL lim_itd_th_rem( 1, jpl, kt )
417
418      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
419
420      !------------------------------------------------------------------------------|
421      !  7) Add frazil ice growing in leads.
422      !------------------------------------------------------------------------------|
423      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
424
425      CALL lim_thd_lac
426     
427      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
428
429      ! Control print
430      IF(ln_ctl) THEN
431         CALL lim_var_glo2eqv
432
433         CALL prt_ctl_info(' ')
434         CALL prt_ctl_info(' - Cell values : ')
435         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
436         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_itd_th  : cell area :')
437         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
438         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
439         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
440         DO jl = 1, jpl
441            CALL prt_ctl_info(' ')
442            CALL prt_ctl_info(' - Category : ', ivar1=jl)
443            CALL prt_ctl_info('   ~~~~~~~~~~')
444            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
445            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
446            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
447            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
448            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
449            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
450            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
451            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
452            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
453            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
454            DO jk = 1, nlay_i
455               CALL prt_ctl_info(' ')
456               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
457               CALL prt_ctl_info('   ~~~~~~~')
458               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
459               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
460            END DO
461         END DO
462      ENDIF
463      !
464      IF( nn_timing == 1 )  CALL timing_stop('limthd')
465
466   END SUBROUTINE lim_thd 
467
468   SUBROUTINE lim_thd_temp( kideb, kiut )
469      !!-----------------------------------------------------------------------
470      !!                   ***  ROUTINE lim_thd_temp ***
471      !!                 
472      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
473      !!
474      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
475      !!-------------------------------------------------------------------
476      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
477      !!
478      INTEGER  ::   ji, jk   ! dummy loop indices
479      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
480      !!-------------------------------------------------------------------
481      ! Recover ice temperature
482      DO jk = 1, nlay_i
483         DO ji = kideb, kiut
484            ztmelts       =  -tmut * s_i_1d(ji,jk) + rt0
485            ! Conversion q(S,T) -> T (second order equation)
486            zaaa          =  cpic
487            zbbb          =  ( rcp - cpic ) * ( ztmelts - rt0 ) + q_i_1d(ji,jk) * r1_rhoic - lfus
488            zccc          =  lfus * ( ztmelts - rt0 )
489            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
490            t_i_1d(ji,jk) =  rt0 - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
491           
492            ! mask temperature
493            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
494            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
495         END DO
496      END DO
497
498   END SUBROUTINE lim_thd_temp
499
500   SUBROUTINE lim_thd_lam( kideb, kiut )
501      !!-----------------------------------------------------------------------
502      !!                   ***  ROUTINE lim_thd_lam ***
503      !!                 
504      !! ** Purpose :   Lateral melting in case monocategory
505      !!                          ( dA = A/2h dh )
506      !!-----------------------------------------------------------------------
507      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
508      INTEGER             ::   ji                 ! dummy loop indices
509      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
510      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
511      REAL(wp)            ::   zvi, zvs           ! ice/snow volumes
512
513      DO ji = kideb, kiut
514         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
515         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
516            zvi          = a_i_1d(ji) * ht_i_1d(ji)
517            zvs          = a_i_1d(ji) * ht_s_1d(ji)
518            ! lateral melting = concentration change
519            zhi_bef     = ht_i_1d(ji) - zdh_mel
520            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
521            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
522            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
523             ! adjust thickness
524            ht_i_1d(ji) = zvi / a_i_1d(ji)           
525            ht_s_1d(ji) = zvs / a_i_1d(ji)           
526            ! retrieve total concentration
527            at_i_1d(ji) = a_i_1d(ji)
528         END IF
529      END DO
530     
531   END SUBROUTINE lim_thd_lam
532
533   SUBROUTINE lim_thd_1d2d( nbpb, jl, kn )
534      !!-----------------------------------------------------------------------
535      !!                   ***  ROUTINE lim_thd_1d2d ***
536      !!                 
537      !! ** Purpose :   move arrays from 1d to 2d and the reverse
538      !!-----------------------------------------------------------------------
539      INTEGER, INTENT(in) ::   kn       ! 1= from 2D to 1D
540                                        ! 2= from 1D to 2D
541      INTEGER, INTENT(in) ::   nbpb     ! size of 1D arrays
542      INTEGER, INTENT(in) ::   jl       ! ice cat
543      INTEGER             ::   jk       ! dummy loop indices
544
545      SELECT CASE( kn )
546
547      CASE( 1 )
548
549         CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
550         CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
551         CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
552         CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
553         
554         CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
555         CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
556         DO jk = 1, nlay_s
557            CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
558            CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
559         END DO
560         DO jk = 1, nlay_i
561            CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
562            CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
563            CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
564         END DO
565         
566         CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
567         CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
568         CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
569         CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
570         CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
571         CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
572         IF( .NOT. lk_cpl ) THEN
573            CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
574            CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
575         ENDIF
576         CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
577         CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
578         CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
579         CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
580         CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
581         CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
582         
583         CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
584         CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
585         
586         CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
587         CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
588         CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
589         CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
590         CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
591         CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
592         
593         CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
594         CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
595         CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
596         CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
597         CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
598         CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
599         
600         CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
601         CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
602         CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
603         CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
604         CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
605         CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
606         CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
607         CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
608         CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
609         CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
610         CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
611         CALL tab_2d_1d( nbpb, hfx_err_dif_1d (1:nbpb), hfx_err_dif , jpi, jpj, npb(1:nbpb) )
612         CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
613
614      CASE( 2 )
615
616         CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
617         CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
618         CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
619         CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
620         CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
621         CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
622         DO jk = 1, nlay_s
623            CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
624            CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
625         END DO
626         DO jk = 1, nlay_i
627            CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
628            CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
629            CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
630         END DO
631         CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
632         
633         CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
634         CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
635         
636         CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
637         CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
638         CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
639         CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
640         CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
641         CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
642         
643         CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
644         CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
645         CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
646         CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
647         CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
648         CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
649         
650         CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
651         CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
652         CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
653         CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
654         CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
655         CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
656         CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
657         CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
658         CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
659         CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
660         CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
661         CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
662         CALL tab_1d_2d( nbpb, hfx_err_dif   , npb, hfx_err_dif_1d(1:nbpb), jpi, jpj )
663         !
664         CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
665         CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
666                 
667      END SELECT
668
669   END SUBROUTINE lim_thd_1d2d
670
671
672   SUBROUTINE lim_thd_init
673      !!-----------------------------------------------------------------------
674      !!                   ***  ROUTINE lim_thd_init ***
675      !!                 
676      !! ** Purpose :   Physical constants and parameters linked to the ice
677      !!              thermodynamics
678      !!
679      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
680      !!              parameter values called at the first timestep (nit000)
681      !!
682      !! ** input   :   Namelist namicether
683      !!-------------------------------------------------------------------
684      INTEGER  ::   ios                 ! Local integer output status for namelist read
685      NAMELIST/namicethd/ rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb,                       &
686         &                rn_himin, rn_betas, rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon, &
687         &                nn_monocat, ln_it_qnsice
688      !!-------------------------------------------------------------------
689      !
690      IF(lwp) THEN
691         WRITE(numout,*)
692         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
693         WRITE(numout,*) '~~~~~~~'
694      ENDIF
695      !
696      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
697      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
698901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
699
700      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
701      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
702902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
703      IF(lwm) WRITE ( numoni, namicethd )
704      !
705      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
706         nn_monocat = 0
707         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
708      ENDIF
709
710      !
711      IF(lwp) THEN                          ! control print
712         WRITE(numout,*)
713         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
714         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
715         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
716         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
717         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
718         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
719         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
720         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
721         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
722         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
723         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
724         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
725         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
726         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
727         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
728         WRITE(numout,*)'      iterate the surface non-solar flux (T) or not (F)       ln_it_qnsice = ', ln_it_qnsice
729      ENDIF
730      !
731   END SUBROUTINE lim_thd_init
732
733#else
734   !!----------------------------------------------------------------------
735   !!   Default option         Dummy module          NO  LIM3 sea-ice model
736   !!----------------------------------------------------------------------
737#endif
738
739   !!======================================================================
740END MODULE limthd
Note: See TracBrowser for help on using the repository browser.