New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 2524

Last change on this file since 2524 was 2466, checked in by cetlod, 13 years ago

v3.2 : suppress useless parameter nn_dynhpg_rst, see ticket:769
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 51.7 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  1.0  !  87-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  91-11  (G. Madec)
8   !!            7.0  !  96-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  97-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  02-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  02-08  (A. Bozec)  hpg_zps: Original code
12   !!            9.0  !  05-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                           Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!            9.0  !  05-11  (G. Madec) style & small optimisation
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   dyn_hpg      : update the momentum trend with the now horizontal
19   !!                  gradient of the hydrostatic pressure
20   !!       hpg_ctl  : initialisation and control of options
21   !!       hpg_zco  : z-coordinate scheme
22   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
23   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
24   !!       hpg_hel  : s-coordinate (helsinki modification)
25   !!       hpg_wdj  : s-coordinate (weighted density jacobian)
26   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
27   !!       hpg_rot  : s-coordinate (ROTated axes scheme)
28   !!----------------------------------------------------------------------
29   USE oce             ! ocean dynamics and tracers
30   USE dom_oce         ! ocean space and time domain
31   USE phycst          ! physical constants
32   USE in_out_manager  ! I/O manager
33   USE trdmod          ! ocean dynamics trends
34   USE trdmod_oce      ! ocean variables trends
35   USE prtctl          ! Print control
36   USE lbclnk          ! lateral boundary condition
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   dyn_hpg    ! routine called by step module
42
43   !                                              !!* Namelist namdyn_hpg : hydrostatic pressure gradient
44   LOGICAL , PUBLIC ::   ln_hpg_zco    = .TRUE.    !: z-coordinate - full steps
45   LOGICAL , PUBLIC ::   ln_hpg_zps    = .FALSE.   !: z-coordinate - partial steps (interpolation)
46   LOGICAL , PUBLIC ::   ln_hpg_sco    = .FALSE.   !: s-coordinate (standard jacobian formulation)
47   LOGICAL , PUBLIC ::   ln_hpg_hel    = .FALSE.   !: s-coordinate (helsinki modification)
48   LOGICAL , PUBLIC ::   ln_hpg_wdj    = .FALSE.   !: s-coordinate (weighted density jacobian)
49   LOGICAL , PUBLIC ::   ln_hpg_djc    = .FALSE.   !: s-coordinate (Density Jacobian with Cubic polynomial)
50   LOGICAL , PUBLIC ::   ln_hpg_rot    = .FALSE.   !: s-coordinate (ROTated axes scheme)
51   REAL(wp), PUBLIC ::   rn_gamma      = 0.e0      !: weighting coefficient
52   LOGICAL , PUBLIC ::   ln_dynhpg_imp = .FALSE.   !: semi-implicite hpg flag
53
54   INTEGER  ::   nhpg  =  0   ! = 0 to 6, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags)
55
56   !! * Substitutions
57#  include "domzgr_substitute.h90"
58#  include "vectopt_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !!   OPA 9.0 , LOCEAN-IPSL (2005)
61   !! $Id$
62   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64
65CONTAINS
66
67   SUBROUTINE dyn_hpg( kt )
68      !!---------------------------------------------------------------------
69      !!                  ***  ROUTINE dyn_hpg  ***
70      !!
71      !! ** Method  :   Call the hydrostatic pressure gradient routine
72      !!              using the scheme defined in the namelist
73      !!   
74      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
75      !!             - Save the trend (l_trddyn=T)
76      !!----------------------------------------------------------------------
77      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
78      !!
79      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztrdu, ztrdv   ! 3D temporary workspace
80      !!----------------------------------------------------------------------
81   
82      IF( kt == nit000 )   CALL hpg_ctl      ! initialisation & control of options
83
84      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
85         ztrdu(:,:,:) = ua(:,:,:) 
86         ztrdv(:,:,:) = va(:,:,:) 
87      ENDIF     
88
89      SELECT CASE ( nhpg )      ! Hydrastatic pressure gradient computation
90      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
91      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
92      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
93      CASE (  3 )   ;   CALL hpg_hel    ( kt )      ! s-coordinate (helsinki modification)
94      CASE (  4 )   ;   CALL hpg_wdj    ( kt )      ! s-coordinate (weighted density jacobian)
95      CASE (  5 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
96      CASE (  6 )   ;   CALL hpg_rot    ( kt )      ! s-coordinate (ROTated axes scheme)
97      END SELECT
98
99      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
100         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
101         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
102         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
103      ENDIF         
104      !
105      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
106         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
107      !
108   END SUBROUTINE dyn_hpg
109
110
111   SUBROUTINE hpg_ctl
112      !!----------------------------------------------------------------------
113      !!                 ***  ROUTINE hpg_ctl  ***
114      !!
115      !! ** Purpose :   initializations for the hydrostatic pressure gradient
116      !!              computation and consistency control
117      !!
118      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
119      !!      with the type of vertical coordinate used (zco, zps, sco)
120      !!----------------------------------------------------------------------
121      INTEGER ::   ioptio = 0      ! temporary integer
122      !!
123!     NAMELIST/namdyn_hpg/ ln_hpg_zco   , ln_hpg_zps   , ln_hpg_sco, ln_hpg_hel,   &
124!        &                 ln_hpg_wdj   , ln_hpg_djc   , ln_hpg_rot, rn_gamma  ,   &
125!        &                 ln_dynhpg_imp
126      !!----------------------------------------------------------------------
127
128!     REWIND ( numnam )               ! Namelist namdyn_hpg : already read in opa.F90 module
129!     READ   ( numnam, namdyn_hpg )
130
131      IF(lwp) THEN                    ! Control print
132         WRITE(numout,*)
133         WRITE(numout,*) 'dyn_hpg : hydrostatic pressure gradient'
134         WRITE(numout,*) '~~~~~~~'
135         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
136         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
137         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
138         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
139         WRITE(numout,*) '      s-coord. (helsinki modification)                  ln_hpg_hel    = ', ln_hpg_hel
140         WRITE(numout,*) '      s-coord. (weighted density jacobian)              ln_hpg_wdj    = ', ln_hpg_wdj
141         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
142         WRITE(numout,*) '      s-coord. (ROTated axes scheme)                    ln_hpg_rot    = ', ln_hpg_rot
143         WRITE(numout,*) '      weighting coeff. (wdj scheme)                     rn_gamma      = ', rn_gamma
144         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
145      ENDIF
146
147      IF( lk_vvl .AND. .NOT. ln_hpg_sco )   THEN
148         CALL ctl_stop( 'hpg_ctl : variable volume key_vvl compatible only with the standard jacobian formulation hpg_sco')
149      ENDIF
150
151      !                               ! Set nhpg from ln_hpg_... flags
152      IF( ln_hpg_zco )   nhpg = 0
153      IF( ln_hpg_zps )   nhpg = 1
154      IF( ln_hpg_sco )   nhpg = 2
155      IF( ln_hpg_hel )   nhpg = 3
156      IF( ln_hpg_wdj )   nhpg = 4
157      IF( ln_hpg_djc )   nhpg = 5
158      IF( ln_hpg_rot )   nhpg = 6
159
160      !                               ! Consitency check
161      ioptio = 0 
162      IF( ln_hpg_zco )   ioptio = ioptio + 1
163      IF( ln_hpg_zps )   ioptio = ioptio + 1
164      IF( ln_hpg_sco )   ioptio = ioptio + 1
165      IF( ln_hpg_hel )   ioptio = ioptio + 1
166      IF( ln_hpg_wdj )   ioptio = ioptio + 1
167      IF( ln_hpg_djc )   ioptio = ioptio + 1
168      IF( ln_hpg_rot )   ioptio = ioptio + 1
169      IF ( ioptio /= 1 )   CALL ctl_stop( ' NO or several hydrostatic pressure gradient options used' )
170
171      !
172   END SUBROUTINE hpg_ctl
173
174
175   SUBROUTINE hpg_zco( kt )
176      !!---------------------------------------------------------------------
177      !!                  ***  ROUTINE hpg_zco  ***
178      !!
179      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
180      !!      The now hydrostatic pressure gradient at a given level, jk,
181      !!      is computed by taking the vertical integral of the in-situ
182      !!      density gradient along the model level from the suface to that
183      !!      level:    zhpi = grav .....
184      !!                zhpj = grav .....
185      !!      add it to the general momentum trend (ua,va).
186      !!            ua = ua - 1/e1u * zhpi
187      !!            va = va - 1/e2v * zhpj
188      !!
189      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
190      !!----------------------------------------------------------------------
191      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
192      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
193      !!
194      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
195      !!
196      INTEGER  ::   ji, jj, jk       ! dummy loop indices
197      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
198      !!----------------------------------------------------------------------
199     
200      IF( kt == nit000 ) THEN
201         IF(lwp) WRITE(numout,*)
202         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
203         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
204      ENDIF
205     
206      ! Local constant initialization
207      zcoef0 = - grav * 0.5
208
209      ! Surface value
210      DO jj = 2, jpjm1
211         DO ji = fs_2, fs_jpim1   ! vector opt.
212            zcoef1 = zcoef0 * fse3w(ji,jj,1)
213            ! hydrostatic pressure gradient
214            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
215            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
216            ! add to the general momentum trend
217            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
218            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
219         END DO
220      END DO
221      !
222      ! interior value (2=<jk=<jpkm1)
223      DO jk = 2, jpkm1
224         DO jj = 2, jpjm1
225            DO ji = fs_2, fs_jpim1   ! vector opt.
226               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
227               ! hydrostatic pressure gradient
228               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
229                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
230                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
231
232               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
233                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
234                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
235               ! add to the general momentum trend
236               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
237               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
238            END DO
239         END DO
240      END DO
241      !
242   END SUBROUTINE hpg_zco
243
244
245   SUBROUTINE hpg_zps( kt )
246      !!---------------------------------------------------------------------
247      !!                 ***  ROUTINE hpg_zps  ***
248      !!                   
249      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
250      !!
251      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
252      !!----------------------------------------------------------------------
253      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
254      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
255      !!
256      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
257      !!
258      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
259      INTEGER  ::   iku, ikv                         ! temporary integers
260      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
261      !!----------------------------------------------------------------------
262
263      IF( kt == nit000 ) THEN
264         IF(lwp) WRITE(numout,*)
265         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
266         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
267      ENDIF
268
269      ! Local constant initialization
270      zcoef0 = - grav * 0.5
271
272      !  Surface value
273      DO jj = 2, jpjm1
274         DO ji = fs_2, fs_jpim1   ! vector opt.
275            zcoef1 = zcoef0 * fse3w(ji,jj,1)
276            ! hydrostatic pressure gradient
277            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
278            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
279            ! add to the general momentum trend
280            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
281            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
282         END DO
283      END DO
284
285      ! interior value (2=<jk=<jpkm1)
286      DO jk = 2, jpkm1
287         DO jj = 2, jpjm1
288            DO ji = fs_2, fs_jpim1   ! vector opt.
289               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
290               ! hydrostatic pressure gradient
291               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
292                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
293                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
294
295               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
296                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
297                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
298               ! add to the general momentum trend
299               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
300               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
301            END DO
302         END DO
303      END DO
304
305      ! partial steps correction at the last level  (new gradient with  intgrd.F)
306# if defined key_vectopt_loop
307         jj = 1
308         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
309# else
310      DO jj = 2, jpjm1
311         DO ji = 2, jpim1
312# endif
313            iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj) ) - 1
314            ikv = MIN ( mbathy(ji,jj), mbathy(ji,jj+1) ) - 1
315            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
316            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
317            ! on i-direction
318            IF ( iku > 2 ) THEN
319               ! subtract old value
320               ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)
321               ! compute the new one
322               zhpi (ji,jj,iku) = zhpi(ji,jj,iku-1)   &
323                  + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
324               ! add the new one to the general momentum trend
325               ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)
326            ENDIF
327            ! on j-direction
328            IF ( ikv > 2 ) THEN
329               ! subtract old value
330               va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)
331               ! compute the new one
332               zhpj (ji,jj,ikv) = zhpj(ji,jj,ikv-1)   &
333                  + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
334               ! add the new one to the general momentum trend
335               va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)
336            ENDIF
337# if ! defined key_vectopt_loop
338         END DO
339# endif
340      END DO
341      !
342   END SUBROUTINE hpg_zps
343
344
345   SUBROUTINE hpg_sco( kt )
346      !!---------------------------------------------------------------------
347      !!                  ***  ROUTINE hpg_sco  ***
348      !!
349      !! ** Method  :   s-coordinate case. Jacobian scheme.
350      !!      The now hydrostatic pressure gradient at a given level, jk,
351      !!      is computed by taking the vertical integral of the in-situ
352      !!      density gradient along the model level from the suface to that
353      !!      level. s-coordinates (ln_sco): a corrective term is added
354      !!      to the horizontal pressure gradient :
355      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
356      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
357      !!      add it to the general momentum trend (ua,va).
358      !!         ua = ua - 1/e1u * zhpi
359      !!         va = va - 1/e2v * zhpj
360      !!
361      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
362      !!----------------------------------------------------------------------
363      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
364      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
365      !!
366      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
367      !!
368      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
369      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
370      !!----------------------------------------------------------------------
371
372      IF( kt == nit000 ) THEN
373         IF(lwp) WRITE(numout,*)
374         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
375         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
376      ENDIF
377
378      ! Local constant initialization
379      zcoef0 = - grav * 0.5
380      ! To use density and not density anomaly
381      IF ( lk_vvl ) THEN   ;     znad = 1.            ! Variable volume
382      ELSE                 ;     znad = 0.e0          ! Fixed volume
383      ENDIF
384
385      ! Surface value
386      DO jj = 2, jpjm1
387         DO ji = fs_2, fs_jpim1   ! vector opt.   
388            ! hydrostatic pressure gradient along s-surfaces
389            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
390               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
391            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
392               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
393            ! s-coordinate pressure gradient correction
394            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2*znad )   &
395               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
396            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2*znad )   &
397               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
398            ! add to the general momentum trend
399            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
400            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
401         END DO 
402      END DO   
403           
404      ! interior value (2=<jk=<jpkm1)
405      DO jk = 2, jpkm1                                 
406         DO jj = 2, jpjm1     
407            DO ji = fs_2, fs_jpim1   ! vector opt.     
408               ! hydrostatic pressure gradient along s-surfaces
409               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
410                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   & 
411                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
412               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
413                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
414                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
415               ! s-coordinate pressure gradient correction
416               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2*znad )   &
417                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
418               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2*znad )   &
419                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
420               ! add to the general momentum trend
421               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
422               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
423            END DO
424         END DO
425      END DO
426      !
427   END SUBROUTINE hpg_sco
428
429
430   SUBROUTINE hpg_hel( kt )
431      !!---------------------------------------------------------------------
432      !!                  ***  ROUTINE hpg_hel  ***
433      !!
434      !! ** Method  :   s-coordinate case.
435      !!      The now hydrostatic pressure gradient at a given level
436      !!      jk is computed by taking the vertical integral of the in-situ
437      !!      density gradient along the model level from the suface to that
438      !!      level. s-coordinates (ln_sco): a corrective term is added
439      !!      to the horizontal pressure gradient :
440      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
441      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
442      !!      add it to the general momentum trend (ua,va).
443      !!         ua = ua - 1/e1u * zhpi
444      !!         va = va - 1/e2v * zhpj
445      !!
446      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
447      !!             - Save the trend (l_trddyn=T)
448      !!----------------------------------------------------------------------
449      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
450      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
451      !!
452      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
453      !!
454      INTEGER  ::   ji, jj, jk           ! dummy loop indices
455      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
456      !!----------------------------------------------------------------------
457
458      IF( kt == nit000 ) THEN
459         IF(lwp) WRITE(numout,*)
460         IF(lwp) WRITE(numout,*) 'dyn:hpg_hel : hydrostatic pressure gradient trend'
461         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, helsinki modified scheme'
462      ENDIF
463
464      ! Local constant initialization
465      zcoef0 = - grav * 0.5
466 
467      ! Surface value
468      DO jj = 2, jpjm1
469         DO ji = fs_2, fs_jpim1   ! vector opt.
470            ! hydrostatic pressure gradient along s-surfaces
471            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  &
472               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
473            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)  &
474               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
475            ! s-coordinate pressure gradient correction
476            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
477               &           * ( fsdept(ji+1,jj,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
478            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
479               &           * ( fsdept(ji,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
480            ! add to the general momentum trend
481            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
482            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
483         END DO
484      END DO
485      !
486      ! interior value (2=<jk=<jpkm1)
487      DO jk = 2, jpkm1
488         DO jj = 2, jpjm1
489            DO ji = fs_2, fs_jpim1   ! vector opt.
490               ! hydrostatic pressure gradient along s-surfaces
491               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
492                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk)     &
493                  &                                     -fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk)   ) &
494                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
495                  &                                     -fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1) )
496               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
497                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk)   &
498                  &                                     -fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk)   ) &
499                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1) &
500                  &                                     -fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1) )
501               ! s-coordinate pressure gradient correction
502               zuap = - zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )   &
503                  &            * ( fsdept(ji+1,jj,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
504               zvap = - zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )   &
505                  &            * ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
506               ! add to the general momentum trend
507               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
508               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
509            END DO
510         END DO
511      END DO
512      !
513   END SUBROUTINE hpg_hel
514
515
516   SUBROUTINE hpg_wdj( kt )
517      !!---------------------------------------------------------------------
518      !!                  ***  ROUTINE hpg_wdj  ***
519      !!
520      !! ** Method  :   Weighted Density Jacobian (wdj) scheme (song 1998)
521      !!      The weighting coefficients from the namelist parameter rn_gamma
522      !!      (alpha=0.5-rn_gamma ; beta=1-alpha=0.5+rn_gamma
523      !!
524      !! Reference : Song, Mon. Wea. Rev., 126, 3213-3230, 1998.
525      !!----------------------------------------------------------------------
526      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
527      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
528      !!
529      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
530      !!
531      INTEGER  ::   ji, jj, jk           ! dummy loop indices
532      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
533      REAL(wp) ::   zalph , zbeta        !    "         "
534      !!----------------------------------------------------------------------
535
536      IF( kt == nit000 ) THEN
537         IF(lwp) WRITE(numout,*)
538         IF(lwp) WRITE(numout,*) 'dyn:hpg_wdj : hydrostatic pressure gradient trend'
539         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   Weighted Density Jacobian'
540      ENDIF
541
542      ! Local constant initialization
543      zcoef0 = - grav * 0.5
544      zalph  = 0.5 - rn_gamma    ! weighting coefficients (alpha=0.5-rn_gamma
545      zbeta  = 0.5 + rn_gamma    !                        (beta =1-alpha=0.5+rn_gamma
546
547      ! Surface value (no ponderation)
548      DO jj = 2, jpjm1
549         DO ji = fs_2, fs_jpim1   ! vector opt.
550            ! hydrostatic pressure gradient along s-surfaces
551            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
552               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
553            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
554               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji,  jj  ,1)  )
555            ! s-coordinate pressure gradient correction
556            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
557               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
558            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
559               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
560            ! add to the general momentum trend
561            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
562            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
563         END DO
564      END DO
565
566      ! Interior value (2=<jk=<jpkm1) (weighted with zalph & zbeta)
567      DO jk = 2, jpkm1
568         DO jj = 2, jpjm1
569            DO ji = fs_2, fs_jpim1   ! vector opt.
570               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)                            &
571                  &           * (   (            fsde3w(ji+1,jj,jk  ) + fsde3w(ji,jj,jk  )        &
572                  &                            - fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1)    )   &
573                  &               * (  zalph * ( rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1) )      &
574                  &                  + zbeta * ( rhd   (ji+1,jj,jk  ) - rhd   (ji,jj,jk  ) )  )   &
575                  &             -   (            rhd   (ji+1,jj,jk  ) + rhd   (ji,jj,jk  )        &
576                  &                           - rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1)     )   &
577                  &               * (  zalph * ( fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1) )      &
578                  &                  + zbeta * ( fsde3w(ji+1,jj,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
579               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)                            &
580                  &           * (   (           fsde3w(ji,jj+1,jk  ) + fsde3w(ji,jj,jk  )         &
581                  &                           - fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1)     )   &
582                  &               * (  zalph * ( rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1) )      &
583                  &                  + zbeta * ( rhd   (ji,jj+1,jk  ) - rhd   (ji,jj,jk  ) )  )   &
584                  &             -   (            rhd   (ji,jj+1,jk  ) + rhd   (ji,jj,jk  )        &
585                  &                            - rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1)    )   &
586                  &               * (  zalph * ( fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1) )      &
587                  &                  + zbeta * ( fsde3w(ji,jj+1,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
588               ! add to the general momentum trend
589               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
590               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
591            END DO
592         END DO
593      END DO
594      !
595   END SUBROUTINE hpg_wdj
596
597
598   SUBROUTINE hpg_djc( kt )
599      !!---------------------------------------------------------------------
600      !!                  ***  ROUTINE hpg_djc  ***
601      !!
602      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
603      !!
604      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
605      !!----------------------------------------------------------------------
606      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
607      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
608      !!
609      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
610      !!
611      INTEGER  ::   ji, jj, jk          ! dummy loop indices
612      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
613      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
614      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
615      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, dzx, drhou, dzu, rho_i   ! 3D workspace
616      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoy, dzy, drhov, dzv, rho_j   !  "      "
617      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoz, dzz, drhow, dzw, rho_k   !  "      "
618      !!----------------------------------------------------------------------
619
620      IF( kt == nit000 ) THEN
621         IF(lwp) WRITE(numout,*)
622         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
623         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
624      ENDIF
625
626
627      ! Local constant initialization
628      zcoef0 = - grav * 0.5
629      z1_10  = 1.0 / 10.0
630      z1_12  = 1.0 / 12.0
631
632      !----------------------------------------------------------------------------------------
633      !  compute and store in provisional arrays elementary vertical and horizontal differences
634      !----------------------------------------------------------------------------------------
635
636!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
637
638      DO jk = 2, jpkm1
639         DO jj = 2, jpjm1
640            DO ji = fs_2, fs_jpim1   ! vector opt.
641               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
642               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
643               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
644               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
645               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
646               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
647            END DO
648         END DO
649      END DO
650
651      !-------------------------------------------------------------------------
652      ! compute harmonic averages using eq. 5.18
653      !-------------------------------------------------------------------------
654      zep = 1.e-15
655
656!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
657!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
658
659      DO jk = 2, jpkm1
660         DO jj = 2, jpjm1
661            DO ji = fs_2, fs_jpim1   ! vector opt.
662               cffw = 2.0 * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
663
664               cffu = 2.0 * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
665               cffx = 2.0 * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
666 
667               cffv = 2.0 * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
668               cffy = 2.0 * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
669
670               IF( cffw > zep) THEN
671                  drhow(ji,jj,jk) = 2.0 *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
672                     &                  / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
673               ELSE
674                  drhow(ji,jj,jk) = 0.e0
675               ENDIF
676
677               dzw(ji,jj,jk) = 2.0 *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
678                  &                / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
679
680               IF( cffu > zep ) THEN
681                  drhou(ji,jj,jk) = 2.0 *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
682                     &                  / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
683               ELSE
684                  drhou(ji,jj,jk ) = 0.e0
685               ENDIF
686
687               IF( cffx > zep ) THEN
688                  dzu(ji,jj,jk) = 2.0*dzx(ji+1,jj,jk)*dzx(ji,jj,jk)   &
689                     &            /(dzx(ji+1,jj,jk)+dzx(ji,jj,jk))
690               ELSE
691                  dzu(ji,jj,jk) = 0.e0
692               ENDIF
693
694               IF( cffv > zep ) THEN
695                  drhov(ji,jj,jk) = 2.0 *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
696                     &                  / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
697               ELSE
698                  drhov(ji,jj,jk) = 0.e0
699               ENDIF
700
701               IF( cffy > zep ) THEN
702                  dzv(ji,jj,jk) = 2.0 *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
703                     &                / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
704               ELSE
705                  dzv(ji,jj,jk) = 0.e0
706               ENDIF
707
708            END DO
709         END DO
710      END DO
711
712      !----------------------------------------------------------------------------------
713      ! apply boundary conditions at top and bottom using 5.36-5.37
714      !----------------------------------------------------------------------------------
715      drhow(:,:, 1 ) = 1.5 * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5 * drhow(:,:,  2  )
716      drhou(:,:, 1 ) = 1.5 * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5 * drhou(:,:,  2  )
717      drhov(:,:, 1 ) = 1.5 * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5 * drhov(:,:,  2  )
718
719      drhow(:,:,jpk) = 1.5 * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5 * drhow(:,:,jpkm1)
720      drhou(:,:,jpk) = 1.5 * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5 * drhou(:,:,jpkm1)
721      drhov(:,:,jpk) = 1.5 * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5 * drhov(:,:,jpkm1)
722
723
724      !--------------------------------------------------------------
725      ! Upper half of top-most grid box, compute and store
726      !-------------------------------------------------------------
727
728!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
729!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
730
731      DO jj = 2, jpjm1
732         DO ji = fs_2, fs_jpim1   ! vector opt.
733            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )            &
734               &                   * (  rhd(ji,jj,1)                                 &
735               &                     + 0.5 * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
736               &                           * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
737               &                           / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
738         END DO
739      END DO
740
741!!bug gm    : here also, simplification is possible
742!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
743
744      DO jk = 2, jpkm1
745         DO jj = 2, jpjm1
746            DO ji = fs_2, fs_jpim1   ! vector opt.
747
748               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
749                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
750                  &            - grav * z1_10 * (                                                                     &
751                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
752                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
753                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
754                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
755                  &                             )
756
757               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
758                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
759                  &            - grav* z1_10 * (                                                                      &
760                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
761                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
762                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
763                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
764                  &                            )
765
766               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
767                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
768                  &            - grav* z1_10 * (                                                                      &
769                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
770                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
771                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
772                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
773                  &                            )
774
775            END DO
776         END DO
777      END DO
778      CALL lbc_lnk(rho_k,'W',1.)
779      CALL lbc_lnk(rho_i,'U',1.)
780      CALL lbc_lnk(rho_j,'V',1.)
781
782
783      ! ---------------
784      !  Surface value
785      ! ---------------
786      DO jj = 2, jpjm1
787         DO ji = fs_2, fs_jpim1   ! vector opt.
788            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
789            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
790            ! add to the general momentum trend
791            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
792            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
793         END DO
794      END DO
795
796      ! ----------------
797      !  interior value   (2=<jk=<jpkm1)
798      ! ----------------
799      DO jk = 2, jpkm1
800         DO jj = 2, jpjm1 
801            DO ji = fs_2, fs_jpim1   ! vector opt.
802               ! hydrostatic pressure gradient along s-surfaces
803               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
804                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
805                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
806               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
807                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
808                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
809               ! add to the general momentum trend
810               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
811               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
812            END DO
813         END DO
814      END DO
815      !
816   END SUBROUTINE hpg_djc
817
818
819   SUBROUTINE hpg_rot( kt )
820      !!---------------------------------------------------------------------
821      !!                  ***  ROUTINE hpg_rot  ***
822      !!
823      !! ** Method  :   rotated axes scheme (Thiem and Berntsen 2005)
824      !!
825      !! Reference: Thiem & Berntsen, Ocean Modelling, In press, 2005.
826      !!----------------------------------------------------------------------
827      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
828      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
829      !!
830      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
831      !!
832      INTEGER  ::   ji, jj, jk          ! dummy loop indices
833      REAL(wp) ::   zforg, zcoef0, zuap, zmskd1, zmskd1m   ! temporary scalar
834      REAL(wp) ::   zfrot        , zvap, zmskd2, zmskd2m   !    "         "
835      REAL(wp), DIMENSION(jpi,jpj)     ::   zdistr, zsina, zcosa                ! 2D workspace
836      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpiorg, zhpirot, zhpitra, zhpine   ! 3D workspace
837      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpjorg, zhpjrot, zhpjtra, zhpjne   !  "      "
838      !!----------------------------------------------------------------------
839
840      IF( kt == nit000 ) THEN
841         IF(lwp) WRITE(numout,*)
842         IF(lwp) WRITE(numout,*) 'dyn:hpg_rot : hydrostatic pressure gradient trend'
843         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, rotated axes scheme used'
844      ENDIF
845
846      ! -------------------------------
847      !  Local constant initialization
848      ! -------------------------------
849      zcoef0 = - grav * 0.5
850      zforg  = 0.95e0
851      zfrot  = 1.e0 - zforg
852
853      ! inverse of the distance between 2 diagonal T-points (defined at F-point) (here zcoef0/distance)
854      zdistr(:,:) = zcoef0 / SQRT( e1f(:,:)*e1f(:,:) + e2f(:,:)*e1f(:,:) )
855
856      ! sinus and cosinus of diagonal angle at F-point
857      zsina(:,:) = ATAN2( e2f(:,:), e1f(:,:) )
858      zcosa(:,:) = COS( zsina(:,:) )
859      zsina(:,:) = SIN( zsina(:,:) )
860
861      ! ---------------
862      !  Surface value
863      ! ---------------
864      ! compute and add to the general trend the pressure gradients along the axes
865      DO jj = 2, jpjm1
866         DO ji = fs_2, fs_jpim1   ! vector opt.
867            ! hydrostatic pressure gradient along s-surfaces
868            zhpiorg(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,1) * rhd(ji+1,jj,1)   &
869               &                                      - fse3t(ji  ,jj,1) * rhd(ji  ,jj,1)  )
870            zhpjorg(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,1) * rhd(ji,jj+1,1)   &
871               &                                      - fse3t(ji,jj  ,1) * rhd(ji,jj  ,1)  )
872            ! s-coordinate pressure gradient correction
873            zuap = -zcoef0 * ( rhd   (ji+1,jj  ,1) + rhd   (ji,jj,1) )   &
874               &           * ( fsdept(ji+1,jj  ,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
875            zvap = -zcoef0 * ( rhd   (ji  ,jj+1,1) + rhd   (ji,jj,1) )   &
876               &           * ( fsdept(ji  ,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
877            ! add to the general momentum trend
878            ua(ji,jj,1) = ua(ji,jj,1) + zforg * ( zhpiorg(ji,jj,1) + zuap )
879            va(ji,jj,1) = va(ji,jj,1) + zforg * ( zhpjorg(ji,jj,1) + zvap )
880         END DO
881      END DO
882
883      ! compute the pressure gradients in the diagonal directions
884      DO jj = 1, jpjm1
885         DO ji = 1, fs_jpim1   ! vector opt.
886            zmskd1 = tmask(ji+1,jj+1,1) * tmask(ji  ,jj,1)      ! mask in the 1st diagnonal
887            zmskd2 = tmask(ji  ,jj+1,1) * tmask(ji+1,jj,1)      ! mask in the 2nd diagnonal
888            ! hydrostatic pressure gradient along s-surfaces
889            zhpitra(ji,jj,1) = zdistr(ji,jj) * zmskd1 * (  fse3t(ji+1,jj+1,1) * rhd(ji+1,jj+1,1)   &
890               &                                         - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
891            zhpjtra(ji,jj,1) = zdistr(ji,jj) * zmskd2 * (  fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
892               &                                         - fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  )
893            ! s-coordinate pressure gradient correction
894            zuap = -zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,1) + rhd   (ji  ,jj,1) )   &
895               &                           * ( fsdept(ji+1,jj+1,1) - fsdept(ji  ,jj,1) )
896            zvap = -zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,1) + rhd   (ji+1,jj,1) )   &
897               &                           * ( fsdept(ji  ,jj+1,1) - fsdept(ji+1,jj,1) )
898            ! back rotation
899            zhpine(ji,jj,1) = zcosa(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
900               &            - zsina(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
901            zhpjne(ji,jj,1) = zsina(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
902               &            + zcosa(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
903         END DO
904      END DO
905
906      ! interpolate and add to the general trend the diagonal gradient
907      DO jj = 2, jpjm1
908         DO ji = fs_2, fs_jpim1   ! vector opt.
909            ! averaging
910            zhpirot(ji,jj,1) = 0.5 * ( zhpine(ji,jj,1) + zhpine(ji  ,jj-1,1) )
911            zhpjrot(ji,jj,1) = 0.5 * ( zhpjne(ji,jj,1) + zhpjne(ji-1,jj  ,1) )
912            ! add to the general momentum trend
913            ua(ji,jj,1) = ua(ji,jj,1) + zfrot * zhpirot(ji,jj,1) 
914            va(ji,jj,1) = va(ji,jj,1) + zfrot * zhpjrot(ji,jj,1) 
915         END DO
916      END DO
917
918      ! -----------------
919      ! 2. interior value (2=<jk=<jpkm1)
920      ! -----------------
921      ! compute and add to the general trend the pressure gradients along the axes
922      DO jk = 2, jpkm1
923         DO jj = 2, jpjm1
924            DO ji = fs_2, fs_jpim1   ! vector opt.
925               ! hydrostatic pressure gradient along s-surfaces
926               zhpiorg(ji,jj,jk) = zhpiorg(ji,jj,jk-1)                                                 &
927                  &              +  zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk  )   &
928                  &                                        - fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk  )   &
929                  &                                        + fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
930                  &                                        - fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1)  )
931               zhpjorg(ji,jj,jk) = zhpjorg(ji,jj,jk-1)                                                 &
932                  &              +  zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk  )   &
933                  &                                        - fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk  )   &
934                  &                                        + fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1)   &
935                  &                                        - fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1)  )
936               ! s-coordinate pressure gradient correction
937               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
938                  &            * ( fsdept(ji+1,jj  ,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
939               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
940                  &            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
941               ! add to the general momentum trend
942               ua(ji,jj,jk) = ua(ji,jj,jk) + zforg*( zhpiorg(ji,jj,jk) + zuap )
943               va(ji,jj,jk) = va(ji,jj,jk) + zforg*( zhpjorg(ji,jj,jk) + zvap )
944            END DO
945         END DO
946      END DO
947
948      ! compute the pressure gradients in the diagonal directions
949      DO jk = 2, jpkm1
950         DO jj = 1, jpjm1
951            DO ji = 1, fs_jpim1   ! vector opt.
952               zmskd1  = tmask(ji+1,jj+1,jk  ) * tmask(ji  ,jj,jk  )      ! level jk   mask in the 1st diagnonal
953               zmskd1m = tmask(ji+1,jj+1,jk-1) * tmask(ji  ,jj,jk-1)      ! level jk-1    "               "     
954               zmskd2  = tmask(ji  ,jj+1,jk  ) * tmask(ji+1,jj,jk  )      ! level jk   mask in the 2nd diagnonal
955               zmskd2m = tmask(ji  ,jj+1,jk-1) * tmask(ji+1,jj,jk-1)      ! level jk-1    "               "     
956               ! hydrostatic pressure gradient along s-surfaces
957               zhpitra(ji,jj,jk) = zhpitra(ji,jj,jk-1)                                                       &
958                  &              + zdistr(ji,jj) * zmskd1  * ( fse3t(ji+1,jj+1,jk  ) * rhd(ji+1,jj+1,jk)     &
959                  &                                           -fse3t(ji  ,jj  ,jk  ) * rhd(ji  ,jj  ,jk) )   &
960                  &              + zdistr(ji,jj) * zmskd1m * ( fse3t(ji+1,jj+1,jk-1) * rhd(ji+1,jj+1,jk-1)   &
961                  &                                           -fse3t(ji  ,jj  ,jk-1) * rhd(ji  ,jj  ,jk-1) )
962               zhpjtra(ji,jj,jk) = zhpjtra(ji,jj,jk-1)                                                       &
963                  &              + zdistr(ji,jj) * zmskd2  * ( fse3t(ji  ,jj+1,jk  ) * rhd(ji  ,jj+1,jk)     &
964                  &                                           -fse3t(ji+1,jj  ,jk  ) * rhd(ji+1,jj,  jk) )   &
965                  &              + zdistr(ji,jj) * zmskd2m * ( fse3t(ji  ,jj+1,jk-1) * rhd(ji  ,jj+1,jk-1)   &
966                  &                                           -fse3t(ji+1,jj  ,jk-1) * rhd(ji+1,jj,  jk-1) )
967               ! s-coordinate pressure gradient correction
968               zuap = - zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,jk) + rhd   (ji  ,jj,jk) )   &
969                  &                            * ( fsdept(ji+1,jj+1,jk) - fsdept(ji  ,jj,jk) )
970               zvap = - zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji+1,jj,jk) )   &
971                  &                            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji+1,jj,jk) )
972               ! back rotation
973               zhpine(ji,jj,jk) = zcosa(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
974                  &             - zsina(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
975               zhpjne(ji,jj,jk) = zsina(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
976                  &             + zcosa(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
977            END DO
978         END DO
979      END DO
980
981      ! interpolate and add to the general trend
982      DO jk = 2, jpkm1
983         DO jj = 2, jpjm1
984            DO ji = fs_2, fs_jpim1   ! vector opt.
985               ! averaging
986               zhpirot(ji,jj,jk) = 0.5 * ( zhpine(ji,jj,jk) + zhpine(ji  ,jj-1,jk) )
987               zhpjrot(ji,jj,jk) = 0.5 * ( zhpjne(ji,jj,jk) + zhpjne(ji-1,jj  ,jk) )
988               ! add to the general momentum trend
989               ua(ji,jj,jk) = ua(ji,jj,jk) + zfrot * zhpirot(ji,jj,jk) 
990               va(ji,jj,jk) = va(ji,jj,jk) + zfrot * zhpjrot(ji,jj,jk) 
991            END DO
992         END DO
993      END DO
994      !
995   END SUBROUTINE hpg_rot
996
997   !!======================================================================
998END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.