| 1 | MODULE dynbfr |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE dynbfr *** |
|---|
| 4 | !! Ocean dynamics : bottom friction component of the momentum mixing trend |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : 3.2 ! 2008-11 (A. C. Coward) Original code |
|---|
| 7 | !! 3.4 ! 2011-09 (H. Liu) Make it consistent with semi-implicit |
|---|
| 8 | !! Bottom friction (ln_bfrimp = .true.) |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! dyn_bfr : Update the momentum trend with the bottom friction contribution |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | USE oce ! ocean dynamics and tracers variables |
|---|
| 15 | USE dom_oce ! ocean space and time domain variables |
|---|
| 16 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 17 | USE zdfbfr ! ocean bottom friction variables |
|---|
| 18 | USE trd_oce ! trends: ocean variables |
|---|
| 19 | USE trddyn ! trend manager: dynamics |
|---|
| 20 | USE in_out_manager ! I/O manager |
|---|
| 21 | USE prtctl ! Print control |
|---|
| 22 | USE timing ! Timing |
|---|
| 23 | USE wrk_nemo ! Memory Allocation |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC dyn_bfr ! routine called by step.F90 |
|---|
| 29 | |
|---|
| 30 | !! * Substitutions |
|---|
| 31 | # include "vectopt_loop_substitute.h90" |
|---|
| 32 | !!---------------------------------------------------------------------- |
|---|
| 33 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 34 | !! $Id$ |
|---|
| 35 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | CONTAINS |
|---|
| 38 | |
|---|
| 39 | SUBROUTINE dyn_bfr( kt ) |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | !! *** ROUTINE dyn_bfr *** |
|---|
| 42 | !! |
|---|
| 43 | !! ** Purpose : compute the bottom friction ocean dynamics physics. |
|---|
| 44 | !! |
|---|
| 45 | !! ** Action : (ua,va) momentum trend increased by bottom friction trend |
|---|
| 46 | !!--------------------------------------------------------------------- |
|---|
| 47 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 48 | !! |
|---|
| 49 | INTEGER :: jk, ji, jj ! dummy loop indexes |
|---|
| 50 | INTEGER :: ikbu, ikbv ! local integers |
|---|
| 51 | REAL(wp) :: zm1_2dt ! local scalar |
|---|
| 52 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv |
|---|
| 53 | !!--------------------------------------------------------------------- |
|---|
| 54 | ! |
|---|
| 55 | IF( nn_timing == 1 ) CALL timing_start('dyn_bfr') |
|---|
| 56 | ! |
|---|
| 57 | !!gm issue: better to put the logical in step to control the call of zdf_bfr |
|---|
| 58 | !! ==> change the logical from ln_bfrimp to ln_bfr_exp !! |
|---|
| 59 | IF( .NOT.ln_bfrimp) THEN ! only for explicit bottom friction form |
|---|
| 60 | ! implicit bfr is implemented in dynzdf_imp |
|---|
| 61 | |
|---|
| 62 | !!gm bug : time step is only rdt (not 2 rdt if euler start !) |
|---|
| 63 | zm1_2dt = - 1._wp / ( 2._wp * rdt ) |
|---|
| 64 | |
|---|
| 65 | IF( l_trddyn ) THEN ! trends: store the input trends |
|---|
| 66 | CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv ) |
|---|
| 67 | !$OMP PARALLEL DO schedule(static) private(jk, jj, ji) |
|---|
| 68 | DO jk = 1, jpk |
|---|
| 69 | DO jj = 1, jpj |
|---|
| 70 | DO ji = 1, jpi |
|---|
| 71 | ztrdu(ji,jj,jk) = ua(ji,jj,jk) |
|---|
| 72 | ztrdv(ji,jj,jk) = va(ji,jj,jk) |
|---|
| 73 | END DO |
|---|
| 74 | END DO |
|---|
| 75 | END DO |
|---|
| 76 | ENDIF |
|---|
| 77 | |
|---|
| 78 | |
|---|
| 79 | !$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv) |
|---|
| 80 | DO jj = 2, jpjm1 |
|---|
| 81 | DO ji = 2, jpim1 |
|---|
| 82 | ikbu = mbku(ji,jj) ! deepest ocean u- & v-levels |
|---|
| 83 | ikbv = mbkv(ji,jj) |
|---|
| 84 | ! |
|---|
| 85 | ! Apply stability criteria on absolute value : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt) |
|---|
| 86 | ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + MAX( bfrua(ji,jj) / e3u_n(ji,jj,ikbu) , zm1_2dt ) * ub(ji,jj,ikbu) |
|---|
| 87 | va(ji,jj,ikbv) = va(ji,jj,ikbv) + MAX( bfrva(ji,jj) / e3v_n(ji,jj,ikbv) , zm1_2dt ) * vb(ji,jj,ikbv) |
|---|
| 88 | END DO |
|---|
| 89 | END DO |
|---|
| 90 | ! |
|---|
| 91 | IF( ln_isfcav ) THEN ! ocean cavities |
|---|
| 92 | !$OMP PARALLEL DO schedule(static) private(jj, ji, ikbu, ikbv) |
|---|
| 93 | DO jj = 2, jpjm1 |
|---|
| 94 | DO ji = 2, jpim1 |
|---|
| 95 | ! (ISF) stability criteria for top friction |
|---|
| 96 | ikbu = miku(ji,jj) ! first wet ocean u- & v-levels |
|---|
| 97 | ikbv = mikv(ji,jj) |
|---|
| 98 | ! |
|---|
| 99 | ! Apply stability criteria on absolute value : abs(bfr/e3) < 1/(2dt) => bfr/e3 > -1/(2dt) |
|---|
| 100 | ua(ji,jj,ikbu) = ua(ji,jj,ikbu) + MAX( tfrua(ji,jj) / e3u_n(ji,jj,ikbu) , zm1_2dt ) * ub(ji,jj,ikbu) & |
|---|
| 101 | & * (1.-umask(ji,jj,1)) |
|---|
| 102 | va(ji,jj,ikbv) = va(ji,jj,ikbv) + MAX( tfrva(ji,jj) / e3v_n(ji,jj,ikbv) , zm1_2dt ) * vb(ji,jj,ikbv) & |
|---|
| 103 | & * (1.-vmask(ji,jj,1)) |
|---|
| 104 | ! (ISF) |
|---|
| 105 | END DO |
|---|
| 106 | END DO |
|---|
| 107 | END IF |
|---|
| 108 | ! |
|---|
| 109 | IF( l_trddyn ) THEN ! trends: send trends to trddyn for further diagnostics |
|---|
| 110 | !$OMP PARALLEL DO schedule(static) private(jk, jj, ji) |
|---|
| 111 | DO jk = 1, jpk |
|---|
| 112 | DO jj = 1, jpj |
|---|
| 113 | DO ji = 1, jpi |
|---|
| 114 | ztrdu(ji,jj,jk) = ua(ji,jj,jk) - ztrdu(ji,jj,jk) |
|---|
| 115 | ztrdv(ji,jj,jk) = va(ji,jj,jk) - ztrdv(ji,jj,jk) |
|---|
| 116 | END DO |
|---|
| 117 | END DO |
|---|
| 118 | END DO |
|---|
| 119 | CALL trd_dyn( ztrdu(:,:,:), ztrdv(:,:,:), jpdyn_bfr, kt ) |
|---|
| 120 | CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv ) |
|---|
| 121 | ENDIF |
|---|
| 122 | ! ! print mean trends (used for debugging) |
|---|
| 123 | IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' bfr - Ua: ', mask1=umask, & |
|---|
| 124 | & tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' ) |
|---|
| 125 | ! |
|---|
| 126 | ENDIF ! end explicit bottom friction |
|---|
| 127 | ! |
|---|
| 128 | IF( nn_timing == 1 ) CALL timing_stop('dyn_bfr') |
|---|
| 129 | ! |
|---|
| 130 | END SUBROUTINE dyn_bfr |
|---|
| 131 | |
|---|
| 132 | !!============================================================================== |
|---|
| 133 | END MODULE dynbfr |
|---|
