New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcfwb.F90 @ 2777

Last change on this file since 2777 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 10.5 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   sbc_fwb      : freshwater budget for global ocean configurations
14   !!                  in free surface and forced mode
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface ocean boundary condition
19   USE phycst          ! physical constants
20   USE sbcrnf          ! ocean runoffs
21   USE sbcssr          ! SS damping terms
22   USE in_out_manager  ! I/O manager
23   USE lib_mpp         ! distribued memory computing library
24   USE lbclnk          ! ocean lateral boundary conditions
25   USE lib_fortran
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   sbc_fwb    ! routine called by step
31
32   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
33   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
34   REAL(wp) ::   fwfold    ! fwfold to be suppressed
35   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
48      !!---------------------------------------------------------------------
49      !!                  ***  ROUTINE sbc_fwb  ***
50      !!
51      !! ** Purpose :   Control the mean sea surface drift
52      !!
53      !! ** Method  :   several ways  depending on kn_fwb
54      !!                =0 no control
55      !!                =1 global mean of emp set to zero at each nn_fsbc time step
56      !!                =2 annual global mean corrected from previous year
57      !!                =3 global mean of emp set to zero at each nn_fsbc time step
58      !!                   & spread out over erp area depending its sign
59      !!----------------------------------------------------------------------
60      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
61      USE wrk_nemo, ONLY:   ztmsk_neg      => wrk_2d_1 , ztmsk_pos => wrk_2d_2
62      USE wrk_nemo, ONLY:   ztmsk_tospread => wrk_2d_3
63      USE wrk_nemo, ONLY:   z_wgt          => wrk_2d_4 , zerp_cor  => wrk_2d_5
64      !
65      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
66      INTEGER, INTENT( in ) ::   kn_fsbc  !
67      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
68      !
69      INTEGER  ::   inum, ikty, iyear   ! local integers
70      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp   ! local scalars
71      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread    !   -      -
72      !!----------------------------------------------------------------------
73      !
74      IF( wrk_in_use(2, 1,2,3,4,5) ) THEN
75         CALL ctl_stop('sbc_fwb: requested workspace arrays are unavailable')   ;   RETURN
76      ENDIF
77      !
78      IF( kt == nit000 ) THEN
79         IF(lwp) THEN
80            WRITE(numout,*)
81            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
82            WRITE(numout,*) '~~~~~~~'
83            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
84            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
85            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
86         ENDIF
87         !
88         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
89         !
90         area = glob_sum( e1e2t(:,:) )           ! interior global domain surface
91      ENDIF
92     
93
94      SELECT CASE ( kn_fwb )
95      !
96      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
97         !
98         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
99            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area   ! sum over the global domain
100            emp (:,:) = emp (:,:) - z_fwf 
101            emps(:,:) = emps(:,:) - z_fwf 
102         ENDIF
103         !
104      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
105         !
106         IF( kt == nit000 ) THEN                   ! initialisation
107            !                                         ! Read the corrective factor on precipitations (fwfold)
108            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
109            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
110            CLOSE( inum )
111            fwfold = a_fwb                            ! current year freshwater budget correction
112            !                                         ! estimate from the previous year budget
113            IF(lwp)WRITE(numout,*)
114            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
115            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
116            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
117         ENDIF   
118         !                                         ! Update fwfold if new year start
119         ikty = 365 * 86400 / rdttra(1)    !!bug  use of 365 days leap year or 360d year !!!!!!!
120         IF( MOD( kt, ikty ) == 0 ) THEN
121            a_fwb_b = a_fwb
122            a_fwb   = glob_sum( e1e2t(:,:) * sshn(:,:) )   ! sum over the global domain
123            a_fwb   = a_fwb * 1.e+3 / ( area * 86400. * 365. )     ! convert in Kg/m3/s = mm/s
124!!gm        !                                                      !!bug 365d year
125            fwfold =  a_fwb                           ! current year freshwater budget correction
126            !                                         ! estimate from the previous year budget
127         ENDIF
128         !
129         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN      ! correct the freshwater fluxes
130            emp (:,:) = emp (:,:) + fwfold
131            emps(:,:) = emps(:,:) + fwfold
132         ENDIF
133         !
134         IF( kt == nitend .AND. lwp ) THEN         ! save fwfold value in a file
135            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
136            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
137            CLOSE( inum )
138         ENDIF
139         !
140      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
141         !
142         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
143            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
144            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
145            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
146            !
147            zsurf_neg = glob_sum( e1e2t(:,:)*ztmsk_neg(:,:) )   ! Area filled by <0 and >0 erp
148            zsurf_pos = glob_sum( e1e2t(:,:)*ztmsk_pos(:,:) )
149            !                                                  ! fwf global mean
150            z_fwf = glob_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) ) ) / area
151            !           
152            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
153                zsurf_tospread      = zsurf_pos
154                ztmsk_tospread(:,:) = ztmsk_pos(:,:)
155            ELSE                             ! spread out over <0 erp area to increase precipitation
156                zsurf_tospread      = zsurf_neg
157                ztmsk_tospread(:,:) = ztmsk_neg(:,:)
158            ENDIF
159            !
160            zsum_fwf   = glob_sum( e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
161!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
162            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
163            !                                                  ! weight to respect erp field 2D structure
164            zsum_erp = glob_sum( ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
165            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
166            !                                                  ! final correction term to apply
167            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
168            !
169!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
170            CALL lbc_lnk( zerp_cor, 'T', 1. )
171            !
172            emp (:,:) = emp (:,:) + zerp_cor(:,:)
173            emps(:,:) = emps(:,:) + zerp_cor(:,:)
174            erp (:,:) = erp (:,:) + zerp_cor(:,:)
175            !
176            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
177               IF( z_fwf < 0._wp ) THEN
178                  WRITE(numout,*)'   z_fwf < 0'
179                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
180               ELSE
181                  WRITE(numout,*)'   z_fwf >= 0'
182                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
183               ENDIF
184               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
185               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
186               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
187               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
188               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
189            ENDIF
190         ENDIF
191         !
192      CASE DEFAULT                           !==  you should never be there  ==!
193         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
194         !
195      END SELECT
196      !
197      IF( wrk_not_released(2, 1,2,3,4,5) )   CALL ctl_stop('sbc_fwb: failed to release workspace arrays')
198      !
199   END SUBROUTINE sbc_fwb
200
201   !!======================================================================
202END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.