New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 8524

Last change on this file since 8524 was 8524, checked in by cbricaud, 7 years ago

bugfix in trunk for ticket #1922

  • Property svn:keywords set to Id
File size: 32.6 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_init      : read namsbc namelist
21   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
22   !!   sbc_final     : Finalize CICE ice model (if used)
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean dynamics and tracers
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE trc_oce        ! shared ocean-passive tracers variables
29   USE sbc_ice        ! Surface boundary condition: ice fields
30   USE sbcdcy         ! surface boundary condition: diurnal cycle
31   USE sbcssm         ! surface boundary condition: sea-surface mean variables
32   USE sbcflx         ! surface boundary condition: flux formulation
33   USE sbcblk         ! surface boundary condition: bulk formulation
34   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
35   USE sbcice_lim     ! surface boundary condition: LIM 3.0 sea-ice model
36   USE sbcice_lim_2   ! surface boundary condition: LIM 2.0 sea-ice model
37   USE sbcice_cice    ! surface boundary condition: CICE    sea-ice model
38   USE sbcisf         ! surface boundary condition: ice-shelf
39   USE sbccpl         ! surface boundary condition: coupled formulation
40   USE cpl_oasis3     ! OASIS routines for coupling
41   USE sbcssr         ! surface boundary condition: sea surface restoring
42   USE sbcrnf         ! surface boundary condition: runoffs
43   USE sbcapr         ! surface boundary condition: atmo pressure
44   USE sbcisf         ! surface boundary condition: ice shelf
45   USE sbcfwb         ! surface boundary condition: freshwater budget
46   USE icbstp         ! Icebergs
47   USE traqsr         ! active tracers: light penetration
48   USE sbcwave        ! Wave module
49   USE bdy_oce   , ONLY: ln_bdy
50   USE usrdef_sbc     ! user defined: surface boundary condition
51   USE usrdef_closea  ! user defined: closed sea
52   !
53   USE prtctl         ! Print control                    (prt_ctl routine)
54   USE iom            ! IOM library
55   USE in_out_manager ! I/O manager
56   USE lib_mpp        ! MPP library
57   USE timing         ! Timing
58
59   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
60
61   IMPLICIT NONE
62   PRIVATE
63
64   PUBLIC   sbc        ! routine called by step.F90
65   PUBLIC   sbc_init   ! routine called by opa.F90
66
67   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
68
69   !!----------------------------------------------------------------------
70   !! NEMO/OPA 4.0 , NEMO-consortium (2016)
71   !! $Id$
72   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE sbc_init
77      !!---------------------------------------------------------------------
78      !!                    ***  ROUTINE sbc_init ***
79      !!
80      !! ** Purpose :   Initialisation of the ocean surface boundary computation
81      !!
82      !! ** Method  :   Read the namsbc namelist and set derived parameters
83      !!                Call init routines for all other SBC modules that have one
84      !!
85      !! ** Action  : - read namsbc parameters
86      !!              - nsbc: type of sbc
87      !!----------------------------------------------------------------------
88      INTEGER ::   ios, icpt                         ! local integer
89      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
90      !!
91      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
92         &             ln_usr   , ln_flx   , ln_blk       ,                          &
93         &             ln_cpl   , ln_mixcpl, nn_components, nn_limflx,               &
94         &             nn_ice   , nn_ice_embd,                                       &
95         &             ln_traqsr, ln_dm2dc ,                                         &
96         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_isf    , ln_apr_dyn ,     &
97         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauoc  , ln_stcor   ,     &
98         &             nn_lsm
99      !!----------------------------------------------------------------------
100      !
101      IF(lwp) THEN
102         WRITE(numout,*)
103         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
104         WRITE(numout,*) '~~~~~~~~ '
105      ENDIF
106      !
107      !                       !**  read Surface Module namelist
108      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
109      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
110901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
111      !
112      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
113      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
114902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
115      IF(lwm) WRITE( numond, namsbc )
116      !
117      !                             !* overwrite namelist parameter using CPP key information
118#if defined key_agrif
119      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
120         IF( lk_lim2 )   nn_ice      = 2
121         IF( lk_lim3 )   nn_ice      = 3
122         IF( lk_cice )   nn_ice      = 4
123      ENDIF
124#else
125      IF( lk_lim2 )   nn_ice      = 2
126      IF( lk_lim3 )   nn_ice      = 3
127      IF( lk_cice )   nn_ice      = 4
128#endif
129      !
130      IF(lwp) THEN                  !* Control print
131         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
132         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
133         WRITE(numout,*) '      Type of air-sea fluxes : '
134         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
135         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
136         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
137         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
138         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
139         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
140!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
141         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
142         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
143         WRITE(numout,*) '         Multicategory heat flux formulation (LIM3) nn_limflx     = ', nn_limflx
144         WRITE(numout,*) '      Sea-ice : '
145         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
146         WRITE(numout,*) '         ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd   = ', nn_ice_embd
147         WRITE(numout,*) '      Misc. options of sbc : '
148         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
149         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
150         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
151         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
152         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
153         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
154         WRITE(numout,*) '         iceshelf formulation                       ln_isf        = ', ln_isf
155         WRITE(numout,*) '         closed sea (=0/1) (set in namdom)          nn_closea     = ', nn_closea
156         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
157         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
158         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
159         WRITE(numout,*) '               wave modified ocean stress           ln_tauoc      = ', ln_tauoc
160         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
161         WRITE(numout,*) '               neutral drag coefficient (CORE, MFS) ln_cdgw       = ', ln_cdgw
162      ENDIF
163      !
164      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
165         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
166         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
167         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
168      ENDIF
169      !                       !**  check option consistency
170      !
171      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
172      SELECT CASE( nn_components )
173      CASE( jp_iam_nemo )
174         IF(lwp) WRITE(numout,*) '   NEMO configured as a single executable (i.e. including both OPA and Surface module'
175      CASE( jp_iam_opa  )
176         IF(lwp) WRITE(numout,*) '   Multi executable configuration. Here, OPA component'
177         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
178         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
179         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
180      CASE( jp_iam_sas  )
181         IF(lwp) WRITE(numout,*) '   Multi executable configuration. Here, SAS component'
182         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
183         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
184      CASE DEFAULT
185         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
186      END SELECT
187      !                             !* coupled options
188      IF( ln_cpl ) THEN
189         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
190            &                                  '           required to defined key_oasis3' )
191      ENDIF
192      IF( ln_mixcpl ) THEN
193         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
194            &                                  '           required to defined key_oasis3' )
195         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
196         IF( nn_components /= jp_iam_nemo )    &
197            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
198            &                                   '          not yet working with sas-opa coupling via oasis' )
199      ENDIF
200      !                             !* sea-ice
201      SELECT CASE( nn_ice )
202      CASE( 0 )                        !- no ice in the domain
203      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
204      CASE( 2 )                        !- LIM2 ice model
205         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : LIM2 sea-ice model requires ln_blk or ln_cpl = T' )
206      CASE( 3 )                        !- LIM3 ice model
207         IF( nn_ice_embd == 0            )   CALL ctl_stop( 'sbc_init : LIM3 sea-ice models require nn_ice_embd = 1 or 2' )
208      CASE( 4 )                        !- CICE ice model
209         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' )
210         IF( nn_ice_embd == 0            )   CALL ctl_stop( 'sbc_init : CICE sea-ice models require nn_ice_embd = 1 or 2' )
211         IF( lk_agrif                    )   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
212      CASE DEFAULT                     !- not supported
213      END SELECT
214      !
215      IF( nn_ice == 3 ) THEN           !- LIM3 case: multi-category flux option
216         IF(lwp) WRITE(numout,*)
217         SELECT CASE( nn_limflx )         ! LIM3 Multi-category heat flux formulation
218         CASE ( -1 )
219            IF(lwp) WRITE(numout,*) '   LIM3: use per-category fluxes (nn_limflx = -1) '
220            IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
221         CASE ( 0  )
222            IF(lwp) WRITE(numout,*) '   LIM3: use average per-category fluxes (nn_limflx = 0) '
223         CASE ( 1  )
224            IF(lwp) WRITE(numout,*) '   LIM3: use average then redistribute per-category fluxes (nn_limflx = 1) '
225            IF( ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
226         CASE ( 2  )
227            IF(lwp) WRITE(numout,*) '   LIM3: Redistribute a single flux over categories (nn_limflx = 2) '
228            IF( .NOT.ln_cpl )   CALL ctl_stop( 'sbc_init : the chosen nn_limflx for LIM3 in forced mode cannot be 2' )
229         CASE DEFAULT
230            CALL ctl_stop( 'sbcmod: LIM3 option, nn_limflx, should be between -1 and 2' )
231         END SELECT
232      ELSE                             ! other sea-ice model
233         IF( nn_limflx >= 0  )   CALL ctl_warn( 'sbc_init : multi-category flux option (nn_limflx) only available in LIM3' )
234      ENDIF
235      !
236      !                       !**  allocate and set required variables
237      !
238      !                             !* allocate sbc arrays
239      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
240      !
241      IF( .NOT.ln_isf ) THEN        !* No ice-shelf in the domain : allocate and set to zero
242         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
243         fwfisf  (:,:)   = 0._wp   ;   risf_tsc  (:,:,:) = 0._wp
244         fwfisf_b(:,:)   = 0._wp   ;   risf_tsc_b(:,:,:) = 0._wp
245      END IF
246      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
247         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
248      ENDIF
249      !
250      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
251      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
252
253      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
254
255      !                          ! Choice of the Surface Boudary Condition (set nsbc)
256      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
257         nday_qsr = -1   ! allow initialization at the 1st call
258         IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa )   &
259            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' )
260      ENDIF
261      !                             !* Choice of the Surface Boudary Condition
262      !                             (set nsbc)
263      !
264      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
265      ll_opa      = nn_components == jp_iam_opa
266      ll_not_nemo = nn_components /= jp_iam_nemo
267      icpt = 0
268      !
269      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
270      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
271      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
272      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
273      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
274      !
275      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
276      !
277      IF(lwp) THEN                     !- print the choice of surface flux formulation
278         WRITE(numout,*)
279         SELECT CASE( nsbc )
280         CASE( jp_usr     )   ;   WRITE(numout,*) '   user defined formulation'
281         CASE( jp_flx     )   ;   WRITE(numout,*) '      ===>>   flux formulation'
282         CASE( jp_blk     )   ;   WRITE(numout,*) '      ===>>   bulk formulation'
283         CASE( jp_purecpl )   ;   WRITE(numout,*) '      ===>>   pure coupled formulation'
284!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
285         CASE( jp_none    )   ;   WRITE(numout,*) '      ===>>   OPA coupled to SAS via oasis'
286            IF( ln_mixcpl )       WRITE(numout,*) '                  + forced-coupled mixed formulation'
287         END SELECT
288         IF( ll_not_nemo  )       WRITE(numout,*) '                  + OASIS coupled SAS'
289      ENDIF
290      !
291      !                             !* OASIS initialization
292      !
293      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
294      !                                              !                      (2) the use of nn_fsbc
295      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
296      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
297      IF( nn_components /= jp_iam_nemo ) THEN
298         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
299         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
300         !
301         IF(lwp)THEN
302            WRITE(numout,*)
303            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
304            WRITE(numout,*)
305         ENDIF
306      ENDIF
307      !
308      !                             !* check consistency between model timeline and nn_fsbc
309      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
310          MOD( nstock             , nn_fsbc) /= 0 ) THEN
311         WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
312            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
313         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
314      ENDIF
315      !
316      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
317         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
318      !
319      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
320         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
321      !
322   
323      !                       !**  associated modules : initialization
324      !
325                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
326      !
327      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
328
329      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
330      !
331      IF( ln_isf      )   CALL sbc_isf_init               ! Compute iceshelves
332      !
333                          CALL sbc_rnf_init            ! Runof initialization
334      !
335      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
336      !
337      IF( nn_ice == 3 )   CALL sbc_lim_init            ! LIM3 initialization
338      !
339      IF( nn_ice == 4 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
340      !
341      IF( ln_wave     )   CALL sbc_wave_init              ! surface wave initialisation
342      !
343   END SUBROUTINE sbc_init
344
345
346   SUBROUTINE sbc( kt )
347      !!---------------------------------------------------------------------
348      !!                    ***  ROUTINE sbc  ***
349      !!
350      !! ** Purpose :   provide at each time-step the ocean surface boundary
351      !!                condition (momentum, heat and freshwater fluxes)
352      !!
353      !! ** Method  :   blah blah  to be written ?????????
354      !!                CAUTION : never mask the surface stress field (tke sbc)
355      !!
356      !! ** Action  : - set the ocean surface boundary condition at before and now
357      !!                time step, i.e.
358      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
359      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
360      !!              - updte the ice fraction : fr_i
361      !!----------------------------------------------------------------------
362      INTEGER, INTENT(in) ::   kt   ! ocean time step
363      !
364      LOGICAL ::   ll_sas, ll_opa   ! local logical
365      !!---------------------------------------------------------------------
366      !
367      IF( nn_timing == 1 )  CALL timing_start('sbc')
368      !
369      !                                            ! ---------------------------------------- !
370      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
371         !                                         ! ---------------------------------------- !
372         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
373         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
374         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
375         emp_b (:,:) = emp (:,:)
376         sfx_b (:,:) = sfx (:,:)
377         IF ( ln_rnf ) THEN
378            rnf_b    (:,:  ) = rnf    (:,:  )
379            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
380         ENDIF
381         IF( ln_isf )  THEN
382            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
383            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
384         ENDIF
385        !
386      ENDIF
387      !                                            ! ---------------------------------------- !
388      !                                            !        forcing field computation         !
389      !                                            ! ---------------------------------------- !
390      !
391      ll_sas = nn_components == jp_iam_sas               ! component flags
392      ll_opa = nn_components == jp_iam_opa
393      !
394      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
395      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
396
397      !
398      !                                            !==  sbc formulation  ==!
399      !                                                   
400      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
401      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
402      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
403      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
404      CASE( jp_blk     )
405         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
406                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
407                               !
408      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
409      CASE( jp_none    )
410         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
411      END SELECT
412      IF ( ln_wave .AND. ln_tauoc) THEN                                 ! Wave stress subctracted
413            utau(:,:) = utau(:,:)*tauoc_wave(:,:)
414            vtau(:,:) = vtau(:,:)*tauoc_wave(:,:)
415            taum(:,:) = taum(:,:)*tauoc_wave(:,:)
416      !
417            SELECT CASE( nsbc )
418            CASE(  0,1,2,3,5,-1 )  ;
419                IF(lwp .AND. kt == nit000 ) WRITE(numout,*) 'WARNING: You are subtracting the wave stress to the ocean. &
420                        & If not requested select ln_tauoc=.false'
421            END SELECT
422      !
423      END IF
424      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
425
426      !
427      !                                            !==  Misc. Options  ==!
428      !
429      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
430      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
431      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
432      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
433      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
434      END SELECT
435
436      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
437
438      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
439
440      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
441
442      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
443
444      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
445
446      ! treatment of closed sea in the model domain   (update freshwater fluxes)
447      ! Should not be ran if ln_diurnal_only
448      IF( .NOT.ln_diurnal_only .AND. nn_closea == 1 )   CALL sbc_clo( kt, cn_cfg, nn_cfg )   
449
450!RBbug do not understand why see ticket 667
451!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
452      CALL lbc_lnk( emp, 'T', 1. )
453      !
454      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
455         !                                             ! ---------------------------------------- !
456         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
457            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
458            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
459            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
460            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
461            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
462            ! The 3D heat content due to qsr forcing is treated in traqsr
463            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
464            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
465            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
466            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
467               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
468            ELSE
469               sfx_b (:,:) = sfx(:,:)
470            ENDIF
471         ELSE                                                   !* no restart: set from nit000 values
472            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
473            utau_b(:,:) = utau(:,:)
474            vtau_b(:,:) = vtau(:,:)
475            qns_b (:,:) = qns (:,:)
476            emp_b (:,:) = emp (:,:)
477            sfx_b (:,:) = sfx (:,:)
478         ENDIF
479      ENDIF
480      !                                                ! ---------------------------------------- !
481      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
482         !                                             ! ---------------------------------------- !
483         IF(lwp) WRITE(numout,*)
484         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
485            &                    'at it= ', kt,' date= ', ndastp
486         IF(lwp) WRITE(numout,*) '~~~~'
487         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
488         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
489         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
490         ! The 3D heat content due to qsr forcing is treated in traqsr
491         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
492         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
493         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx  )
494      ENDIF
495      !                                                ! ---------------------------------------- !
496      !                                                !        Outputs and control print         !
497      !                                                ! ---------------------------------------- !
498      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
499         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
500         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
501         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
502         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
503         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
504         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
505         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
506         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
507         CALL iom_put( "taum"  , taum       )                   ! wind stress module
508         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
509      ENDIF
510      !
511      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
512      CALL iom_put( "vtau", vtau )   ! j-wind stress
513      !
514      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
515         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask, ovlap=1 )
516         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 )
517         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 )
518         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
519         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
520         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
521         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
522         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
523         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
524            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
525      ENDIF
526
527      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
528      !
529      IF( nn_timing == 1 )  CALL timing_stop('sbc')
530      !
531   END SUBROUTINE sbc
532
533
534   SUBROUTINE sbc_final
535      !!---------------------------------------------------------------------
536      !!                    ***  ROUTINE sbc_final  ***
537      !!
538      !! ** Purpose :   Finalize CICE (if used)
539      !!---------------------------------------------------------------------
540      !
541      IF( nn_ice == 4 )   CALL cice_sbc_final
542      !
543   END SUBROUTINE sbc_final
544
545   !!======================================================================
546END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.