[3] | 1 | MODULE ldftra |
---|
| 2 | !!====================================================================== |
---|
| 3 | !! *** MODULE ldftra *** |
---|
[5836] | 4 | !! Ocean physics: lateral diffusivity coefficients |
---|
[3] | 5 | !!===================================================================== |
---|
[5836] | 6 | !! History : ! 1997-07 (G. Madec) from inimix.F split in 2 routines |
---|
| 7 | !! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module |
---|
| 8 | !! 2.0 ! 2005-11 (G. Madec) |
---|
| 9 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) restructuration/simplification of aht/aeiv specification, |
---|
| 10 | !! ! add velocity dependent coefficient and optional read in file |
---|
[3] | 11 | !!---------------------------------------------------------------------- |
---|
[1601] | 12 | |
---|
| 13 | !!---------------------------------------------------------------------- |
---|
[3] | 14 | !! ldf_tra_init : initialization, namelist read, and parameters control |
---|
[5836] | 15 | !! ldf_tra : update lateral eddy diffusivity coefficients at each time step |
---|
| 16 | !! ldf_eiv_init : initialization of the eiv coeff. from namelist choices |
---|
| 17 | !! ldf_eiv : time evolution of the eiv coefficients (function of the growth rate of baroclinic instability) |
---|
| 18 | !! ldf_eiv_trp : add to the input ocean transport the contribution of the EIV parametrization |
---|
| 19 | !! ldf_eiv_dia : diagnose the eddy induced velocity from the eiv streamfunction |
---|
[3] | 20 | !!---------------------------------------------------------------------- |
---|
| 21 | USE oce ! ocean dynamics and tracers |
---|
| 22 | USE dom_oce ! ocean space and time domain |
---|
| 23 | USE phycst ! physical constants |
---|
[5836] | 24 | USE ldfslp ! lateral diffusion: slope of iso-neutral surfaces |
---|
| 25 | USE ldfc1d_c2d ! lateral diffusion: 1D & 2D cases |
---|
[7646] | 26 | USE diaptr |
---|
[5836] | 27 | ! |
---|
[3] | 28 | USE in_out_manager ! I/O manager |
---|
[5836] | 29 | USE iom ! I/O module for ehanced bottom friction file |
---|
[3] | 30 | USE lib_mpp ! distribued memory computing library |
---|
| 31 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
[5836] | 32 | USE wrk_nemo ! work arrays |
---|
| 33 | USE timing ! timing |
---|
[3] | 34 | |
---|
| 35 | IMPLICIT NONE |
---|
| 36 | PRIVATE |
---|
| 37 | |
---|
[5836] | 38 | PUBLIC ldf_tra_init ! called by nemogcm.F90 |
---|
| 39 | PUBLIC ldf_tra ! called by step.F90 |
---|
| 40 | PUBLIC ldf_eiv_init ! called by nemogcm.F90 |
---|
| 41 | PUBLIC ldf_eiv ! called by step.F90 |
---|
| 42 | PUBLIC ldf_eiv_trp ! called by traadv.F90 |
---|
| 43 | PUBLIC ldf_eiv_dia ! called by traldf_iso and traldf_iso_triad.F90 |
---|
| 44 | |
---|
| 45 | ! !!* Namelist namtra_ldf : lateral mixing on tracers * |
---|
| 46 | ! != Operator type =! |
---|
| 47 | LOGICAL , PUBLIC :: ln_traldf_lap !: laplacian operator |
---|
| 48 | LOGICAL , PUBLIC :: ln_traldf_blp !: bilaplacian operator |
---|
| 49 | ! != Direction of action =! |
---|
| 50 | LOGICAL , PUBLIC :: ln_traldf_lev !: iso-level direction |
---|
| 51 | LOGICAL , PUBLIC :: ln_traldf_hor !: horizontal (geopotential) direction |
---|
| 52 | ! LOGICAL , PUBLIC :: ln_traldf_iso !: iso-neutral direction (see ldfslp) |
---|
| 53 | ! LOGICAL , PUBLIC :: ln_traldf_triad !: griffies triad scheme (see ldfslp) |
---|
| 54 | LOGICAL , PUBLIC :: ln_traldf_msc !: Method of Stabilizing Correction |
---|
| 55 | ! LOGICAL , PUBLIC :: ln_triad_iso !: pure horizontal mixing in ML (see ldfslp) |
---|
| 56 | ! LOGICAL , PUBLIC :: ln_botmix_triad !: mixing on bottom (see ldfslp) |
---|
| 57 | ! REAL(wp), PUBLIC :: rn_sw_triad !: =1/0 switching triad / all 4 triads used (see ldfslp) |
---|
| 58 | ! REAL(wp), PUBLIC :: rn_slpmax !: slope limit (see ldfslp) |
---|
| 59 | ! != Coefficients =! |
---|
| 60 | INTEGER , PUBLIC :: nn_aht_ijk_t !: choice of time & space variations of the lateral eddy diffusivity coef. |
---|
| 61 | REAL(wp), PUBLIC :: rn_aht_0 !: laplacian lateral eddy diffusivity [m2/s] |
---|
| 62 | REAL(wp), PUBLIC :: rn_bht_0 !: bilaplacian lateral eddy diffusivity [m4/s] |
---|
[3] | 63 | |
---|
[5836] | 64 | ! !!* Namelist namtra_ldfeiv : eddy induced velocity param. * |
---|
| 65 | ! != Use/diagnose eiv =! |
---|
| 66 | LOGICAL , PUBLIC :: ln_ldfeiv !: eddy induced velocity flag |
---|
| 67 | LOGICAL , PUBLIC :: ln_ldfeiv_dia !: diagnose & output eiv streamfunction and velocity (IOM) |
---|
| 68 | ! != Coefficients =! |
---|
| 69 | INTEGER , PUBLIC :: nn_aei_ijk_t !: choice of time/space variation of the eiv coeff. |
---|
| 70 | REAL(wp), PUBLIC :: rn_aeiv_0 !: eddy induced velocity coefficient [m2/s] |
---|
| 71 | |
---|
| 72 | LOGICAL , PUBLIC :: l_ldftra_time = .FALSE. !: flag for time variation of the lateral eddy diffusivity coef. |
---|
| 73 | LOGICAL , PUBLIC :: l_ldfeiv_time = .FALSE. ! flag for time variation of the eiv coef. |
---|
| 74 | |
---|
| 75 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ahtu, ahtv !: eddy diffusivity coef. at U- and V-points [m2/s] |
---|
| 76 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: aeiu, aeiv !: eddy induced velocity coeff. [m2/s] |
---|
| 77 | |
---|
| 78 | REAL(wp) :: r1_4 = 0.25_wp ! =1/4 |
---|
| 79 | REAL(wp) :: r1_12 = 1._wp / 12._wp ! =1/12 |
---|
| 80 | |
---|
[3] | 81 | !! * Substitutions |
---|
| 82 | # include "vectopt_loop_substitute.h90" |
---|
[1601] | 83 | !!---------------------------------------------------------------------- |
---|
[5836] | 84 | !! NEMO/OPA 3.7 , NEMO Consortium (2015) |
---|
[1152] | 85 | !! $Id$ |
---|
[2715] | 86 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
[1601] | 87 | !!---------------------------------------------------------------------- |
---|
[3] | 88 | CONTAINS |
---|
| 89 | |
---|
| 90 | SUBROUTINE ldf_tra_init |
---|
| 91 | !!---------------------------------------------------------------------- |
---|
| 92 | !! *** ROUTINE ldf_tra_init *** |
---|
| 93 | !! |
---|
[461] | 94 | !! ** Purpose : initializations of the tracer lateral mixing coeff. |
---|
[3] | 95 | !! |
---|
[5836] | 96 | !! ** Method : * the eddy diffusivity coef. specification depends on: |
---|
[3] | 97 | !! |
---|
[5836] | 98 | !! ln_traldf_lap = T laplacian operator |
---|
| 99 | !! ln_traldf_blp = T bilaplacian operator |
---|
| 100 | !! |
---|
| 101 | !! nn_aht_ijk_t = 0 => = constant |
---|
| 102 | !! ! |
---|
| 103 | !! = 10 => = F(z) : constant with a reduction of 1/4 with depth |
---|
| 104 | !! ! |
---|
| 105 | !! =-20 => = F(i,j) = shape read in 'eddy_diffusivity.nc' file |
---|
| 106 | !! = 20 = F(i,j) = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case) |
---|
| 107 | !! = 21 = F(i,j,t) = F(growth rate of baroclinic instability) |
---|
| 108 | !! ! |
---|
| 109 | !! =-30 => = F(i,j,k) = shape read in 'eddy_diffusivity.nc' file |
---|
| 110 | !! = 30 = F(i,j,k) = 2D (case 20) + decrease with depth (case 10) |
---|
| 111 | !! = 31 = F(i,j,k,t) = F(local velocity) ( |u|e /12 laplacian operator |
---|
| 112 | !! or |u|e^3/12 bilaplacian operator ) |
---|
| 113 | !! * initialisation of the eddy induced velocity coefficient by a call to ldf_eiv_init |
---|
| 114 | !! |
---|
| 115 | !! ** action : ahtu, ahtv initialized once for all or l_ldftra_time set to true |
---|
| 116 | !! aeiu, aeiv initialized once for all or l_ldfeiv_time set to true |
---|
[3] | 117 | !!---------------------------------------------------------------------- |
---|
[7753] | 118 | INTEGER :: jk ! dummy loop indices |
---|
[5836] | 119 | INTEGER :: ierr, inum, ios ! local integer |
---|
| 120 | REAL(wp) :: zah0 ! local scalar |
---|
| 121 | ! |
---|
| 122 | NAMELIST/namtra_ldf/ ln_traldf_lap, ln_traldf_blp , & ! type of operator |
---|
| 123 | & ln_traldf_lev, ln_traldf_hor , ln_traldf_triad, & ! acting direction of the operator |
---|
| 124 | & ln_traldf_iso, ln_traldf_msc , rn_slpmax , & ! option for iso-neutral operator |
---|
| 125 | & ln_triad_iso , ln_botmix_triad, rn_sw_triad , & ! option for triad operator |
---|
| 126 | & rn_aht_0 , rn_bht_0 , nn_aht_ijk_t ! lateral eddy coefficient |
---|
[3] | 127 | !!---------------------------------------------------------------------- |
---|
[5836] | 128 | ! |
---|
| 129 | ! Choice of lateral tracer physics |
---|
| 130 | ! ================================= |
---|
| 131 | ! |
---|
[4147] | 132 | REWIND( numnam_ref ) ! Namelist namtra_ldf in reference namelist : Lateral physics on tracers |
---|
| 133 | READ ( numnam_ref, namtra_ldf, IOSTAT = ios, ERR = 901) |
---|
| 134 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldf in reference namelist', lwp ) |
---|
[5836] | 135 | ! |
---|
[4147] | 136 | REWIND( numnam_cfg ) ! Namelist namtra_ldf in configuration namelist : Lateral physics on tracers |
---|
| 137 | READ ( numnam_cfg, namtra_ldf, IOSTAT = ios, ERR = 902 ) |
---|
| 138 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldf in configuration namelist', lwp ) |
---|
[4624] | 139 | IF(lwm) WRITE ( numond, namtra_ldf ) |
---|
[5836] | 140 | ! |
---|
[1601] | 141 | IF(lwp) THEN ! control print |
---|
[3] | 142 | WRITE(numout,*) |
---|
[461] | 143 | WRITE(numout,*) 'ldf_tra_init : lateral tracer physics' |
---|
| 144 | WRITE(numout,*) '~~~~~~~~~~~~ ' |
---|
[2528] | 145 | WRITE(numout,*) ' Namelist namtra_ldf : lateral mixing parameters (type, direction, coefficients)' |
---|
[5836] | 146 | ! |
---|
| 147 | WRITE(numout,*) ' type :' |
---|
| 148 | WRITE(numout,*) ' laplacian operator ln_traldf_lap = ', ln_traldf_lap |
---|
| 149 | WRITE(numout,*) ' bilaplacian operator ln_traldf_blp = ', ln_traldf_blp |
---|
| 150 | ! |
---|
| 151 | WRITE(numout,*) ' direction of action :' |
---|
| 152 | WRITE(numout,*) ' iso-level ln_traldf_lev = ', ln_traldf_lev |
---|
| 153 | WRITE(numout,*) ' horizontal (geopotential) ln_traldf_hor = ', ln_traldf_hor |
---|
| 154 | WRITE(numout,*) ' iso-neutral Madec operator ln_traldf_iso = ', ln_traldf_iso |
---|
| 155 | WRITE(numout,*) ' iso-neutral triad operator ln_traldf_triad = ', ln_traldf_triad |
---|
| 156 | WRITE(numout,*) ' iso-neutral (Method of Stab. Corr.) ln_traldf_msc = ', ln_traldf_msc |
---|
| 157 | WRITE(numout,*) ' maximum isoppycnal slope rn_slpmax = ', rn_slpmax |
---|
| 158 | WRITE(numout,*) ' pure lateral mixing in ML ln_triad_iso = ', ln_triad_iso |
---|
| 159 | WRITE(numout,*) ' switching triad or not rn_sw_triad = ', rn_sw_triad |
---|
| 160 | WRITE(numout,*) ' lateral mixing on bottom ln_botmix_triad = ', ln_botmix_triad |
---|
| 161 | ! |
---|
| 162 | WRITE(numout,*) ' coefficients :' |
---|
| 163 | WRITE(numout,*) ' lateral eddy diffusivity (lap case) rn_aht_0 = ', rn_aht_0 |
---|
| 164 | WRITE(numout,*) ' lateral eddy diffusivity (bilap case) rn_bht_0 = ', rn_bht_0 |
---|
| 165 | WRITE(numout,*) ' type of time-space variation nn_aht_ijk_t = ', nn_aht_ijk_t |
---|
[3] | 166 | ENDIF |
---|
[5836] | 167 | ! |
---|
| 168 | ! ! Parameter control |
---|
| 169 | ! |
---|
| 170 | IF( .NOT.ln_traldf_lap .AND. .NOT.ln_traldf_blp ) THEN |
---|
| 171 | IF(lwp) WRITE(numout,*) ' No diffusive operator selected. ahtu and ahtv are not allocated' |
---|
| 172 | l_ldftra_time = .FALSE. |
---|
| 173 | RETURN |
---|
| 174 | ENDIF |
---|
| 175 | ! |
---|
| 176 | IF( ln_traldf_blp .AND. ( ln_traldf_iso .OR. ln_traldf_triad) ) THEN ! iso-neutral bilaplacian need MSC |
---|
| 177 | IF( .NOT.ln_traldf_msc ) CALL ctl_stop( 'tra_ldf_init: iso-neutral bilaplacian requires ln_traldf_msc=.true.' ) |
---|
| 178 | ENDIF |
---|
| 179 | ! |
---|
| 180 | ! Space/time variation of eddy coefficients |
---|
| 181 | ! =========================================== |
---|
| 182 | ! ! allocate the aht arrays |
---|
| 183 | ALLOCATE( ahtu(jpi,jpj,jpk) , ahtv(jpi,jpj,jpk) , STAT=ierr ) |
---|
| 184 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'ldf_tra_init: failed to allocate arrays') |
---|
| 185 | ! |
---|
[7753] | 186 | ahtu(:,:,jpk) = 0._wp ! last level always 0 |
---|
| 187 | ahtv(:,:,jpk) = 0._wp |
---|
[5836] | 188 | ! |
---|
| 189 | ! ! value of eddy mixing coef. |
---|
| 190 | IF ( ln_traldf_lap ) THEN ; zah0 = rn_aht_0 ! laplacian operator |
---|
| 191 | ELSEIF( ln_traldf_blp ) THEN ; zah0 = ABS( rn_bht_0 ) ! bilaplacian operator |
---|
| 192 | ENDIF |
---|
| 193 | ! |
---|
| 194 | l_ldftra_time = .FALSE. ! no time variation except in case defined below |
---|
| 195 | ! |
---|
| 196 | IF( ln_traldf_lap .OR. ln_traldf_blp ) THEN ! only if a lateral diffusion operator is used |
---|
| 197 | ! |
---|
| 198 | SELECT CASE( nn_aht_ijk_t ) ! Specification of space time variations of ehtu, ahtv |
---|
| 199 | ! |
---|
| 200 | CASE( 0 ) !== constant ==! |
---|
| 201 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = constant = ', rn_aht_0 |
---|
[7753] | 202 | ahtu(:,:,:) = zah0 * umask(:,:,:) |
---|
| 203 | ahtv(:,:,:) = zah0 * vmask(:,:,:) |
---|
[5836] | 204 | ! |
---|
| 205 | CASE( 10 ) !== fixed profile ==! |
---|
| 206 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F( depth )' |
---|
[7753] | 207 | ahtu(:,:,1) = zah0 * umask(:,:,1) ! constant surface value |
---|
| 208 | ahtv(:,:,1) = zah0 * vmask(:,:,1) |
---|
[5836] | 209 | CALL ldf_c1d( 'TRA', r1_4, ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv ) |
---|
| 210 | ! |
---|
| 211 | CASE ( -20 ) !== fixed horizontal shape read in file ==! |
---|
| 212 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F(i,j) read in eddy_diffusivity.nc file' |
---|
| 213 | CALL iom_open( 'eddy_diffusivity_2D.nc', inum ) |
---|
| 214 | CALL iom_get ( inum, jpdom_data, 'ahtu_2D', ahtu(:,:,1) ) |
---|
| 215 | CALL iom_get ( inum, jpdom_data, 'ahtv_2D', ahtv(:,:,1) ) |
---|
| 216 | CALL iom_close( inum ) |
---|
| 217 | DO jk = 2, jpkm1 |
---|
[7753] | 218 | ahtu(:,:,jk) = ahtu(:,:,1) * umask(:,:,jk) |
---|
| 219 | ahtv(:,:,jk) = ahtv(:,:,1) * vmask(:,:,jk) |
---|
[5836] | 220 | END DO |
---|
| 221 | ! |
---|
| 222 | CASE( 20 ) !== fixed horizontal shape ==! |
---|
| 223 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F( e1, e2 ) or F( e1^3, e2^3 ) (lap or blp case)' |
---|
| 224 | IF( ln_traldf_lap ) CALL ldf_c2d( 'TRA', 'LAP', zah0, ahtu, ahtv ) ! surface value proportional to scale factor |
---|
| 225 | IF( ln_traldf_blp ) CALL ldf_c2d( 'TRA', 'BLP', zah0, ahtu, ahtv ) ! surface value proportional to scale factor |
---|
| 226 | ! |
---|
| 227 | CASE( 21 ) !== time varying 2D field ==! |
---|
| 228 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F( latitude, longitude, time )' |
---|
| 229 | IF(lwp) WRITE(numout,*) ' = F( growth rate of baroclinic instability )' |
---|
| 230 | IF(lwp) WRITE(numout,*) ' min value = 0.1 * rn_aht_0' |
---|
| 231 | IF(lwp) WRITE(numout,*) ' max value = rn_aht_0 (rn_aeiv_0 if nn_aei_ijk_t=21)' |
---|
| 232 | IF(lwp) WRITE(numout,*) ' increased to rn_aht_0 within 20N-20S' |
---|
| 233 | ! |
---|
| 234 | l_ldftra_time = .TRUE. ! will be calculated by call to ldf_tra routine in step.F90 |
---|
| 235 | ! |
---|
| 236 | IF( ln_traldf_blp ) THEN |
---|
| 237 | CALL ctl_stop( 'ldf_tra_init: aht=F(growth rate of baroc. insta.) incompatible with bilaplacian operator' ) |
---|
| 238 | ENDIF |
---|
| 239 | ! |
---|
| 240 | CASE( -30 ) !== fixed 3D shape read in file ==! |
---|
| 241 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F(i,j,k) read in eddy_diffusivity.nc file' |
---|
| 242 | CALL iom_open( 'eddy_diffusivity_3D.nc', inum ) |
---|
| 243 | CALL iom_get ( inum, jpdom_data, 'ahtu_3D', ahtu ) |
---|
| 244 | CALL iom_get ( inum, jpdom_data, 'ahtv_3D', ahtv ) |
---|
| 245 | CALL iom_close( inum ) |
---|
| 246 | DO jk = 1, jpkm1 |
---|
[7753] | 247 | ahtu(:,:,jk) = ahtu(:,:,jk) * umask(:,:,jk) |
---|
| 248 | ahtv(:,:,jk) = ahtv(:,:,jk) * vmask(:,:,jk) |
---|
[5836] | 249 | END DO |
---|
| 250 | ! |
---|
| 251 | CASE( 30 ) !== fixed 3D shape ==! |
---|
| 252 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F( latitude, longitude, depth )' |
---|
| 253 | IF( ln_traldf_lap ) CALL ldf_c2d( 'TRA', 'LAP', zah0, ahtu, ahtv ) ! surface value proportional to scale factor |
---|
| 254 | IF( ln_traldf_blp ) CALL ldf_c2d( 'TRA', 'BLP', zah0, ahtu, ahtv ) ! surface value proportional to scale factor |
---|
| 255 | ! ! reduction with depth |
---|
| 256 | CALL ldf_c1d( 'TRA', r1_4, ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv ) |
---|
| 257 | ! |
---|
| 258 | CASE( 31 ) !== time varying 3D field ==! |
---|
| 259 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F( latitude, longitude, depth , time )' |
---|
| 260 | IF(lwp) WRITE(numout,*) ' proportional to the velocity : |u|e/12 or |u|e^3/12' |
---|
| 261 | ! |
---|
| 262 | l_ldftra_time = .TRUE. ! will be calculated by call to ldf_tra routine in step.F90 |
---|
| 263 | ! |
---|
| 264 | CASE DEFAULT |
---|
| 265 | CALL ctl_stop('ldf_tra_init: wrong choice for nn_aht_ijk_t, the type of space-time variation of aht') |
---|
| 266 | END SELECT |
---|
| 267 | ! |
---|
| 268 | IF( ln_traldf_blp .AND. .NOT. l_ldftra_time ) THEN |
---|
[7753] | 269 | ahtu(:,:,:) = SQRT( ahtu(:,:,:) ) |
---|
| 270 | ahtv(:,:,:) = SQRT( ahtv(:,:,:) ) |
---|
[5836] | 271 | ENDIF |
---|
| 272 | ! |
---|
| 273 | ENDIF |
---|
| 274 | ! |
---|
| 275 | END SUBROUTINE ldf_tra_init |
---|
[3] | 276 | |
---|
| 277 | |
---|
[5836] | 278 | SUBROUTINE ldf_tra( kt ) |
---|
| 279 | !!---------------------------------------------------------------------- |
---|
| 280 | !! *** ROUTINE ldf_tra *** |
---|
| 281 | !! |
---|
| 282 | !! ** Purpose : update at kt the tracer lateral mixing coeff. (aht and aeiv) |
---|
| 283 | !! |
---|
| 284 | !! ** Method : time varying eddy diffusivity coefficients: |
---|
| 285 | !! |
---|
| 286 | !! nn_aei_ijk_t = 21 aeiu, aeiv = F(i,j, t) = F(growth rate of baroclinic instability) |
---|
| 287 | !! with a reduction to 0 in vicinity of the Equator |
---|
| 288 | !! nn_aht_ijk_t = 21 ahtu, ahtv = F(i,j, t) = F(growth rate of baroclinic instability) |
---|
| 289 | !! |
---|
| 290 | !! = 31 ahtu, ahtv = F(i,j,k,t) = F(local velocity) ( |u|e /12 laplacian operator |
---|
| 291 | !! or |u|e^3/12 bilaplacian operator ) |
---|
| 292 | !! |
---|
| 293 | !! ** action : ahtu, ahtv update at each time step |
---|
| 294 | !! aeiu, aeiv - - - - (if ln_ldfeiv=T) |
---|
| 295 | !!---------------------------------------------------------------------- |
---|
| 296 | INTEGER, INTENT(in) :: kt ! time step |
---|
| 297 | ! |
---|
| 298 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
[7646] | 299 | REAL(wp) :: zaht, zahf, zaht_min, z1_f20 ! local scalar |
---|
[5836] | 300 | !!---------------------------------------------------------------------- |
---|
| 301 | ! |
---|
[7646] | 302 | IF( ln_ldfeiv .AND. nn_aei_ijk_t == 21 ) THEN ! eddy induced velocity coefficients |
---|
[5836] | 303 | ! ! =F(growth rate of baroclinic instability) |
---|
| 304 | ! ! max value rn_aeiv_0 ; decreased to 0 within 20N-20S |
---|
| 305 | CALL ldf_eiv( kt, rn_aeiv_0, aeiu, aeiv ) |
---|
| 306 | ENDIF |
---|
| 307 | ! |
---|
| 308 | SELECT CASE( nn_aht_ijk_t ) ! Eddy diffusivity coefficients |
---|
| 309 | ! |
---|
| 310 | CASE( 21 ) !== time varying 2D field ==! = F( growth rate of baroclinic instability ) |
---|
| 311 | ! ! min value rn_aht_0 / 10 |
---|
| 312 | ! ! max value rn_aht_0 (rn_aeiv_0 if nn_aei_ijk_t=21) |
---|
| 313 | ! ! increase to rn_aht_0 within 20N-20S |
---|
[7646] | 314 | IF( ln_ldfeiv .AND. nn_aei_ijk_t == 21 ) THEN ! use the already computed aei. |
---|
[7753] | 315 | ahtu(:,:,1) = aeiu(:,:,1) |
---|
| 316 | ahtv(:,:,1) = aeiv(:,:,1) |
---|
[7646] | 317 | ELSE ! compute aht. |
---|
| 318 | CALL ldf_eiv( kt, rn_aht_0, ahtu, ahtv ) |
---|
[5836] | 319 | ENDIF |
---|
| 320 | ! |
---|
| 321 | z1_f20 = 1._wp / ( 2._wp * omega * SIN( rad * 20._wp ) ) ! 1 / ff(20 degrees) |
---|
| 322 | zaht_min = 0.2_wp * rn_aht_0 ! minimum value for aht |
---|
| 323 | DO jj = 1, jpj |
---|
| 324 | DO ji = 1, jpi |
---|
[7646] | 325 | !!gm CAUTION : here we assume lat/lon grid in 20deg N/S band (like all ORCA cfg) |
---|
| 326 | !! ==>>> The Coriolis value is identical for t- & u_points, and for v- and f-points |
---|
| 327 | zaht = ( 1._wp - MIN( 1._wp , ABS( ff_t(ji,jj) * z1_f20 ) ) ) * ( rn_aht_0 - zaht_min ) |
---|
| 328 | zahf = ( 1._wp - MIN( 1._wp , ABS( ff_f(ji,jj) * z1_f20 ) ) ) * ( rn_aht_0 - zaht_min ) |
---|
[5836] | 329 | ahtu(ji,jj,1) = ( MAX( zaht_min, ahtu(ji,jj,1) ) + zaht ) * umask(ji,jj,1) ! min value zaht_min |
---|
[7646] | 330 | ahtv(ji,jj,1) = ( MAX( zaht_min, ahtv(ji,jj,1) ) + zahf ) * vmask(ji,jj,1) ! increase within 20S-20N |
---|
[5836] | 331 | END DO |
---|
| 332 | END DO |
---|
| 333 | DO jk = 2, jpkm1 ! deeper value = surface value |
---|
[7753] | 334 | ahtu(:,:,jk) = ahtu(:,:,1) * umask(:,:,jk) |
---|
| 335 | ahtv(:,:,jk) = ahtv(:,:,1) * vmask(:,:,jk) |
---|
[5836] | 336 | END DO |
---|
| 337 | ! |
---|
| 338 | CASE( 31 ) !== time varying 3D field ==! = F( local velocity ) |
---|
| 339 | IF( ln_traldf_lap ) THEN ! laplacian operator |u| e /12 |
---|
| 340 | DO jk = 1, jpkm1 |
---|
[7753] | 341 | ahtu(:,:,jk) = ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12 |
---|
| 342 | ahtv(:,:,jk) = ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12 |
---|
[5836] | 343 | END DO |
---|
| 344 | ELSEIF( ln_traldf_blp ) THEN ! bilaplacian operator sqrt( |u| e^3 /12 ) = sqrt( |u| e /12 ) * e |
---|
| 345 | DO jk = 1, jpkm1 |
---|
[7753] | 346 | ahtu(:,:,jk) = SQRT( ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12 ) * e1u(:,:) |
---|
| 347 | ahtv(:,:,jk) = SQRT( ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12 ) * e2v(:,:) |
---|
[5836] | 348 | END DO |
---|
| 349 | ENDIF |
---|
| 350 | ! |
---|
| 351 | END SELECT |
---|
| 352 | ! |
---|
[7646] | 353 | CALL iom_put( "ahtu_2d", ahtu(:,:,1) ) ! surface u-eddy diffusivity coeff. |
---|
| 354 | CALL iom_put( "ahtv_2d", ahtv(:,:,1) ) ! surface v-eddy diffusivity coeff. |
---|
| 355 | CALL iom_put( "ahtu_3d", ahtu(:,:,:) ) ! 3D u-eddy diffusivity coeff. |
---|
| 356 | CALL iom_put( "ahtv_3d", ahtv(:,:,:) ) ! 3D v-eddy diffusivity coeff. |
---|
| 357 | ! |
---|
[5836] | 358 | !!gm : THE IF below is to be checked (comes from Seb) |
---|
[7646] | 359 | IF( ln_ldfeiv ) THEN |
---|
| 360 | CALL iom_put( "aeiu_2d", aeiu(:,:,1) ) ! surface u-EIV coeff. |
---|
| 361 | CALL iom_put( "aeiv_2d", aeiv(:,:,1) ) ! surface v-EIV coeff. |
---|
| 362 | CALL iom_put( "aeiu_3d", aeiu(:,:,:) ) ! 3D u-EIV coeff. |
---|
| 363 | CALL iom_put( "aeiv_3d", aeiv(:,:,:) ) ! 3D v-EIV coeff. |
---|
[5836] | 364 | ENDIF |
---|
| 365 | ! |
---|
| 366 | END SUBROUTINE ldf_tra |
---|
[1601] | 367 | |
---|
[3] | 368 | |
---|
[5836] | 369 | SUBROUTINE ldf_eiv_init |
---|
| 370 | !!---------------------------------------------------------------------- |
---|
| 371 | !! *** ROUTINE ldf_eiv_init *** |
---|
| 372 | !! |
---|
| 373 | !! ** Purpose : initialization of the eiv coeff. from namelist choices. |
---|
| 374 | !! |
---|
| 375 | !! ** Method : |
---|
| 376 | !! |
---|
| 377 | !! ** Action : aeiu , aeiv : EIV coeff. at u- & v-points |
---|
| 378 | !! l_ldfeiv_time : =T if EIV coefficients vary with time |
---|
| 379 | !!---------------------------------------------------------------------- |
---|
[7753] | 380 | INTEGER :: jk ! dummy loop indices |
---|
[5836] | 381 | INTEGER :: ierr, inum, ios ! local integer |
---|
| 382 | ! |
---|
| 383 | NAMELIST/namtra_ldfeiv/ ln_ldfeiv , ln_ldfeiv_dia, & ! eddy induced velocity (eiv) |
---|
| 384 | & nn_aei_ijk_t, rn_aeiv_0 ! eiv coefficient |
---|
| 385 | !!---------------------------------------------------------------------- |
---|
| 386 | ! |
---|
| 387 | REWIND( numnam_ref ) ! Namelist namtra_ldfeiv in reference namelist : eddy induced velocity param. |
---|
| 388 | READ ( numnam_ref, namtra_ldfeiv, IOSTAT = ios, ERR = 901) |
---|
| 389 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldfeiv in reference namelist', lwp ) |
---|
| 390 | ! |
---|
| 391 | REWIND( numnam_cfg ) ! Namelist namtra_ldfeiv in configuration namelist : eddy induced velocity param. |
---|
| 392 | READ ( numnam_cfg, namtra_ldfeiv, IOSTAT = ios, ERR = 902 ) |
---|
| 393 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_ldfeiv in configuration namelist', lwp ) |
---|
| 394 | IF(lwm) WRITE ( numond, namtra_ldfeiv ) |
---|
| 395 | |
---|
| 396 | IF(lwp) THEN ! control print |
---|
| 397 | WRITE(numout,*) |
---|
| 398 | WRITE(numout,*) 'ldf_eiv_init : eddy induced velocity parametrization' |
---|
| 399 | WRITE(numout,*) '~~~~~~~~~~~~ ' |
---|
| 400 | WRITE(numout,*) ' Namelist namtra_ldfeiv : ' |
---|
| 401 | WRITE(numout,*) ' Eddy Induced Velocity (eiv) param. ln_ldfeiv = ', ln_ldfeiv |
---|
| 402 | WRITE(numout,*) ' eiv streamfunction & velocity diag. ln_ldfeiv_dia = ', ln_ldfeiv_dia |
---|
| 403 | WRITE(numout,*) ' eddy induced velocity coef. rn_aeiv_0 = ', rn_aeiv_0 |
---|
| 404 | WRITE(numout,*) ' type of time-space variation nn_aei_ijk_t = ', nn_aei_ijk_t |
---|
| 405 | WRITE(numout,*) |
---|
[3] | 406 | ENDIF |
---|
[5836] | 407 | ! |
---|
| 408 | IF( ln_ldfeiv .AND. ln_traldf_blp ) CALL ctl_stop( 'ldf_eiv_init: eddy induced velocity ONLY with laplacian diffusivity' ) |
---|
[3] | 409 | |
---|
[5836] | 410 | ! ! Parameter control |
---|
| 411 | l_ldfeiv_time = .FALSE. |
---|
| 412 | ! |
---|
| 413 | IF( ln_ldfeiv ) THEN ! allocate the aei arrays |
---|
| 414 | ALLOCATE( aeiu(jpi,jpj,jpk), aeiv(jpi,jpj,jpk), STAT=ierr ) |
---|
| 415 | IF( ierr /= 0 ) CALL ctl_stop('STOP', 'ldf_eiv: failed to allocate arrays') |
---|
| 416 | ! |
---|
| 417 | SELECT CASE( nn_aei_ijk_t ) ! Specification of space time variations of eaiu, aeiv |
---|
| 418 | ! |
---|
| 419 | CASE( 0 ) !== constant ==! |
---|
| 420 | IF(lwp) WRITE(numout,*) ' eddy induced velocity coef. = constant = ', rn_aeiv_0 |
---|
[7753] | 421 | aeiu(:,:,:) = rn_aeiv_0 |
---|
| 422 | aeiv(:,:,:) = rn_aeiv_0 |
---|
[5836] | 423 | ! |
---|
| 424 | CASE( 10 ) !== fixed profile ==! |
---|
| 425 | IF(lwp) WRITE(numout,*) ' eddy induced velocity coef. = F( depth )' |
---|
[7753] | 426 | aeiu(:,:,1) = rn_aeiv_0 ! constant surface value |
---|
| 427 | aeiv(:,:,1) = rn_aeiv_0 |
---|
[5836] | 428 | CALL ldf_c1d( 'TRA', r1_4, aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv ) |
---|
| 429 | ! |
---|
| 430 | CASE ( -20 ) !== fixed horizontal shape read in file ==! |
---|
| 431 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F(i,j) read in eddy_diffusivity_2D.nc file' |
---|
| 432 | CALL iom_open ( 'eddy_induced_velocity_2D.nc', inum ) |
---|
| 433 | CALL iom_get ( inum, jpdom_data, 'aeiu', aeiu(:,:,1) ) |
---|
| 434 | CALL iom_get ( inum, jpdom_data, 'aeiv', aeiv(:,:,1) ) |
---|
| 435 | CALL iom_close( inum ) |
---|
| 436 | DO jk = 2, jpk |
---|
[7753] | 437 | aeiu(:,:,jk) = aeiu(:,:,1) |
---|
| 438 | aeiv(:,:,jk) = aeiv(:,:,1) |
---|
[5836] | 439 | END DO |
---|
| 440 | ! |
---|
| 441 | CASE( 20 ) !== fixed horizontal shape ==! |
---|
| 442 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F( e1, e2 ) or F( e1^3, e2^3 ) (lap or bilap case)' |
---|
| 443 | CALL ldf_c2d( 'TRA', 'LAP', rn_aeiv_0, aeiu, aeiv ) ! surface value proportional to scale factor |
---|
| 444 | ! |
---|
| 445 | CASE( 21 ) !== time varying 2D field ==! |
---|
| 446 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F( latitude, longitude, time )' |
---|
| 447 | IF(lwp) WRITE(numout,*) ' = F( growth rate of baroclinic instability )' |
---|
| 448 | ! |
---|
| 449 | l_ldfeiv_time = .TRUE. ! will be calculated by call to ldf_tra routine in step.F90 |
---|
| 450 | ! |
---|
| 451 | CASE( -30 ) !== fixed 3D shape read in file ==! |
---|
| 452 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F(i,j,k) read in eddy_diffusivity_3D.nc file' |
---|
| 453 | CALL iom_open ( 'eddy_induced_velocity_3D.nc', inum ) |
---|
| 454 | CALL iom_get ( inum, jpdom_data, 'aeiu', aeiu ) |
---|
| 455 | CALL iom_get ( inum, jpdom_data, 'aeiv', aeiv ) |
---|
| 456 | CALL iom_close( inum ) |
---|
| 457 | ! |
---|
| 458 | CASE( 30 ) !== fixed 3D shape ==! |
---|
| 459 | IF(lwp) WRITE(numout,*) ' tracer mixing coef. = F( latitude, longitude, depth )' |
---|
| 460 | CALL ldf_c2d( 'TRA', 'LAP', rn_aeiv_0, aeiu, aeiv ) ! surface value proportional to scale factor |
---|
| 461 | ! ! reduction with depth |
---|
| 462 | CALL ldf_c1d( 'TRA', r1_4, aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv ) |
---|
| 463 | ! |
---|
| 464 | CASE DEFAULT |
---|
| 465 | CALL ctl_stop('ldf_tra_init: wrong choice for nn_aei_ijk_t, the type of space-time variation of aei') |
---|
| 466 | END SELECT |
---|
| 467 | ! |
---|
[3] | 468 | ELSE |
---|
[5836] | 469 | IF(lwp) WRITE(numout,*) ' eddy induced velocity param is NOT used neither diagnosed' |
---|
| 470 | ln_ldfeiv_dia = .FALSE. |
---|
[3] | 471 | ENDIF |
---|
[5836] | 472 | ! |
---|
| 473 | END SUBROUTINE ldf_eiv_init |
---|
[3] | 474 | |
---|
| 475 | |
---|
[5836] | 476 | SUBROUTINE ldf_eiv( kt, paei0, paeiu, paeiv ) |
---|
| 477 | !!---------------------------------------------------------------------- |
---|
| 478 | !! *** ROUTINE ldf_eiv *** |
---|
| 479 | !! |
---|
| 480 | !! ** Purpose : Compute the eddy induced velocity coefficient from the |
---|
| 481 | !! growth rate of baroclinic instability. |
---|
| 482 | !! |
---|
| 483 | !! ** Method : coefficient function of the growth rate of baroclinic instability |
---|
| 484 | !! |
---|
| 485 | !! Reference : Treguier et al. JPO 1997 ; Held and Larichev JAS 1996 |
---|
| 486 | !!---------------------------------------------------------------------- |
---|
| 487 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
| 488 | REAL(wp) , INTENT(inout) :: paei0 ! max value [m2/s] |
---|
| 489 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: paeiu, paeiv ! eiv coefficient [m2/s] |
---|
| 490 | ! |
---|
| 491 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
| 492 | REAL(wp) :: zfw, ze3w, zn2, z1_f20, zaht, zaht_min, zzaei ! local scalars |
---|
| 493 | REAL(wp), DIMENSION(:,:), POINTER :: zn, zah, zhw, zross, zaeiw ! 2D workspace |
---|
| 494 | !!---------------------------------------------------------------------- |
---|
| 495 | ! |
---|
| 496 | IF( nn_timing == 1 ) CALL timing_start('ldf_eiv') |
---|
| 497 | ! |
---|
| 498 | CALL wrk_alloc( jpi,jpj, zn, zah, zhw, zross, zaeiw ) |
---|
| 499 | ! |
---|
[7753] | 500 | zn (:,:) = 0._wp ! Local initialization |
---|
| 501 | zhw (:,:) = 5._wp |
---|
| 502 | zah (:,:) = 0._wp |
---|
| 503 | zross(:,:) = 0._wp |
---|
[5836] | 504 | ! ! Compute lateral diffusive coefficient at T-point |
---|
| 505 | IF( ln_traldf_triad ) THEN |
---|
| 506 | DO jk = 1, jpk |
---|
| 507 | DO jj = 2, jpjm1 |
---|
| 508 | DO ji = 2, jpim1 |
---|
| 509 | ! Take the max of N^2 and zero then take the vertical sum |
---|
| 510 | ! of the square root of the resulting N^2 ( required to compute |
---|
| 511 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
---|
| 512 | zn2 = MAX( rn2b(ji,jj,jk), 0._wp ) |
---|
[6140] | 513 | zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk) |
---|
[5836] | 514 | ! Compute elements required for the inverse time scale of baroclinic |
---|
| 515 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
---|
| 516 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
---|
[6140] | 517 | ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk) |
---|
[5836] | 518 | zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w |
---|
| 519 | zhw(ji,jj) = zhw(ji,jj) + ze3w |
---|
| 520 | END DO |
---|
| 521 | END DO |
---|
| 522 | END DO |
---|
| 523 | ELSE |
---|
| 524 | DO jk = 1, jpk |
---|
| 525 | DO jj = 2, jpjm1 |
---|
| 526 | DO ji = 2, jpim1 |
---|
| 527 | ! Take the max of N^2 and zero then take the vertical sum |
---|
| 528 | ! of the square root of the resulting N^2 ( required to compute |
---|
| 529 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
---|
| 530 | zn2 = MAX( rn2b(ji,jj,jk), 0._wp ) |
---|
[6140] | 531 | zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk) |
---|
[5836] | 532 | ! Compute elements required for the inverse time scale of baroclinic |
---|
| 533 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
---|
| 534 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
---|
[6140] | 535 | ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk) |
---|
[5836] | 536 | zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk) & |
---|
| 537 | & + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w |
---|
| 538 | zhw(ji,jj) = zhw(ji,jj) + ze3w |
---|
| 539 | END DO |
---|
| 540 | END DO |
---|
| 541 | END DO |
---|
| 542 | END IF |
---|
| 543 | |
---|
| 544 | DO jj = 2, jpjm1 |
---|
| 545 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
| 546 | zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 ) |
---|
| 547 | ! Rossby radius at w-point taken < 40km and > 2km |
---|
| 548 | zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 ) |
---|
| 549 | ! Compute aeiw by multiplying Ro^2 and T^-1 |
---|
| 550 | zaeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1) |
---|
| 551 | END DO |
---|
| 552 | END DO |
---|
| 553 | |
---|
| 554 | ! !== Bound on eiv coeff. ==! |
---|
| 555 | z1_f20 = 1._wp / ( 2._wp * omega * sin( rad * 20._wp ) ) |
---|
| 556 | DO jj = 2, jpjm1 |
---|
| 557 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
[7646] | 558 | zzaei = MIN( 1._wp, ABS( ff_t(ji,jj) * z1_f20 ) ) * zaeiw(ji,jj) ! tropical decrease |
---|
[5836] | 559 | zaeiw(ji,jj) = MIN( zzaei , paei0 ) ! Max value = paei0 |
---|
| 560 | END DO |
---|
| 561 | END DO |
---|
| 562 | CALL lbc_lnk( zaeiw(:,:), 'W', 1. ) ! lateral boundary condition |
---|
| 563 | ! |
---|
| 564 | DO jj = 2, jpjm1 !== aei at u- and v-points ==! |
---|
| 565 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
| 566 | paeiu(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji+1,jj ) ) * umask(ji,jj,1) |
---|
| 567 | paeiv(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji ,jj+1) ) * vmask(ji,jj,1) |
---|
| 568 | END DO |
---|
| 569 | END DO |
---|
| 570 | CALL lbc_lnk( paeiu(:,:,1), 'U', 1. ) ; CALL lbc_lnk( paeiv(:,:,1), 'V', 1. ) ! lateral boundary condition |
---|
| 571 | |
---|
| 572 | DO jk = 2, jpkm1 !== deeper values equal the surface one ==! |
---|
[7753] | 573 | paeiu(:,:,jk) = paeiu(:,:,1) * umask(:,:,jk) |
---|
| 574 | paeiv(:,:,jk) = paeiv(:,:,1) * vmask(:,:,jk) |
---|
[5836] | 575 | END DO |
---|
| 576 | ! |
---|
| 577 | CALL wrk_dealloc( jpi,jpj, zn, zah, zhw, zross, zaeiw ) |
---|
| 578 | ! |
---|
| 579 | IF( nn_timing == 1 ) CALL timing_stop('ldf_eiv') |
---|
| 580 | ! |
---|
| 581 | END SUBROUTINE ldf_eiv |
---|
| 582 | |
---|
| 583 | |
---|
| 584 | SUBROUTINE ldf_eiv_trp( kt, kit000, pun, pvn, pwn, cdtype ) |
---|
| 585 | !!---------------------------------------------------------------------- |
---|
| 586 | !! *** ROUTINE ldf_eiv_trp *** |
---|
| 587 | !! |
---|
| 588 | !! ** Purpose : add to the input ocean transport the contribution of |
---|
| 589 | !! the eddy induced velocity parametrization. |
---|
| 590 | !! |
---|
| 591 | !! ** Method : The eddy induced transport is computed from a flux stream- |
---|
| 592 | !! function which depends on the slope of iso-neutral surfaces |
---|
| 593 | !! (see ldf_slp). For example, in the i-k plan : |
---|
| 594 | !! psi_uw = mk(aeiu) e2u mi(wslpi) [in m3/s] |
---|
| 595 | !! Utr_eiv = - dk[psi_uw] |
---|
| 596 | !! Vtr_eiv = + di[psi_uw] |
---|
| 597 | !! ln_ldfeiv_dia = T : output the associated streamfunction, |
---|
| 598 | !! velocity and heat transport (call ldf_eiv_dia) |
---|
| 599 | !! |
---|
| 600 | !! ** Action : pun, pvn increased by the eiv transport |
---|
| 601 | !!---------------------------------------------------------------------- |
---|
| 602 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
| 603 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
| 604 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
| 605 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: pun ! in : 3 ocean transport components [m3/s] |
---|
| 606 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: pvn ! out: 3 ocean transport components [m3/s] |
---|
| 607 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: pwn ! increased by the eiv [m3/s] |
---|
| 608 | !! |
---|
| 609 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
| 610 | REAL(wp) :: zuwk, zuwk1, zuwi, zuwi1 ! local scalars |
---|
| 611 | REAL(wp) :: zvwk, zvwk1, zvwj, zvwj1 ! - - |
---|
| 612 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zpsi_uw, zpsi_vw |
---|
| 613 | !!---------------------------------------------------------------------- |
---|
| 614 | ! |
---|
| 615 | IF( nn_timing == 1 ) CALL timing_start( 'ldf_eiv_trp') |
---|
| 616 | ! |
---|
| 617 | CALL wrk_alloc( jpi,jpj,jpk, zpsi_uw, zpsi_vw ) |
---|
| 618 | |
---|
| 619 | IF( kt == kit000 ) THEN |
---|
| 620 | IF(lwp) WRITE(numout,*) |
---|
| 621 | IF(lwp) WRITE(numout,*) 'ldf_eiv_trp : eddy induced advection on ', cdtype,' :' |
---|
| 622 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ add to velocity fields the eiv component' |
---|
[3] | 623 | ENDIF |
---|
[3634] | 624 | |
---|
[5836] | 625 | |
---|
[7753] | 626 | zpsi_uw(:,:, 1 ) = 0._wp ; zpsi_vw(:,:, 1 ) = 0._wp |
---|
| 627 | zpsi_uw(:,:,jpk) = 0._wp ; zpsi_vw(:,:,jpk) = 0._wp |
---|
[5836] | 628 | ! |
---|
| 629 | DO jk = 2, jpkm1 |
---|
| 630 | DO jj = 1, jpjm1 |
---|
| 631 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
| 632 | zpsi_uw(ji,jj,jk) = - 0.25_wp * e2u(ji,jj) * ( wslpi(ji,jj,jk ) + wslpi(ji+1,jj,jk) ) & |
---|
| 633 | & * ( aeiu (ji,jj,jk-1) + aeiu (ji ,jj,jk) ) * umask(ji,jj,jk) |
---|
| 634 | zpsi_vw(ji,jj,jk) = - 0.25_wp * e1v(ji,jj) * ( wslpj(ji,jj,jk ) + wslpj(ji,jj+1,jk) ) & |
---|
| 635 | & * ( aeiv (ji,jj,jk-1) + aeiv (ji,jj ,jk) ) * vmask(ji,jj,jk) |
---|
| 636 | END DO |
---|
| 637 | END DO |
---|
| 638 | END DO |
---|
| 639 | ! |
---|
| 640 | DO jk = 1, jpkm1 |
---|
| 641 | DO jj = 1, jpjm1 |
---|
| 642 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
| 643 | pun(ji,jj,jk) = pun(ji,jj,jk) - ( zpsi_uw(ji,jj,jk) - zpsi_uw(ji,jj,jk+1) ) |
---|
| 644 | pvn(ji,jj,jk) = pvn(ji,jj,jk) - ( zpsi_vw(ji,jj,jk) - zpsi_vw(ji,jj,jk+1) ) |
---|
| 645 | END DO |
---|
| 646 | END DO |
---|
| 647 | END DO |
---|
| 648 | DO jk = 1, jpkm1 |
---|
| 649 | DO jj = 2, jpjm1 |
---|
| 650 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
| 651 | pwn(ji,jj,jk) = pwn(ji,jj,jk) + ( zpsi_uw(ji,jj,jk) - zpsi_uw(ji-1,jj ,jk) & |
---|
| 652 | & + zpsi_vw(ji,jj,jk) - zpsi_vw(ji ,jj-1,jk) ) |
---|
| 653 | END DO |
---|
| 654 | END DO |
---|
| 655 | END DO |
---|
| 656 | ! |
---|
| 657 | ! ! diagnose the eddy induced velocity and associated heat transport |
---|
| 658 | IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' ) CALL ldf_eiv_dia( zpsi_uw, zpsi_vw ) |
---|
| 659 | ! |
---|
| 660 | CALL wrk_dealloc( jpi,jpj,jpk, zpsi_uw, zpsi_vw ) |
---|
| 661 | ! |
---|
| 662 | IF( nn_timing == 1 ) CALL timing_stop( 'ldf_eiv_trp') |
---|
| 663 | ! |
---|
| 664 | END SUBROUTINE ldf_eiv_trp |
---|
[3634] | 665 | |
---|
[5836] | 666 | |
---|
| 667 | SUBROUTINE ldf_eiv_dia( psi_uw, psi_vw ) |
---|
| 668 | !!---------------------------------------------------------------------- |
---|
| 669 | !! *** ROUTINE ldf_eiv_dia *** |
---|
| 670 | !! |
---|
| 671 | !! ** Purpose : diagnose the eddy induced velocity and its associated |
---|
| 672 | !! vertically integrated heat transport. |
---|
| 673 | !! |
---|
| 674 | !! ** Method : |
---|
| 675 | !! |
---|
| 676 | !!---------------------------------------------------------------------- |
---|
| 677 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: psi_uw, psi_vw ! streamfunction [m3/s] |
---|
[1601] | 678 | ! |
---|
[5836] | 679 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
| 680 | REAL(wp) :: zztmp ! local scalar |
---|
| 681 | REAL(wp), DIMENSION(:,:) , POINTER :: zw2d ! 2D workspace |
---|
| 682 | REAL(wp), DIMENSION(:,:,:), POINTER :: zw3d ! 3D workspace |
---|
| 683 | !!---------------------------------------------------------------------- |
---|
| 684 | ! |
---|
| 685 | IF( nn_timing == 1 ) CALL timing_start( 'ldf_eiv_dia') |
---|
| 686 | ! |
---|
| 687 | ! !== eiv stream function: output ==! |
---|
| 688 | CALL lbc_lnk( psi_uw, 'U', -1. ) ! lateral boundary condition |
---|
| 689 | CALL lbc_lnk( psi_vw, 'V', -1. ) |
---|
| 690 | ! |
---|
| 691 | !!gm CALL iom_put( "psi_eiv_uw", psi_uw ) ! output |
---|
| 692 | !!gm CALL iom_put( "psi_eiv_vw", psi_vw ) |
---|
| 693 | ! |
---|
| 694 | ! !== eiv velocities: calculate and output ==! |
---|
| 695 | CALL wrk_alloc( jpi,jpj,jpk, zw3d ) |
---|
| 696 | ! |
---|
[7753] | 697 | zw3d(:,:,jpk) = 0._wp ! bottom value always 0 |
---|
[5836] | 698 | ! |
---|
| 699 | DO jk = 1, jpkm1 ! e2u e3u u_eiv = -dk[psi_uw] |
---|
[7753] | 700 | zw3d(:,:,jk) = ( psi_uw(:,:,jk+1) - psi_uw(:,:,jk) ) / ( e2u(:,:) * e3u_n(:,:,jk) ) |
---|
[5836] | 701 | END DO |
---|
| 702 | CALL iom_put( "uoce_eiv", zw3d ) |
---|
| 703 | ! |
---|
| 704 | DO jk = 1, jpkm1 ! e1v e3v v_eiv = -dk[psi_vw] |
---|
[7753] | 705 | zw3d(:,:,jk) = ( psi_vw(:,:,jk+1) - psi_vw(:,:,jk) ) / ( e1v(:,:) * e3v_n(:,:,jk) ) |
---|
[5836] | 706 | END DO |
---|
| 707 | CALL iom_put( "voce_eiv", zw3d ) |
---|
| 708 | ! |
---|
| 709 | DO jk = 1, jpkm1 ! e1 e2 w_eiv = dk[psix] + dk[psix] |
---|
| 710 | DO jj = 2, jpjm1 |
---|
| 711 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
| 712 | zw3d(ji,jj,jk) = ( psi_vw(ji,jj,jk) - psi_vw(ji ,jj-1,jk) & |
---|
| 713 | & + psi_uw(ji,jj,jk) - psi_uw(ji-1,jj ,jk) ) / e1e2t(ji,jj) |
---|
| 714 | END DO |
---|
| 715 | END DO |
---|
| 716 | END DO |
---|
| 717 | CALL lbc_lnk( zw3d, 'T', 1. ) ! lateral boundary condition |
---|
| 718 | CALL iom_put( "woce_eiv", zw3d ) |
---|
| 719 | ! |
---|
| 720 | ! |
---|
| 721 | ! |
---|
[7646] | 722 | CALL wrk_alloc( jpi,jpj, zw2d ) |
---|
| 723 | ! |
---|
| 724 | zztmp = 0.5_wp * rau0 * rcp |
---|
| 725 | IF( iom_use('ueiv_heattr') .OR. iom_use('ueiv_heattr3d') ) THEN |
---|
[7753] | 726 | zw2d(:,:) = 0._wp |
---|
| 727 | zw3d(:,:,:) = 0._wp |
---|
| 728 | DO jk = 1, jpkm1 |
---|
| 729 | DO jj = 2, jpjm1 |
---|
| 730 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
| 731 | zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_uw(ji,jj,jk+1) - psi_uw(ji,jj,jk) ) & |
---|
| 732 | & * ( tsn (ji,jj,jk,jp_tem) + tsn (ji+1,jj,jk,jp_tem) ) |
---|
| 733 | zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk) |
---|
| 734 | END DO |
---|
| 735 | END DO |
---|
| 736 | END DO |
---|
| 737 | CALL lbc_lnk( zw2d, 'U', -1. ) |
---|
| 738 | CALL lbc_lnk( zw3d, 'U', -1. ) |
---|
| 739 | CALL iom_put( "ueiv_heattr" , zztmp * zw2d ) ! heat transport in i-direction |
---|
| 740 | CALL iom_put( "ueiv_heattr3d", zztmp * zw3d ) ! heat transport in i-direction |
---|
[7646] | 741 | ENDIF |
---|
[7753] | 742 | zw2d(:,:) = 0._wp |
---|
| 743 | zw3d(:,:,:) = 0._wp |
---|
[7646] | 744 | DO jk = 1, jpkm1 |
---|
| 745 | DO jj = 2, jpjm1 |
---|
| 746 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
| 747 | zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_vw(ji,jj,jk+1) - psi_vw(ji,jj,jk) ) & |
---|
| 748 | & * ( tsn (ji,jj,jk,jp_tem) + tsn (ji,jj+1,jk,jp_tem) ) |
---|
| 749 | zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk) |
---|
[5836] | 750 | END DO |
---|
| 751 | END DO |
---|
[7646] | 752 | END DO |
---|
| 753 | CALL lbc_lnk( zw2d, 'V', -1. ) |
---|
| 754 | CALL iom_put( "veiv_heattr", zztmp * zw2d ) ! heat transport in j-direction |
---|
| 755 | CALL iom_put( "veiv_heattr", zztmp * zw3d ) ! heat transport in j-direction |
---|
| 756 | ! |
---|
| 757 | IF( ln_diaptr ) CALL dia_ptr_hst( jp_tem, 'eiv', 0.5 * zw3d ) |
---|
| 758 | ! |
---|
| 759 | zztmp = 0.5_wp * 0.5 |
---|
| 760 | IF( iom_use('ueiv_salttr') .OR. iom_use('ueiv_salttr3d')) THEN |
---|
[7753] | 761 | zw2d(:,:) = 0._wp |
---|
| 762 | zw3d(:,:,:) = 0._wp |
---|
| 763 | DO jk = 1, jpkm1 |
---|
| 764 | DO jj = 2, jpjm1 |
---|
| 765 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
| 766 | zw3d(ji,jj,jk) = zw3d(ji,jj,jk) * ( psi_uw(ji,jj,jk+1) - psi_uw(ji,jj,jk) ) & |
---|
| 767 | & * ( tsn (ji,jj,jk,jp_sal) + tsn (ji+1,jj,jk,jp_sal) ) |
---|
| 768 | zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk) |
---|
| 769 | END DO |
---|
| 770 | END DO |
---|
| 771 | END DO |
---|
| 772 | CALL lbc_lnk( zw2d, 'U', -1. ) |
---|
| 773 | CALL lbc_lnk( zw3d, 'U', -1. ) |
---|
| 774 | CALL iom_put( "ueiv_salttr", zztmp * zw2d ) ! salt transport in i-direction |
---|
| 775 | CALL iom_put( "ueiv_salttr3d", zztmp * zw3d ) ! salt transport in i-direction |
---|
[7646] | 776 | ENDIF |
---|
[7753] | 777 | zw2d(:,:) = 0._wp |
---|
| 778 | zw3d(:,:,:) = 0._wp |
---|
[7646] | 779 | DO jk = 1, jpkm1 |
---|
| 780 | DO jj = 2, jpjm1 |
---|
| 781 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
| 782 | zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_vw(ji,jj,jk+1) - psi_vw(ji,jj,jk) ) & |
---|
| 783 | & * ( tsn (ji,jj,jk,jp_sal) + tsn (ji,jj+1,jk,jp_sal) ) |
---|
| 784 | zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk) |
---|
[5836] | 785 | END DO |
---|
| 786 | END DO |
---|
[7646] | 787 | END DO |
---|
| 788 | CALL lbc_lnk( zw2d, 'V', -1. ) |
---|
| 789 | CALL iom_put( "veiv_salttr", zztmp * zw2d ) ! salt transport in j-direction |
---|
| 790 | CALL iom_put( "veiv_salttr", zztmp * zw3d ) ! salt transport in j-direction |
---|
[5836] | 791 | ! |
---|
[7646] | 792 | IF( ln_diaptr ) CALL dia_ptr_hst( jp_sal, 'eiv', 0.5 * zw3d ) |
---|
| 793 | ! |
---|
| 794 | CALL wrk_dealloc( jpi,jpj, zw2d ) |
---|
| 795 | CALL wrk_dealloc( jpi,jpj,jpk, zw3d ) |
---|
| 796 | ! |
---|
[5836] | 797 | IF( nn_timing == 1 ) CALL timing_stop( 'ldf_eiv_dia') |
---|
| 798 | ! |
---|
| 799 | END SUBROUTINE ldf_eiv_dia |
---|
[3] | 800 | |
---|
| 801 | !!====================================================================== |
---|
| 802 | END MODULE ldftra |
---|