New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domhgr.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DOM/domhgr.F90 @ 8314

Last change on this file since 8314 was 7753, checked in by mocavero, 7 years ago

Reverting trunk to remove OpenMP
  • Property svn:keywords set to Id
File size: 12.9 KB
RevLine 
[3]1MODULE domhgr
2   !!==============================================================================
[93]3   !!                       ***  MODULE domhgr   ***
[3]4   !! Ocean initialization : domain initialization
5   !!==============================================================================
[2528]6   !! History :  OPA  ! 1988-03  (G. Madec) Original code
7   !!            7.0  ! 1996-01  (G. Madec)  terrain following coordinates
8   !!            8.0  ! 1997-02  (G. Madec)  print mesh informations
9   !!            8.1  ! 1999-11  (M. Imbard) NetCDF format with IO-IPSL
10   !!            8.2  ! 2000-08  (D. Ludicone) Reduced section at Bab el Mandeb
11   !!             -   ! 2001-09  (M. Levy)  eel config: grid in km, beta-plane
12   !!  NEMO      1.0  ! 2002-08  (G. Madec)  F90: Free form and module, namelist
13   !!             -   ! 2004-01  (A.M. Treguier, J.M. Molines) Case 4 (Mercator mesh)
14   !!                            use of parameters in par_CONFIG-Rxx.h90, not in namelist
15   !!             -   ! 2004-05  (A. Koch-Larrouy) Add Gyre configuration
[5836]16   !!            3.7  ! 2015-09  (G. Madec, S. Flavoni) add cell surface and their inverse
17   !!                                       add optional read of e1e2u & e1e2v
[7646]18   !!             -   ! 2016-04  (S. Flavoni, G. Madec) new configuration interface: read or usrdef.F90
[473]19   !!----------------------------------------------------------------------
[3]20
21   !!----------------------------------------------------------------------
[2528]22   !!   dom_hgr       : initialize the horizontal mesh
[7646]23   !!   hgr_read      : read horizontal information in the domain configuration file
[3]24   !!----------------------------------------------------------------------
[2528]25   USE dom_oce        ! ocean space and time domain
[7646]26   USE par_oce        ! ocean space and time domain
[2528]27   USE phycst         ! physical constants
[7646]28   USE usrdef_hgr     ! User defined routine
[5836]29   !
[2528]30   USE in_out_manager ! I/O manager
[7646]31   USE iom            ! I/O library
[2528]32   USE lib_mpp        ! MPP library
[3294]33   USE timing         ! Timing
[3]34
35   IMPLICIT NONE
36   PRIVATE
37
[2528]38   PUBLIC   dom_hgr   ! called by domain.F90
39
[3]40   !!----------------------------------------------------------------------
[7646]41   !! NEMO/OPA 3.7 , NEMO Consortium (2016)
[7753]42   !! $Id$
[2528]43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[3]44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE dom_hgr
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE dom_hgr  ***
50      !!
[7646]51      !! ** Purpose :   Read or compute the geographical position (in degrees) 
52      !!      of the model grid-points, the horizontal scale factors (in meters),
53      !!      the associated horizontal metrics, and the Coriolis factor (in s-1).
[3]54      !!
[7646]55      !! ** Method  :   Controlled by ln_read_cfg logical
56      !!              =T : all needed arrays are read in mesh_mask.nc file
57      !!              =F : user-defined configuration, all needed arrays
58      !!                   are computed in usr-def_hgr subroutine
[3]59      !!
[7646]60      !!                If Coriolis factor is neither read nor computed (iff=0)
61      !!              it is computed from gphit assuming that the mesh is
62      !!              defined on the sphere :
63      !!                   ff = 2.*omega*sin(gphif)      (in s-1)
64      !!   
65      !!                If u- & v-surfaces are neither read nor computed (ie1e2u_v=0)
66      !!              (i.e. no use of reduced scale factors in some straits)
67      !!              they are computed from e1u, e2u, e1v and e2v as:
68      !!                   e1e2u = e1u*e2u   and   e1e2v = e1v*e2v 
69      !!   
70      !! ** Action  : - define longitude & latitude of t-, u-, v- and f-points (in degrees)
71      !!              - define Coriolis parameter at f-point                   (in 1/s)
72      !!              - define i- & j-scale factors at t-, u-, v- and f-points (in meters)
73      !!              - define associated horizontal metrics at t-, u-, v- and f-points
74      !!                (inverse of scale factors 1/e1 & 1/e2, surface e1*e2, ratios e1/e2 & e2/e1)
[3]75      !!----------------------------------------------------------------------
[7646]76      INTEGER ::   ji, jj     ! dummy loop indices
77      INTEGER ::   ie1e2u_v   ! flag for u- & v-surfaces
78      INTEGER ::   iff        ! flag for Coriolis parameter
[3]79      !!----------------------------------------------------------------------
[3294]80      !
81      IF( nn_timing == 1 )  CALL timing_start('dom_hgr')
82      !
[3]83      IF(lwp) THEN
84         WRITE(numout,*)
85         WRITE(numout,*) 'dom_hgr : define the horizontal mesh from ithe following par_oce parameters '
[7646]86         WRITE(numout,*) '~~~~~~~   '
87         WRITE(numout,*) '   namcfg : read (=T) or user defined (=F) configuration    ln_read_cfg  = ', ln_read_cfg
[3]88      ENDIF
[5836]89      !
90      !
[7646]91      IF( ln_read_cfg ) THEN        !==  read in mesh_mask.nc file  ==!
[3]92         IF(lwp) WRITE(numout,*)
[7646]93         IF(lwp) WRITE(numout,*) '          read horizontal mesh in ', TRIM( cn_domcfg ), ' file'
[5836]94         !
[7646]95         CALL hgr_read   ( glamt , glamu , glamv , glamf ,   &    ! geographic position (required)
96            &              gphit , gphiu , gphiv , gphif ,   &    !     -        -
97            &              iff   , ff_f  , ff_t  ,           &    ! Coriolis parameter (if not on the sphere)
98            &              e1t   , e1u   , e1v   , e1f   ,   &    ! scale factors (required)
99            &              e2t   , e2u   , e2v   , e2f   ,   &    !    -     -        -
100            &              ie1e2u_v      , e1e2u , e1e2v     )    ! u- & v-surfaces (if gridsize reduction in some straits)
[5836]101         !
[7646]102      ELSE                          !==  User defined configuration  ==!
[3]103         IF(lwp) WRITE(numout,*)
[7646]104         IF(lwp) WRITE(numout,*) '          User defined horizontal mesh (usr_def_hgr)'
[5836]105         !
[7646]106         CALL usr_def_hgr( glamt , glamu , glamv , glamf ,   &    ! geographic position (required)
107            &              gphit , gphiu , gphiv , gphif ,   &    !
108            &              iff   , ff_f  , ff_t  ,           &    ! Coriolis parameter  (if domain not on the sphere)
109            &              e1t   , e1u   , e1v   , e1f   ,   &    ! scale factors       (required)
110            &              e2t   , e2u   , e2v   , e2f   ,   &    !
111            &              ie1e2u_v      , e1e2u , e1e2v     )    ! u- & v-surfaces (if gridsize reduction is used in strait(s))
[5836]112         !
[7646]113      ENDIF
114      !
115      !                             !==  Coriolis parameter  ==!   (if necessary)
116      !
117      IF( iff == 0 ) THEN                 ! Coriolis parameter has not been defined
118         IF(lwp) WRITE(numout,*) '          Coriolis parameter calculated on the sphere from gphif & gphit'
[7753]119         ff_f(:,:) = 2. * omega * SIN( rad * gphif(:,:) )     ! compute it on the sphere at f-point
120         ff_t(:,:) = 2. * omega * SIN( rad * gphit(:,:) )     !    -        -       -    at t-point
[7646]121      ELSE
122         IF( ln_read_cfg ) THEN
123            IF(lwp) WRITE(numout,*) '          Coriolis parameter have been read in ', TRIM( cn_domcfg ), ' file'
124         ELSE
125            IF(lwp) WRITE(numout,*) '          Coriolis parameter have been set in usr_def_hgr routine'
[389]126         ENDIF
[7646]127      ENDIF
128
[5836]129      !
[7646]130      !                             !==  associated horizontal metrics  ==!
131      !
[7753]132      r1_e1t(:,:) = 1._wp / e1t(:,:)   ;   r1_e2t (:,:) = 1._wp / e2t(:,:)
133      r1_e1u(:,:) = 1._wp / e1u(:,:)   ;   r1_e2u (:,:) = 1._wp / e2u(:,:)
134      r1_e1v(:,:) = 1._wp / e1v(:,:)   ;   r1_e2v (:,:) = 1._wp / e2v(:,:)
135      r1_e1f(:,:) = 1._wp / e1f(:,:)   ;   r1_e2f (:,:) = 1._wp / e2f(:,:)
136      !
137      e1e2t (:,:) = e1t(:,:) * e2t(:,:)   ;   r1_e1e2t(:,:) = 1._wp / e1e2t(:,:)
138      e1e2f (:,:) = e1f(:,:) * e2f(:,:)   ;   r1_e1e2f(:,:) = 1._wp / e1e2f(:,:)
[7646]139      IF( ie1e2u_v == 0 ) THEN               ! u- & v-surfaces have not been defined
140         IF(lwp) WRITE(numout,*) '          u- & v-surfaces calculated as e1 e2 product'
[7753]141         e1e2u (:,:) = e1u(:,:) * e2u(:,:)         ! compute them
142         e1e2v (:,:) = e1v(:,:) * e2v(:,:) 
[7646]143      ELSE
144         IF(lwp) WRITE(numout,*) '          u- & v-surfaces have been read in "mesh_mask" file:'
145         IF(lwp) WRITE(numout,*) '                     grid size reduction in strait(s) is used'
[5836]146      ENDIF
[7753]147      r1_e1e2u(:,:) = 1._wp / e1e2u(:,:)     ! compute their invert in any cases
148      r1_e1e2v(:,:) = 1._wp / e1e2v(:,:)
149      !   
150      e2_e1u(:,:) = e2u(:,:) / e1u(:,:)
151      e1_e2v(:,:) = e1v(:,:) / e2v(:,:)
[5836]152      !
[3294]153      !
154      IF( nn_timing == 1 )  CALL timing_stop('dom_hgr')
155      !
[3]156   END SUBROUTINE dom_hgr
157
158
[7646]159   SUBROUTINE hgr_read( plamt , plamu , plamv  , plamf  ,   &    ! gridpoints position (required)
160      &                 pphit , pphiu , pphiv  , pphif  ,   &     
161      &                 kff   , pff_f , pff_t  ,            &    ! Coriolis parameter  (if not on the sphere)
162      &                 pe1t  , pe1u  , pe1v   , pe1f   ,   &    ! scale factors       (required)
163      &                 pe2t  , pe2u  , pe2v   , pe2f   ,   &
164      &                 ke1e2u_v      , pe1e2u , pe1e2v     )    ! u- & v-surfaces (if gridsize reduction in some straits)
[3]165      !!---------------------------------------------------------------------
[81]166      !!              ***  ROUTINE hgr_read  ***
[3]167      !!
[7646]168      !! ** Purpose :   Read a mesh_mask file in NetCDF format using IOM
[3]169      !!
170      !!----------------------------------------------------------------------
[7646]171      REAL(wp), DIMENSION(:,:), INTENT(out) ::   plamt, plamu, plamv, plamf   ! longitude outputs
172      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pphit, pphiu, pphiv, pphif   ! latitude outputs
173      INTEGER                 , INTENT(out) ::   kff                          ! =1 Coriolis parameter read here, =0 otherwise
174      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pff_f, pff_t                 ! Coriolis factor at f-point (if found in file)
175      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pe1t, pe1u, pe1v, pe1f       ! i-scale factors
176      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pe2t, pe2u, pe2v, pe2f       ! j-scale factors
177      INTEGER                 , INTENT(out) ::   ke1e2u_v                     ! =1 u- & v-surfaces read here, =0 otherwise
178      REAL(wp), DIMENSION(:,:), INTENT(out) ::   pe1e2u, pe1e2v              ! u- & v-surfaces (if found in file)
[5836]179      !
[7646]180      INTEGER  ::   inum                  ! logical unit
[3]181      !!----------------------------------------------------------------------
[5836]182      !
[3]183      IF(lwp) THEN
184         WRITE(numout,*)
[7646]185         WRITE(numout,*) 'hgr_read : read the horizontal coordinates in mesh_mask'
[473]186         WRITE(numout,*) '~~~~~~~~      jpiglo = ', jpiglo, ' jpjglo = ', jpjglo, ' jpk = ', jpk
[3]187      ENDIF
[5836]188      !
[7646]189      CALL iom_open( cn_domcfg, inum )
[5836]190      !
[7646]191      CALL iom_get( inum, jpdom_data, 'glamt', plamt, lrowattr=ln_use_jattr )
192      CALL iom_get( inum, jpdom_data, 'glamu', plamu, lrowattr=ln_use_jattr )
193      CALL iom_get( inum, jpdom_data, 'glamv', plamv, lrowattr=ln_use_jattr )
194      CALL iom_get( inum, jpdom_data, 'glamf', plamf, lrowattr=ln_use_jattr )
[5836]195      !
[7646]196      CALL iom_get( inum, jpdom_data, 'gphit', pphit, lrowattr=ln_use_jattr )
197      CALL iom_get( inum, jpdom_data, 'gphiu', pphiu, lrowattr=ln_use_jattr )
198      CALL iom_get( inum, jpdom_data, 'gphiv', pphiv, lrowattr=ln_use_jattr )
199      CALL iom_get( inum, jpdom_data, 'gphif', pphif, lrowattr=ln_use_jattr )
[5836]200      !
[7646]201      CALL iom_get( inum, jpdom_data, 'e1t'  , pe1t  , lrowattr=ln_use_jattr )
202      CALL iom_get( inum, jpdom_data, 'e1u'  , pe1u  , lrowattr=ln_use_jattr )
203      CALL iom_get( inum, jpdom_data, 'e1v'  , pe1v  , lrowattr=ln_use_jattr )
204      CALL iom_get( inum, jpdom_data, 'e1f'  , pe1f  , lrowattr=ln_use_jattr )
[5836]205      !
[7646]206      CALL iom_get( inum, jpdom_data, 'e2t'  , pe2t  , lrowattr=ln_use_jattr )
207      CALL iom_get( inum, jpdom_data, 'e2u'  , pe2u  , lrowattr=ln_use_jattr )
208      CALL iom_get( inum, jpdom_data, 'e2v'  , pe2v  , lrowattr=ln_use_jattr )
209      CALL iom_get( inum, jpdom_data, 'e2f'  , pe2f  , lrowattr=ln_use_jattr )
[5836]210      !
[7646]211      IF(  iom_varid( inum, 'ff_f', ldstop = .FALSE. ) > 0  .AND.  &
212         & iom_varid( inum, 'ff_t', ldstop = .FALSE. ) > 0    ) THEN
213         IF(lwp) WRITE(numout,*) '           Coriolis factor at f- and t-points read in ', TRIM( cn_domcfg ), ' file'
214         CALL iom_get( inum, jpdom_data, 'ff_f'  , pff_f  , lrowattr=ln_use_jattr )
215         CALL iom_get( inum, jpdom_data, 'ff_t'  , pff_t  , lrowattr=ln_use_jattr )
216         kff = 1
217      ELSE
218         kff = 0
219      ENDIF
220      !
[5836]221      IF( iom_varid( inum, 'e1e2u', ldstop = .FALSE. ) > 0 ) THEN
[7646]222         IF(lwp) WRITE(numout,*) '           e1e2u & e1e2v read in ', TRIM( cn_domcfg ), ' file'
223         CALL iom_get( inum, jpdom_data, 'e1e2u'  , pe1e2u  , lrowattr=ln_use_jattr )
224         CALL iom_get( inum, jpdom_data, 'e1e2v'  , pe1e2v  , lrowattr=ln_use_jattr )
[5836]225         ke1e2u_v = 1
226      ELSE
227         ke1e2u_v = 0
228      ENDIF
229      !
[473]230      CALL iom_close( inum )
[7646]231      !
232   END SUBROUTINE hgr_read
[473]233   
[3]234   !!======================================================================
235END MODULE domhgr
Note: See TracBrowser for help on using the repository browser.