source: trunk/NEMOGCM/NEMO/OPA_SRC/DIA/diaar5.F90 @ 4990

Last change on this file since 4990 was 4990, checked in by timgraham, 6 years ago

Merged branches/2014/dev_MERGE_2014 back onto the trunk as follows:

In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
1 conflict in LIM_SRC_3/limdiahsb.F90
Resolved by keeping the version from dev_MERGE_2014 branch
and commited at r4989

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge —reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2014/dev_MERGE_2014
to merge the branch into the trunk - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 11.2 KB
Line 
1MODULE diaar5
2   !!======================================================================
3   !!                       ***  MODULE  diaar5  ***
4   !! AR5 diagnostics
5   !!======================================================================
6   !! History :  3.2  !  2009-11  (S. Masson)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_diaar5   || defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_diaar5'  :                           activate ar5 diagnotics
12   !!----------------------------------------------------------------------
13   !!   dia_ar5       : AR5 diagnostics
14   !!   dia_ar5_init  : initialisation of AR5 diagnostics
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE eosbn2         ! equation of state                (eos_bn2 routine)
19   USE lib_mpp        ! distribued memory computing library
20   USE iom            ! I/O manager library
21   USE timing         ! preformance summary
22   USE wrk_nemo       ! working arrays
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   dia_ar5        ! routine called in step.F90 module
28   PUBLIC   dia_ar5_init   ! routine called in opa.F90 module
29   PUBLIC   dia_ar5_alloc  ! routine called in nemogcm.F90 module
30
31   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .TRUE.   ! coupled flag
32
33   REAL(wp)                         ::   vol0         ! ocean volume (interior domain)
34   REAL(wp)                         ::   area_tot     ! total ocean surface (interior domain)
35   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   area         ! cell surface (interior domain)
36   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   thick0       ! ocean thickness (interior domain)
37   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sn0          ! initial salinity
38     
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   FUNCTION dia_ar5_alloc()
49      !!----------------------------------------------------------------------
50      !!                    ***  ROUTINE dia_ar5_alloc  ***
51      !!----------------------------------------------------------------------
52      INTEGER :: dia_ar5_alloc
53      !!----------------------------------------------------------------------
54      !
55      ALLOCATE( area(jpi,jpj), thick0(jpi,jpj) , sn0(jpi,jpj,jpk) , STAT=dia_ar5_alloc )
56      !
57      IF( lk_mpp             )   CALL mpp_sum ( dia_ar5_alloc )
58      IF( dia_ar5_alloc /= 0 )   CALL ctl_warn('dia_ar5_alloc: failed to allocate arrays')
59      !
60   END FUNCTION dia_ar5_alloc
61
62
63   SUBROUTINE dia_ar5( kt )
64      !!----------------------------------------------------------------------
65      !!                    ***  ROUTINE dia_ar5  ***
66      !!
67      !! ** Purpose :   compute and output some AR5 diagnostics
68      !!----------------------------------------------------------------------
69      !
70      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
71      !
72      INTEGER  ::   ji, jj, jk                      ! dummy loop arguments
73      REAL(wp) ::   zvolssh, zvol, zssh_steric, zztmp, zarho, ztemp, zsal, zmass
74      !
75      REAL(wp), POINTER, DIMENSION(:,:)     :: zarea_ssh , zbotpres       ! 2D workspace
76      REAL(wp), POINTER, DIMENSION(:,:,:)   :: zrhd , zrhop               ! 3D workspace
77      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztsn                       ! 4D workspace
78      !!--------------------------------------------------------------------
79      IF( nn_timing == 1 )   CALL timing_start('dia_ar5')
80 
81      CALL wrk_alloc( jpi , jpj              , zarea_ssh , zbotpres )
82      CALL wrk_alloc( jpi , jpj , jpk        , zrhd      , zrhop    )
83      CALL wrk_alloc( jpi , jpj , jpk , jpts , ztsn                 )
84
85      CALL iom_put( 'cellthc', fse3t(:,:,:) )
86
87      zarea_ssh(:,:) = area(:,:) * sshn(:,:)
88
89      !                                         ! total volume of liquid seawater
90      zvolssh = SUM( zarea_ssh(:,:) ) 
91      IF( lk_mpp )   CALL mpp_sum( zvolssh )
92      zvol = vol0 + zvolssh
93     
94      CALL iom_put( 'voltot', zvol               )
95      CALL iom_put( 'sshtot', zvolssh / area_tot )
96
97      !                     
98      ztsn(:,:,:,jp_tem) = tsn(:,:,:,jp_tem)                    ! thermosteric ssh
99      ztsn(:,:,:,jp_sal) = sn0(:,:,:)
100      CALL eos( ztsn, zrhd, fsdept_n(:,:,:) )                       ! now in situ density using initial salinity
101      !
102      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
103      DO jk = 1, jpkm1
104         zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
105      END DO
106      IF( .NOT.lk_vvl ) THEN
107         DO ji=1,jpi
108            DO jj=1,jpj
109               zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
110            END DO
111         END DO
112      END IF
113      !                                         
114      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
115      IF( lk_mpp )   CALL mpp_sum( zarho )
116      zssh_steric = - zarho / area_tot
117      CALL iom_put( 'sshthster', zssh_steric )
118     
119      !                                         ! steric sea surface height
120      CALL eos( tsn, zrhd, zrhop, fsdept_n(:,:,:) )                 ! now in situ and potential density
121      zrhop(:,:,jpk) = 0._wp
122      CALL iom_put( 'rhop', zrhop )
123      !
124      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
125      DO jk = 1, jpkm1
126         zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
127      END DO
128      IF( .NOT.lk_vvl ) THEN
129         DO ji=1,jpi
130            DO jj=1,jpj
131               zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
132            END DO
133         END DO
134      END IF
135      !   
136      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
137      IF( lk_mpp )   CALL mpp_sum( zarho )
138      zssh_steric = - zarho / area_tot
139      CALL iom_put( 'sshsteric', zssh_steric )
140     
141      !                                         ! ocean bottom pressure
142      zztmp = rau0 * grav * 1.e-4_wp               ! recover pressure from pressure anomaly and cover to dbar = 1.e4 Pa
143      zbotpres(:,:) = zztmp * ( zbotpres(:,:) + sshn(:,:) + thick0(:,:) )
144      CALL iom_put( 'botpres', zbotpres )
145
146      !                                         ! Mean density anomalie, temperature and salinity
147      ztemp = 0._wp
148      zsal  = 0._wp
149      DO jk = 1, jpkm1
150         DO jj = 1, jpj
151            DO ji = 1, jpi
152               zztmp = area(ji,jj) * fse3t(ji,jj,jk)
153               ztemp = ztemp + zztmp * tsn(ji,jj,jk,jp_tem)
154               zsal  = zsal  + zztmp * tsn(ji,jj,jk,jp_sal)
155            END DO
156         END DO
157      END DO
158      IF( .NOT.lk_vvl ) THEN
159         DO ji=1,jpi
160            DO jj=1,jpj
161               ztemp = ztemp + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_tem) 
162               zsal  = zsal  + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_sal) 
163            END DO
164         END DO
165      ENDIF
166      IF( lk_mpp ) THEN 
167         CALL mpp_sum( ztemp )
168         CALL mpp_sum( zsal  )
169      END IF
170      !
171      zmass = rau0 * ( zarho + zvol )                 ! total mass of liquid seawater
172      ztemp = ztemp / zvol                            ! potential temperature in liquid seawater
173      zsal  = zsal  / zvol                            ! Salinity of liquid seawater
174      !
175      CALL iom_put( 'masstot', zmass )
176      CALL iom_put( 'temptot', ztemp )
177      CALL iom_put( 'saltot' , zsal  )
178      !
179      CALL wrk_dealloc( jpi , jpj              , zarea_ssh , zbotpres )
180      CALL wrk_dealloc( jpi , jpj , jpk        , zrhd      , zrhop    )
181      CALL wrk_dealloc( jpi , jpj , jpk , jpts , ztsn                 )
182      !
183      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5')
184      !
185   END SUBROUTINE dia_ar5
186
187
188   SUBROUTINE dia_ar5_init
189      !!----------------------------------------------------------------------
190      !!                  ***  ROUTINE dia_ar5_init  ***
191      !!                   
192      !! ** Purpose :   initialization for AR5 diagnostic computation
193      !!----------------------------------------------------------------------
194      INTEGER  ::   inum
195      INTEGER  ::   ik
196      INTEGER  ::   ji, jj, jk  ! dummy loop indices
197      REAL(wp) ::   zztmp 
198      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   zsaldta   ! Jan/Dec levitus salinity
199      !!----------------------------------------------------------------------
200      !
201      IF( nn_timing == 1 )   CALL timing_start('dia_ar5_init')
202      !
203      CALL wrk_alloc( jpi , jpj , jpk, jpts, zsaldta )
204      !                                      ! allocate dia_ar5 arrays
205      IF( dia_ar5_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dia_ar5_init : unable to allocate arrays' )
206
207      area(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:)
208
209      area_tot = SUM( area(:,:) )   ;   IF( lk_mpp )   CALL mpp_sum( area_tot )
210
211      vol0        = 0._wp
212      thick0(:,:) = 0._wp
213      DO jk = 1, jpkm1
214         vol0        = vol0        + SUM( area (:,:) * tmask(:,:,jk) * e3t_0(:,:,jk) )
215         thick0(:,:) = thick0(:,:) +    tmask_i(:,:) * tmask(:,:,jk) * e3t_0(:,:,jk)
216      END DO
217      IF( lk_mpp )   CALL mpp_sum( vol0 )
218     
219      CALL iom_open ( 'data_1m_salinity_nomask', inum )
220      CALL iom_get  ( inum, jpdom_data, 'vosaline', zsaldta(:,:,:,1), 1  )
221      CALL iom_get  ( inum, jpdom_data, 'vosaline', zsaldta(:,:,:,2), 12 )
222      CALL iom_close( inum )
223      sn0(:,:,:) = 0.5_wp * ( zsaldta(:,:,:,1) + zsaldta(:,:,:,2) )       
224      sn0(:,:,:) = sn0(:,:,:) * tmask(:,:,:)
225      IF( ln_zps ) THEN               ! z-coord. partial steps
226         DO jj = 1, jpj               ! interpolation of salinity at the last ocean level (i.e. the partial step)
227            DO ji = 1, jpi
228               ik = mbkt(ji,jj)
229               IF( ik > 1 ) THEN
230                  zztmp = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
231                  sn0(ji,jj,ik) = ( 1._wp - zztmp ) * sn0(ji,jj,ik) + zztmp * sn0(ji,jj,ik-1)
232               ENDIF
233            END DO
234         END DO
235      ENDIF
236      !
237      CALL wrk_dealloc( jpi , jpj , jpk, jpts, zsaldta )
238      !
239      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5_init')
240      !
241   END SUBROUTINE dia_ar5_init
242
243#else
244   !!----------------------------------------------------------------------
245   !!   Default option :                                         NO diaar5
246   !!----------------------------------------------------------------------
247   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .FALSE.   ! coupled flag
248CONTAINS
249   SUBROUTINE dia_ar5_init    ! Dummy routine
250   END SUBROUTINE dia_ar5_init
251   SUBROUTINE dia_ar5( kt )   ! Empty routine
252      INTEGER ::   kt
253      WRITE(*,*) 'dia_ar5: You should not have seen this print! error?', kt
254   END SUBROUTINE dia_ar5
255#endif
256
257   !!======================================================================
258END MODULE diaar5
Note: See TracBrowser for help on using the repository browser.