New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldfeiv.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/LDF – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/LDF/ldfeiv.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 11.0 KB
Line 
1MODULE ldfeiv
2   !!======================================================================
3   !!                     ***  MODULE  ldfeiv  ***
4   !! Ocean physics:  variable eddy induced velocity coefficients
5   !!======================================================================
6   !! History :  OPA  ! 1999-03  (G. Madec, A. Jouzeau)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  Free form, F90
8   !!----------------------------------------------------------------------
9#if   defined key_traldf_eiv   &&   defined key_traldf_c2d
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'      and                     eddy induced velocity
12   !!   'key_traldf_c2d'                    2D tracer lateral  mixing coef.
13   !!----------------------------------------------------------------------
14   !!   ldf_eiv      : compute the eddy induced velocity coefficients
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface boundary condition: ocean
19   USE sbcrnf          ! river runoffs
20   USE ldftra_oce      ! ocean tracer   lateral physics
21   USE phycst          ! physical constants
22   USE ldfslp          ! iso-neutral slopes
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE prtctl          ! Print control
26   USE iom             ! I/O library
27
28   IMPLICIT NONE
29   PRIVATE
30   
31   PUBLIC   ldf_eiv    ! routine called by step.F90
32   
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
38   !! $Id$
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE ldf_eiv( kt )
44      !!----------------------------------------------------------------------
45      !!                  ***  ROUTINE ldf_eiv  ***
46      !!
47      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
48      !!              growth rate of baroclinic instability.
49      !!
50      !! ** Method :
51      !!
52      !! ** Action : - uslp , vslp  : i- and j-slopes of neutral surfaces at u- & v-points
53      !!             - wslpi, wslpj : i- and j-slopes of neutral surfaces at w-points.
54      !!----------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
56      !!
57      INTEGER  ::   ji, jj, jk   ! dummy loop indices
58      REAL(wp) ::   zfw, ze3w, zn2, zf20, zaht, zaht_min      ! temporary scalars
59      REAL(wp), DIMENSION(jpi,jpj) ::   zn, zah, zhw, zross   ! 2D workspace
60      !!----------------------------------------------------------------------
61     
62      IF( kt == nit000 ) THEN
63         IF(lwp) WRITE(numout,*)
64         IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients'
65         IF(lwp) WRITE(numout,*) '~~~~~~~'
66      ENDIF
67     
68      ! 0. Local initialization
69      ! -----------------------
70      zn   (:,:) = 0._wp
71      zhw  (:,:) = 5._wp
72      zah  (:,:) = 0._wp
73      zross(:,:) = 0._wp
74
75
76      ! 1. Compute lateral diffusive coefficient
77      ! ----------------------------------------
78      IF( ln_traldf_grif ) THEN
79         DO jk = 1, jpk
80#  if defined key_vectopt_loop 
81!CDIR NOVERRCHK
82            DO ji = 1, jpij   ! vector opt.
83               ! Take the max of N^2 and zero then take the vertical sum
84               ! of the square root of the resulting N^2 ( required to compute
85               ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
86               zn2 = MAX( rn2b(ji,1,jk), 0._wp )
87               zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk)
88               ! Compute elements required for the inverse time scale of baroclinic
89               ! eddies using the isopycnal slopes calculated in ldfslp.F :
90               ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
91               ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk)
92               zah(ji,1) = zah(ji,1) + zn2 * wslp2(ji,1,jk) * ze3w
93               zhw(ji,1) = zhw(ji,1) + ze3w
94            END DO
95#  else
96            DO jj = 2, jpjm1
97!CDIR NOVERRCHK
98               DO ji = 2, jpim1
99                  ! Take the max of N^2 and zero then take the vertical sum
100                  ! of the square root of the resulting N^2 ( required to compute
101                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
102                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
103                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
104                  ! Compute elements required for the inverse time scale of baroclinic
105                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
106                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
107                  ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
108                  zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w
109                  zhw(ji,jj) = zhw(ji,jj) + ze3w
110               END DO
111            END DO
112#  endif
113         END DO
114      ELSE
115         DO jk = 1, jpk
116#  if defined key_vectopt_loop 
117!CDIR NOVERRCHK
118            DO ji = 1, jpij   ! vector opt.
119               ! Take the max of N^2 and zero then take the vertical sum
120               ! of the square root of the resulting N^2 ( required to compute
121               ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
122               zn2 = MAX( rn2b(ji,1,jk), 0._wp )
123               zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk)
124               ! Compute elements required for the inverse time scale of baroclinic
125               ! eddies using the isopycnal slopes calculated in ldfslp.F :
126               ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
127               ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk)
128               zah(ji,1) = zah(ji,1) + zn2 * ( wslpi(ji,1,jk) * wslpi(ji,1,jk)   &
129                  &                          + wslpj(ji,1,jk) * wslpj(ji,1,jk) ) * ze3w
130               zhw(ji,1) = zhw(ji,1) + ze3w
131            END DO
132#  else
133            DO jj = 2, jpjm1
134!CDIR NOVERRCHK
135               DO ji = 2, jpim1
136                  ! Take the max of N^2 and zero then take the vertical sum
137                  ! of the square root of the resulting N^2 ( required to compute
138                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
139                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
140                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
141                  ! Compute elements required for the inverse time scale of baroclinic
142                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
143                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
144                  ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
145                  zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
146                     &                            + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w
147                  zhw(ji,jj) = zhw(ji,jj) + ze3w
148               END DO
149            END DO
150#  endif
151         END DO
152      END IF
153
154      DO jj = 2, jpjm1
155!CDIR NOVERRCHK
156         DO ji = fs_2, fs_jpim1   ! vector opt.
157            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
158            ! Rossby radius at w-point taken < 40km and  > 2km
159            zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 )
160            ! Compute aeiw by multiplying Ro^2 and T^-1
161            aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1)
162         END DO
163      END DO
164
165      IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN   ! ORCA R2
166         DO jj = 2, jpjm1
167!CDIR NOVERRCHK
168            DO ji = fs_2, fs_jpim1   ! vector opt.
169               ! Take the minimum between aeiw and 1000 m2/s over shelves (depth shallower than 650 m)
170               IF( mbkt(ji,jj) <= 20 )   aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. )
171            END DO
172         END DO
173      ENDIF
174
175      ! Decrease the coefficient in the tropics (20N-20S)
176      zf20 = 2._wp * omega * sin( rad * 20._wp )
177      DO jj = 2, jpjm1
178         DO ji = fs_2, fs_jpim1   ! vector opt.
179            aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj)
180         END DO
181      END DO
182
183      ! ORCA R05: Take the minimum between aeiw  and aeiv0
184      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
185         DO jj = 2, jpjm1
186            DO ji = fs_2, fs_jpim1   ! vector opt.
187               aeiw(ji,jj) = MIN( aeiw(ji,jj), aeiv0 )
188            END DO
189         END DO
190      ENDIF
191      CALL lbc_lnk( aeiw, 'W', 1. )      ! lateral boundary condition on aeiw
192
193
194      ! Average the diffusive coefficient at u- v- points
195      DO jj = 2, jpjm1
196         DO ji = fs_2, fs_jpim1   ! vector opt.
197            aeiu(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji+1,jj  ) )
198            aeiv(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji  ,jj+1) )
199         END DO
200      END DO
201      CALL lbc_lnk( aeiu, 'U', 1. )   ;   CALL lbc_lnk( aeiv, 'V', 1. )      ! lateral boundary condition
202
203
204      IF(ln_ctl) THEN
205         CALL prt_ctl(tab2d_1=aeiu, clinfo1=' eiv  - u: ', ovlap=1)
206         CALL prt_ctl(tab2d_1=aeiv, clinfo1=' eiv  - v: ', ovlap=1)
207      ENDIF
208
209      ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth)
210      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
211         zf20     = 2._wp * omega * SIN( rad * 20._wp )
212         zaht_min = 100._wp                           ! minimum value for aht
213         DO jj = 1, jpj
214            DO ji = 1, jpi
215               zaht      = ( 1._wp -  MIN( 1._wp , ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min )  &
216                  &      + aht0 * rnfmsk(ji,jj)                          ! enhanced near river mouths
217               ahtu(ji,jj) = MAX( MAX( zaht_min, aeiu(ji,jj) ) + zaht, aht0 )
218               ahtv(ji,jj) = MAX( MAX( zaht_min, aeiv(ji,jj) ) + zaht, aht0 )
219               ahtw(ji,jj) = MAX( MAX( zaht_min, aeiw(ji,jj) ) + zaht, aht0 )
220            END DO
221         END DO
222         IF(ln_ctl) THEN
223            CALL prt_ctl(tab2d_1=ahtu, clinfo1=' aht  - u: ', ovlap=1)
224            CALL prt_ctl(tab2d_1=ahtv, clinfo1=' aht  - v: ', ovlap=1)
225            CALL prt_ctl(tab2d_1=ahtw, clinfo1=' aht  - w: ', ovlap=1)
226         ENDIF
227      ENDIF
228
229      IF( aeiv0 == 0._wp ) THEN
230         aeiu(:,:) = 0._wp
231         aeiv(:,:) = 0._wp
232         aeiw(:,:) = 0._wp
233      ENDIF
234
235      CALL iom_put( "aht2d"    , ahtw )   ! lateral eddy diffusivity
236      CALL iom_put( "aht2d_eiv", aeiw )   ! EIV lateral eddy diffusivity
237      !
238   END SUBROUTINE ldf_eiv
239
240#else
241   !!----------------------------------------------------------------------
242   !!   Default option                                         Dummy module
243   !!----------------------------------------------------------------------
244CONTAINS
245   SUBROUTINE ldf_eiv( kt )       ! Empty routine
246      WRITE(*,*) 'ldf_eiv: You should not have seen this print! error?', kt
247   END SUBROUTINE ldf_eiv
248#endif
249
250   !!======================================================================
251END MODULE ldfeiv
Note: See TracBrowser for help on using the repository browser.