New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd_sal.F90 in trunk/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: trunk/NEMOGCM/NEMO/LIM_SRC_3/limthd_sal.F90 @ 3319

Last change on this file since 3319 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk
  • Property svn:keywords set to Id
File size: 12.4 KB
Line 
1MODULE limthd_sal
2   !!======================================================================
3   !!                       ***  MODULE limthd_sal ***
4   !! LIM-3 sea-ice :  computation of salinity variations in the ice
5   !!======================================================================
6   !! History :   -   ! 2003-05 (M. Vancoppenolle) UCL-ASTR first coding for LIM3-1D
7   !!            3.0  ! 2005-12 (M. Vancoppenolle) adapted to the 3-D version
8   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
9   !!---------------------------------------------------------------------
10#if defined key_lim3
11   !!----------------------------------------------------------------------
12   !!   'key_lim3'                                      LIM-3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_thd_sal : salinity variations in the ice
15   !!----------------------------------------------------------------------
16   USE par_oce          ! ocean parameters
17   USE phycst           ! physical constants (ocean directory)
18   USE sbc_oce          ! Surface boundary condition: ocean fields
19   USE ice              ! LIM variables
20   USE par_ice          ! LIM parameters
21   USE thd_ice          ! LIM thermodynamics
22   USE limvar           ! LIM variables
23   USE in_out_manager   ! I/O manager
24   USE lib_mpp          ! MPP library
25   USE wrk_nemo         ! work arrays
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   lim_thd_sal        ! called by limthd module
31   PUBLIC   lim_thd_sal_init   ! called by iceini module
32
33   !!----------------------------------------------------------------------
34   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE lim_thd_sal( kideb, kiut )
41      !!-------------------------------------------------------------------
42      !!                ***  ROUTINE lim_thd_sal  ***   
43      !!   
44      !! ** Purpose :   computes new salinities in the ice
45      !!
46      !! ** Method  :  4 possibilities
47      !!               -> num_sal = 1 -> constant salinity for z,t
48      !!               -> num_sal = 2 -> S = S(z,t) [simple Vancoppenolle et al 2005]
49      !!               -> num_sal = 3 -> S = S(z)   [multiyear ice]
50      !!               -> num_sal = 4 -> S = S(h)   [Cox and Weeks 74]
51      !!---------------------------------------------------------------------
52      INTEGER, INTENT(in) ::  kideb, kiut   ! thickness category index
53      !
54      INTEGER  ::   ji, jk     ! dummy loop indices
55      INTEGER  ::   zji, zjj   ! local integers
56      REAL(wp) ::   zsold, iflush, iaccrbo, igravdr, isnowic, i_ice_switch,  ztmelts   ! local scalars
57      REAL(wp) ::   zaaa, zbbb, zccc, zdiscrim   ! local scalars
58      REAL(wp), POINTER, DIMENSION(:) ::   ze_init, zhiold, zsiold
59      !!---------------------------------------------------------------------
60
61      CALL wrk_alloc( jpij, ze_init, zhiold, zsiold )
62
63      !------------------------------------------------------------------------------|
64      ! 1) Constant salinity, constant in time                                       |
65      !------------------------------------------------------------------------------|
66!!gm comment: if num_sal = 1 s_i_b and sm_i_b can be set to bulk_sal one for all in the initialisation phase !!
67      IF( num_sal == 1 ) THEN
68         !
69         DO jk = 1, nlay_i
70            DO ji = kideb, kiut
71               s_i_b(ji,jk) =  bulk_sal
72            END DO ! ji
73         END DO ! jk
74         !
75         DO ji = kideb, kiut
76            sm_i_b(ji)      =  bulk_sal 
77         END DO ! ji
78         !
79      ENDIF
80
81      !------------------------------------------------------------------------------|
82      !  Module 2 : Constant salinity varying in time                                |
83      !------------------------------------------------------------------------------|
84
85      IF(  num_sal == 2  .OR.  num_sal == 4  ) THEN
86
87         !---------------------------------
88         ! Thickness at previous time step
89         !---------------------------------
90         DO ji = kideb, kiut
91            zhiold(ji) = ht_i_b(ji) - dh_i_bott(ji) - dh_snowice(ji) - dh_i_surf(ji)
92         END DO
93
94         !---------------------
95         ! Global heat content
96         !---------------------
97         ze_init(:)  =  0._wp
98         DO jk = 1, nlay_i
99            DO ji = kideb, kiut
100               ze_init(ji) = ze_init(ji) + q_i_b(ji,jk) * ht_i_b(ji) / nlay_i
101            END DO
102         END DO
103
104         DO ji = kideb, kiut
105            !
106            ! Switches
107            !----------
108            iflush       =         MAX( 0._wp , SIGN( 1.0 , t_su_b(ji) - rtt )        )    ! =1 if summer
109            igravdr      =         MAX( 0._wp , SIGN( 1.0 , t_bo_b(ji) - t_su_b(ji) ) )    ! =1 if t_su < t_bo
110            iaccrbo      =         MAX( 0._wp , SIGN( 1.0 , dh_i_bott(ji) )           )    ! =1 if bottom accretion
111            i_ice_switch = 1._wp - MAX ( 0._wp , SIGN( 1._wp , - ht_i_b(ji) + 1.e-2 ) )
112            isnowic      = 1._wp - MAX ( 0._wp , SIGN( 1._wp , - dh_snowice(ji) ) ) * i_ice_switch   ! =1 if snow ice formation
113
114            !---------------------
115            ! Salinity tendencies
116            !---------------------
117            !                                   ! drainage by gravity drainage
118            dsm_i_gd_1d(ji) = - igravdr * MAX( sm_i_b(ji) - sal_G , 0._wp ) / time_G * rdt_ice 
119            !                                   ! drainage by flushing 
120            dsm_i_fl_1d(ji) = - iflush * MAX( sm_i_b(ji) - sal_F , 0._wp ) / time_F * rdt_ice
121
122            !-----------------
123            ! Update salinity   
124            !-----------------
125            ! only drainage terms ( gravity drainage and flushing )
126            ! snow ice / bottom sources are added in lim_thd_ent to conserve energy
127            zsiold(ji) = sm_i_b(ji)
128            sm_i_b(ji) = sm_i_b(ji) + dsm_i_fl_1d(ji) + dsm_i_gd_1d(ji)
129
130            ! if no ice, salinity = 0.1
131            i_ice_switch = 1._wp - MAX ( 0._wp, SIGN( 1._wp , - ht_i_b(ji) ) )
132            sm_i_b(ji)   = i_ice_switch * sm_i_b(ji) + s_i_min * ( 1._wp - i_ice_switch )
133         END DO ! ji
134
135         ! Salinity profile
136         CALL lim_var_salprof1d( kideb, kiut )
137
138         !----------------------------
139         ! Heat flux - brine drainage
140         !----------------------------
141
142         DO ji = kideb, kiut
143!!gm useless
144            ! iflush  : 1 if summer
145            iflush  =  MAX( 0._wp , SIGN ( 1._wp , t_su_b(ji) - rtt ) ) 
146            ! igravdr : 1 if t_su lt t_bo
147            igravdr =  MAX( 0._wp , SIGN ( 1._wp , t_bo_b(ji) - t_su_b(ji) ) ) 
148            ! iaccrbo : 1 if bottom accretion
149            iaccrbo =  MAX( 0._wp , SIGN ( 1._wp , dh_i_bott(ji) ) )
150!!gm end useless
151            !
152            fhbri_1d(ji) = 0._wp
153         END DO ! ji
154
155         !----------------------------
156         ! Salt flux - brine drainage
157         !----------------------------
158         DO ji = kideb, kiut
159            i_ice_switch = 1._wp - MAX ( 0._wp, SIGN( 1._wp , - ht_i_b(ji) ) )
160            fsbri_1d(ji) = fsbri_1d(ji) - i_ice_switch * rhoic * a_i_b(ji) * ht_i_b(ji)         &
161               &         * ( MAX(dsm_i_gd_1d(ji) + dsm_i_fl_1d(ji), sm_i_b(ji) - zsiold(ji) ) ) / rdt_ice
162            IF( num_sal == 4 ) fsbri_1d(ji) = 0._wp
163         END DO ! ji
164
165         ! Only necessary for conservation check since salinity is modified
166         !--------------------
167         ! Temperature update
168         !--------------------
169         DO jk = 1, nlay_i
170            DO ji = kideb, kiut
171               ztmelts    =  -tmut*s_i_b(ji,jk) + rtt
172               !Conversion q(S,T) -> T (second order equation)
173               zaaa         =  cpic
174               zbbb         =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_b(ji,jk) / rhoic - lfus
175               zccc         =  lfus * ( ztmelts - rtt )
176               zdiscrim     =  SQRT(  MAX( zbbb*zbbb - 4.0*zaaa*zccc, 0._wp )  )
177               t_i_b(ji,jk) =  rtt - ( zbbb + zdiscrim ) / ( 2.0 *zaaa )
178            END DO
179         END DO
180         !
181      ENDIF ! num_sal .EQ. 2
182
183      !------------------------------------------------------------------------------|
184      !  Module 3 : Profile of salinity, constant in time                            |
185      !------------------------------------------------------------------------------|
186
187      IF( num_sal == 3 )   CALL lim_var_salprof1d( kideb, kiut )
188
189      !------------------------------------------------------------------------------|
190      !  Module 4 : Constant salinity varying in time                                |
191      !------------------------------------------------------------------------------|
192
193      IF( num_sal == 5 ) THEN      ! Cox and Weeks, 1974
194         !
195         DO ji = kideb, kiut
196            zsold = sm_i_b(ji)
197            IF( ht_i_b(ji) < 0.4 ) THEN
198               sm_i_b(ji) = 14.24 - 19.39 * ht_i_b(ji) 
199            ELSE
200               sm_i_b(ji) =  7.88 - 1.59 * ht_i_b(ji)
201               sm_i_b(ji) = MIN( sm_i_b(ji) , zsold ) 
202            ENDIF
203            IF( ht_i_b(ji) > 3.06918239 ) THEN
204               sm_i_b(ji) = 3._wp
205            ENDIF
206            DO jk = 1, nlay_i
207               s_i_b(ji,jk)   = sm_i_b(ji)
208            END DO
209         END DO
210         !
211      ENDIF ! num_sal
212
213      !------------------------------------------------------------------------------|
214      ! 5) Computation of salt flux due to Bottom growth
215      !------------------------------------------------------------------------------|
216
217      IF ( num_sal == 4 ) THEN
218         DO ji = kideb, kiut
219            zji = MOD( npb(ji) - 1 , jpi ) + 1
220            zjj =    ( npb(ji) - 1 ) / jpi + 1
221            fseqv_1d(ji) = fseqv_1d(ji) + ( sss_m(zji,zjj) - bulk_sal    )               &
222               &                        * rhoic * a_i_b(ji) * MAX( dh_i_bott(ji) , 0.0 ) / rdt_ice
223         END DO
224      ELSE
225         DO ji = kideb, kiut
226            zji = MOD( npb(ji) - 1 , jpi ) + 1
227            zjj =    ( npb(ji) - 1 ) / jpi + 1
228            fseqv_1d(ji) = fseqv_1d(ji) + ( sss_m(zji,zjj) - s_i_new(ji) )               &
229               &                        * rhoic * a_i_b(ji) * MAX( dh_i_bott(ji) , 0.0 ) / rdt_ice
230         END DO
231      ENDIF
232      !
233      CALL wrk_dealloc( jpij, ze_init, zhiold, zsiold )
234      !
235   END SUBROUTINE lim_thd_sal
236
237
238   SUBROUTINE lim_thd_sal_init
239      !!-------------------------------------------------------------------
240      !!                  ***  ROUTINE lim_thd_sal_init  ***
241      !!
242      !! ** Purpose :   initialization of ice salinity parameters
243      !!
244      !! ** Method  :   Read the namicesal namelist and check the parameter
245      !!              values called at the first timestep (nit000)
246      !!
247      !! ** input   :   Namelist namicesal
248      !!-------------------------------------------------------------------
249      NAMELIST/namicesal/ num_sal, bulk_sal, sal_G, time_G, sal_F, time_F,   &
250         &                s_i_max, s_i_min, s_i_0, s_i_1
251      !!-------------------------------------------------------------------
252      !
253      REWIND( numnam_ice )                   ! Read Namelist namicesal
254      READ  ( numnam_ice  , namicesal )
255      !
256      IF(lwp) THEN                           ! control print
257         WRITE(numout,*)
258         WRITE(numout,*) 'lim_thd_sal_init : Ice parameters for salinity '
259         WRITE(numout,*) '~~~~~~~~~~~~~~~~'
260         WRITE(numout,*) ' switch for salinity num_sal        : ', num_sal
261         WRITE(numout,*) ' bulk salinity value if num_sal = 1 : ', bulk_sal
262         WRITE(numout,*) ' restoring salinity for GD          : ', sal_G
263         WRITE(numout,*) ' restoring time for GD              : ', time_G
264         WRITE(numout,*) ' restoring salinity for flushing    : ', sal_F
265         WRITE(numout,*) ' restoring time for flushing        : ', time_F
266         WRITE(numout,*) ' Maximum tolerated ice salinity     : ', s_i_max
267         WRITE(numout,*) ' Minimum tolerated ice salinity     : ', s_i_min
268         WRITE(numout,*) ' 1st salinity for salinity profile  : ', s_i_0
269         WRITE(numout,*) ' 2nd salinity for salinity profile  : ', s_i_1
270      ENDIF
271      !
272   END SUBROUTINE lim_thd_sal_init
273
274#else
275   !!----------------------------------------------------------------------
276   !!   Default option         Dummy Module          No LIM-3 sea-ice model
277   !!----------------------------------------------------------------------
278#endif
279   !!======================================================================
280END MODULE limthd_sal
Note: See TracBrowser for help on using the repository browser.