New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaar5.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DIA/diaar5.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 8.8 KB
Line 
1MODULE diaar5
2   !!======================================================================
3   !!                       ***  MODULE  diaar5  ***
4   !! AR5 diagnostics
5   !!======================================================================
6   !! History :  3.2  !  2009-11  (S. Masson)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_diaar5
10   !!----------------------------------------------------------------------
11   !!   'key_diaar5'  :                           activate ar5 diagnotics
12   !!----------------------------------------------------------------------
13   !!   dia_ar5       : AR5 diagnostics
14   !!   dia_ar5_init  : initialisation of AR5 diagnostics
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE eosbn2         ! equation of state                (eos_bn2 routine)
19   USE lib_mpp        ! distribued memory computing library
20   USE iom            ! I/O manager library
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   dia_ar5        ! routine called in step.F90 module
26   PUBLIC   dia_ar5_init   ! routine called in opa.F90 module
27
28   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .TRUE.   ! coupled flag
29
30   REAL(wp)                         ::   vol0         ! ocean volume (interior domain)
31   REAL(wp)                         ::   area_tot     ! total ocean surface (interior domain)
32   REAL(wp), DIMENSION(jpi,jpj    ) ::   area         ! cell surface (interior domain)
33   REAL(wp), DIMENSION(jpi,jpj    ) ::   thick0       ! ocean thickness (interior domain)
34   REAL(wp), DIMENSION(jpi,jpj,jpk) ::   sn0          ! initial salinity
35     
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE dia_ar5( kt )
46      !!----------------------------------------------------------------------
47      !!                    ***  ROUTINE dia_ar5  ***
48      !!
49      !! ** Purpose :   compute and output some AR5 diagnostics
50      !!
51      !!----------------------------------------------------------------------
52      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
53      !!
54      INTEGER  ::   ji, jj, jk                      ! dummy loop arguments
55      REAL(wp) ::   zvolssh, zvol, zssh_steric, zztmp, zarho, ztemp, zsal, zmass
56      REAL(wp), DIMENSION(jpi,jpj    ) ::   zarea_ssh, zbotpres
57      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zrhd, zrhop
58      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts) ::   ztsn
59      !!--------------------------------------------------------------------
60
61      CALL iom_put( 'cellthc', fse3t(:,:,:) )
62
63      zarea_ssh(:,:) = area(:,:) * sshn(:,:)
64
65      !                                         ! total volume of liquid seawater
66      zvolssh = SUM( zarea_ssh(:,:) ) 
67      IF( lk_mpp )   CALL mpp_sum( zvolssh )
68      zvol = vol0 + zvolssh
69     
70      CALL iom_put( 'voltot', zvol               )
71      CALL iom_put( 'sshtot', zvolssh / area_tot )
72
73      !                                         ! thermosteric ssh
74      ztsn(:,:,:,jp_tem) = tn (:,:,:)
75      ztsn(:,:,:,jp_sal) = sn0(:,:,:)
76      CALL eos( ztsn, zrhd )                       ! now in situ density using initial salinity
77      !
78      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
79      DO jk = 1, jpkm1
80         zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
81      END DO
82      IF( .NOT.lk_vvl )   zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1)
83      !                                         
84      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
85      IF( lk_mpp )   CALL mpp_sum( zarho )
86      zssh_steric = - zarho / area_tot
87      CALL iom_put( 'sshthster', zssh_steric )
88     
89      !                                         ! steric sea surface height
90      CALL eos( tsn, zrhd, zrhop )                 ! now in situ and potential density
91      zrhop(:,:,jpk) = 0._wp
92      CALL iom_put( 'rhop', zrhop )
93      !
94      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
95      DO jk = 1, jpkm1
96         zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
97      END DO
98      IF( .NOT.lk_vvl )   zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1)
99      !   
100      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
101      IF( lk_mpp )   CALL mpp_sum( zarho )
102      zssh_steric = - zarho / area_tot
103      CALL iom_put( 'sshsteric', zssh_steric )
104     
105      !                                         ! ocean bottom pressure
106      zztmp = rau0 * grav * 1.e-4_wp               ! recover pressure from pressure anomaly and cover to dbar = 1.e4 Pa
107      zbotpres(:,:) = zztmp * ( zbotpres(:,:) + sshn(:,:) + thick0(:,:) )
108      CALL iom_put( 'botpres', zbotpres )
109
110      !                                         ! Mean density anomalie, temperature and salinity
111      ztemp = 0._wp
112      zsal  = 0._wp
113      DO jk = 1, jpkm1
114         DO jj = 1, jpj
115            DO ji = 1, jpi
116               zztmp = area(ji,jj) * fse3t(ji,jj,jk)
117               ztemp = ztemp + zztmp * tn(ji,jj,jk)
118               zsal  = zsal  + zztmp * sn(ji,jj,jk)
119            END DO
120         END DO
121      END DO
122      IF( .NOT.lk_vvl ) THEN
123         ztemp = ztemp + SUM( zarea_ssh(:,:) * tn(:,:,1) )
124         zsal  = zsal  + SUM( zarea_ssh(:,:) * sn(:,:,1) )
125      ENDIF
126      IF( lk_mpp ) THEN 
127         CALL mpp_sum( ztemp )
128         CALL mpp_sum( zsal  )
129      END IF
130      !
131      zmass = rau0 * ( zarho + zvol )                 ! total mass of liquid seawater
132      ztemp = ztemp / zvol                            ! potential temperature in liquid seawater
133      zsal  = zsal  / zvol                            ! Salinity of liquid seawater
134      !
135      CALL iom_put( 'masstot', zmass )
136      CALL iom_put( 'temptot', ztemp )
137      CALL iom_put( 'saltot' , zsal  )
138      !
139   END SUBROUTINE dia_ar5
140
141
142   SUBROUTINE dia_ar5_init
143      !!----------------------------------------------------------------------
144      !!                  ***  ROUTINE dia_ar5_init  ***
145      !!                   
146      !! ** Purpose :   initialization for AR5 diagnostic computation
147      !!----------------------------------------------------------------------
148      INTEGER  ::   inum
149      INTEGER  ::   ik
150      INTEGER  ::   ji, jj, jk  ! dummy loop indices
151      REAL(wp) ::   zztmp 
152      REAL(wp), DIMENSION(jpi,jpj,jpk, 2) ::   zsaldta   ! Jan/Dec levitus salinity
153      !!----------------------------------------------------------------------
154      !
155      area(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:)
156
157      area_tot = SUM( area(:,:) )   ;   IF( lk_mpp )   CALL mpp_sum( area_tot )
158
159      vol0        = 0._wp
160      thick0(:,:) = 0._wp
161      DO jk = 1, jpkm1
162         vol0        = vol0        + SUM( area (:,:) * tmask(:,:,jk) * fse3t_0(:,:,jk) )
163         thick0(:,:) = thick0(:,:) +    tmask_i(:,:) * tmask(:,:,jk) * fse3t_0(:,:,jk)
164      END DO
165      IF( lk_mpp )   CALL mpp_sum( vol0 )
166     
167      CALL iom_open ( 'data_1m_salinity_nomask', inum )
168      CALL iom_get  ( inum, jpdom_data, 'vosaline', zsaldta(:,:,:,1), 1  )
169      CALL iom_get  ( inum, jpdom_data, 'vosaline', zsaldta(:,:,:,2), 12 )
170      CALL iom_close( inum )
171      sn0(:,:,:) = 0.5_wp * ( zsaldta(:,:,:,1) + zsaldta(:,:,:,2) )       
172      sn0(:,:,:) = sn0(:,:,:) * tmask(:,:,:)
173      IF( ln_zps ) THEN               ! z-coord. partial steps
174         DO jj = 1, jpj               ! interpolation of salinity at the last ocean level (i.e. the partial step)
175            DO ji = 1, jpi
176               ik = mbkt(ji,jj)
177               IF( ik > 1 ) THEN
178                  zztmp = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) )
179                  sn0(ji,jj,ik) = ( 1._wp - zztmp ) * sn0(ji,jj,ik) + zztmp * sn0(ji,jj,ik-1)
180               ENDIF
181            END DO
182         END DO
183      ENDIF
184      !
185   END SUBROUTINE dia_ar5_init
186
187#else
188   !!----------------------------------------------------------------------
189   !!   Default option :                                         NO diaar5
190   !!----------------------------------------------------------------------
191   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .FALSE.   ! coupled flag
192CONTAINS
193   SUBROUTINE dia_ar5_init    ! Dummy routine
194   END SUBROUTINE dia_ar5_init
195   SUBROUTINE dia_ar5( kt )   ! Empty routine
196      INTEGER ::   kt
197      WRITE(*,*) 'dia_ar5: You should not have seen this print! error?', kt
198   END SUBROUTINE dia_ar5
199#endif
200
201   !!======================================================================
202END MODULE diaar5
Note: See TracBrowser for help on using the repository browser.