source: trunk/NEMOGCM/NEMO/OPA_SRC/DOM/daymod.F90 @ 5002

Last change on this file since 5002 was 5002, checked in by smasson, 6 years ago

cut a line exceeding 132 characters in daymod

  • Property svn:keywords set to Id
File size: 18.2 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !!
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !!
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE trc_oce, ONLY : lk_offline ! offline flag
35   USE timing          ! Timing
36   USE restart         ! restart
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   day        ! called by step.F90
42   PUBLIC   day_init   ! called by istate.F90
43   PUBLIC   day_mth    ! Needed by TAM
44
45   INTEGER, PUBLIC ::   nsecd, nsecd05, ndt, ndt05 ! (PUBLIC for TAM)
46
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE day_init
55      !!----------------------------------------------------------------------
56      !!                   ***  ROUTINE day_init  ***
57      !!
58      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
59      !!                because day will be called at the beginning of step
60      !!
61      !! ** Action  : - nyear        : current year
62      !!              - nmonth       : current month of the year nyear
63      !!              - nday         : current day of the month nmonth
64      !!              - nday_year    : current day of the year nyear
65      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
66      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
67      !!              - nsec_day     : current time step counted in second since 00h of the current day
68      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
69      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
70      !!----------------------------------------------------------------------
71      INTEGER  ::   inbday, idweek
72      REAL(wp) ::   zjul
73      !!----------------------------------------------------------------------
74      !
75      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
76      IF( MOD( rday     , rdttra(1) ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
77      IF( MOD( rday     , 2.        ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
78      IF( MOD( rdttra(1), 2.        ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
79      nsecd   = NINT(rday           )
80      nsecd05 = NINT(0.5 * rday     )
81      ndt     = NINT(      rdttra(1))
82      ndt05   = NINT(0.5 * rdttra(1))
83
84      IF( .NOT. lk_offline ) CALL day_rst( nit000, 'READ' )
85
86      ! set the calandar from ndastp (read in restart file and namelist)
87
88      nyear   =   ndastp / 10000
89      nmonth  = ( ndastp - (nyear * 10000) ) / 100
90      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 )
91
92      CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday )  ! we assume that we start run at 00:00
93      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
94      fjulday = fjulday + 1.                             ! move back to the day at nit000 (and not at nit000 - 1)
95
96      nsec1jan000 = 0
97      CALL day_mth
98
99      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
100         nmonth = nmonth - 1
101         nday = nmonth_len(nmonth)
102      ENDIF
103      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
104         nmonth = 12
105         nyear = nyear - 1
106         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
107         IF( nleapy == 1 )   CALL day_mth
108      ENDIF
109
110      ! day since january 1st
111      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
112
113      !compute number of days between last monday and today
114      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
115      inbday = NINT(fjulday - zjul)            ! compute nb day between  01.01.1900 and current day
116      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day
117
118      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
119      nsec_year  = nday_year * nsecd - ndt05   ! 1 time step before the middle of the first time step
120      nsec_month = nday      * nsecd - ndt05   ! because day will be called at the beginning of step
121      nsec_week  = idweek    * nsecd - ndt05
122      nsec_day   =             nsecd - ndt05
123
124      ! control print
125      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8)')' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
126           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week
127
128      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
129      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
130      CALL day( nit000 )
131      !
132   END SUBROUTINE day_init
133
134
135   SUBROUTINE day_mth
136      !!----------------------------------------------------------------------
137      !!                   ***  ROUTINE day_init  ***
138      !!
139      !! ** Purpose :   calendar values related to the months
140      !!
141      !! ** Action  : - nmonth_len    : length in days of the months of the current year
142      !!              - nyear_len     : length in days of the previous/current year
143      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
144      !!              - nmonth_end    : second since the beginning of the year and the end of the months
145      !!----------------------------------------------------------------------
146      INTEGER  ::   jm               ! dummy loop indice
147      !!----------------------------------------------------------------------
148
149      ! length of the month of the current year (from nleapy, read in namelist)
150      IF ( nleapy < 2 ) THEN
151         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
152         nyear_len(:) = 365
153         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
154            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
155               nyear_len(0)  = 366
156            ENDIF
157            IF ( MOD(nyear  , 4) == 0 .AND. ( MOD(nyear  , 400) == 0 .OR. MOD(nyear  , 100) /= 0 ) ) THEN
158               nmonth_len(2) = 29
159               nyear_len(1)  = 366
160            ENDIF
161            IF ( MOD(nyear+1, 4) == 0 .AND. ( MOD(nyear+1, 400) == 0 .OR. MOD(nyear+1, 100) /= 0 ) ) THEN
162               nyear_len(2)  = 366
163            ENDIF
164         ENDIF
165      ELSE
166         nmonth_len(:) = nleapy   ! all months with nleapy days per year
167         nyear_len(:) = 12 * nleapy
168      ENDIF
169
170      ! half month in second since the begining of the year:
171      ! time since Jan 1st   0     1     2    ...    11    12    13
172      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
173      !                 <---> <---> <--->  ...  <---> <---> <--->
174      ! month number      0     1     2    ...    11    12    13
175      !
176      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
177      nmonth_half(0) = - nsecd05 * nmonth_len(0)
178      DO jm = 1, 13
179         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
180      END DO
181
182      nmonth_end(0) = 0
183      DO jm = 1, 13
184         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
185      END DO
186      !
187   END SUBROUTINE
188
189
190   SUBROUTINE day( kt )
191      !!----------------------------------------------------------------------
192      !!                      ***  ROUTINE day  ***
193      !!
194      !! ** Purpose :   Compute the date with a day iteration IF necessary.
195      !!
196      !! ** Method  : - ???
197      !!
198      !! ** Action  : - nyear     : current year
199      !!              - nmonth    : current month of the year nyear
200      !!              - nday      : current day of the month nmonth
201      !!              - nday_year : current day of the year nyear
202      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
203      !!              - adatrj    : date in days since the beginning of the run
204      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
205      !!----------------------------------------------------------------------
206      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
207      !
208      CHARACTER (len=25) ::   charout
209      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
210      !!----------------------------------------------------------------------
211      !
212      IF( nn_timing == 1 )  CALL timing_start('day')
213      !
214      zprec = 0.1 / rday
215      !                                                 ! New time-step
216      nsec_year  = nsec_year  + ndt
217      nsec_month = nsec_month + ndt
218      nsec_week  = nsec_week  + ndt
219      nsec_day   = nsec_day   + ndt
220      adatrj  = adatrj  + rdttra(1) / rday
221      fjulday = fjulday + rdttra(1) / rday
222      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
223      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
224
225      IF( nsec_day > nsecd ) THEN                       ! New day
226         !
227         nday      = nday + 1
228         nday_year = nday_year + 1
229         nsec_day  = ndt05
230         !
231         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
232            nday   = 1
233            nmonth = nmonth + 1
234            nsec_month = ndt05
235            IF( nmonth == 13 ) THEN                     ! New year
236               nyear     = nyear + 1
237               nmonth    = 1
238               nday_year = 1
239               nsec_year = ndt05
240               IF( nsec1jan000 >= 2 * (2**30 - nsecd * nyear_len(1) / 2 ) ) THEN   ! test integer 4 max value
241                  CALL ctl_stop( 'The number of seconds between Jan. 1st 00h of nit000 year and Jan. 1st 00h ',   &
242                     &           'of the current year is exceeding the INTEGER 4 max VALUE: 2^31-1 -> 68.09 years in seconds', &
243                     & 'You must do a restart at higher frequency (or remove this STOP and recompile everything in I8)' )
244               ENDIF
245               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
246               IF( nleapy == 1 )   CALL day_mth
247            ENDIF
248         ENDIF
249         !
250         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
251         !
252         !compute first day of the year in julian days
253         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
254         !
255         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
256              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
257         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
258              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
259      ENDIF
260
261      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
262
263      IF(ln_ctl) THEN
264         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
265         CALL prt_ctl_info(charout)
266      ENDIF
267
268      IF( .NOT. lk_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
269      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
270      !
271      IF( nn_timing == 1 )  CALL timing_stop('day')
272      !
273   END SUBROUTINE day
274
275
276   SUBROUTINE day_rst( kt, cdrw )
277      !!---------------------------------------------------------------------
278      !!                   ***  ROUTINE ts_rst  ***
279      !!
280      !!  ** Purpose : Read or write calendar in restart file:
281      !!
282      !!  WRITE(READ) mode:
283      !!       kt        : number of time step since the begining of the experiment at the
284      !!                   end of the current(previous) run
285      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
286      !!                   end of the current(previous) run (REAL -> keep fractions of day)
287      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
288      !!
289      !!   According to namelist parameter nrstdt,
290      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
291      !!       nrstdt = 1  we verify that nit000 is equal to the last
292      !!                   time step of previous run + 1.
293      !!       In both those options, the  exact duration of the experiment
294      !!       since the beginning (cumulated duration of all previous restart runs)
295      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
296      !!       This is valid is the time step has remained constant.
297      !!
298      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
299      !!                    has been stored in the restart file.
300      !!----------------------------------------------------------------------
301      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
302      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
303      !
304      REAL(wp) ::   zkt, zndastp
305      !!----------------------------------------------------------------------
306
307      IF( TRIM(cdrw) == 'READ' ) THEN
308
309         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
310            ! Get Calendar informations
311            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
312            IF(lwp) THEN
313               WRITE(numout,*) ' *** Info read in restart : '
314               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
315               WRITE(numout,*) ' *** restart option'
316               SELECT CASE ( nrstdt )
317               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
318               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
319               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
320               END SELECT
321               WRITE(numout,*)
322            ENDIF
323            ! Control of date
324            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
325                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
326                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
327            ! define ndastp and adatrj
328            IF ( nrstdt == 2 ) THEN
329               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
330               CALL iom_get( numror, 'ndastp', zndastp )
331               ndastp = NINT( zndastp )
332               CALL iom_get( numror, 'adatrj', adatrj  )
333            ELSE
334               ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
335               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
336               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
337               ! note this is wrong if time step has changed during run
338            ENDIF
339         ELSE
340            ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
341            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
342            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
343         ENDIF
344         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
345         !
346         IF(lwp) THEN
347            WRITE(numout,*) ' *** Info used values : '
348            WRITE(numout,*) '   date ndastp                                      : ', ndastp
349            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
350            WRITE(numout,*)
351         ENDIF
352         !
353      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
354         !
355         IF( kt == nitrst ) THEN
356            IF(lwp) WRITE(numout,*)
357            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
358            IF(lwp) WRITE(numout,*) '~~~~~~~'
359         ENDIF
360         ! calendar control
361         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
362         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
363         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
364         !                                                                     ! the begining of the run [s]
365      ENDIF
366      !
367   END SUBROUTINE day_rst
368
369   !!======================================================================
370END MODULE daymod
Note: See TracBrowser for help on using the repository browser.