source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcblk_algo_ncar.F90 @ 7753

Last change on this file since 7753 was 7753, checked in by mocavero, 4 years ago

Reverting trunk to remove OpenMP

File size: 16.4 KB
Line 
1MODULE sbcblk_algo_ncar
2   !!======================================================================
3   !!                   ***  MODULE  sbcblk_algo_ncar  ***
4   !! Computes:
5   !!   * bulk transfer coefficients C_D, C_E and C_H
6   !!   * air temp. and spec. hum. adjusted from zt (2m) to zu (10m) if needed
7   !!   * the effective bulk wind speed at 10m U_blk
8   !!   => all these are used in bulk formulas in sbcblk.F90
9   !!
10   !!    Using the bulk formulation/param. of Large & Yeager 2008
11   !!
12   !!       Routine turb_ncar maintained and developed in AeroBulk
13   !!                     (http://aerobulk.sourceforge.net/)
14   !!
15   !!                         L. Brodeau, 2015
16   !!=====================================================================
17   !! History :  3.6  !  2016-02  (L.Brodeau) successor of old turb_ncar of former sbcblk_core.F90
18   !!----------------------------------------------------------------------
19
20   !!----------------------------------------------------------------------
21   !!   turb_ncar  : computes the bulk turbulent transfer coefficients
22   !!                   adjusts t_air and q_air from zt to zu m
23   !!                   returns the effective bulk wind speed at 10m
24   !!----------------------------------------------------------------------
25   USE oce             ! ocean dynamics and tracers
26   USE dom_oce         ! ocean space and time domain
27   USE phycst          ! physical constants
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbcwave, ONLY   :  cdn_wave ! wave module
30#if defined key_lim3 || defined key_cice
31   USE sbc_ice         ! Surface boundary condition: ice fields
32#endif
33   !
34   USE iom             ! I/O manager library
35   USE lib_mpp         ! distribued memory computing library
36   USE wrk_nemo        ! work arrays
37   USE timing          ! Timing
38   USE in_out_manager  ! I/O manager
39   USE prtctl          ! Print control
40   USE lib_fortran     ! to use key_nosignedzero
41
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC ::   TURB_NCAR   ! called by sbcblk.F90
47
48   !                              ! NCAR own values for given constants:
49   REAL(wp), PARAMETER ::   rctv0 = 0.608   ! constant to obtain virtual temperature...
50   
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE turb_ncar( zt, zu, sst, t_zt, ssq, q_zt, U_zu, &
55      &                  Cd, Ch, Ce, t_zu, q_zu, U_blk )
56      !!----------------------------------------------------------------------------------
57      !!                      ***  ROUTINE  turb_ncar  ***
58      !!
59      !! ** Purpose :   Computes turbulent transfert coefficients of surface
60      !!                fluxes according to Large & Yeager (2004) and Large & Yeager (2008)
61      !!                If relevant (zt /= zu), adjust temperature and humidity from height zt to zu
62      !!                Returns the effective bulk wind speed at 10m to be used in the bulk formulas
63      !!
64      !! ** Method : Monin Obukhov Similarity Theory
65      !!             + Large & Yeager (2004,2008) closure: CD_n10 = f(U_n10)
66      !!
67      !! ** References :   Large & Yeager, 2004 / Large & Yeager, 2008
68      !!
69      !! ** Last update: Laurent Brodeau, June 2014:
70      !!    - handles both cases zt=zu and zt/=zu
71      !!    - optimized: less 2D arrays allocated and less operations
72      !!    - better first guess of stability by checking air-sea difference of virtual temperature
73      !!       rather than temperature difference only...
74      !!    - added function "cd_neutral_10m" that uses the improved parametrization of
75      !!      Large & Yeager 2008. Drag-coefficient reduction for Cyclone conditions!
76      !!    - using code-wide physical constants defined into "phycst.mod" rather than redifining them
77      !!      => 'vkarmn' and 'grav'
78      !!
79      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
80      !!
81      !! INPUT :
82      !! -------
83      !!    *  zt   : height for temperature and spec. hum. of air            [m]
84      !!    *  zu   : height for wind speed (generally 10m)                   [m]
85      !!    *  U_zu : scalar wind speed at 10m                                [m/s]
86      !!    *  sst  : SST                                                     [K]
87      !!    *  t_zt : potential air temperature at zt                         [K]
88      !!    *  ssq  : specific humidity at saturation at SST                  [kg/kg]
89      !!    *  q_zt : specific humidity of air at zt                          [kg/kg]
90      !!
91      !!
92      !! OUTPUT :
93      !! --------
94      !!    *  Cd     : drag coefficient
95      !!    *  Ch     : sensible heat coefficient
96      !!    *  Ce     : evaporation coefficient
97      !!    *  t_zu   : pot. air temperature adjusted at wind height zu       [K]
98      !!    *  q_zu   : specific humidity of air        //                    [kg/kg]
99      !!    *  U_blk  : bulk wind at 10m                                      [m/s]
100      !!----------------------------------------------------------------------------------
101      REAL(wp), INTENT(in   )                     ::   zt       ! height for t_zt and q_zt                    [m]
102      REAL(wp), INTENT(in   )                     ::   zu       ! height for U_zu                             [m]
103      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   sst      ! sea surface temperature                [Kelvin]
104      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   t_zt     ! potential air temperature              [Kelvin]
105      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   ssq      ! sea surface specific humidity           [kg/kg]
106      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   q_zt     ! specific air humidity                   [kg/kg]
107      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj) ::   U_zu     ! relative wind module at zu                [m/s]
108      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Cd       ! transfer coefficient for momentum         (tau)
109      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ch       ! transfer coefficient for sensible heat (Q_sens)
110      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   Ce       ! transfert coefficient for evaporation   (Q_lat)
111      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   t_zu     ! pot. air temp. adjusted at zu               [K]
112      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   q_zu     ! spec. humidity adjusted at zu           [kg/kg]
113      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj) ::   U_blk    ! bulk wind at 10m                          [m/s]
114      !
115      INTEGER ::   j_itt
116      LOGICAL ::   l_zt_equal_zu = .FALSE.      ! if q and t are given at same height as U
117      INTEGER , PARAMETER ::   nb_itt = 4       ! number of itterations
118      !
119      REAL(wp), DIMENSION(:,:), POINTER ::   Cx_n10        ! 10m neutral latent/sensible coefficient
120      REAL(wp), DIMENSION(:,:), POINTER ::   sqrt_Cd_n10   ! root square of Cd_n10
121      REAL(wp), DIMENSION(:,:), POINTER ::   zeta_u        ! stability parameter at height zu
122      REAL(wp), DIMENSION(:,:), POINTER ::   zpsi_h_u
123      REAL(wp), DIMENSION(:,:), POINTER ::   ztmp0, ztmp1, ztmp2
124      REAL(wp), DIMENSION(:,:), POINTER ::   stab          ! stability test integer
125      !!----------------------------------------------------------------------------------
126      !
127      IF( nn_timing == 1 )   CALL timing_start('turb_ncar')
128      !
129      CALL wrk_alloc( jpi,jpj,   Cx_n10, sqrt_Cd_n10, zeta_u, stab )
130      CALL wrk_alloc( jpi,jpj,   zpsi_h_u, ztmp0, ztmp1, ztmp2 )
131      !
132      l_zt_equal_zu = .FALSE.
133      IF( ABS(zu - zt) < 0.01 ) l_zt_equal_zu = .TRUE.    ! testing "zu == zt" is risky with double precision
134
135      U_blk = MAX( 0.5 , U_zu )   !  relative wind speed at zu (normally 10m), we don't want to fall under 0.5 m/s
136
137      !! First guess of stability:
138      ztmp0 = t_zt*(1. + rctv0*q_zt) - sst*(1. + rctv0*ssq) ! air-sea difference of virtual pot. temp. at zt
139      stab  = 0.5 + sign(0.5,ztmp0)                           ! stab = 1 if dTv > 0  => STABLE, 0 if unstable
140
141      !! Neutral coefficients at 10m:
142      IF( ln_cdgw ) THEN      ! wave drag case
143         cdn_wave(:,:) = cdn_wave(:,:) + rsmall * ( 1._wp - tmask(:,:,1) )
144         ztmp0   (:,:) = cdn_wave(:,:)
145      ELSE
146         ztmp0 = cd_neutral_10m( U_blk )
147      ENDIF
148
149      sqrt_Cd_n10 = SQRT( ztmp0 )
150
151      !! Initializing transf. coeff. with their first guess neutral equivalents :
152      Cd = ztmp0
153      Ce = 1.e-3*( 34.6 * sqrt_Cd_n10 )
154      Ch = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab))
155      stab = sqrt_Cd_n10   ! Temporaty array !!! stab == SQRT(Cd)
156
157      !! Initializing values at z_u with z_t values:
158      t_zu = t_zt   ;   q_zu = q_zt
159
160      !!  * Now starting iteration loop
161      DO j_itt=1, nb_itt
162         !
163         ztmp1 = t_zu - sst   ! Updating air/sea differences
164         ztmp2 = q_zu - ssq
165
166         ! Updating turbulent scales :   (L&Y 2004 eq. (7))
167         ztmp1  = Ch/stab*ztmp1    ! theta*   (stab == SQRT(Cd))
168         ztmp2  = Ce/stab*ztmp2    ! q*       (stab == SQRT(Cd))
169
170         ztmp0 = 1. + rctv0*q_zu      ! multiply this with t and you have the virtual temperature
171
172         ! Estimate the inverse of Monin-Obukov length (1/L) at height zu:
173         ztmp0 =  (grav*vkarmn/(t_zu*ztmp0)*(ztmp1*ztmp0 + rctv0*t_zu*ztmp2)) / (Cd*U_blk*U_blk)
174         !                                                      ( Cd*U_blk*U_blk is U*^2 at zu )
175
176         !! Stability parameters :
177         zeta_u   = zu*ztmp0   ;  zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
178         zpsi_h_u = psi_h( zeta_u )
179
180         !! Shifting temperature and humidity at zu (L&Y 2004 eq. (9b-9c))
181         IF( .NOT. l_zt_equal_zu ) THEN
182            !! Array 'stab' is free for the moment so using it to store 'zeta_t'
183            stab = zt*ztmp0 ;  stab = SIGN( MIN(ABS(stab),10.0), stab )  ! Temporaty array stab == zeta_t !!!
184            stab = LOG(zt/zu) + zpsi_h_u - psi_h(stab)                   ! stab just used as temp array again!
185            t_zu = t_zt - ztmp1/vkarmn*stab    ! ztmp1 is still theta*  L&Y 2004 eq.(9b)
186            q_zu = q_zt - ztmp2/vkarmn*stab    ! ztmp2 is still q*      L&Y 2004 eq.(9c)
187            q_zu = max(0., q_zu)
188         END IF
189
190         ztmp2 = psi_m(zeta_u)
191         IF( ln_cdgw ) THEN      ! surface wave case
192            stab = vkarmn / ( vkarmn / sqrt_Cd_n10 - ztmp2 )  ! (stab == SQRT(Cd))
193            Cd      = stab * stab
194         ELSE
195            ! Update neutral wind speed at 10m and neutral Cd at 10m (L&Y 2004 eq. 9a)...
196            !   In very rare low-wind conditions, the old way of estimating the
197            !   neutral wind speed at 10m leads to a negative value that causes the code
198            !   to crash. To prevent this a threshold of 0.25m/s is imposed.
199            ztmp0 = MAX( 0.25 , U_blk/(1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - ztmp2)) ) ! U_n10 (ztmp2 == psi_m(zeta_u))
200            ztmp0 = cd_neutral_10m(ztmp0)                                               ! Cd_n10
201            sqrt_Cd_n10 = sqrt(ztmp0)
202
203            stab    = 0.5 + sign(0.5,zeta_u)                           ! update stability
204            Cx_n10  = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab))  ! L&Y 2004 eq. (6c-6d)    (Cx_n10 == Ch_n10)
205
206            !! Update of transfer coefficients:
207            ztmp1 = 1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - ztmp2)   ! L&Y 2004 eq. (10a) (ztmp2 == psi_m(zeta_u))
208            Cd      = ztmp0 / ( ztmp1*ztmp1 )
209            stab = SQRT( Cd ) ! Temporary array !!! (stab == SQRT(Cd))
210         ENDIF
211
212         ztmp0 = (LOG(zu/10.) - zpsi_h_u) / vkarmn / sqrt_Cd_n10
213         ztmp2 = stab / sqrt_Cd_n10   ! (stab == SQRT(Cd))
214         ztmp1 = 1. + Cx_n10*ztmp0    ! (Cx_n10 == Ch_n10)
215         Ch  = Cx_n10*ztmp2 / ztmp1   ! L&Y 2004 eq. (10b)
216
217         Cx_n10  = 1.e-3 * (34.6 * sqrt_Cd_n10)  ! L&Y 2004 eq. (6b)    ! Cx_n10 == Ce_n10
218         ztmp1 = 1. + Cx_n10*ztmp0
219         Ce  = Cx_n10*ztmp2 / ztmp1  ! L&Y 2004 eq. (10c)
220
221      END DO
222
223      CALL wrk_dealloc( jpi,jpj,   Cx_n10, sqrt_Cd_n10, zeta_u, stab )
224      CALL wrk_dealloc( jpi,jpj,   zpsi_h_u, ztmp0, ztmp1, ztmp2 )
225
226      IF( nn_timing == 1 )   CALL timing_stop('turb_ncar')
227
228   END SUBROUTINE turb_ncar
229
230
231   FUNCTION cd_neutral_10m( pw10 )
232      !!----------------------------------------------------------------------------------     
233      !! Estimate of the neutral drag coefficient at 10m as a function
234      !! of neutral wind  speed at 10m
235      !!
236      !! Origin: Large & Yeager 2008 eq.(11a) and eq.(11b)
237      !!
238      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
239      !!----------------------------------------------------------------------------------
240      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pw10           ! scalar wind speed at 10m (m/s)
241      REAL(wp), DIMENSION(jpi,jpj)             :: cd_neutral_10m
242      !
243      INTEGER  ::     ji, jj     ! dummy loop indices
244      REAL(wp) :: zgt33, zw, zw6 ! local scalars
245      !!----------------------------------------------------------------------------------
246      !
247      DO jj = 1, jpj
248         DO ji = 1, jpi
249            !
250            zw  = pw10(ji,jj)
251            zw6 = zw*zw*zw
252            zw6 = zw6*zw6
253            !
254            ! When wind speed > 33 m/s => Cyclone conditions => special treatment
255            zgt33 = 0.5 + SIGN( 0.5, (zw - 33.) )   ! If pw10 < 33. => 0, else => 1
256            !
257            cd_neutral_10m(ji,jj) = 1.e-3 * ( &
258               &       (1. - zgt33)*( 2.7/zw + 0.142 + zw/13.09 - 3.14807E-10*zw6) & ! wind <  33 m/s
259               &      +    zgt33   *      2.34 )                                     ! wind >= 33 m/s
260            !
261            cd_neutral_10m(ji,jj) = MAX(cd_neutral_10m(ji,jj), 1.E-6)
262            !
263         END DO
264      END DO
265      !
266   END FUNCTION cd_neutral_10m
267
268
269   FUNCTION psi_m( pzeta )
270      !!----------------------------------------------------------------------------------
271      !! Universal profile stability function for momentum
272      !!    !! Psis, L&Y 2004 eq. (8c), (8d), (8e)
273      !!     
274      !! pzet0 : stability paramenter, z/L where z is altitude measurement                                         
275      !!         and L is M-O length
276      !!
277      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
278      !!----------------------------------------------------------------------------------
279      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pzeta
280      REAL(wp), DIMENSION(jpi,jpj)             ::   psi_m
281      !
282      INTEGER  ::   ji, jj         ! dummy loop indices
283      REAL(wp) :: zx2, zx, zstab   ! local scalars
284      !!----------------------------------------------------------------------------------
285      !
286      DO jj = 1, jpj
287         DO ji = 1, jpi
288            zx2 = SQRT( ABS( 1. - 16.*pzeta(ji,jj) ) )
289            zx2 = MAX ( zx2 , 1. )
290            zx  = SQRT( zx2 )
291            zstab = 0.5 + SIGN( 0.5 , pzeta(ji,jj) )
292            !
293            psi_m(ji,jj) =        zstab  * (-5.*pzeta(ji,jj))       &          ! Stable
294               &          + (1. - zstab) * (2.*LOG((1. + zx)*0.5)   &          ! Unstable
295               &               + LOG((1. + zx2)*0.5) - 2.*ATAN(zx) + rpi*0.5)  !    "
296            !
297         END DO
298      END DO
299      !
300   END FUNCTION psi_m
301
302
303   FUNCTION psi_h( pzeta )
304      !!----------------------------------------------------------------------------------
305      !! Universal profile stability function for temperature and humidity
306      !!    !! Psis, L&Y 2004 eq. (8c), (8d), (8e)
307      !!
308      !! pzet0 : stability paramenter, z/L where z is altitude measurement                                         
309      !!         and L is M-O length
310      !!
311      !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk)
312      !!----------------------------------------------------------------------------------
313      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta
314      REAL(wp), DIMENSION(jpi,jpj)             :: psi_h
315      !
316      INTEGER  ::   ji, jj    ! dummy loop indices
317      REAL(wp) :: zx2, zstab  ! local scalars
318      !!----------------------------------------------------------------------------------
319      !
320      DO jj = 1, jpj
321         DO ji = 1, jpi
322            zx2 = SQRT( ABS( 1. - 16.*pzeta(ji,jj) ) )
323            zx2 = MAX ( zx2 , 1. )
324            zstab = 0.5 + SIGN( 0.5 , pzeta(ji,jj) )
325            !
326            psi_h(ji,jj) =         zstab  * (-5.*pzeta(ji,jj))        &  ! Stable
327               &           + (1. - zstab) * (2.*LOG( (1. + zx2)*0.5 ))   ! Unstable
328            !
329         END DO
330      END DO
331      !
332   END FUNCTION psi_h
333
334   !!======================================================================
335END MODULE sbcblk_algo_ncar
Note: See TracBrowser for help on using the repository browser.